Keep Moving - GameCreators Forum

Author

Message

BeastDeath

15

Years of Service

User Offline

Joined: 7th Jul 2011

Location:

Posted: 20th May 2012 23:01 Edited at: 20th May 2012 23:03

Link

Hello everyone, I was wondering how I'd make the current code (credit to hodgey) to always go forward from the position? WITHOUT using any of the dark automatic functions such as move object or move sprite?

An example would be that the point the object needs to travel is at a mouse cursor position, but it needs to keep going forward like a bullet.

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

+ Code Snippet

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

Back to top

Profile PM

zeroSlave

17

Years of Service

User Offline

Joined: 13th Jun 2009

Location: Springfield

Posted: 20th May 2012 23:58

Link

Not sure if you mean that the red circle should always be at the mouse cursor's position, or if the red shape should move towards the mouse cursor's position.

The former would be something like this:

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float
hide mouse
do
    mX = mouseX()
    mY = mouseY()
    player.x = mX
    player.y = mY
    cls

// get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use mouse to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

+ Code Snippet

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float
hide mouse
do
    mX = mouseX()
    mY = mouseY()
    player.x = mX
    player.y = mY
    cls

    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use mouse to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

Everybody is a genius. But if you judge a fish by its ability to climb a tree, it will live its whole life believing that it is stupid.

Back to top

Profile PM Email

chafari

Valued Member

20

Years of Service

User Offline

Joined: 2nd May 2006

Location: Canary Islands

Posted: 21st May 2012 06:06

Link

Hi there
Like zeroSlave, I can't figure out what you mean with keeping going forward like a bullet. Your piece of code use a function that increase or decrease x,y values to follow the other circle....here you don't use any command to point from one object to the other. You can do it using newxvalue, newyvalue depending on an given angle.

+ Code Snippet

x#=200
y#=-300

do
`increasing values
x#=newxvalue(x#,a#,0.2)
y#=newzvalue(y#,a#,0.2)

`turning
if leftkey()=1 THEN a#=a#-0.5
if rightkey()=1 then a#=a#+0.5

cls
set cursor 5,5
print "left/right to drive circle"

circle x#,-y#,8

sync
loop]

Cheers.

I'm not a grumpy grandpa

Back to top

Profile PM Email

BeastDeath

15

Years of Service

User Offline

Joined: 7th Jul 2011

Location:

Posted: 21st May 2012 09:35 Edited at: 21st May 2012 09:36

Link

What I mean is, if I clicked once on the screen, the circle will go to that position as well as continuing in the same direction to keep going like a bullet would, this could be easily achieved with move sprite or move object but how would I do it with the maths like above?

Back to top

Profile PM

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 21st May 2012 14:16

Link

Like chafari pointed out, the commands you need are:

newxvalue
newzvalue

So the new positions of the bullet can be calculated by:

+ Code Snippet

NewX# = newxvalue( CurrentX# , CurrentAngle# , CurrentSpeed# )
NewY# = newzvalue( CurrentY# , CurrentAngle# , CurrentSpeed# )

paste sprite BulletSPR , NewX# , NewY#

TheComet

TimePlan : https://docs.google.com/spreadsheet/ccc?key=0AmuAKJolqASndEVYOWMxb3l2OWV0UkV1anRSczZScHc

Back to top

Profile PM Email Website

BeastDeath

15

Years of Service

User Offline

Joined: 7th Jul 2011

Location:

Posted: 21st May 2012 22:55

Link

Thanks for the help everybody, but how would I do this without using any automatic functions? I want to use only maths such as COS, TAN etc?

Back to top

Profile PM

Diggsey

20

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 22nd May 2012 01:49

Link

I can't remember which way around it is, but the new_value commands are equivalent to sin/cos:

newxvalue( Current# , Angle# , Speed# )
newzvalue( Current# , Angle# , Speed# )

are equivalent to (order/signs may be wrong):

Current# + sin(Angle#)*Speed#
Current# + cos(Angle#)*Speed#

[b]

Back to top

Profile PM Email Website

zeroSlave

17

Years of Service

User Offline

Joined: 13th Jun 2009

Location: Springfield

Posted: 22nd May 2012 10:50 Edited at: 22nd May 2012 11:16

Link

Take a look at this code:

sync on
sync rate 60

`Set up our global variables
global ScreenWidth
global ScreenHeight
global CannonX
global CannonY
global Speed# = 5.0
ScreenWidth = Screen Width()
ScreenHeight = Screen Height()
CannonX = ScreenWidth / 2
CannonY = ScreenHeight / 2

`Create a new User Defined Type and Arraylist
Type Bullet
    X# as float
    Y# as float
    XSpeed# as float
    YSpeed# as float
EndType
Dim BulletList() as Bullet

do
    cls
    mX = mouseX()
    mY = mouseY()

if mouseclick() then New_Bullet(mX, mY)
    
    Bullet_Update()
    Render_Cannon(mX, mY)
    Render_HUD()
    
    `Control cannon's position with WASD keys
    CannonX = CannonX + keystate(32) - keystate(30)
    CannonY = CannonY + keystate(31) - keystate(17)
    
    sync
loop

end

`Add a bullet to our array and store the information needed to travel to and beyond mouse position
function New_Bullet(mX as integer, mY as integer)
    array insert at bottom BulletList()
    Angle# = atanfull(mX - CannonX, mY - CannonY)
    BulletList().X# = CannonX
    BulletList().Y# = CannonY
    BulletList().XSpeed# = (sin(Angle#) * Speed#)
    BulletList().YSpeed# = (cos(Angle#) * Speed#)
endfunction

`Update our bullet's position, draw it to the screen, and remove it from the list if it exceeds the screen's bounds
function Bullet_Update()
    array index to top BulletList()
    ink rgb(255,0,0), 0
    while array index valid(BulletList())
        inc BulletList().X#, BulletList().XSpeed#
        inc BulletList().Y#, BulletList().YSpeed#
        circle int(BulletList().X#), int(BulletList().Y#), 1
        if BulletList().X# > ScreenWidth || BulletList().X# < 0 || BulletList().Y# > ScreenHeight || BulletList().Y# < 0 then array delete element BulletList()
        next array index BulletList()
    endwhile
endfunction

`Draw our cannon
function Render_Cannon(mX as integer, mY as integer)
    ink rgb(255,255,255), 0
    CannonAngle# = atanfull(mX - CannonX, mY - CannonY)
    CannonPointX = (sin(CannonAngle#) * 10) + CannonX
    CannonPointY = (cos(CannonAngle#) * 10) + CannonY
    line CannonX, CannonY, CannonPointX, CannonPointY
    circle CannonX, CannonY, 3
endfunction

`Place text on the screen
function Render_HUD()
    set cursor 0,0 
    Print "Screen FPS: " + str$(screen fps())
    Print "Total bullets on screen: " + str$(Array Count(BulletList()) + 1)
    Print "Use WASD keys to move the cannon. Click in the screen to shoot the cannon"
endfunction

+ Code Snippet

sync on
sync rate 60

`Set up our global variables
global ScreenWidth
global ScreenHeight
global CannonX
global CannonY
global Speed# = 5.0
ScreenWidth = Screen Width()
ScreenHeight = Screen Height()
CannonX = ScreenWidth / 2
CannonY = ScreenHeight / 2

`Create a new User Defined Type and Arraylist
Type Bullet
    X# as float
    Y# as float
    XSpeed# as float
    YSpeed# as float
EndType
Dim BulletList() as Bullet

do
    cls
    mX = mouseX()
    mY = mouseY()

    if mouseclick() then New_Bullet(mX, mY)
    
    Bullet_Update()
    Render_Cannon(mX, mY)
    Render_HUD()
    
    `Control cannon's position with WASD keys
    CannonX = CannonX + keystate(32) - keystate(30)
    CannonY = CannonY + keystate(31) - keystate(17)
    
    sync
loop

end


`Add a bullet to our array and store the information needed to travel to and beyond mouse position
function New_Bullet(mX as integer, mY as integer)
    array insert at bottom BulletList()
    Angle# = atanfull(mX - CannonX, mY - CannonY)
    BulletList().X# = CannonX
    BulletList().Y# = CannonY
    BulletList().XSpeed# = (sin(Angle#) * Speed#)
    BulletList().YSpeed# = (cos(Angle#) * Speed#)
endfunction

`Update our bullet's position, draw it to the screen, and remove it from the list if it exceeds the screen's bounds
function Bullet_Update()
    array index to top BulletList()
    ink rgb(255,0,0), 0
    while array index valid(BulletList())
        inc BulletList().X#, BulletList().XSpeed#
        inc BulletList().Y#, BulletList().YSpeed#
        circle int(BulletList().X#), int(BulletList().Y#), 1
        if BulletList().X# > ScreenWidth || BulletList().X# < 0 || BulletList().Y# > ScreenHeight || BulletList().Y# < 0 then array delete element BulletList()
        next array index BulletList()
    endwhile
endfunction

`Draw our cannon
function Render_Cannon(mX as integer, mY as integer)
    ink rgb(255,255,255), 0
    CannonAngle# = atanfull(mX - CannonX, mY - CannonY)
    CannonPointX = (sin(CannonAngle#) * 10) + CannonX
    CannonPointY = (cos(CannonAngle#) * 10) + CannonY
    line CannonX, CannonY, CannonPointX, CannonPointY
    circle CannonX, CannonY, 3
endfunction

`Place text on the screen
function Render_HUD()
    set cursor 0,0 
    Print "Screen FPS: " + str$(screen fps())
    Print "Total bullets on screen: " + str$(Array Count(BulletList()) + 1)
    Print "Use WASD keys to move the cannon. Click in the screen to shoot the cannon"
endfunction

It's a little movable turret that shoot towards the mouse cursor. If the bullet's velocity does not change, you would only need to use sin/cos/atan when the bullet is created which would save some resources. The math you'll use and the data you'll want to store is:

+ Code Snippet

Angle# = atanfull(mX - CannonX, mY - CannonY)
BulletList().X# = CannonX
BulletList().Y# = CannonY
BulletList().XSpeed# = (sin(Angle#) * Speed#)
BulletList().YSpeed# = (cos(Angle#) * Speed#)

Then you can move the bullet by adding its 'speed' to it's current position:

+ Code Snippet

inc BulletList().X#, BulletList().XSpeed#
inc BulletList().Y#, BulletList().YSpeed#

Then to draw it:

+ Code Snippet

circle int(BulletList().X#), int(BulletList().Y#), 1

Hope this helps.

Everybody is a genius. But if you judge a fish by its ability to climb a tree, it will live its whole life believing that it is stupid.

Back to top

Profile PM Email

BeastDeath

15

Years of Service

User Offline

Joined: 7th Jul 2011

Location:

Posted: 23rd May 2012 15:50

Link

Just what I was looking for, thanks everyone for the help

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Keep Moving