Intersect point - GameCreators Forum

Author

Message

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 24th Jun 2014 12:44

Link

Hi to all ,

Can you write a function
to calculate x, y of the intersection point
perpendicular to the two objects? (As attached)

I know:

x, y of the two objects and the angle of the two objects

Thanks and sorry for my Inglese!

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 24th Jun 2014 13:55 Edited at: 24th Jun 2014 13:58

Link

I'm a little rusty, but here's the math behind it.

Note: Vectors are denoted as V=[x,y] where V.x=x and V.y=y.

For each object, you need a directional vector D and a position vector P. Since you have the angle of the object, that's easy enough to calculate using trigonometry:

D1 = [cos(a1), sin(a1)]
D2 = [cos(a2), sin(a2)]

Where a1 is the angle of object 1 and a2 is the angle of object 2, and D1 and D2 are both unit vectors.

The position vectors are obviously:

P1 = [a1x, a1y]
P2 = [a2x, a2y]

Where a1x and a1y are the 2D coordinates of object 1 and a2x and a2y are the 2D coordinates of object 2.

From this data, we can define two rays, R1 and R2:

R1(t1) = P1 + t1 * D1
R2(t2) = P2 + t2 * D2

Where t1 and t2 are unknown scalars indicating a single position along the ray, and R1 and R2 are position vectors.

The intersection point of the two rays exists when R1 and R2 are equal, i.e.

R1(t1) = R2(t2)

Which gives us the equation:

P1 + t1 * D1 = P2 + t2 * D2

Rearrange:

P1 - P2 = t2 * D2 - t1 * D1

Giving us a simultaneous linear equation:

P1.x - P2.x = t2 * D2.x - t1 * D1.x
P1.y - P2.y = t2 * D2.y - t1 * D1.y

To efficiently solve that, you can use conventional algebra, or you can do some fancy stuff and build a matrix and two vectors:

D = [[D2.x, -D1.x],[D2.y, -D1.y]]
T = [t2, t1]
P = P1 - P2

where:

P = D * T

If the matrix D is singular, i.e. its determinant is 0, it means there is no solution. Otherwise you can use the standard simultaneous linear equation method for solving both t1 and t2.

TheComet, what the frick is this frack??? you may be asking yourself at this point in time. Don't worry, here's some code. (This is untested because I don't have a DBP compiler. Let me know how it works. I'll test myself it when I get home.)

type Vec2
    x as float
    y as float
endtype

type Mat2x2
    m11 as float
    m12 as float
    m21 as float
    m22 as float
endtype

rem in your main loop, call the function as follows.
rem The return values are stored in the "ret" variable.
global ret as Vec2
if intersect2D(object position x(1), object position y(1), object position x(2), object position y(2), object angle x(1), object angle y(1))
    print "intersection found at: ";ret.x;",";ret.y
else
    print "no intersection found!"
endif

rem .....

function intersect2D(x1, y1, x2, y2, angle1, angle2)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d1 as Vec2
    d1.x = cos(angle1)
    d1.y = sin(angle1)
    D.m11 = cos(angle2)
    D.m12 = -d1.x
    D.m21 = sin(angle2)
    D.m22 = -d1.y

rem if matrix is singular, no solution exists
    det = D.m11*D.m22 - D.m12*D.m21
    if det = 0.0 then exitfunction 0

rem compute inverse of matrix
    rem not required (optimisation): temp = D.m11
    D.m11 = D.m22/det
    rem not required (optimisation): D.m22 = temp/det
    D.m12 = -D.m12/det
    rem not required (optimisation): D.m21 = -D.m21/det

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t2
    rem is omitted.
    P as Vec2
    P.x = x1-x2
    P.y = y1-y2
    t1 = D.m11*P.x + D.m12*P.y
    rem not required: t2 = D.m21*P.x + D.m22*P.y

rem plug t1 back into original equation to find intersection position
    ret.x = x1 + t1*d1.x
    ret.y = y1 + t1*d1.y
        
endfunction 1

+ Code Snippet

type Vec2
    x as float
    y as float
endtype

type Mat2x2
    m11 as float
    m12 as float
    m21 as float
    m22 as float
endtype

rem in your main loop, call the function as follows.
rem The return values are stored in the "ret" variable.
global ret as Vec2
if intersect2D(object position x(1), object position y(1), object position x(2), object position y(2), object angle x(1), object angle y(1))
    print "intersection found at: ";ret.x;",";ret.y
else
    print "no intersection found!"
endif

rem .....


