Sorry your browser is not supported!

sync on
hide mouse

rem arms, legs
 make object box 1,5,20,5
 make mesh from object 1,1
 delete object 1

rem torso
 make object box 1,15,15,10
 make mesh from object 2,1
 delete object 1

rem head
 make object box 1,7,7,10
 make mesh from object 3,1
 delete object 1

rem body
 make object cube 2233,10
 add limb 2233,1,2
 add limb 2233,2,1
 add limb 2233,3,1
 add limb 2233,4,1
 add limb 2233,5,1
 add limb 2233,6,3

rem torso
 offset limb 2233,1,0,15,0

rem head
 offset limb 2233,6,0,12,0
 link limb 2233,6,1

rem left arm
 offset limb 2233,2,-10,-5,0
 offset limb 2233,3,0,-21,0

 link limb 2233,2,1
 link limb 2233,3,2


rem right arm
 offset limb 2233,4,10,-5,0
 offset limb 2233,5,0,-21,0

 link limb 2233,4,1
 link limb 2233,5,4

rem camera
 position camera 0,30,-100
 point camera 0,0,0

rem color object to for clear view
 color object 2233,rgb(0,100,0)
 color limb 2233,1,rgb(100,0,0)
 color limb 2233,2,rgb(200,0,0)
 color limb 2233,3,rgb(200,0,0)
 color limb 2233,4,rgb(255,0,0)
 color limb 2233,5,rgb(255,0,0)
 color limb 2233,6,rgb(100,0,0)


rem main loop
 repeat
 rem how to rotate like a real arm??
	n=wrapvalue(n+1)
	yrotate object 2233,45
	rotate limb 2233,4,n,0,0

 sync

 until spacekey()=1

 delete object 2233

 end

`**************************************
`* Title  : Steam-Sapien Clock
`* Author : latch
`* Date   : 01/11/2007
`* Version:
`**************************************

rem =============================================================
rem = set up display
rem =============================================================
autocam off
set display mode 800,600,32
sync on
sync rate 60
hide mouse

set text font "system",1

position camera 0,80,-200
point camera 0,40,0

dim man(1000)

remstart
for img = 20 to 80
   ink rgb(rnd(255),rnd(255),rnd(255)),0
   box 0,0,32,32
   ink 0,0
   text 16,16,str$(img-19)
   get image img,0,0,33,33
next img
remend

box 1,1,10,10
get image 1,0,0,11,11

ground=make_floor(1,100000.0,100000.0,0.0,-100.0,0.0,1,200.0,200.0)

for n = 20 to 60
   man(n)=stick_man(n)
   loop object man(n)
   `hide object man(n)
   set object speed man(n),rnd(25)+25
   `texture object man(n),n
next n

randomize timer()

do
      create bitmap 1,192,128
      ink rgb(0,255,0),0
      box 0,0,127,127
      ink 0,0
      text 33,64,get time$()
      get image 2,0,0,128,128
      cls 0
      ink rgb(255,255,255),0
      text 0,0,"I'M LATE!!  I'M LATE!!"
      get image 3,0,0,140,17
      delete bitmap 1

      sprite 1,330,10,3
      set sprite 3,1,0

   for obj = 20 to 60

      move object man(obj),rnd(10)
      yrotate object man(obj),wrapvalue(object angle y(man(obj))+rnd(20)-10)
      texture object man(obj),2
   next obj

   `move object 40,7

   objx#=object position x(man(20))
   objy#=object position y(man(20))
   objz#=object position z(man(20))
   angy#=object angle y(man(20))

   set camera to follow objx#,objy#,objz#,angy#,150,50,30,1


   sync
loop








end

rem =============================================================
rem = FUNCTIONS
rem =============================================================

   function is_even(num)
      true = 1
      false = 0
      test#=num/2.0
      if test# > (num/2) then exitfunction false
   endfunction true
`----------------------------------------------------------------
   function avail_obj(obj)
      while object exist(obj)=1
         inc obj
      endwhile
   endfunction obj
