hope this code and notes help you come to some understanding of how the sprites and backdrop work
sync on
sync rate 60
`here you will load in your bitmap as bitmap 1 - this bit of code is so "demo" can be compiled without media
cls 0
for t=1 to 50
circle screen width()/2,screen height()/2,screen height()/t
next t
create bitmap 1,screen width(),screen height()
copy bitmap 0,1
`set back to operate on bitmap zero once bitmap 1 has been loaded
set current bitmap 0
`here you will load your sprite image(s) - this bit of code is so "demo" can be compiled without media
cls rgb(255,0,0)
ink 0,0
circle 16,16,16
get image 1,0,0,32,32
ink rgb(255,255,255),0
`create and set sprites to manual backsave
sprite 1,-32,-32,1
sprite 2,10,10,1
`this only needs doing once
set sprite 1,0,1
set sprite 2,0,1
`this only needs to be here for purpose of this "demo"
copy bitmap 1,0
do
mc=mouseclick()
`manually update the backdrop if LMB is pressed - by doing it here we can see the pasted sprites
if mc=1 then copy bitmap 1,0
`"update" sprites by recreating them - this will allow for collision detection
sprite 1,mousex(),mousey(),1
sprite 2,10,10,1
`using paste sprite will allow multiple copies - but none will respond to collision detection
for t=1 to 5
paste sprite 2,55+((t*32)-32)+t*5,10
next t
`manually update the backdrop if RMB is pressed - by doing it here we can NOT see the pasted sprites
if mc=2 then copy bitmap 1,0
set cursor 45,16
print sprite collision(1,0)
sync
loop
