To add to BMacZero's post, this is an example of how to use the pick object and pick vector commands, it's not as all that straight forward. I don't think it's exactly what you want but it should help (I think I did this for someone else).
sync on
sync rate 60
autocam off
`make a board (a white plain)
make object plain 1, 1000,1000
rotate object 1, -90,0,0
`make a marker object (a red cube)
make object cube 2, 20
color object 2, rgb(255,0,0)
position object 2,0,10,0
`make a marker object
make object cube 3, 1
hide object 3
position object 3,0,0,0
`position and point camera
position camera 0,400,-800
point camera 0,0,0
`main loop
do
`determines the position of the mouse projected onto the board if the mouse is over the board
if mouseclick() = 1
if pick object(mousex(),mousey(),1,1) = 1
target_x# = get pick vector x() + camera position x()
`target_y# = get pick vector y() + camera position y() :`not required in this example
target_z# = get pick vector z() + camera position z()
`point the red cube at the point that was selected on the map (note that the y position is simply the mid height of the cube
point object 2, target_x#, 10, target_z#
endif
endif
`calculate the distance between the target coordinates and the cube
distance# = sqrt( (object position x(2) - target_x#)^2 + (object position z(2) - target_z#)^2 )
`if the target position is a suitable distance away then point the cube at the target coordinates and move the object toward it
if distance# > 10
move object 2, 2
endif
`print stuff
set cursor 0,0
sync
loop
As for changing the speed of scrolling, add a multiplier to speed up or slow down the movement.
sync on
sync rate 60
autocam off
`value above 1 will give a faster scroll speed, values below 1 will give a slower scroll speed
scroll_speed_multiplier# = 0.2
do
cls
mouse_move_z = mousemovez()
value_a = value_a + mouse_move_z
value_b# = value_b# + mouse_move_z*scroll_speed_multiplier#
set cursor 0,0
print "value_a : ", value_a
print "value_b# : ", value_b#
sync
loop
As BMacZero said, mousemovez() is the scroll wheel and isn't linked to the movement of the mouse in the same way as mousemovex() and mousemovey() are.
