Pick Object On Camera Image - GameCreators Forum

Author

Message

Dimension

22

Years of Service

User Offline

Joined: 23rd Nov 2003

Location:

Posted: 14th Dec 2012 07:36

Link

I working on basically creating a 3D graphical interface and need to use a viewport of some kind to create several views using different cameras. My question is how do I create multiple views to be able to use such functions such as pick object?

Back to top

Profile PM

Rudolpho

20

Years of Service

User Offline

Joined: 28th Dec 2005

Location: Sweden

Posted: 16th Dec 2012 01:28 Edited at: 16th Dec 2012 12:34

Link

set camera image will work. If you want to put the viewports in different windows however that will be more tricky, but it doesn't sound like you need that?

Edit: wow, I've must been tired when I wrote that, it's set camera view, if you render to an image you can't use pick object

"Why do programmers get Halloween and Christmas mixed up?"

+ Code Snippet

Because Oct(31) = Dec(25)

Back to top

Profile PM Email Website

Dimension

22

Years of Service

User Offline

Joined: 23rd Nov 2003

Location:

Posted: 16th Dec 2012 02:31

Link

It seems to work for one camera but on a second camera and the main camera it doesn't seem to work... Is there perhaps a command that can select the camera being used?

+ Code Snippet

set display mode 1280, 720, 32
sync on
sync rate 60
autocam off

make camera 1
set camera to image 1, 1, 320, 180
make camera 2
set camera to image 2, 2, 320, 180

make object cube 1, 1
position camera 1, 0, 5, -5
point camera 1, 0, 0, 0
position camera 2, 0, 5, -5
point camera 2, 0, 0, 0

position camera 0, 0, 2, -2
point camera 0, 0, 0, 0

set current camera 2
do
    paste image 1, 0, 0
    paste image 2, screen width() - 320, 0
    obj = pick object(mousex(), mousey(), 1, 1)
    text 0, 0, str$(obj)
    sync
loop

Back to top

Profile PM

Dimension

22

Years of Service

User Offline

Joined: 23rd Nov 2003

Location:

Posted: 16th Dec 2012 02:50 Edited at: 16th Dec 2012 02:59

Link

Here is an alternative solution that might work using viewports...

+ Code Snippet

Rem Project: Dark Basic Pro Project
Rem Created: Saturday, December 15, 2012

Rem ***** Main Source File *****
set display mode 1280, 720, 32
sync on
sync rate 60
autocam off

make object cube 1, 1

position camera 0, 0, 2, -2
point camera 0, 0, 0, 0

i = 0
do
    i = i + 1
    if i = 1
        set camera aspect 720 / 640
        set camera view 0, 0, 640, 720
    endif
    if i = 2
        set camera view 640, 0, 1280, 720
        i = 0
    endif
    obj = pick object(mousex(), mousey(), 1, 1)
    text 0, 0, str$(obj)
    sync
loop

Back to top

Profile PM

Rudolpho

20

Years of Service

User Offline

Joined: 28th Dec 2005

Location: Sweden

Posted: 16th Dec 2012 12:32

Link

You shouldn't set the camera view in each loop cycle.
I modified your snippet a bit, is this what you wanted?

Rem Project: Dark Basic Pro Project
Rem Created: Saturday, December 15, 2012

Rem ***** Main Source File *****
set display mode 1280, 720, 32
set window position (desktop width() - 1280) / 2, (desktop height() - 720) / 2
sync on
sync rate 60
autocam off

make object cube 1, 1

dim viewport(2, 2)
    viewport(0, 0) = 0  : set camera view 0, 0, 0, (screen width() / 2) - 1, (screen height() / 2) - 1                                  : color backdrop 0, 0xcccccc
    viewport(1, 0) = 1  : make camera 1 : set camera view 1, screen width() / 2, 0, screen width(), (screen height() / 2) - 1           : color backdrop 1, 0xff7f7f
    viewport(0, 1) = 2  : make camera 2 : set camera view 2, 0, screen height() / 2, (screen width() / 2) - 1, screen height()          : color backdrop 2, 0x7fff7f
    viewport(1, 1) = 3  : make camera 3 : set camera view 3, screen width() / 2, screen height() / 2, screen width(), screen height()   : color backdrop 3, 0x7f7fff
