that looks amazing ashingda!
C'mon people, still time left to participate! It's about entering and having fun coding, not necessarily winning
Here's a little entry from me as well, i call these 'creepy trees', i'd like to implement them in a game eventually
Rem Project: Dark Basic Pro Project
Rem Created: Thursday, February 21, 2013
Rem ***** Main Source File *****
set display mode 800, 600, 32
hide mouse
do
cls
circle mousex(), mousey(), 10
bentLine(250, 600, -10, -15, 10, mousex(), mousey(), 6, 0.7, 0.5, 0.7)
bentLine(400, 600, 0, -30, 14, mousex(), mousey(), 5, 1, 0.5, 0.7)
bentLine(550, 600, 10, -10, 14, mousex(), mousey(), 5, 2, 0.6, 0.4)
sync
LOOP
function bentLine(x, y, force1X as float, force1Y as float, tiles, zX, zY, iterations, lengthFac as float, lIterFac as float, rIterFac as float)
force2Angle = atan_full(x-zX, y-zY)
force2X = cos(force2Angle)*10
force2Y = sin(force2Angle)*10
oldX = x : oldY = y
for t = 0 to tiles-1
infl# = t*1.0/(tiles-1)
newX = oldX+force1X*(1-infl#)+force2X*infl# : newY = oldY+force1Y*(1-infl#)+force2Y*infl#
line oldX, oldY, newX, newY
oldX = newX : oldY = newY
NEXT t
if iterations > 1
angle = atan_full(-force2X, -force2Y) : dist = getDistance(0, 0, force2X, force2Y)
bentLine(newX, newY, cos(angle-55)*dist, sin(angle-55)*dist, tiles*lIterFac, zX, zY, iterations-1, lengthFac, lIterFac, rIterFac)
angle = atan_full(-force2X, -force2Y) : dist = getDistance(0, 0, force2X, force2Y)
bentLine(newX, newY, cos(angle+55)*dist, sin(angle+55)*dist, tiles*rIterFac, zX, zY, iterations-1, lengthFac, lIterFac, rIterFac)
endif
endfunction
function tree(x, y, angle, length, iterations)
x2 = x+cos(angle)*length
y2 = y+sin(angle)*length
line x, y, x2, y2
if iterations > 0
tree(x2, y2, angle-45, length*0.7, iterations-1)
tree(x2, y2, angle+45, length*0.7, iterations-1)
endif
ENDFUNCTION
function getDistance(x1, y1, x2, y2)
res = sqrt((x2-x1)^2+(y2-y1)^2)
ENDFUNCTION res
function atan_full(dist_x as float, dist_y as float)
local angle as float
`--
if dist_y >= 0
if dist_x > 0 then angle = 180.0 + abs(Atan(dist_y/dist_x))
if dist_x < 0 then angle = 360.0 - abs(Atan(dist_y/dist_x))
if dist_x = 0 then angle = 270.0
else
if dist_x > 0 then angle = Atan(dist_y/dist_x) + 180.0
if dist_x < 0 then angle = Atan(dist_y/dist_x)
if dist_x = 0 then angle = 90.0
endif
endfunction angle
