Swiping left to right for next page

Author

Message

Doveyy04

12

Years of Service

User Offline

Joined: 30th Apr 2012

Location:

Posted: 12th Jun 2012 18:53

Link

On my program I have a set of pages of various info and to get from one page to the next I have a left and flipped right png image that u click on to go forward and back. How do you get the program to eventually be able to change page by swiping across the screen? Also like the weather app on the iPhone I want a set number of small circles that individually light up (fill up) showing what page you are on, how could I do that, thanks for your help

Back to top

Profile PM

Ancient Lady

Valued Member

20

Years of Service

User Offline

Joined: 17th Mar 2004

Location: Anchorage, Alaska, USA

Posted: 12th Jun 2012 19:56 Edited at: 12th Jun 2012 19:58

Link

The following code was posted in this thread: http://forum.thegamecreators.com/?m=forum_view&t=195049&b=41

Global _UCFSwipeRightTime as Float
Global _UCFSwipeRightX as Integer
Global _UCFSwipeLeftTime as Float
Global _UCFSwipeLeftX as Integer

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )

do
    If GetSwipeRight( 0.1, 30 ) = 1 then Flag$ = "You Swiped Right"
    If GetSwipeLeft( 0.1, 30 ) = 1 then Flag$ = "You Swiped Left"
    If GetRawKeyPressed( 27 ) = 1 then END
    Print(Flag$)
 Sync()
loop

