How to quickly position parallel lines next to the middle one

Author

Message

JoeOh

17

Years of Service

User Offline

Joined: 25th Feb 2009

Location:

Posted: 28th Dec 2012 22:42

Link

I've been trying to figure out how to best place parallel lines next to the main middle one for the past few days with no luck. Here's the function code I have so far:

+ Code Snippet

function Draw3DLine(dx1#, dy1#, dz1#, dx2#, dy2#, dz2#, r1, g1, b1, r2, g2, b2)
nx# as float
ny# as float
dr# as float
dr#=yyy3#*.015
dlx as float = dx2#-dx1#
dly as float = dy2#-dy1#
ny#=atan(dly)*dr#
nx#=atan(dlx)*dr#
d3d_line3d dx1#+(nx#), dy1#, dz1#+(ny#), dx2#+(nx#), dy2#, dz2#+(ny#), rgb(r1,g1,b1), rgb(r2,g2,b2), 0
d3d_line3d dx1#, dy1#, dz1#, dx2#, dy2#, dz2#, rgb(r1,g1,b1), rgb(r2,g2,b2), 0
d3d_line3d dx1#-(nx#), dy1#, dz1#-(ny#), dx2#-(nx#), dy2#, dz2#-(ny#), rgb(r1,g1,b1), rgb(r2,g2,b2), 0
endfunction

As you see with the code, I am trying to create a function that places 2 parallel lines next to the main one in the middle while maintaining equilateral distance from the middle line.

I may have to provide a picture to show exactly what I want, but try to imagine a long box has it's 2 long sides stay parallel to the center of the box and keeping the same distance from the center of that box.

Home is where my souped-up computer is...

Back to top

Profile PM

The Weeping Corpse

14

Years of Service

User Offline

Joined: 19th Sep 2011

Location: United Kingdom

Posted: 29th Dec 2012 03:15 Edited at: 29th Dec 2012 03:22

Link

There are an infinite number of solutions so you need to provide us with more information, you don't use the z coordinate in your calculations?

If you think of the master line as a rod through the center of a cylinder then all lines laying on the surface of that cylinder are equal distance from the master line, so which lines do you want?.

Back to top

Profile PM Email

JoeOh

17

Years of Service

User Offline

Joined: 25th Feb 2009

Location:

Posted: 29th Dec 2012 04:24

Link

let me try it ascii-wise

m=middle line

p=parallel line

+ Code Snippet


"For a 90 degree layout of what I need..."

p--------------------------------------------------p
m--------------------------------------------------m
p--------------------------------------------------p

+ Code Snippet


"For a Zero degree layout of what I need..."

p m p
| | |
| | |
| | |
| | |
| | |
| | |
| | |
| | |
| | |
| | |
p m p

see what I'm saying? the middle line is easy enough to do. It's just a point a-to-b coordinate set. But the other 2 need to keep equal distance from the middle and proper angle translation like a rotating box would. Except that a box in DBPro, wont do 3d coordinated.

As far as the "z" axis is concerned, I forgot about that. I would need to take that into account as well.

If this doesn't clear things up, then I'll do an animated GIF to show what I would like to do.

Home is where my souped-up computer is...

Back to top

Profile PM

Chris Tate

DBPro Master

17

Years of Service

User Offline

Joined: 29th Aug 2008

Location: London, England

Posted: 29th Dec 2012 04:40 Edited at: 29th Dec 2012 04:44

Link

Quote: "If this doesn't clear things up, then I'll do an animated GIF to show what I would like to do."

Please, please no, don't do that; if you had to go so far for something so simple you'd make me feel retarded. lol.

You seem smart enough to figure out the code, so here's the english. Work out the angle from point A to B using Atanfull). You will also need the distance.

Add 90 degrees to you original angle; then set your outer starting point at your thickness distance. Do the same in the other direction by subtracting 90 degrees from your original angle.

Now draw all three lines in the given direction from their individual starting points.

Back to top

Profile PM Email Website

Phaelax

DBPro Master

23

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 29th Dec 2012 09:32

Link

If you're ignoring Z at the moment, then I'll just do it in 2D for ya.

Specify the coordinates of the middle line and the distance you want the parallel lines to be from the middle. The function will draw the middle line in red, and the other two parallel lines in white both of equal distance from the middle and match the length of the middle.

For the demo, mouse buttons will change the distance of the lines, move mouse to change ending point of middle line.

d# = 30

sync on
sync rate 60
repeat
    cls
    
    if mouseclick() = 1 then inc d#
    if mouseclick() = 2 then dec d#
    if d# < 5 then d# = 5
    
    drawLines(100, 100, mousex(), mousey(), d#)

sync
until spacekey()
end

function drawLines(ax, ay, bx, by, distance#)
    
    rem draw middle line
    ink rgb(255,0,0),0
    line ax, ay, bx, by
    ink rgb(255,255,255),0
    
    rem get length of middle line
    length# = sqrt((bx-ax)^2 + (by-ay)^2)
    
    rem get a normalized vector of middle line segment
    nx# = (bx-ax) / length#
    ny# = (by-ay) / length#
    
    rem Get angle the middle line is facing, rotate by 90 to get
    rem a point perpendicular below the middle line.
    a# = atanfull(ax-bx, ay-by)+90
    
    rem turn angle into a unit vector
    sa# = sin(a#)
    ca# = cos(a#)
    
    rem starting point of new line, running parallel 
    rem to middle line and being specified 'distance' away
    x1 = ax + sa#*distance#
    y1 = ay + ca#*distance#
    
    rem ending point of new line
    x2 = x1 + nx#*length#
    y2 = y1 + ny#*length#
    
    rem repeat last two steps, using a negative distance to get
    rem coordinates for other line on opposite side of the middle
    x3 = ax + sa#*-distance#
    y3 = ay + ca#*-distance#
    x4 = x3 + nx#*length#
    y4 = y3 + ny#*length#
    
    rem draw lines
    line x1, y1, x2, y2
    line x3, y3, x4, y4
endfunction

+ Code Snippet


d# = 30

sync on
sync rate 60
repeat
    cls
    
    if mouseclick() = 1 then inc d#
    if mouseclick() = 2 then dec d#
    if d# < 5 then d# = 5
    
    drawLines(100, 100, mousex(), mousey(), d#)

    sync
until spacekey()
end


function drawLines(ax, ay, bx, by, distance#)
    
    rem draw middle line
    ink rgb(255,0,0),0
    line ax, ay, bx, by
    ink rgb(255,255,255),0
    
    rem get length of middle line
    length# = sqrt((bx-ax)^2 + (by-ay)^2)
    
    rem get a normalized vector of middle line segment
    nx# = (bx-ax) / length#
    ny# = (by-ay) / length#
    
    rem Get angle the middle line is facing, rotate by 90 to get
    rem a point perpendicular below the middle line.
    a# = atanfull(ax-bx, ay-by)+90
    
    rem turn angle into a unit vector
    sa# = sin(a#)
    ca# = cos(a#)
    
    rem starting point of new line, running parallel 
    rem to middle line and being specified 'distance' away
    x1 = ax + sa#*distance#
    y1 = ay + ca#*distance#
    
    rem ending point of new line
    x2 = x1 + nx#*length#
    y2 = y1 + ny#*length#
    
    rem repeat last two steps, using a negative distance to get
    rem coordinates for other line on opposite side of the middle
    x3 = ax + sa#*-distance#
    y3 = ay + ca#*-distance#
    x4 = x3 + nx#*length#
    y4 = y3 + ny#*length#
    
    rem draw lines
    line x1, y1, x2, y2
    line x3, y3, x4, y4
endfunction

"You're not going crazy. You're going sane in a crazy world!" ~Tick

Back to top

Profile PM Email Website

JoeOh

17

Years of Service

User Offline

Joined: 25th Feb 2009

Location:

Posted: 29th Dec 2012 17:37

Link

Phaelax, they don't call you the 'Silver Codemaster' for nothin

It's just what I need and works like a charm!

Home is where my souped-up computer is...

Back to top

Profile PM

Phaelax

DBPro Master

23

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 29th Dec 2012 19:42

Link

It just occurred to me that I don't even to calculate the line segments length or form a normalized vector. I can simply calculate the end point the same as I did the starting point, thus dropping the square root function and two divisions.

+ Code Snippet


function drawLines(ax, ay, bx, by, distance#)
    
    rem draw middle line
    ink rgb(255,0,0),0
    line ax, ay, bx, by
    ink rgb(255,255,255),0

    rem Get angle the middle line is facing, rotate by 90 to get
    rem a point perpendicular below the middle line.
    a# = atanfull(ax-bx, ay-by)+90
    
    rem turn angle into a unit vector
    sa# = sin(a#)
    ca# = cos(a#)
    
    rem starting point of new line, running parallel 
    rem to middle line and being specified 'distance' away
    x1 = ax + sa#*distance#
    y1 = ay + ca#*distance#
    
    rem ending point of new line
    x2 = bx + sa#*distance#
    y2 = by + ca#*distance#
    
    rem repeat last two steps, using a negative distance to get
    rem coordinates for other line on opposite side of the middle
    x3 = ax + sa#*-distance#
    y3 = ay + ca#*-distance#
    x4 = bx + sa#*-distance#
    y4 = by + ca#*-distance#
    
    rem draw lines
    line x1, y1, x2, y2
    line x3, y3, x4, y4
endfunction

"You're not going crazy. You're going sane in a crazy world!" ~Tick

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / How to quickly position parallel lines next to the middle one