Sorry your browser is not supported!

sync on
sync rate 60
hide mouse

screen_width = screen width()
screen_height = screen height()

gravity# = 0.05

gun_pos_x# = 10
gun_pos_y# = screen_height - 10
gun_angle# = 45.0

bullet_speed# = 5.0

do
	
	cls

	if bullet_fired = 0

		`if the bullet has not been fired then allow the player to adjust the angle of the gun
		`and to fired the gun.
				
		`controls
		if downkey() = 1 then dec gun_angle#, 0.5
		if gun_angle# < 0 then gun_angle# = 0
		if upkey() = 1 then inc gun_angle#, 0.5
		if gun_angle# > 90 then gun_angle# = 90
		
		`fire canon!!!!!!
		if spacekey() = 1
			
			`set the flag to show that the bullet has been fired
			bullet_fired = 1
			
			`bullet's initial position
			bullet_pos_x# = gun_pos_x#
			bullet_pos_y# = gun_pos_y#
			
			`initial velocity of the bullet split into x and y
			bullet_vel_x# = bullet_speed#*cos(gun_angle#)
			bullet_vel_y# = bullet_speed#*sin(gun_angle#)
	
		endif
	
	else
	
		`if the bullet has been fired then move the bullet
	
		`apply gravity to the bullet	
		bullet_vel_y# = bullet_vel_y# - gravity#
		
		`calculate the bullets position
		bullet_pos_x# = bullet_pos_x# + bullet_vel_x#
		bullet_pos_y# = bullet_pos_y# - bullet_vel_y#	:`note that in 2D position y is downward so we minus the velocity in order to move upward.
		
		`if the bullet goes off the screen then reset
		if bullet_pos_x# > screen_width or bullet_pos_y# > screen_height
			bullet_fired = 0
		endif
	
		`draw a circle for the bullet	
		circle bullet_pos_x#,bullet_pos_y#, 3
					
	endif

	`draw the gun	
	line gun_pos_x#,gun_pos_y#, gun_pos_x# + 20*cos(gun_angle#),gun_pos_y# - 20*sin(gun_angle#)
	circle gun_pos_x#,gun_pos_y#, 5


	set cursor 0,0
	print "use up and down arrow keys to angle gun"
	print "press space to shoot"

	sync

loop

sync on
sync rate 50
autocam off
randomize timer()
hide mouse
`Get the center of the screen
set display mode 800,600,32
cx# = screen width() / 2.0
cy# = screen height() / 2.0


`make the 'mouse'
make object box 1,2,2,2
color object 1,rgb(255,10,10)

`make base
Make object sphere 2,15
basex#=0
basey#=0
basez#=0
position object 2,basex#,basey#,basez#

`make crosshair
make object plain 3,10,10
xrotate object 3,90
hide object 3
fade object 3,2000
ghost object on 3

`make bullet
make object cube 4,5

`make target
make object cube 5,2
hide object 5

position camera 0,500,-10
point camera 0,0,0
position mouse cx#,cy#

`declare a few variables
speed# = 10
fire = 0
load = 0

do
`control the 3d mouse
position object 1,mousex()-400,0,-mousey()+300
` detect if mouseclick on base
pick = pick object (mousex(),mousey(),2,2)

`if you click the base get ready to fire
if pick = 2 and mouseclick() = 1 and fire = 0
load = 1
endif
`draw the line while holding the mouse button after clicking the base
if load = 1 and mouseclick() = 1
line cx#,cy#,mousex(),mousey()
targetx#=(mousex()-cx#)*-1
targety#=(mousey()-cy#)
position object 3,targetx#,0,targety#
show object 3
endif

`fire if user releases mouse
` position the target at the spot where the bullet will land
if load = 1 and mouseclick() = 0
fire = 1
load = 0
firex#=object position x(1)
firez#=object position z(1)
hitx#=object position x(3)
hitz#=object position z(3)
position object 5,hitx#,0,hitz#
targetx#=cx#
targety#=cy#
endif


`position bullet at 3d mouse and show it
if fire = 1
position object 4,firex#,0,firez#
show object 4
fire = 2
endif
` point the bullet at the target and move it forward
` check for dist between bullet and target and kill bullet when close enough
if fire = 2
point object 4,hitx#,0,hitz#
move object 4,speed#
firex#=object position x(4)
firez#=object position z(4)
dist#= sqrt(((firex#-hitx#)*(firex#-hitx#)) + ((firez#-hitz#)*(firez#-hitz#)))
if dist# <= speed# then dist#=0:fire = 3
endif

`kill bullet and cleanup for next shot
if fire = 3

hide object 4
hide object 3
position object 4, basex#,basey#,basez#
position object 3, basex#,basey#,basez#
position object 5, basex#,basey#,basez#
hide object 5
fire = 0
endif

sync
loop

sync on
sync rate 60
set window off
hide mouse


make matrix 1, 1000,1000,10,10

`make a projectile
make object sphere 1, 20

`make a canon (green cube)
make object cube 101, 20
position object 101,100,10,100
color object 101, rgb(0,255,0)

`make a target (red cube)
make object cube 102, 20
position object 102, 900,10,900
color object 102, rgb(255,0,0)

`a# is the angle that the canon is inclined relative to the horizontal
a# = 60

`gravity
g# = 0.1

`flag indicating if projectile has been fired.
fire_flag = 0

do

	`controls
	move object 102, (upkey()-downkey())*5
	move object right 102, (rightkey()-leftkey())*5
	

	if fire_flag = 0

		`calculate the horizontal distance between the canon and the target
		dx# = sqrt( (object position x(101)-object position x(102))^2 + (object position z(101)-object position z(102))^2 )
		
		`calculate the veritcal distance between the canon and the target
		dy# = object position y(102) - object position y(101)
	
		`calculate the velocity of the bullet
		v# = sqrt( g#*dx#^2 / ((2*cos(a#)^2)*(tan(a#)*dx# - dy#)) )

		`horizontal component of the velocity
		vx# = v#*cos(a#)
		`vertical component of the velocity
		vy# = v#*sin(a#)
		
	
		`position the projectile on the canon
		position object 1, object position x(101), object position y(101), object position z(101)
		
		`point the projectile at the target
		point object 1, object position x(102), object position y(102), object position z(102)
		
		`set flag
		fire_flag = 1
		
	else
	
		`move the object horizontally and vertically
		move object 1, vx#
		move object up 1, vy#
		
		`if the object is below the ground then set flag to zero to repeat shooting
		if object position y(1) < 0
			fire_flag = 0
		endif

		`apply gravity to the vertical component of the velocity
		vy# = vy# - g#
			
	endif


	position camera 1000,500,-100
	point camera 500,100,500	

	set cursor 0,0
	print "use arrow keys to move target"

	sync

loop