function intersect2D(x1, y1, x2, y2, angle1, angle2)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d1 as Vec2
    d1.x = cos(angle1)
    d1.y = sin(angle1)
    D.m11 = cos(angle2)
    D.m12 = -d1.x
    D.m21 = sin(angle2)
    D.m22 = -d1.y

    rem if matrix is singular, no solution exists
    det = D.m11*D.m22 - D.m12*D.m21
    if det = 0.0 then exitfunction 0

    rem compute inverse of matrix
    rem not required (optimisation): temp = D.m11
    D.m11 = D.m22/det
    rem not required (optimisation): D.m22 = temp/det
    D.m12 = -D.m12/det
    rem not required (optimisation): D.m21 = -D.m21/det

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t2
    rem is omitted.
    P as Vec2
    P.x = x1-x2
    P.y = y1-y2
    t1 = D.m11*P.x + D.m12*P.y
    rem not required: t2 = D.m21*P.x + D.m22*P.y

    rem plug t1 back into original equation to find intersection position
    ret.x = x1 + t1*d1.x
    ret.y = y1 + t1*d1.y
        
endfunction 1

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 24th Jun 2014 18:22

Link

thank you very much !

Check when I get home!

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 24th Jun 2014 18:50

Link

Hi !

mmmm. I found aerror in the translation to DbPro

proble is Type/EndType

type Mat2x2 is not global and you have problem in Function

and ather problem that i not understand ... ( sorry and than )

Ciao , Guido

my mail is [email protected]

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 25th Jun 2014 01:25 Edited at: 25th Jun 2014 01:26

Link

I accidentally switched t1 and t2.

Here's the unoptimised code (don't use this, this is only so you understand the math):

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#
    t1# = D.m21#*P.x# + D.m22#*P.y#

rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#
        
endfunction 1

+ Code Snippet

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

    rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

    rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#
    t1# = D.m21#*P.x# + D.m22#*P.y#

    rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#
        
endfunction 1

Since we only need t2, there's some stuff we can omit to make it faster:

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

rem compute inverse of matrix (only necessary fields are computed for speed)
    D.m11# = D.m22#/det#
    D.m12# = -D.m12#/det#

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t1
    rem is omitted.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#

rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#

endfunction 1

+ Code Snippet

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

    rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

    rem compute inverse of matrix (only necessary fields are computed for speed)
    D.m11# = D.m22#/det#
    D.m12# = -D.m12#/det#

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t1
    rem is omitted.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#

    rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#

endfunction 1

Example:

`%Project Title%
`2d_intersection.dba
`======================

rem setup screen
sync on
sync rate 60
backdrop on
color backdrop 0
show mouse

rem required for 2D return values
global ret as Vec2

rem position and direction of two entities
x1 = 200
y1 = 200
a1 = 76

x2 = 400
y2 = 500
a2 = 170

rem main loop
do
	
	rem user info
	set cursor 0, 0
	
	rem draw entities
	circle x1, y1, 10
	line x1, y1, cos(a1)*20+x1, sin(a1)*20+y1
	circle x2, y2, 10
	line x2, y2, cos(a2)*20+x2, sin(a2)*20+y2
	
	if intersect2D(x1, y1, x2, y2, a1, a2)
		center text ret.x#, ret.y#+20, "intersection"
		circle ret.x#, ret.y#, 10
	else
		print "no intersection"
	endif
	
	rem refresh screen
	sync 
	
rem end of main loop
loop

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

rem compute inverse of matrix (only necessary fields are computed for speed)
    D.m11# = D.m22#/det#
    D.m12# = -D.m12#/det#

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t1
    rem is omitted.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#

rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#

endfunction 1

+ Code Snippet

`%Project Title%
`2d_intersection.dba
`======================

rem setup screen
sync on
sync rate 60
backdrop on
color backdrop 0
show mouse

rem required for 2D return values
global ret as Vec2

rem position and direction of two entities
x1 = 200
y1 = 200
a1 = 76

x2 = 400
y2 = 500
a2 = 170

rem main loop
do
	
	rem user info
	set cursor 0, 0
	
	rem draw entities
	circle x1, y1, 10
	line x1, y1, cos(a1)*20+x1, sin(a1)*20+y1
	circle x2, y2, 10
	line x2, y2, cos(a2)*20+x2, sin(a2)*20+y2
	
	if intersect2D(x1, y1, x2, y2, a1, a2)
		center text ret.x#, ret.y#+20, "intersection"
		circle ret.x#, ret.y#, 10
	else
		print "no intersection"
	endif
	
	rem refresh screen
	sync 
	
