Looking for Inertia Help - GameCreators Forum

Author

Message

Marabas

15

Years of Service

User Offline

Joined: 12th Dec 2010

Location:

Posted: 26th Jun 2012 22:57 Edited at: 26th Jun 2012 23:13

Link

OK I have looked at the other posts involving inertia and they seemed a little complex for me so I came up with a simple solution to double the speed until we arrive at maximum speed and do the opposite until we arrive back at idle speed.

This is what I have so far

global sc_spd#=0.001
set display mode 800, 600, 32
sx=desktop width()
sy=desktop height()
set window position (sx-800)/2, (sy-600)/2
sync on : sync rate 60 : color backdrop 0 : hide mouse

` as you can see the background is simply a textured plain
load image "bg1.png",1
make object plain 1,800,600
texture object 1,1
position camera 0,0,-300

` My initial idea was to half or double the movement speed each sync but that doesn't seem to work
do
    sc_spd#=0.001
    
    if (rightkey()=1) or (leftkey()=1) or (upkey()=1) or (downkey()=1)
        sc_spd# = sc_spd# * 2.0
        if sc_spd# > 0.008 then sc_spd# = 0.008 ` 0.008 is max speed
    ENDIF
    
    if (rightkey()<>1) and (leftkey()<>1) and (upkey()<>1) and (downkey()<>1)
        sc_spd# = sc_spd# / 2.0
        if sc_spd# < 0.001 then sc_spd# = 0.001 ` 0.001 is min speed
    ENDIF
        
    if rightkey()=1 then scroll object texture 1,sc_spd#,0.0
    if leftkey()=1 then scroll object texture 1,0-sc_spd#,0.0
    if downkey()=1 then scroll object texture 1,0.0,sc_spd#
    if upkey()=1 then scroll object texture 1,0.0,0-sc_spd#
    
    ink rgb (255,255,0),0
    text 10, 10, str$(sc_spd#)
    
    
    
    sync
LOOP

+ Code Snippet

global sc_spd#=0.001
set display mode 800, 600, 32
sx=desktop width()
sy=desktop height()
set window position (sx-800)/2, (sy-600)/2
sync on : sync rate 60 : color backdrop 0 : hide mouse


` as you can see the background is simply a textured plain
load image "bg1.png",1
make object plain 1,800,600
texture object 1,1
position camera 0,0,-300

` My initial idea was to half or double the movement speed each sync but that doesn't seem to work
do
    sc_spd#=0.001
    
    if (rightkey()=1) or (leftkey()=1) or (upkey()=1) or (downkey()=1)
        sc_spd# = sc_spd# * 2.0
        if sc_spd# > 0.008 then sc_spd# = 0.008 ` 0.008 is max speed
    ENDIF
    
    if (rightkey()<>1) and (leftkey()<>1) and (upkey()<>1) and (downkey()<>1)
        sc_spd# = sc_spd# / 2.0
        if sc_spd# < 0.001 then sc_spd# = 0.001 ` 0.001 is min speed
    ENDIF
        
    if rightkey()=1 then scroll object texture 1,sc_spd#,0.0
    if leftkey()=1 then scroll object texture 1,0-sc_spd#,0.0
    if downkey()=1 then scroll object texture 1,0.0,sc_spd#
    if upkey()=1 then scroll object texture 1,0.0,0-sc_spd#
    
    ink rgb (255,255,0),0
    text 10, 10, str$(sc_spd#)
    
    
    
    sync
LOOP

The problem is that when I double the speed it will only do it once and then doesn't even bother to look if a key is pressed. How can I get it to double the speed each sync? I'm not worried aboutthe numbers for now because I will fiddle with the max and min values until they are right.

I have attached the background so you can try this if you are kind enough to help.

EDIT: I have just tried using keystate instead of scancode but still hit the same problem, the value only doubles once ???

Signature removed by moderator. Please do not give out the meaning of life in an open forum.

Back to top

Profile PM Email Website

Pincho Paxton

23

Years of Service

User Offline

Joined: 8th Dec 2002

Location:

Posted: 26th Jun 2012 23:16

Link

with this at the top ..... sc_spd#=0.001

You keep resetting the speed. You need to get rid of it from the loop, or not trigger it when a key is pressed.

Back to top

Profile PM Email Website

29 games

20

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 26th Jun 2012 23:18

Link

Hi Marabas

Delete the line "sc_spd#=0.001" after the DO and you'll reach maximum speed. It's reseting the value sc_spd# at the start of the loop and giving the issue you describe.

Once you've done this, you'll probably find that doubling the speed each loop is too fast so you'll have to play with the numbers to get a noticable accelertion..

Other options would be to use to use an addition formula i.e. speed = speed + constant_value or use the CURVEVALUE commands.

I can't give a preference as I don't have one. All that really counts is that you get a nice smooth effect.

Back to top

Profile PM Email

Marabas

15

Years of Service

User Offline

Joined: 12th Dec 2010

Location:

Posted: 26th Jun 2012 23:47 Edited at: 26th Jun 2012 23:56

Link

Thanks, I'm dumb sometimes...

My code has now kind of evolved to this

+ Code Snippet

do

    
    while rightkey()=1 
        sc_spd# = sc_spd# * 1.2
        if sc_spd# > 0.008 then sc_spd# = 0.008
        scroll object texture 1,sc_spd#,0.0
        sync
    endwhile
    
    while leftkey()=1 
        sc_spd# = sc_spd# * 1.2
        if sc_spd# > 0.008 then sc_spd# = 0.008
        scroll object texture 1,0-sc_spd#,0.0
        sync
    endwhile
 
    while downkey()=1 
        sc_spd# = sc_spd# * 1.2
        if sc_spd# > 0.008 then sc_spd# = 0.008
        scroll object texture 1,0.0,sc_spd#
        sync
    endwhile
    
    while upkey()=1 
        sc_spd# = sc_spd# * 1.2
        if sc_spd# > 0.008 then sc_spd# = 0.008
        scroll object texture 1,0.0,0-sc_spd#
        sync
    endwhile

 while (rightkey()<>1) and (leftkey()<>1) and (upkey()<>1) and (downkey()<>1)   
    sc_spd# = sc_spd# / 1.0001
    if (sc_spd# < 0.0001) or (sc_spd# > -0.0001) then sc_spd# = 0.0
    scroll object texture 1,sc_spd#,sc_spd#
    sync
 endwhile
    
    
    
    sync
LOOP

problem is that it just stops dead rather than slowing to a stop. I have tried all sorts of values to divide by but even at 1.0001 the scroll doesn't slow to a stop it just stops dead.

Any ideas why it might be doing this?

EDIT:
Hmmm CURVEVALUE looks like it could be useful, thank you 29 Games. I can understand the destination and current values but if I was using CURVEVALUE 0.001, 0.008, ?????? what might the speed value be? Or maybe I will experiment and report back

Signature removed by moderator. Please do not give out the meaning of life in an open forum.

Back to top

Profile PM Email Website

29 games

20

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 27th Jun 2012 00:28 Edited at: 27th Jun 2012 01:06

Link

With the formula you're using it will just stop dead. To illustrate:

If you start with speed = 1 then let's say you double the speed each loop, so speed = speed*2, then the speed increases like this:

1st loop: speed = 1
2nd loop: speed = 2
3rd loop: speed = 4
4th loop: speed = 8
5th loop: speed = 16
6th loop: speed = 32

and so on until the maximum speed is reached. But what you can see is that you get big leaps in speed toward the end, the speed is increasing exponentially. This is why the speed doesn't slowly reach the maximum value.

If you use: speed = speed + constant_value, you'll get a linear increase in speed. If the constant_value = 6 then:

1st loop: speed = 0
2nd loop: speed = 6
3rd loop: speed = 12
4th loop: speed = 18
5th loop: speed = 24
6th loop: speed = 32

If you want a big jump in speed at the start and then a slower increases as it reaches maximum speed:

1st loop: speed = 1
2nd loop: speed = 17
3rd loop: speed = 25
4th loop: speed = 29
5th loop: speed = 31
6th loop: speed = 32

then you need a different formula, which I can't quite get my head round at the moment [see edit at bottom of post]. However, the CURVEVALUE command will give you this effect.

+ Code Snippet

sync on
sync rate 60

max_speed# = 32

do

	cls

	if upkey() = 1
		speed# = curvevalue(max_speed#, speed#, 90)
	else
		speed# = curvevalue(0, speed#, 90)
	endif

	set cursor 0,0
	print "pess upkey to accelerate"
	print
	print "max_speed : ", max_speed#
	print
	print "speed# : ", speed#

	sync

loop

What you'll notice is that, what ever you change max_speed# to, it'll take the same amount of time to reach it. One thing to bare in mind is the the "speed value" of the curve value command needs to be high if you want a slow transition.

Edit: for the sake of completeness, the formula is: speed = speed + 0.5*(max_speed - speed + 1). Where, in this example, max_speed = 32.

Back to top

Profile PM Email

Marabas

15

Years of Service

User Offline

Joined: 12th Dec 2010

Location:

Posted: 27th Jun 2012 01:49

Link

WOW thank you so much, I have been fiddling with CURVEVALUE but couldn't get my head round it and the help files really don't, erm, help LOL

I will try to incorporate this into my code and see how it goes.

Signature removed by moderator. Please do not give out the meaning of life in an open forum.

Back to top

Profile PM Email Website

Marabas

15

Years of Service

User Offline

Joined: 12th Dec 2010

Location:

Posted: 27th Jun 2012 02:48

Link

OK, I got it now. I will post it here in case anyone else has a similar problem. Big thanks to 29 Games for helping me to solve this. It moved a long way from my original puny code.

Please note that this code only scrolls the texture background, you would have to add the speed# to your object to get it to move in the x or y directions. Anyway, here's the code, the texture is in the OP at the top.

set display mode 800, 600, 32
sx=desktop width()
sy=desktop height()
set window position (sx-800)/2, (sy-600)/2
sync on : sync rate 60 : color backdrop 0 : hide mouse

` as you can see the background is simply a textured plain
load image "bg1.png",1
make object plain 1,800,600
texture object 1,1
position camera 0,0,-300

global xspeed#=0.00
global yspeed#=0.00
global max_xspeed#=0.008
global max_yspeed#=0.008
global max_xnspeed#=-0.008
global max_ynspeed#=-0.008

do
    if rightkey()=1
        xspeed# = curvevalue(max_xspeed#, xspeed#, 90)
    endif

if leftkey()=1
        xspeed# = curvevalue(max_xnspeed#, xspeed#, 90)
    endif

if downkey()=1
        yspeed# = curvevalue(max_yspeed#, yspeed#, 90)
    endif

if upkey()=1
        yspeed# = curvevalue(max_ynspeed#, yspeed#, 90)
    endif

if leftkey()<>1 and rightkey()<>1 and upkey()<>1 and downkey()<>1
         xspeed# = curvevalue(0, xspeed#, 10)        
         yspeed# = curvevalue(0, yspeed#, 10)        
    endif
    
    
    
    scroll object texture 1, xspeed#, yspeed#
    text 10, 10, str$(xspeed#)+"    "+str$(yspeed#)
    sync
loop

+ Code Snippet

set display mode 800, 600, 32
sx=desktop width()
sy=desktop height()
set window position (sx-800)/2, (sy-600)/2
sync on : sync rate 60 : color backdrop 0 : hide mouse


` as you can see the background is simply a textured plain
load image "bg1.png",1
make object plain 1,800,600
texture object 1,1
position camera 0,0,-300

global xspeed#=0.00
global yspeed#=0.00
global max_xspeed#=0.008
global max_yspeed#=0.008
global max_xnspeed#=-0.008
global max_ynspeed#=-0.008

do
    if rightkey()=1
        xspeed# = curvevalue(max_xspeed#, xspeed#, 90)
    endif

    if leftkey()=1
        xspeed# = curvevalue(max_xnspeed#, xspeed#, 90)
    endif

    if downkey()=1
        yspeed# = curvevalue(max_yspeed#, yspeed#, 90)
    endif

    if upkey()=1
        yspeed# = curvevalue(max_ynspeed#, yspeed#, 90)
    endif

    if leftkey()<>1 and rightkey()<>1 and upkey()<>1 and downkey()<>1
         xspeed# = curvevalue(0, xspeed#, 10)        
         yspeed# = curvevalue(0, yspeed#, 10)        
    endif
    
    
    
    scroll object texture 1, xspeed#, yspeed#
    text 10, 10, str$(xspeed#)+"    "+str$(yspeed#)
    sync
loop

Signature removed by moderator. Please do not give out the meaning of life in an open forum.

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Looking for Inertia Help