Sorry your browser is not supported!

function spriteselected()
    
        //LOAD MOUSE COLLISION
if image exist(60000) and sprite exist(60000) = 1
    delete image 60000
    delete sprite 60000
ENDIF
load image "Engine\Sprites\mcol.png", 60000
    
    do
        
        
        //MOVE MOUSE COLLISION WITH CURSOR
        sprite 60000, mousex(), mousey(), 60000
        
        //SPRITE NUMBER ON SCREEN
        text 5,5, "Sprite Selected " + str$(spr)
        
        //SCALE SELECTED SPRITE
        if file exist("spritescale") = 1
        open to read 1, "spritescale"
        if file open(1) = 1
        read string 1, spritecalevariable$
        endif
        close file 1
        scale sprite spr, val(spritecalevariable$)
        delete file "spritescale"
        endif
        
        //MOVE SELECTED SPRITE
        if mouseclick() = 1
        mssprmv = mssprmv + 1
        if mssprmv = 2
        sprite sprsel, mousex(), mousey(), img
        endif
        endif
        if mouseclick() = 0
        mssprmv = 0
        endif
        
        //SCALE SELECTED SPRITE
        if mouseclick() = 2
        sprprop = sprprop + 1
        if sprprop = 2
        open to write 1, "sprprop"
        endif
        close file 1
        else
        sprprop = 0
        endif
        
        //EXIT FUNCTION
        if keystate(1) = 1
        exit
        ENDIF
        
        
        
        sync
LOOP
    
    
    
    
ENDFUNCTION

REM Variables ////////////////////////////////
#CONSTANT SPR_CURSOR = 6000
Global _ImgIdx = 0



hide mouse

REM Load images //////////////////////////////
load image "c:\cursor.png", 6000
sprite SPR_CURSOR, 0, 0, 6000
// Set cursor sprite's priorit so it always appears on top
set sprite priority SPR_CURSOR, 1




sync on

REPEAT
    cls
    
    // Move cursor sprite with mouse
    sprite 6000, mousex(), mousey(), SPR_CURSOR
    
    
    // Press space key to load a new sprite
    // Flag variable keeps from loading multiple sprites at a time
    // if space key were to be held down.
    if spacekey() = 1 and flag = 0
        flag = 1
        importSprite("c:\hfavatar.png")
    endif
    if spacekey() = 0 then flag = 0
    
    
    
    
    if mouseclick() = 1
        // if no sprite has been selected yet
        if selectID = 0
            // Loop through sprites backwards, because we want to detect
            // collision with what appears to be the topmost sprite first
            for i = _ImgIdx to 1 step -1
                // Check for collision with cursor
                if sprite collision(SPR_CURSOR, i) = 1
                    // On initial contact with sprite, store the offset
                    // of the sprite's position from the mouse. This is
                    // so we can position the sprite based on where the
                    // cursor is instead of the sprite's origin (the top-
                    // left corner) jumping to the mouse.
                    if offsetX = -1
                        offsetX = mousex() - sprite x(i)
                        offsetY = mousey() - sprite y(i)
                    endif
                    
                    // Store selected sprite's ID
                    selectID = i
                    // Exit the loop early once a sprite collision is detected
                    exit
                endif
            next i
        else // sprite is selected
            // Update sprite's position
            sprite selectID, mousex()-offsetX, mousey()-offsetY, selectID
        endif
    else
        // Reset flags
        offsetX  = -1
        selectID = 0
    endif
    

    
    // Display some helpful feedback
    set cursor 0,0
    print "Sprite Count: ",_ImgIdx
    
    sync
UNTIL escapekey() = 1
end




////////////////////////////////////////////////////////////////
// Give an image, this will load the image and assign it
// to a sprite. Both image ID and sprite ID will be the same.
///////////////////////////////////////////////////////////////
function importSprite(imgPath$)
    // increment our image pointer. 
    // this keeps track of how many sprites we have
    inc _ImgIdx, 1
    
    // load the image
    load image imgPath$, _ImgIdx
    
    // create the sprite and center its position on screen
    sprite _ImgIdx, screen width()/2 - image width(_ImgIdx)/2, screen height()/2 - image height(_ImgIdx)/2, _ImgIdx
endfunction