rem end of main loop
loop

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

    rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

    rem compute inverse of matrix (only necessary fields are computed for speed)
    D.m11# = D.m22#/det#
    D.m12# = -D.m12#/det#

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since we only need one of the t's, computing t1
    rem is omitted.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    t2# = D.m11#*P.x# + D.m12#*P.y#

    rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + t2#*d2.x#
    ret.y# = y2# + t2#*d2.y#

endfunction 1

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 13:31

Link

Thank you !!

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 15:18

Link

Hi Comet,

I tried your code now
I made some changes just to try better

In the attached picture you will see that there is a problem,

in the case of the figure should not respond with an intersection ...

Can you help me?

Thank , Guido

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 25th Jun 2014 15:32

Link

Oh right, try changing this:

+ Code Snippet

if det# = 0.0 then exitfunction 0

to this:

+ Code Snippet

if det# <= 0.0 then exitfunction 0

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 15:42

Link

mmm. same problem intersection is detected ...

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 15:47

Link

ps thank ...

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 25th Jun 2014 15:57

Link

Really? Damn, I guess I suck at math. Does this work?

+ Code Snippet

t2# = D.m11#*P.x# + D.m12#*P.y#

Add this line:

+ Code Snippet

t2# = D.m11#*P.x# + D.m12#*P.y#
if t2# < 0.0 then exitfunction 0

I'm at work so can't verify what I'm saying. It's got something to do with t2 and the determinant being greater than 0.

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 16:01

Link

Ciao ,

still not ok,

No problem now I have to go back to work too!

Thank Guido

Ps This evening can i write you an e-mail ?

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 25th Jun 2014 16:26

Link

No need for e-mails when we have this shiny forum.

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 25th Jun 2014 21:34

Link

... sorry any news ? ( thank )

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 26th Jun 2014 00:58

Link

Made it better. New code:

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

type RetType
	x# as float
	y# as float
	dist1# as float
	dist2# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since directional vectors are unit vectors,
	 rem t1 and t2 are also the distance.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    ret.dist2# = D.m11#*P.x# + D.m12#*P.y#
	 if ret.dist2# <= 0.0 then exitfunction 0
    ret.dist1# = D.m21#*P.x# + D.m22#*P.y#
	 if ret.dist1# <= 0.0 then exitfunction 0

rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + ret.dist2#*d2.x#
    ret.y# = y2# + ret.dist2#*d2.y#
        
endfunction 1

+ Code Snippet

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

type RetType
	x# as float
	y# as float
	dist1# as float
	dist2# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

    rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

    rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since directional vectors are unit vectors,
	 rem t1 and t2 are also the distance.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    ret.dist2# = D.m11#*P.x# + D.m12#*P.y#
	 if ret.dist2# <= 0.0 then exitfunction 0
    ret.dist1# = D.m21#*P.x# + D.m22#*P.y#
	 if ret.dist1# <= 0.0 then exitfunction 0

    rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + ret.dist2#*d2.x#
    ret.y# = y2# + ret.dist2#*d2.y#
        
endfunction 1

Example:

`2d_intersection
`2d_intersection.dba
`======================

rem setup screen
sync on
sync rate 60
backdrop on
color backdrop 0
show mouse

rem required for 2D return values
global ret as RetType

rem position and direction of two entities
x1 = 200
y1 = 200
a1 = 76

x2 = 400
y2 = 500
a2 = 170

drag = 0
change_angle = 0

initMouse()

rem main loop
do
	
	rem user info
	set cursor 0, 0
	print "Left-click to drag and drop entities"
	print "Right-click to change angle of entities"
	
	processMouse()
	
	rem drag and drop entities
	if Mouse.posEdge = LEFT_MOUSE_BUTTON
		if (Mouse.position.x-x1)^2 + (Mouse.position.y-y1)^2 < 100 then drag = 1
		if (Mouse.position.x-x2)^2 + (Mouse.position.y-y2)^2 < 100 then drag = 2
	endif
	if Mouse.negEdge = LEFT_MOUSE_BUTTON then drag = 0
	if drag = 1
		x1 = Mouse.position.x
		y1 = Mouse.position.y
	endif
	if drag = 2
		x2 = Mouse.position.x
		y2 = Mouse.position.y
	endif
	
	rem change angle of entities
	if Mouse.posEdge = RIGHT_MOUSE_BUTTON
		if (Mouse.position.x-x1)^2 + (Mouse.position.y-y1)^2 < 100 then change_angle = 1
		if (Mouse.position.x-x2)^2 + (Mouse.position.y-y2)^2 < 100 then change_angle = 2
	endif
	if Mouse.negEdge = RIGHT_MOUSE_BUTTON then change_angle = 0
	if change_angle = 1 then a1 = atanfull(Mouse.position.y-y1, Mouse.position.x-x1)
	if change_angle = 2 then a2 = atanfull(Mouse.position.y-y2, Mouse.position.x-x2)
	
	rem draw entities
	circle x1, y1, 10
	line x1, y1, cos(a1)*20+x1, sin(a1)*20+y1
	circle x2, y2, 10
	line x2, y2, cos(a2)*20+x2, sin(a2)*20+y2
	
	if intersect2D(x1, y1, x2, y2, a1, a2)
		center text ret.x#, ret.y#+20, "intersection"
		center text ret.x#, ret.y#+32, "distance to entity 1: "+str$(ret.dist1#)
		center text ret.x#, ret.y#+44, "distance to entity 2: "+str$(ret.dist2#)
		circle ret.x#, ret.y#, 10
	else
		print "no intersection"
	endif
	
	rem refresh screen
	sync 
	
rem end of main loop
loop

#constant LEFT_MOUSE_BUTTON         0x01
#constant RIGHT_MOUSE_BUTTON        0x02
#constant MIDDLE_MOUSE_BUTTON       0x04

type IntVec3
    x as integer
    y as integer
    z as integer
endtype

type MouseVT
    state as integer
    posEdge as integer
    negEdge as integer
    position as IntVec3
    relative as IntVec3
endtype

function initMouse()
    global Mouse as MouseVT
endfunction

function processMouse()
    rem fast positive/negative edge detection
    Mouse.posEdge = mouseclick() && (Mouse.state..0x07)
    Mouse.negEdge = (mouseclick()..0x07) && Mouse.state
    Mouse.state = mouseclick()
    rem relative positions
    Mouse.relative.x = mousemovex()
    Mouse.relative.y = mousemovey()
    Mouse.relative.z = mousemovez()
    rem absolute positions
    Mouse.position.x = mousex()
    Mouse.position.y = mousey()
    Mouse.position.z = mousez()
endfunction

function positionMouse(x, y)
    Mouse.position.x = x
    Mouse.position.y = y
    position mouse x, y
endfunction

rem --------------------------------------------------------------------------
rem intersection code begins here
rem --------------------------------------------------------------------------

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

type RetType
	x# as float
	y# as float
	dist1# as float
	dist2# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since directional vectors are unit vectors,
	 rem t1 and t2 are also the distance.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    ret.dist2# = D.m11#*P.x# + D.m12#*P.y#
	 if ret.dist2# <= 0.0 then exitfunction 0
    ret.dist1# = D.m21#*P.x# + D.m22#*P.y#
	 if ret.dist1# <= 0.0 then exitfunction 0

rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + ret.dist2#*d2.x#
    ret.y# = y2# + ret.dist2#*d2.y#
        
endfunction 1

+ Code Snippet

`2d_intersection
`2d_intersection.dba
`======================

rem setup screen
sync on
sync rate 60
backdrop on
color backdrop 0
show mouse

rem required for 2D return values
global ret as RetType

rem position and direction of two entities
x1 = 200
y1 = 200
a1 = 76

x2 = 400
y2 = 500
a2 = 170

drag = 0
change_angle = 0

initMouse()

rem main loop
do
	
	rem user info
	set cursor 0, 0
	print "Left-click to drag and drop entities"
	print "Right-click to change angle of entities"
	
	processMouse()
	
	rem drag and drop entities
	if Mouse.posEdge = LEFT_MOUSE_BUTTON
		if (Mouse.position.x-x1)^2 + (Mouse.position.y-y1)^2 < 100 then drag = 1
		if (Mouse.position.x-x2)^2 + (Mouse.position.y-y2)^2 < 100 then drag = 2
	endif
	if Mouse.negEdge = LEFT_MOUSE_BUTTON then drag = 0
	if drag = 1
		x1 = Mouse.position.x
		y1 = Mouse.position.y
	endif
	if drag = 2
		x2 = Mouse.position.x
		y2 = Mouse.position.y
	endif
	
	rem change angle of entities
	if Mouse.posEdge = RIGHT_MOUSE_BUTTON
		if (Mouse.position.x-x1)^2 + (Mouse.position.y-y1)^2 < 100 then change_angle = 1
		if (Mouse.position.x-x2)^2 + (Mouse.position.y-y2)^2 < 100 then change_angle = 2
	endif
	if Mouse.negEdge = RIGHT_MOUSE_BUTTON then change_angle = 0
	if change_angle = 1 then a1 = atanfull(Mouse.position.y-y1, Mouse.position.x-x1)
	if change_angle = 2 then a2 = atanfull(Mouse.position.y-y2, Mouse.position.x-x2)
	
	rem draw entities
	circle x1, y1, 10
	line x1, y1, cos(a1)*20+x1, sin(a1)*20+y1
	circle x2, y2, 10
	line x2, y2, cos(a2)*20+x2, sin(a2)*20+y2
	
	if intersect2D(x1, y1, x2, y2, a1, a2)
		center text ret.x#, ret.y#+20, "intersection"
		center text ret.x#, ret.y#+32, "distance to entity 1: "+str$(ret.dist1#)
		center text ret.x#, ret.y#+44, "distance to entity 2: "+str$(ret.dist2#)
		circle ret.x#, ret.y#, 10
	else
		print "no intersection"
	endif
	
	rem refresh screen
	sync 
	
