There are two default lights, an ambient light which lights every point in the scene uniformly regardless of position or orientation, and light 0 which is a directional light. Your demo therefore had three lights: the ambient light, the default directional light 0 and your point light 1. Simply hide light 0 and you'll see the effect of your light (plus ambient light of course).
There's one further issue you need to bear in mind with DBPro point lights - the lighting is calculated per vertex and the result is interpolated over the relevant polygons. This can give unexpected results with low poly plains, boxes, etc. For example, if you create a plain using
make object plain 1, 500, 500
position object 1, 0, 0, 10
and then light it using a point light as follows:
hide light 0 ` turn off the default directional light
set ambient light 0 ` this turns off the ambient light
make light 1
set point light 1, 0, 0, 0
set light range 1, 100
you will find that the plain is completely unlit even though the centre of the plain is only 10 units away from the point light.
What's happened is that all the vertices of the plain, which are located at the four corners, are beyond the light's range and so get a light value of zero. This is what then gets interpolated over the whole object - the central point of the plain, for example, will simply be lit by the average of the two diagonally opposite corner points and the average of two zeroes is zero.
There at least two solutions, one is to use high poly plains instead of default plains (IanM's Matrix1 plugins have a function for this) which will reduce this effect to some extent, a second solution is to use a shader to give you true per pixel lighting.
I use the second but it does require you to know about shaders - or at least how to use them.
A further problem with default point lights is that it isn't obvious how they are attenuated with distance - for example you can't make a light brighter just by increasing the range. In a shader you can get exactly the attenuation effect you want.
The following demo illustrates the difference between the default low poly plains and the high poly ones provided by the Matrix1 commands:
set display mode desktop width(), desktop height(), 32
sync on : sync rate 60 : sync
autocam off
position camera 0, 0, -500
point camera 0, 0, 0
useDefaultPlain = 0
if useDefaultPlain
make object plain 1, 500, 500
else ` use high poly plain using Matrix1 version of the command
make object plain 1, 500, 500, 40, 40
xrotate object 1, -90 ` Matrix1 plains need to be rotated
endif
position object 1, 0, 0, 10
color object 1, rgb(255, 0, 0) ` bright red
hide light 0 ` turn off the default directional light
set ambient light 0 ` this turns off the ambient light
make light 1
set point light 1, 0, 0, 0 ` this light will be just 10 DBPro world units from the plain
color light 1, rgb(255, 255, 255) ` full white light just in case
set light range 1, 100 ` this light won't reach the four corners of the plain
` but it does reach the intermediate vertices of the high poly version
repeat
sync
until spacekey()
Hope this helps.