position camera 0, 0, 0, -2 : point camera 0, 0, 0, 0   // Front
position camera 1, 0, 2, 0  : point camera 1, 0, 0, 0   // Top
position camera 2, -2, 0, 0 : point camera 2, 0, 0, 0   // Left
position camera 3, 2, 0, 0  : point camera 3, 0, 0, 0   // Right
sync mask 0xf   // Only render the above 4 cameras by default (1 + 2 + 4 + 8 = 15)

while not escapekey()
    // Over which viewport is the mouse cursor?
    mx = mouseX() / (screen width() / 2)
    my = mouseY() / (screen height() / 2)
    
    // Pick the object by holding the LMB over it
    if mouseclick() = 1
        // Set the current camera to the corresponding viewport camera for use with the pick object function
        set current camera viewport(mx, my)
        // Pick the object
        obj = pick object(mousex(), mousey(), 1, 1)
        text mx * (screen width() / 2) + 20, my * (screen height() / 2) + (screen height() / 4), "Picked object " + str$(obj)
    endif
    
    text 0, 0, "Front"
    text screen width() / 2, 0, "Top"
    text 0, screen height() / 2, "Left"
    text screen width() / 2, screen height() / 2, "Right"
    
    yrotate object 1, wrapvalue(object angle y(1) + 0.5)
    sync
endwhile

+ Code Snippet

Rem Project: Dark Basic Pro Project
Rem Created: Saturday, December 15, 2012

Rem ***** Main Source File *****
set display mode 1280, 720, 32
set window position (desktop width() - 1280) / 2, (desktop height() - 720) / 2
sync on
sync rate 60
autocam off

make object cube 1, 1

dim viewport(2, 2)
    viewport(0, 0) = 0  : set camera view 0, 0, 0, (screen width() / 2) - 1, (screen height() / 2) - 1                                  : color backdrop 0, 0xcccccc
    viewport(1, 0) = 1  : make camera 1 : set camera view 1, screen width() / 2, 0, screen width(), (screen height() / 2) - 1           : color backdrop 1, 0xff7f7f
    viewport(0, 1) = 2  : make camera 2 : set camera view 2, 0, screen height() / 2, (screen width() / 2) - 1, screen height()          : color backdrop 2, 0x7fff7f
    viewport(1, 1) = 3  : make camera 3 : set camera view 3, screen width() / 2, screen height() / 2, screen width(), screen height()   : color backdrop 3, 0x7f7fff
position camera 0, 0, 0, -2 : point camera 0, 0, 0, 0   // Front
position camera 1, 0, 2, 0  : point camera 1, 0, 0, 0   // Top
position camera 2, -2, 0, 0 : point camera 2, 0, 0, 0   // Left
position camera 3, 2, 0, 0  : point camera 3, 0, 0, 0   // Right
sync mask 0xf   // Only render the above 4 cameras by default (1 + 2 + 4 + 8 = 15)


while not escapekey()
    // Over which viewport is the mouse cursor?
    mx = mouseX() / (screen width() / 2)
    my = mouseY() / (screen height() / 2)
    
    // Pick the object by holding the LMB over it
    if mouseclick() = 1
        // Set the current camera to the corresponding viewport camera for use with the pick object function
        set current camera viewport(mx, my)
        // Pick the object
        obj = pick object(mousex(), mousey(), 1, 1)
        text mx * (screen width() / 2) + 20, my * (screen height() / 2) + (screen height() / 4), "Picked object " + str$(obj)
    endif
    
    text 0, 0, "Front"
    text screen width() / 2, 0, "Top"
    text 0, screen height() / 2, "Left"
    text screen width() / 2, screen height() / 2, "Right"
    
    yrotate object 1, wrapvalue(object angle y(1) + 0.5)
    sync
endwhile

"Why do programmers get Halloween and Christmas mixed up?"

+ Code Snippet

Because Oct(31) = Dec(25)

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Pick Object On Camera Image