rem end of main loop
loop

#constant LEFT_MOUSE_BUTTON         0x01
#constant RIGHT_MOUSE_BUTTON        0x02
#constant MIDDLE_MOUSE_BUTTON       0x04

type IntVec3
    x as integer
    y as integer
    z as integer
endtype

type MouseVT
    state as integer
    posEdge as integer
    negEdge as integer
    position as IntVec3
    relative as IntVec3
endtype

function initMouse()
    global Mouse as MouseVT
endfunction

function processMouse()
    rem fast positive/negative edge detection
    Mouse.posEdge = mouseclick() && (Mouse.state..0x07)
    Mouse.negEdge = (mouseclick()..0x07) && Mouse.state
    Mouse.state = mouseclick()
    rem relative positions
    Mouse.relative.x = mousemovex()
    Mouse.relative.y = mousemovey()
    Mouse.relative.z = mousemovez()
    rem absolute positions
    Mouse.position.x = mousex()
    Mouse.position.y = mousey()
    Mouse.position.z = mousez()
endfunction

function positionMouse(x, y)
    Mouse.position.x = x
    Mouse.position.y = y
    position mouse x, y
endfunction

rem --------------------------------------------------------------------------
rem intersection code begins here
rem --------------------------------------------------------------------------

type Vec2
    x# as float
    y# as float
endtype

type Mat2x2
    m11# as float
    m12# as float
    m21# as float
    m22# as float
endtype

type RetType
	x# as float
	y# as float
	dist1# as float
	dist2# as float
endtype

function intersect2D(x1#, y1#, x2#, y2#, angle1#, angle2#)

    rem build matrix from directional vectors for simultaneous linear equation solving
    D as Mat2x2
    d2 as Vec2
    d2.x# = cos(angle2#)
    d2.y# = sin(angle2#)
    D.m11# = d2.x#
    D.m12# = -cos(angle1#)
    D.m21# = d2.y#
    D.m22# = -sin(angle1#)

    rem if matrix is singular (i.e. determinant is zero), no solution exists
    det# = D.m11#*D.m22# - D.m12#*D.m21#
    if det# = 0.0 then exitfunction 0

    rem compute inverse of matrix
    temp# = D.m11#
    D.m11# = D.m22#/det#
    D.m22# = temp#/det#
    D.m12# = -D.m12#/det#
    D.m21# = -D.m21#/det#

    rem Multiply inverse of matrix with difference of the input position vectors
    rem The result is t1 and t2. Since directional vectors are unit vectors,
	 rem t1 and t2 are also the distance.
    P as Vec2
    P.x# = x1#-x2#
    P.y# = y1#-y2#
    ret.dist2# = D.m11#*P.x# + D.m12#*P.y#
	 if ret.dist2# <= 0.0 then exitfunction 0
    ret.dist1# = D.m21#*P.x# + D.m22#*P.y#
	 if ret.dist1# <= 0.0 then exitfunction 0

    rem plug t2 back into original equation to find intersection position
    ret.x# = x2# + ret.dist2#*d2.x#
    ret.y# = y2# + ret.dist2#*d2.y#
        
endfunction 1

hands are ruined by repetitive stroking... - Mr. V, 2014

Back to top

Profile PM Email Website

Guido Italy

20

Years of Service

User Offline

Joined: 25th Dec 2005

Location:

Posted: 26th Jun 2014 15:19

Link

Fantastic !

Is perfect !

Many many Thank !

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Intersect point