Sorry your browser is not supported!

Rem * Title  : Simple 3DS Converter
Rem * Author : DBS-LB
Rem * Date   : 25th November 1999
rem Simple 3DS to X Converter
rem By Popular Demand :)

rem Set viewing font
set text size 30
set text font "Arial"

rem Greetings
cls rgb(0,0,100)
ink rgB(255,255,0),rgb(0,0,100)
print "DB> Very Simple 3DS Converter (Version 1.3)"
print "DB> "
print "DB> This program will scan the current directory and convert any 3DS files"
print "DB> to X files. The original files will not be affected during this process.."
print "DB> "
print "DB> Enter C to continue, A for all or Q to quit."
a$="" : while a$<>"c" and a$<>"a" and a$<>"q" : a$=lower$(inkey$()) : endwhile
if a$="q" then end
if a$="a" then donotwaitforkeypress=1
`
rem Scan current directory and convert/show files
cls
print "Scanning for 3DS files.." : print
find first : find next : find next
type=get file type()
scline=0
while type<>-1

 rem Get file name
 name$=get file name$()

 rem List files
 print "Found File: ";name$
 scline=scline+1

 rem Only if 3DS file, convert it..
 if lower$(right$(name$,4))=".3ds"

   rem Construct X filename
   newname$=left$(name$,len(name$)-4)
   newname$=newname$+".x"

   rem Convert file
   if file exist(newname$)=0
      print "Converting ";name$;" to ";newname$
      3ds2x name$,newname$
   else
      print "The file ";newname$;" already exists. Cannot overwrite!"
   endif
   scline=scline+1

   rem Store screen
   get image 1,0,0,640,480

   rem Show file
   sync on
   backdrop on
   load object newname$,1
   range=object size(1)*6
   if range<2 then range=2
   set camera range 1,range
   if total object frames(1)>1 then loop object 1
   while inkey$()="" and donotwaitforkeypress=0

      rem Spin object
      rotate object 1,wrapvalue(object angle x(1)+0.5),wrapvalue(object angle y(1)+3.0),wrapvalue(object angle y(1)+1.0)

      rem Wait for user to continue
      center text 320,410,"VIEWING: "+newname$
      center text 320,440,"PRESS KEY TO CONTINUE"

      rem Update screen
      sync

   endwhile
   sync off

   rem Delete object
   delete object 1
   backdrop off

   rem Restore screen
   paste image 1,0,0

 endif

 rem New Page
 if scline>25 : cls : scline=0 : endif

 rem Next file
 find next
 type=get file type()

endwhile
print "done." : print
print "Press Any Key to Quit"
wait key
end