I've just set up a simple scene using a tiled wall and I don't get the problem you're having.
Can you produce a simple trimmed down sample which shows the problem?
Here's the code I used. The "ground" is a single flat plain, the wall on the right is a sequence of identical tiles:
set display mode desktop width(), desktop height(), 32
sync on : sync rate 60 : sync
autocam off
position camera 0, 100, -500
point camera 0, 0, 0
lm start
` load tile images
load image "tile.png", 1
load image "ground.png", 2
` make ground plain
make object plain 1, 2000, 2000
texture object 1, 2
xrotate object 1, -90
` make some tiles and place on the ground
for obj = 101 to 140
make object plain obj, 50, 50
texture object obj, 1
yrotate object obj, -90
position object obj, 500, 25, -1000+25 + 50 * (obj-101)
next obj
` set up the lightmapper
lm add point light 400, 25, 400, 500, 0, 1, 0
lm add point light 400, 25, -400, 400, 0, 0, 1
` add the objects to the lightmapper
lm add light map object 1
for obj = 101 to 140
lm add light map object obj
lm set ambient light 0.0, 0.0, 0.0
next obj
lm build light maps 64, 0.2, 2
hide light 0
repeat
sync
until spacekey()
end
Here's a better version of the same thing. The first time you run it, it creates the lightmaps and saves the objects. The next time it simply loads the previously created objects and lightmaps. Uses clones for illustration - and includes the extra flag when the plains are created (seems to be necessary).
` is this a relevant link?
` http://forum.thegamecreators.com/?m=forum_view&t=184172&b=1
` probably not but kept here for reference
set display mode desktop width(), desktop height(), 32
sync on : sync rate 60 : sync
autocam off
position camera 0, 100, -500
point camera 0, 0, 0
if file exist("ground.dbo")
` load objects - lightmaps, etc, will be loaded automatically
load object "ground.dbo", 1
xrotate object 1, 90
for obj = 101 to 140
load object "obj"+str$(obj)+".dbo", obj
yrotate object obj, 90
position object obj, 500, 25, -1000+25 + 50 * (obj-101)
next obj
else
` create objects and lightmaps
` load tile images
load image "tile.png", 1
load image "ground.png", 2
` make ground plain
make object plain 1, 2000, 2000 , 1 ` final flag needed to ensure tiles are correctly oriented after reload
texture object 1, 2
xrotate object 1, 90
` make some tiles and place on the ground
for obj = 101 to 140
if obj = 101
make object plain obj, 50, 50, 1 ` final flag needed to ensure tiles are correctly oriented after reload
else
clone object obj, 101 ` not much point with plains - but illustrates method for more complex objects
endif
texture object obj, 1
yrotate object obj, 90
position object obj, 500, 25, -1000+25 + 50 * (obj-101)
next obj
` set up the lightmapper
lm start
lm add point light 400, 25, 400, 800, 0, 1, 0
lm add point light 400, 25, 0, 800, 0, 0, 1
lm set ambient light 0.0, 0.0, 0.0
` add the objects to the lightmapper
lm add light map object 1, 0
for obj = 101 to 140
lm add light map object obj
next obj
lm build light maps 512, 0.2, 2
` save objects for re-use later
save object "ground.dbo", 1
for obj = 101 to 140
save object "obj"+str$(obj)+".dbo", obj
next obj
endif
hide light 0
repeat
sync
until spacekey()
end
