Wrong way I'm afraid. Try following which uses a sprite as crosshair and new pick object command to work out what object is under mouse pointer. It will also give you distance to object and intersect world position. Perfect for a fist person shooter!
line 15,0,15,10
line 15,20,15,32
line 0,15,10,15
line 20,15,32,15
get image 1,0,0,32,32,1
sync on : sync rate 0 : autocam off : randomize timer() : hide mouse
for f=1 to 20
make object cube f,50
position object f,-200+rnd(400),-200+rnd(400),rnd(100)
color object f,rgb(rnd(255),rnd(255),rnd(255))
next f
make object sphere 100,10
position camera -100,0,-500
sprite 1,0,0,1
set sprite 1,1,1
offset sprite 1,15,15
do
sprite 1,mousex(),mousey(),1
p=pick object(mousex(),mousey(),1,20)
set cursor 0,0
if p=0
print "You are not pointing at any object"
hide object 100
else
pd#=get pick distance()
print "You are pointing at object: ";p
print "Distance from camera: ";pd#
px#=get pick vector x()
py#=get pick vector y()
pz#=get pick vector z()
wx#=px#+camera position x()
wy#=py#+camera position y()
wz#=pz#+camera position z()
print "Relative to Camera: X = ";px#
print "Relative to Camera: Y = ";py#
print "Relative to Camera: Z = ";pz#
print "World: X = ";wx#
print "World: Y = ";wy#
print "World: Z = ";wz#
show object 100
position object 100,wx#,wy#,wz#
endif
sync
loop
Boo!