`-----------------------------------------------------------------

function stick_man(obj)
   rem =============================================================
   rem = Create character
   rem =============================================================

   rem variables
   body=avail_obj(obj)
   joint=avail_obj(body+1)
   head=avail_obj(body+2)
   chimney=avail_obj(body+3)
   bone=body

         rem right leg
         r_hip=1:r_thigh=2:r_knee=3:r_shin=4

         rem left leg
         l_hip=5:l_thigh=6:l_knee=7:l_shin=8

         rem right arm
         r_shold=9:r_bi=10:r_elbow=11:r_arm=12

         rem left arm
         l_shold=13:l_bi=14:l_elbow=15:l_arm=16

         rem head
         kneck=17:head=18:chimney=19

   rem body parts
   make object cylinder body,50
   scale object body,25,70,25
   make mesh from object bone,body
   scale object body,100,100,100
   make object cube head,25
   make mesh from object head,head
   make object cylinder chimney,5
   scale object chimney,60,400,60
   make mesh from object chimney,chimney

   rem joints
   make object sphere joint,50
   scale object joint,36,36,36
   make mesh from object joint,joint
   scale object joint,100,100,100

   rem create limbs
   count = 0
   for lmb=1 to 16
      inc count
      if is_even(lmb)=1
         add limb body,lmb,bone
      else
         add limb body,lmb,joint
      endif

      rem link limbs
      if count > 1
         link limb body,lmb,lmb-1
      endif

      if count = 4 then count = 0

   next lmb

   rem neck head and smoke stack
   add limb body,kneck,bone
   add limb body,head,head
   link limb body,head,kneck
   add limb body,chimney,chimney
   link limb body,chimney,head

   rem initial position of limbs
         rem right leg
   offset limb body,r_hip,-12,-26,0
   offset limb body,r_thigh,0,-20,0
   offset limb body,r_knee,0,-20,0
   offset limb body,r_shin,0,-20,0

         rem left leg
   offset limb body,l_hip,12,-26,0
   offset limb body,l_thigh,0,-20,0
   offset limb body,l_knee,0,-20,0
   offset limb body,l_shin,0,-20,0

         rem right arm
   offset limb body,r_shold,-33,20,0
   offset limb body,r_bi,-2,-20,0
   offset limb body,r_elbow,0,-20,0
   rotate limb body,r_elbow,300,0,0
   offset limb body,r_arm,0,-20,0

         rem left arm
   offset limb body,l_shold,33,20,0
   offset limb body,l_bi,2,-20,0
   offset limb body,l_elbow,0,-20,0
   rotate limb body,l_elbow,300,0,0
   offset limb body,l_arm,0,-20,0

         rem head
   offset limb body,kneck,0,20,0
   offset limb body,head,0,20,0
   offset limb body,chimney,5,20,-8

   rem object animation
   set object keyframe body,0
   rotate limb body,r_hip,310,0,0
   rotate limb body,r_knee,60,0,0
   rotate limb body,r_shold,30,0,0
   rotate limb body,l_hip,20,0,0
   rotate limb body,l_knee,20,0,0
   rotate limb body,l_shold,310,0,0
   set object keyframe body,10
   rotate limb body,r_hip,0,0,0
   rotate limb body,r_knee,3,0,0
   rotate limb body,r_shold,330,0,0
   rotate limb body,l_hip,340,0,0
   rotate limb body,l_knee,60,0,0
   rotate limb body,l_shold,0,0,0
   set object keyframe body,20
   rotate limb body,r_hip,20,0,0
   rotate limb body,r_knee,30,0,0
   rotate limb body,r_shold,300,0,0
   rotate limb body,l_hip,310,0,0
   rotate limb body,l_knee,30,0,0
   rotate limb body,l_shold,20,0,0
   set object keyframe body,28
   rotate limb body,l_hip,0,0,0
   rotate limb body,l_knee,3,0,0
   rotate limb body,l_shold,359,0,0
   rotate limb body,r_hip,359,0,0
   rotate limb body,r_knee,10,0,0
   rotate limb body,r_shold,0,0,0
   set object keyframe body,38

   rem cleanup unneeded meshes and objects
   delete object chimney
   delete mesh chimney
   delete object head
   delete mesh head
   delete object joint
   delete mesh joint
   delete mesh bone

endfunction body
`-----------------------------------------------------------------------------
function make_floor(obj,width#,height#,posx#,posy#,posz#,texture,across#,down#)

   rem check for exisiting objects
   while object exist(obj)=1
      inc obj
   endwhile

   rem make the actual plain object and rotate it flat
   make object plain obj,width#,height#
   xrotate object obj,90
   fix object pivot obj

   rem texture and scale the texture to tile it or not
   texture object obj,texture
   scale object texture obj,across#,down#

   rem set the initial position of the floor
   position object obj,posx#,posy#,posz#
endfunction obj

offsety# = 0-10

offset limb 1,0,offsety#,0

make mesh from object 1,1

delete object 1
make object 1,1,0 : rem the last digit would be the image number to texture if you had one

do
   zrotate object 1,wrapvalue(object angle z(1)+1)
   sync
loop

sync on

make object box 1,4,20,4
offset limb 1,0,0,-10,0
make mesh from object 1,1
delete object 1
make object 1,1,0

do
   zrotate object 1,wrapvalue(object angle z(1)+1)
   sync
loop

sync on
sync rate 60
autocam off

rem make a sphere for the shoulder.  This will be the main object
make object sphere 1,25

rem make a long box that will be used as the limbs for the arm
rem the box will be longest along the x axis
make object box 2,50,10,10

remstart
   to create a limb, we have to use a mesh.  Let's make a mesh out
   of the box.  The problem though is, the box rotates around it's
   center.  We want it to rotate around it's end like a baseball bat
   or like an arm does at the shoulder or elbow

   To do that, we have to offset the box from it's center along the
   long axis, which in this case is the x axis.  Since it's 50 units
   long on the x axis, and we want to move the point from the center,
   that's an offset of 25 units

   The base limb of an object is LIMB 0 .  That is what we have to offset
   for the box
remend
offset limb 2,0,25,0,0
`now make a mesh out of the offset object
make mesh from object 2,2

rem we're done with the box because we have our mesh.  We can delete
rem the box
delete object 2

rem now we need to add the box as a limb to the sphere
rem this will be the upper arm
add limb 1,1,2

rem add another one for the lower arm
add limb 1,2,2

remstart
   the lower arm is linked to the sphere by default.  We want it linked
   to the upper arm.  This is called parent child relationships.  The
   main parent is the shoulder.  It's first child is the upper arm.
   The upper arm is the parent of the lower arm, so we have to make
   the lower arm the child of the upper arm by using the LINK LIMB
   command
remend
link limb 1,2,1

rem we need to offset the lower arm so that it is end to end
rem with the upper arm
offset limb 1,2,50,0,0

rem now we are ready to animate.  We position and rotate the limbs
rem and set keyframes.  A keyframe is a pose at a certain period
rem of time or frame.  We can set the keyframes far apart and the
rem computer will figure out all the little poses in between.
set object keyframe 1,1
rem rotate the lower arm 90 degrees on the z axis
rotate limb 1,2,0,0,90
rem set this rotation for 10 frames later than the previous
set object keyframe 1,11
rem rotate the lower arm back to the starting point
rotate limb 1,2,0,0,0
rem set this keyframe for 10 frames later than the previous
set object keyframe 1,21

position camera 50,0,-100

rem loop the animation
loop object 1

rem wait for a key
wait key