Quote: "What I do need to know is how to use the mouse cursor to put items on the sphere where the mouse cursor is over at."
Is this what you mean?
sync on
sync rate 60
autocam off
`this variable is for object id management
num_objects = 0
`make the sphere
inc num_objects
sphere_object = num_objects
make object sphere num_objects, 100
position object num_objects, 0,0,0
`initial position of camera
position camera 0,0,-300
point camera 0,0,0
`main loop
do
`camere movement controls
move camera 2*(upkey() - downkey())
turn camera right (rightkey() - leftkey())
`get the current mouse position
mx = mousex()
my = mousey()
`place the cursor over the sphere
`press the left mouse button to place a cube on the sphere
if lmb = 0
if mouseclick() = 1
lmb = 1
`if the pick object the cursor is on the sphere
if pick object(mx,my,sphere_object,sphere_object) = sphere_object
`calculate the 3D coordinates of the cursor projected onto the sphere
xpos# = get pick vector x() + camera position x()
ypos# = get pick vector y() + camera position y()
zpos# = get pick vector z() + camera position z()
`create a cube object, position it and point it at the centre of the sphere
inc num_objects
make object cube num_objects, 10
color object num_objects, rgb(255,0,0)
position object num_objects, xpos#, ypos#, zpos#
point object num_objects, object position x(sphere_object), object position y(sphere_object), object position z(sphere_object)
endif
endif
endif
if mouseclick() = 0 then lmb = 0
set cursor 0,0
print "place cursor on sphere and press left mouse button to place a cube"
print "use arrow keys to move camera"
sync
loop