Function GetSwipeRight( t#, d )

Output = 0

If GetPointerPressed() = 1
        _UCFSwipeRightX = GetPointerX() + d
        _UCFSwipeRightTime = Timer() + t#
    EndIf

If GetPointerState() = 1 and _UCFSwipeRightTime < Timer() and _UCFSwipeRightX < GetPointerX()
        _UCFSwipeRightTime = 0
        Output = 1
    EndIf

EndFunction Output

Function GetSwipeLeft( t#, d )

Output = 0

If GetPointerPressed() = 1
        _UCFSwipeLeftX = GetPointerX() - d
        _UCFSwipeLeftTime = Timer() + t#
    EndIf

If GetPointerState() = 1 and _UCFSwipeLeftTime < Timer() and _UCFSwipeLeftX > GetPointerX()
        _UCFSwipeLeftTime = 0
        Output = 1
    EndIf

EndFunction Output

+ Code Snippet

Global _UCFSwipeRightTime as Float
Global _UCFSwipeRightX as Integer
Global _UCFSwipeLeftTime as Float
Global _UCFSwipeLeftX as Integer

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )

do
    If GetSwipeRight( 0.1, 30 ) = 1 then Flag$ = "You Swiped Right"
    If GetSwipeLeft( 0.1, 30 ) = 1 then Flag$ = "You Swiped Left"
    If GetRawKeyPressed( 27 ) = 1 then END
    Print(Flag$)
 Sync()
loop

Function GetSwipeRight( t#, d )

    Output = 0

    If GetPointerPressed() = 1
        _UCFSwipeRightX = GetPointerX() + d
        _UCFSwipeRightTime = Timer() + t#
    EndIf

    If GetPointerState() = 1 and _UCFSwipeRightTime < Timer() and _UCFSwipeRightX < GetPointerX()
        _UCFSwipeRightTime = 0
        Output = 1
    EndIf

EndFunction Output

Function GetSwipeLeft( t#, d )

    Output = 0

    If GetPointerPressed() = 1
        _UCFSwipeLeftX = GetPointerX() - d
        _UCFSwipeLeftTime = Timer() + t#
    EndIf

    If GetPointerState() = 1 and _UCFSwipeLeftTime < Timer() and _UCFSwipeLeftX > GetPointerX()
        _UCFSwipeLeftTime = 0
        Output = 1
    EndIf

EndFunction Output

It appears to work just fine. I tested it on my touch screen in Windows.

As for the dots, create a simple white circle image file and then the correct number of sprites for your pages and set the color for the the page number to something different from the the colors for the others.

Cheers,
Ancient Lady

Back to top

Profile PM

Ancient Lady

Valued Member

20

Years of Service

User Offline

Joined: 17th Mar 2004

Location: Anchorage, Alaska, USA

Posted: 12th Jun 2012 21:43 Edited at: 12th Jun 2012 21:54

Link

I just took some of the other bits in the same post and tweaked a bit:

// I know dim 15 works, but I'm old-school with zero based arrays
dim _UCF_Swiped[16] AS string
_UCF_Swiped[0] = "No swipe - b0000"
_UCF_Swiped[1] = "Right - b0001"
_UCF_Swiped[2] = "Left - b0010"
_UCF_Swiped[3] = "No swipe - b0011"
_UCF_Swiped[4] = "Down - b0100"
_UCF_Swiped[5] = "Down-Right - b0101"
_UCF_Swiped[6] = "Down-Left - b0110"
_UCF_Swiped[7] = "No swipe - b0111"
_UCF_Swiped[8] = "Up - b1000"
_UCF_Swiped[9] = "Up-Right - b1001"
_UCF_Swiped[10] = "Up-Left - b1010"
_UCF_Swiped[11] = "No swipe - b1011"
_UCF_Swiped[12] = "No swipe - b1100"
_UCF_Swiped[13] = "No swipe - b1101"
_UCF_Swiped[14] = "No swipe - b1110"
_UCF_Swiped[15] = "No swipe - b1111"

Global _UCFSwipeTime as float
Global _UCFSwipeRightX as Integer
Global _UCFSwipeLeftX as Integer
Global _UCFSwipeUpY as Integer
Global _UCFSwipeDownY as Integer

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )
SetSyncRate(60,0)
lastmsg$ = ""
do
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()
	swiped = GetSwipeInfo(0.1,30)
	if swiped > 0
		// set the message
		lastmsg$ = _UCF_Swiped[swiped]

// do logical ands to check for specific swipe types
		if swiped && 1 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"right"
		if swiped && 2 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"left"
		if swiped && 4 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"down"
		if swiped && 8 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"up"
	endif
	print("use escape key to exit")
	print(lastmsg$)
	if GetRawKeyPressed( 27 ) = 1 then end
	Sync()
loop

function GetSwipeInfo(t#, d)
	// assume no swipe
	swiped = 0

// get the current pointer position and time
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()

// check for newly pressed
	if GetPointerPressed() = 1
		// get the current state
		_UCFSwipeRightX = x# + d
		_UCFSwipeLeftX = x# - d
		_UCFSwipeDownY = y# + d
		_UCFSwipeUpY = y# - d
		_UCFSwipeTime = n# + t#

// done
		exitfunction 0
	endif

// check for still pressed
	if GetPointerReleased() = 1
		if _UCFSwipeTime < n#
			// check for left/right directions
			if x# > _UCFSwipeRightX
				swiped = swiped + 1
			elseif x# < _UCFSwipeLeftX
				swiped = swiped + 2
			endif

// check for change up/down directions
			if y# > _UCFSwipeDownY
				swiped = swiped + 4
			elseif y# < _UCFSwipeUpY
				swiped = swiped + 8
			endif

// clear if swiped
			if swiped > 0
				// clear everything
				_UCFSwipeTime = 0
			endif
		endif
	endif
endfunction swiped

+ Code Snippet

// I know dim 15 works, but I'm old-school with zero based arrays
dim _UCF_Swiped[16] AS string
_UCF_Swiped[0] = "No swipe - b0000"
_UCF_Swiped[1] = "Right - b0001"
_UCF_Swiped[2] = "Left - b0010"
_UCF_Swiped[3] = "No swipe - b0011"
_UCF_Swiped[4] = "Down - b0100"
_UCF_Swiped[5] = "Down-Right - b0101"
_UCF_Swiped[6] = "Down-Left - b0110"
_UCF_Swiped[7] = "No swipe - b0111"
_UCF_Swiped[8] = "Up - b1000"
_UCF_Swiped[9] = "Up-Right - b1001"
_UCF_Swiped[10] = "Up-Left - b1010"
_UCF_Swiped[11] = "No swipe - b1011"
_UCF_Swiped[12] = "No swipe - b1100"
_UCF_Swiped[13] = "No swipe - b1101"
_UCF_Swiped[14] = "No swipe - b1110"
_UCF_Swiped[15] = "No swipe - b1111"

Global _UCFSwipeTime as float
Global _UCFSwipeRightX as Integer
Global _UCFSwipeLeftX as Integer
Global _UCFSwipeUpY as Integer
Global _UCFSwipeDownY as Integer

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )
SetSyncRate(60,0)
lastmsg$ = ""
do
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()
	swiped = GetSwipeInfo(0.1,30)
	if swiped > 0
		// set the message
		lastmsg$ = _UCF_Swiped[swiped]

		// do logical ands to check for specific swipe types
		if swiped && 1 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"right"
		if swiped && 2 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"left"
		if swiped && 4 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"down"
		if swiped && 8 then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"up"
	endif
	print("use escape key to exit")
	print(lastmsg$)
	if GetRawKeyPressed( 27 ) = 1 then end
	Sync()
loop

function GetSwipeInfo(t#, d)
	// assume no swipe
	swiped = 0

	// get the current pointer position and time
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()

	// check for newly pressed
	if GetPointerPressed() = 1
		// get the current state
		_UCFSwipeRightX = x# + d
		_UCFSwipeLeftX = x# - d
		_UCFSwipeDownY = y# + d
		_UCFSwipeUpY = y# - d
		_UCFSwipeTime = n# + t#

		// done
		exitfunction 0
	endif

	// check for still pressed
	if GetPointerReleased() = 1
		if _UCFSwipeTime < n#
			// check for left/right directions
			if x# > _UCFSwipeRightX
				swiped = swiped + 1
			elseif x# < _UCFSwipeLeftX
				swiped = swiped + 2
			endif

			// check for change up/down directions
			if y# > _UCFSwipeDownY
				swiped = swiped + 4
			elseif y# < _UCFSwipeUpY
				swiped = swiped + 8
			endif

			// clear if swiped
			if swiped > 0
				// clear everything
				_UCFSwipeTime = 0
			endif
		endif
	endif
endfunction swiped

EDIT: updated code to show how to logically AND the results to check for specific swipe.

Cheers,
Ancient Lady

Back to top

Profile PM

Ancient Lady

Valued Member

20

Years of Service

User Offline

Joined: 17th Mar 2004

Location: Anchorage, Alaska, USA

Posted: 12th Jun 2012 22:10

Link

And here is an 'encapsulated' version:

TYPE tSwiped
	swipe_time AS float
	swipe_rX AS integer
	swipe_lX AS integer
	swipe_dY AS integer
	swipe_uY AS integer
	did_swipe AS integer
	all_swipe AS integer
	swipe_lft AS integer
	swipe_rgt AS integer
	swipe_dn AS integer
	swipe_up AS integer
ENDTYPE
global g_Swipe AS tSwiped

// I know dim 15 works, but I'm old-school with zero based arrays
dim g_SwipeStates[16] AS string
g_SwipeStates[0] = "No swipe - b0000"
g_SwipeStates[1] = "Right - b0001"
g_SwipeStates[2] = "Left - b0010"
g_SwipeStates[3] = "No swipe - b0011"
g_SwipeStates[4] = "Down - b0100"
g_SwipeStates[5] = "Down-Right - b0101"
g_SwipeStates[6] = "Down-Left - b0110"
g_SwipeStates[7] = "No swipe - b0111"
g_SwipeStates[8] = "Up - b1000"
g_SwipeStates[9] = "Up-Right - b1001"
g_SwipeStates[10] = "Up-Left - b1010"
g_SwipeStates[11] = "No swipe - b1011"
g_SwipeStates[12] = "No swipe - b1100"
g_SwipeStates[13] = "No swipe - b1101"
g_SwipeStates[14] = "No swipe - b1110"
g_SwipeStates[15] = "No swipe - b1111"

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )
SetSyncRate(60,0)
lastmsg$ = ""
do
	// check for swiped
	if GetSwipeInfo(0.1,30) > 0
		// set the message
		lastmsg$ = g_SwipeStates[g_Swipe.all_swipe]

// do logical ands to check for specific swipe types
		if g_Swipe.swipe_rgt then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"right"
		if g_Swipe.swipe_lft then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"left"
		if g_Swipe.swipe_dn then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"down"
		if g_Swipe.swipe_up then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"up"
	endif
	print("use escape key to exit")
	print(lastmsg$)
	if GetRawKeyPressed( 27 ) = 1 then end
	Sync()
loop

function GetSwipeInfo(t#, d)
	// assume no swipe
	g_Swipe.all_swipe = 0
	g_Swipe.swipe_lft = 0
	g_Swipe.swipe_rgt = 0
	g_Swipe.swipe_dn = 0
	g_Swipe.swipe_up = 0

// get the current pointer position and time
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()

// check for newly pressed
	if GetPointerPressed() = 1
		// get the current state
		g_Swipe.swipe_time = n# + t#
		g_Swipe.swipe_rX = x# + d
		g_Swipe.swipe_lX = x# - d
		g_Swipe.swipe_dY = y# + d
		g_Swipe.swipe_uY = y# - d

// done
		exitfunction 0
	endif

// check for still pressed
	if GetPointerReleased() = 1
		if g_Swipe.swipe_time < n#
			// check for left/right directions
			if x# > g_Swipe.swipe_rX
				g_Swipe.all_swipe = g_Swipe.all_swipe + 1
				g_Swipe.swipe_rgt = 1
			elseif x# < g_Swipe.swipe_lX
				g_Swipe.all_swipe = g_Swipe.all_swipe + 2
				g_Swipe.swipe_lft = 1
			endif

// check for change up/down directions
			if y# > g_Swipe.swipe_dY
				g_Swipe.all_swipe = g_Swipe.all_swipe + 4
				g_Swipe.swipe_dn = 1
			elseif y# < g_Swipe.swipe_uY
				g_Swipe.all_swipe = g_Swipe.all_swipe + 8
				g_Swipe.swipe_up = 1
			endif

// clear if swiped
			if g_Swipe.all_swipe > 0
				// clear everything
				g_Swipe.swipe_time = 0
			endif
		endif
	endif
endfunction g_Swipe.all_swipe

+ Code Snippet

TYPE tSwiped
	swipe_time AS float
	swipe_rX AS integer
	swipe_lX AS integer
	swipe_dY AS integer
	swipe_uY AS integer
	did_swipe AS integer
	all_swipe AS integer
	swipe_lft AS integer
	swipe_rgt AS integer
	swipe_dn AS integer
	swipe_up AS integer
ENDTYPE
global g_Swipe AS tSwiped

// I know dim 15 works, but I'm old-school with zero based arrays
dim g_SwipeStates[16] AS string
g_SwipeStates[0] = "No swipe - b0000"
g_SwipeStates[1] = "Right - b0001"
g_SwipeStates[2] = "Left - b0010"
g_SwipeStates[3] = "No swipe - b0011"
g_SwipeStates[4] = "Down - b0100"
g_SwipeStates[5] = "Down-Right - b0101"
g_SwipeStates[6] = "Down-Left - b0110"
g_SwipeStates[7] = "No swipe - b0111"
g_SwipeStates[8] = "Up - b1000"
g_SwipeStates[9] = "Up-Right - b1001"
g_SwipeStates[10] = "Up-Left - b1010"
g_SwipeStates[11] = "No swipe - b1011"
g_SwipeStates[12] = "No swipe - b1100"
g_SwipeStates[13] = "No swipe - b1101"
g_SwipeStates[14] = "No swipe - b1110"
g_SwipeStates[15] = "No swipe - b1111"

SetVirtualResolution( 1024, 600 )
SetDisplayAspect( 1024 / 600 )
SetSyncRate(60,0)
lastmsg$ = ""
do
	// check for swiped
	if GetSwipeInfo(0.1,30) > 0
		// set the message
		lastmsg$ = g_SwipeStates[g_Swipe.all_swipe]

		// do logical ands to check for specific swipe types
		if g_Swipe.swipe_rgt then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"right"
		if g_Swipe.swipe_lft then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"left"
		if g_Swipe.swipe_dn then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"down"
		if g_Swipe.swipe_up then lastmsg$ = lastmsg$ + chr(10)+chr(10)+"up"
	endif
	print("use escape key to exit")
	print(lastmsg$)
	if GetRawKeyPressed( 27 ) = 1 then end
	Sync()
loop

function GetSwipeInfo(t#, d)
	// assume no swipe
	g_Swipe.all_swipe = 0
	g_Swipe.swipe_lft = 0
	g_Swipe.swipe_rgt = 0
	g_Swipe.swipe_dn = 0
	g_Swipe.swipe_up = 0

	// get the current pointer position and time
	x# = GetPointerX()
	y# = GetPointerY()
	n# = Timer()

	// check for newly pressed
	if GetPointerPressed() = 1
		// get the current state
		g_Swipe.swipe_time = n# + t#
		g_Swipe.swipe_rX = x# + d
		g_Swipe.swipe_lX = x# - d
		g_Swipe.swipe_dY = y# + d
		g_Swipe.swipe_uY = y# - d

		// done
		exitfunction 0
	endif

	// check for still pressed
	if GetPointerReleased() = 1
		if g_Swipe.swipe_time < n#
			// check for left/right directions
			if x# > g_Swipe.swipe_rX
				g_Swipe.all_swipe = g_Swipe.all_swipe + 1
				g_Swipe.swipe_rgt = 1
			elseif x# < g_Swipe.swipe_lX
				g_Swipe.all_swipe = g_Swipe.all_swipe + 2
				g_Swipe.swipe_lft = 1
			endif

			// check for change up/down directions
			if y# > g_Swipe.swipe_dY
				g_Swipe.all_swipe = g_Swipe.all_swipe + 4
				g_Swipe.swipe_dn = 1
			elseif y# < g_Swipe.swipe_uY
				g_Swipe.all_swipe = g_Swipe.all_swipe + 8
				g_Swipe.swipe_up = 1
			endif

			// clear if swiped
			if g_Swipe.all_swipe > 0
				// clear everything
				g_Swipe.swipe_time = 0
			endif
		endif
	endif
endfunction g_Swipe.all_swipe

Cheers,
Ancient Lady

Back to top

Profile PM

Sorry your browser is not supported!

AppGameKit Classic Chat / Swiping left to right for next page