Sort of procedurally generated landscape?

Author

Message

Fluorescent

FPSC Reloaded TGC Backer

19

Years of Service

User Offline

Joined: 1st Aug 2005

Location: Stockholm, Sweden

Posted: 21st Aug 2015 19:53 Edited at: 21st Aug 2015 19:55

Link

I've been enjoying making classic games in AppGameKit and I was thinking that my next project should be Lunar Lander.

I was thinking about an approach regarding procedurally generating the landscape that the lander must travel over. And it's probably quite difficult to explain, but I'll try.

If I define a high of my landscape, for example between 0 and 10, this is not pixels but a arbitrary unit, And I then make a sprite where the mountain starts at say 8 on the left side and end on 5 on the right and as long as I then pick a sprite that starts with 5 these two sprites will appear to fit together.

So my approach is that I can randomly pick a starting sprite and as long as the next sprite has the same starting value as the previous sprites ending value the level would always appear new but also appear to fit together. The biggest drawback that I see is that I would have to create several sprites for each starting value in order to get a big variation of the levels.

Does this seem like a usable solution or can you see any big flaws, except for the fact that I can't draw anything?

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 26th Aug 2015 01:28 Edited at: 26th Aug 2015 01:42

Link

Do you mean than the sprites would be trapezoid in shape?

If so then I'd generate the height map and then work out the triangle top that would be needed, something like this:

In this case I've limited to the height increments to +/-2 units, this would then require five triangles. So the difference between columns one and two is +1 so this would get top "a", the height difference between five and six is -2 so gets top "d".

To randomly generate the landscape you could do something like this:

// 2D landscape made from columns

SetVirtualResolution(800,480)
SetWindowSize(800,480,0)

for i = 1 to 40
	createSprite(i,0)
	SetSpriteSize(i,20,440)
	col = random(0,5)*5+100
	SetSpriteColor(i,col,col,255,255)
	SetSpritePosition(i,(i-1)*20,280)
next i

do

// create landscape

// starting height
	y = random(20,28)*10

// there are twenty sprites making up the landscape
	// split into 10 groups of 4
	s = 0
	for i = 1 to 10

// calculate height change increment
		repeat
			delta_y = (random(0,4)-2)*20
		until delta_y <> 0

for j = 1 to 4

// calculate new height
			y = y + delta_y

// restrict the height between limits and alter delta_y to bring landscape away from screen edge
			if y <= 80
				y = 80
				delta_y = 20
			endif
			if y >= 440
				y = 440
				delta_y = -20
			endif

// position landscape sprite
			inc s
			SetSpriteY(s,y)

next j

next i

// show landscape
	repeat
		print("press pointer to generate new landscape")

sync()
	until GetPointerPressed() = 1

loop

+ Code Snippet

// 2D landscape made from columns

SetVirtualResolution(800,480)
SetWindowSize(800,480,0)

for i = 1 to 40
	createSprite(i,0)
	SetSpriteSize(i,20,440)
	col = random(0,5)*5+100
	SetSpriteColor(i,col,col,255,255)
	SetSpritePosition(i,(i-1)*20,280)
next i

do

	// create landscape

	// starting height
	y = random(20,28)*10


	// there are twenty sprites making up the landscape
	// split into 10 groups of 4
	s = 0
	for i = 1 to 10

		// calculate height change increment
		repeat
			delta_y = (random(0,4)-2)*20
		until delta_y <> 0

		for j = 1 to 4

			// calculate new height
			y = y + delta_y

			// restrict the height between limits and alter delta_y to bring landscape away from screen edge
			if y <= 80
				y = 80
				delta_y = 20
			endif
			if y >= 440
				y = 440
				delta_y = -20
			endif

			// position landscape sprite
			inc s
			SetSpriteY(s,y)

		next j

	next i

	// show landscape
	repeat
		print("press pointer to generate new landscape")

		sync()
	until GetPointerPressed() = 1

loop

Invaders of the 29th Dimension - available now on Google Play
Find me on indieDB

Attachments

Login to view attachments

Back to top

Profile PM Email

Scraggle

Moderator

21

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 26th Aug 2015 09:27 Edited at: 26th Aug 2015 09:51

Link

I would recommend looking into the midpoint-displacement algorithm. It's a very easy way to generate a random 2D landscape. You could 'seed' it with initial values if you need particular heights along the 'mountain range' or just leave it to do its thing.

A very similar algorithm is often used for 3D terrains and it is then more commonly known as diamond-square but since I presume you are talking 2D then midpoint-displacement is fine

That will get you the 'points' on your terrain. As for getting them on screen - that's a whole different ballgame and it really depends on how you want it to appear.

1. If you want to go for the vector graphics look of the original than drawing lines across the top of the terrain would be fine.
2. If you prefer a filled terrain then having carried out step 1 you could use a fill algorithm on it.
3. If you want a textured surface then things gt a little more tricky.
a. You could try creating a textured sprite and then warp the UVs to fit the terrain but I suspect it might stretch the texture a bit.
b. If the sky (space) is a uniform colour then you could perhaps draw a flat landscape and cut the top out of it by overlaying warped sky sprites on it.

As for collision detection. Regardless of which method you use to draw the landscape, you can use the points array from the midpoint-displacement algorithm to generate a polygon and perform collision calculations on that.

I've just thought of another idea for drawing a textured terrain and I like it a lot!
Create an image that will cover the screen left to right (or tiled) and as far up as your mountain range will go. Put that image into a memblock and then run through it and check against the result of the M-D algorithm. If the point is outside the range (i.e not part of the landscape) then change the pixel value to full alpha making it invisible

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

BatVink

Moderator

21

Years of Service

User Offline

Joined: 4th Apr 2003

Location: Gods own County, UK

Posted: 26th Aug 2015 09:49

Link

I used the same method as 29 Games in the game below.

Scraggle, useful link, bookmarked for another day

Quidquid latine dictum sit, altum sonatur
TutCity is being rebuilt

Back to top

Profile PM Email

Fluorescent

FPSC Reloaded TGC Backer

19

Years of Service

User Offline

Joined: 1st Aug 2005

Location: Stockholm, Sweden

Posted: 26th Aug 2015 20:34

Link

@29 games, @BatVink, do I need to create sprites for every possible angle for the sprites on top of the "pilars" for the solution to work? Have I understood the problem correctly?

Back to top

Profile PM

BatVink

Moderator

21

Years of Service

User Offline

Joined: 4th Apr 2003

Location: Gods own County, UK

Posted: 27th Aug 2015 11:17

Link

It depends on your tiles. If they are textured, you will need sprites that are 1 tile and 2 tiles high for example. If your tile is textured in a specific direction (e.g horizontal bricks) then you will also need 1 and 2-tile wide sprites.

If they are just one colour, you can create a 1-tile angled sprite and stretch it. You can also rotate and mirror it to get everything you need.

Quidquid latine dictum sit, altum sonatur
TutCity is being rebuilt

Back to top

Profile PM Email

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 27th Aug 2015 12:00 Edited at: 27th Aug 2015 12:01

Link

This thread inspired me to make a simple canon shooting game.

http://forum.thegamecreators.com/?m=forum_view&t=215283&b=48&p=0

Invaders of the 29th Dimension - available now on Google Play
Find me on indieDB

Back to top

Profile PM Email

gwargl

9

Years of Service

User Offline

Joined: 31st Aug 2015

Location:

Posted: 31st Aug 2015 21:15

Link

Hi,

I think i've managed to port code from scraggle link.
I'm new to agk so it isn't perfect (as my english

).
For example, I've lost a couple of hour with integer/float (no) implicit conversion...

// Project: 2dMidpointDisplacement 
// Created: 2015-08-31
// Inspired by Loktar http://www.somethinghitme.com/2013/11/11/simple-2d-terrain-with-midpoint-displacement
// set window properties
SetWindowTitle( "2dMidpointDisplacement" )
SetWindowSize( 1024, 768, 0 )
SetDisplayAspect ( 1024.0/768.0)
//SetWindowSize( 1280, 800, 0 )
//SetDisplayAspect ( 1280.0/800.0)
//SetDisplayAspect ( 640/480.0)
SetOrientationAllowed( 1, 1, 1, 1 )

points as float[]
points2 as float[]
displace as float 
roughness as float

// our array size (must be of form 2n +1)
// an array of 64 contains 65 values
terrainStep=64

// How much height can vary 
displace  =25.0 //25%
roughness =0.6
points=makeTerrainHeight(displace,roughness,terrainStep,0)
points2=makeTerrainHeight(displace,roughness,terrainStep,points[points.length])

percentageXStep as float
a1 as float
a2 as float
percentageXStep=100.0/terrainStep

offset as float = 0
do
	offset = offset -0.8
	Print(points[points.length])
	Print(points2[0])
    Print(percentageXStep)
	for i = 0 to points.length -1
		DrawLine(i*percentageXStep+offset,points[i],(i+1)*percentageXStep+offset,points[i+1],255,0,0)	
    next i
 
    for i = 0 to points2.length -1
		DrawLine(i*percentageXStep+offset+100,points2[i],(i+1)*percentageXStep+offset+100,points2[i+1],255,255,0)	
    next i
    
    if ( offset < -100)
        points = points2
        points2 = makeTerrainHeight(displace,roughness,terrainStep,points[points.length])
        offset = 0
    endif
    
 
    Sync()
loop

// displace : How much height can vary
// roughness : control smoothing
// size : size of terrain array  must be a power of two (2n+1)
// seed : define first point height to seed if <> 0

function makeTerrainHeight(displace as float, roughness as float,size,seed as float)
	
	terrainPoints as float[]
	terrainPoints.length=size

t as float
	if seed = 0
		//terrainPoints[0]=100-Random(minHeight,maxHeight)
		t=Random(0,100)/100.0
		terrainPoints[0]=50.0+(2*t*displace)-displace
	else
		terrainPoints[0]=seed
	endif
	t=Random(0,100)/100.0
	//terrainPoints[size]=100-Random(minHeight,maxHeight)
	
	terrainPoints[size]=50.0+(2*t*displace)-displace
	displace=displace*roughness
	// Increase the number of segments
	i=1
	
	while i < size
		
		j=(size/i)/2
	
		while j < size
			startp=j - (size / i) / 2.0
			endp= j + (size / i) / 2.0
		
			terrainPoints[j] = (terrainPoints[startp] + terrainPoints[endp])/2.0
           // terrainPoints[j] = terrainPoints[j]+Random(-deviation,deviation)
           t=Random(0,100)/100.0
           terrainPoints[j] = terrainPoints[j]+(2*t*displace)-displace
			j=j+size/i 
			
		endwhile
		displace=displace*roughness
	
		i=i*2
	endwhile
	
	
endfunction terrainPoints

+ Code Snippet

// Project: 2dMidpointDisplacement 
// Created: 2015-08-31
// Inspired by Loktar http://www.somethinghitme.com/2013/11/11/simple-2d-terrain-with-midpoint-displacement
// set window properties
SetWindowTitle( "2dMidpointDisplacement" )
SetWindowSize( 1024, 768, 0 )
SetDisplayAspect ( 1024.0/768.0)
//SetWindowSize( 1280, 800, 0 )
//SetDisplayAspect ( 1280.0/800.0)
//SetDisplayAspect ( 640/480.0)
SetOrientationAllowed( 1, 1, 1, 1 )

points as float[]
points2 as float[]
displace as float 
roughness as float 

// our array size (must be of form 2n +1)
// an array of 64 contains 65 values
terrainStep=64

// How much height can vary 
displace  =25.0 //25%
roughness =0.6
points=makeTerrainHeight(displace,roughness,terrainStep,0)
points2=makeTerrainHeight(displace,roughness,terrainStep,points[points.length])


percentageXStep as float
a1 as float
a2 as float
percentageXStep=100.0/terrainStep

offset as float = 0
do
	offset = offset -0.8
	Print(points[points.length])
	Print(points2[0])
    Print(percentageXStep)
	for i = 0 to points.length -1
		DrawLine(i*percentageXStep+offset,points[i],(i+1)*percentageXStep+offset,points[i+1],255,0,0)	
    next i
 
    for i = 0 to points2.length -1
		DrawLine(i*percentageXStep+offset+100,points2[i],(i+1)*percentageXStep+offset+100,points2[i+1],255,255,0)	
    next i
    
    if ( offset < -100)
        points = points2
        points2 = makeTerrainHeight(displace,roughness,terrainStep,points[points.length])
        offset = 0
    endif
    
 
    Sync()
loop


// displace : How much height can vary
// roughness : control smoothing
// size : size of terrain array  must be a power of two (2n+1)
// seed : define first point height to seed if <> 0

function makeTerrainHeight(displace as float, roughness as float,size,seed as float)
	
	terrainPoints as float[]
	terrainPoints.length=size

	t as float
	if seed = 0
		//terrainPoints[0]=100-Random(minHeight,maxHeight)
		t=Random(0,100)/100.0
		terrainPoints[0]=50.0+(2*t*displace)-displace
	else
		terrainPoints[0]=seed
	endif
	t=Random(0,100)/100.0
	//terrainPoints[size]=100-Random(minHeight,maxHeight)
	
	terrainPoints[size]=50.0+(2*t*displace)-displace
	displace=displace*roughness
	// Increase the number of segments
	i=1
	
	while i < size
		
		j=(size/i)/2
	
		while j < size
			startp=j - (size / i) / 2.0
			endp= j + (size / i) / 2.0
		
			terrainPoints[j] = (terrainPoints[startp] + terrainPoints[endp])/2.0
           // terrainPoints[j] = terrainPoints[j]+Random(-deviation,deviation)
           t=Random(0,100)/100.0
           terrainPoints[j] = terrainPoints[j]+(2*t*displace)-displace
			j=j+size/i 
			
		endwhile
		displace=displace*roughness
	
		i=i*2
	endwhile
	
	
endfunction terrainPoints

Back to top

Profile PM

Scraggle

Moderator

21

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 1st Sep 2015 00:11 Edited at: 1st Sep 2015 00:20

Link

That's a nice scrolling terrain you have there

Rather coincidentally, I did one of these too.

Press W to toggle edge wrapping
Press Enter to change the seed

Hold Up or down and then press:
S to change the scale of the terrain.
P to change the amount of points to calculate along it.
R to change the roughness.

And since this thread was brought up because of a lunar lander project:
Press F to create a flat spot on the terrain to land on.

I was going to handle the collision next but I've got side-tracked (or rather, stopped being side-tracked) and got on with my main project.
However, all of the ponints that make up the terrain are stored in an array so it will be a very easy job to create a polygon collision mesh from them.

This is the terrain code. I've kept it separate so that it can be dropped into any project:

type tTerrain2D
	width as float
	points as float[]
	seed as float
	scale as float
	roughness as float
	wrap as integer
endtype

global terrain2D as tTerrain2D[]

function CreateTerrain2D( points, width#, roughness#, wrap, seed# )

if seed# <0 then seed# = timer()
	SetRandomSeed(seed#)

displace# = 50.0

terrain2D.length = terrain2D.length + 1
	t = terrain2D.length

terrain2D[t].width = width#
	terrain2D[t].seed = seed#
	terrain2D[t].roughness = roughness#
	terrain2D[t].wrap = wrap

terrain2D[t].points.length = points
	terrain2D[t].points[0] = random(-displace#, displace#)
	if wrap
		terrain2D[t].points[points] = terrain2D[t].points[0]
	else
		terrain2D[t].points[points] = random(displace#, displace#)
	endif

newstep = points
	repeat
		for k = 0 to points-midpoint step newstep
			midpoint = newstep>>1
			displace( t, k+midpoint, midpoint, displace# )
		next k
		newstep = midpoint
		displace# =  displace# * roughness#
	until newStep = 1
endfunction t

function displace( t, p, m, d# )
	terrain2D[t].points[p] = (terrain2D[t].points[p-m] + terrain2D[t].points[p+m]) *0.5
	inc terrain2D[t].points[p], random(0,d#*2)-d#
endfunction

function DrawTerrain( t, h#, s# )
	s = makecolor( 192, 192, 192 )
	b = MakeColor( 64, 64, 64 )
	xStep# = terrain2D[t].width/terrain2D[t].points.length
	for k = 1 to terrain2D[t].points.length
		drawline( (k-1)*xStep#, h#-(terrain2D[t].points[k-1]*s#), k*xStep#, h#-(terrain2D[t].points[k]*s#), s, s)
		drawline( (k)*xStep#, h#, k*xStep#, h#-(terrain2D[t].points[k]*s#), b, b)
	next k
endfunction

function DeleteTerrain(t)
	terrain2D.remove(t)
endfunction

function CreateTerrainFlatSpot( t, pos, width, height# )
	if height#<0
		totalHeight# = 0
		for k = pos to pos+width
			inc totalHeight#, terrain2D[t].points[k]
		next k
		avgHeight# = totalHeight#/(width+1)
	else
		avgHeight# = height#
	endif
	for k = pos to pos+width
		terrain2D[t].points[k] = avgHeight#
	next k
endfunction

function GetTerrainNearestPoint( t, p )
	n = p/(display.dw/terrain2D[t].points.length)
endfunction n

function GetTerrainX( t, p )
	x# = (terrain2D[t].width/terrain2D[t].points.length) * p
endfunction x#

+ Code Snippet

type tTerrain2D
	width as float
	points as float[]
	seed as float
	scale as float
	roughness as float
	wrap as integer
endtype

global terrain2D as tTerrain2D[]


function CreateTerrain2D( points, width#, roughness#, wrap, seed# )

	if seed# <0 then seed# = timer()
	SetRandomSeed(seed#)

	displace# = 50.0

	terrain2D.length = terrain2D.length + 1
	t = terrain2D.length

	terrain2D[t].width = width#
	terrain2D[t].seed = seed#
	terrain2D[t].roughness = roughness#
	terrain2D[t].wrap = wrap

	terrain2D[t].points.length = points
	terrain2D[t].points[0] = random(-displace#, displace#)
	if wrap
		terrain2D[t].points[points] = terrain2D[t].points[0]
	else
		terrain2D[t].points[points] = random(displace#, displace#)
	endif

	newstep = points
	repeat
		for k = 0 to points-midpoint step newstep
			midpoint = newstep>>1
			displace( t, k+midpoint, midpoint, displace# )
		next k
		newstep = midpoint
		displace# =  displace# * roughness#
	until newStep = 1
endfunction t


function displace( t, p, m, d# )
	terrain2D[t].points[p] = (terrain2D[t].points[p-m] + terrain2D[t].points[p+m]) *0.5
	inc terrain2D[t].points[p], random(0,d#*2)-d#
endfunction


function DrawTerrain( t, h#, s# )
	s = makecolor( 192, 192, 192 )
	b = MakeColor( 64, 64, 64 )
	xStep# = terrain2D[t].width/terrain2D[t].points.length
	for k = 1 to terrain2D[t].points.length
		drawline( (k-1)*xStep#, h#-(terrain2D[t].points[k-1]*s#), k*xStep#, h#-(terrain2D[t].points[k]*s#), s, s)
		drawline( (k)*xStep#, h#, k*xStep#, h#-(terrain2D[t].points[k]*s#), b, b)
	next k
endfunction


function DeleteTerrain(t)
	terrain2D.remove(t)
endfunction


function CreateTerrainFlatSpot( t, pos, width, height# )
	if height#<0
		totalHeight# = 0
		for k = pos to pos+width
			inc totalHeight#, terrain2D[t].points[k]
		next k
		avgHeight# = totalHeight#/(width+1)
	else
		avgHeight# = height#
	endif
	for k = pos to pos+width
		terrain2D[t].points[k] = avgHeight#
	next k
endfunction


function GetTerrainNearestPoint( t, p )
	n = p/(display.dw/terrain2D[t].points.length)
endfunction n


function GetTerrainX( t, p )
	x# = (terrain2D[t].width/terrain2D[t].points.length) * p
endfunction x#

And this the 'main' file used to call the terrain functions and provide user input:

// Project: TerrainGenerator2D
// Created: 2015-08-31

#include "../_libs/display.agc"
#include "terrain2D.agc"

initDisplay( VIRTUAL, 1024, 480 )

SetPrintSize(14)
global seed#
global points
global roughness#
global wrap
global scale#

seed# = 0
points = 128
roughness# = 0.5
wrap = 1
scale# = 4.0

t = CreateTerrain2D( points, display.dw, roughness#, wrap, seed# )

do
	if GetUserInput(t)
		DeleteTerrain(t)
		realSeed# = seed#
		if seed# = -1 then realSeed# = timer()
		t = CreateTerrain2D( points, display.dw, roughness#, wrap, realSeed# )
	endif
	DrawTerrain( t, display.b, scale# )

print("Seed = " + str(realSeed#))
	print("Points = " + str(points))
	print("Roughness = " + str(roughness#))
	print("Wrap = " + str(wrap))
	print("Scale = " + str(scale#))
	print("Points = " + str(terrain2D[t].points.length))
	print("")

Sync()
loop

function GetUserInput(t)

if GetRawKeyState(38)
		if GetRawKeyPressed(80)
			points=points<<1
			exitfunction 1
		endif
		if GetRawKeyState(82)
			inc roughness#, 0.001
			exitfunction 1
		endif
		if GetRawKeyState(83)
			inc scale#, 0.01
			exitfunction 1
		endif
	endif

if GetRawKeyState(40)
		if GetRawKeyPressed(80)
			if points > 2
				points=points>>1
				exitfunction 1
			endif
		endif
		if GetRawKeyState(82)
			dec roughness#, 0.001
			exitfunction 1
		endif
		if GetRawKeyState(83)
			dec scale#, 0.01
			exitfunction 1
		endif
	endif

if GetRawKeyPressed(70)
		CreateTerrainFlatSpot(t, random(0, terrain2D[t].points.length-10), random(3,10), -1)
		DrawTerrain( t, display.b, scale# )
		exitfunction 0
	endif

if GetRawKeyPressed(87)
		wrap = not wrap
		exitfunction 1
	endif

if GetRawKeyPressed(13)
		seed# = random(0, 1000) * 0.1
		exitfunction 1
	endif

endfunction 0

+ Code Snippet

// Project: TerrainGenerator2D
// Created: 2015-08-31

#include "../_libs/display.agc"
#include "terrain2D.agc"


initDisplay( VIRTUAL, 1024, 480 )

SetPrintSize(14)
global seed#
global points
global roughness#
global wrap
global scale#

seed# = 0
points = 128
roughness# = 0.5
wrap = 1
scale# = 4.0

t = CreateTerrain2D( points, display.dw, roughness#, wrap, seed# )

do
	if GetUserInput(t)
		DeleteTerrain(t)
		realSeed# = seed#
		if seed# = -1 then realSeed# = timer()
		t = CreateTerrain2D( points, display.dw, roughness#, wrap, realSeed# )
	endif
	DrawTerrain( t, display.b, scale# )


	print("Seed = " + str(realSeed#))
	print("Points = " + str(points))
	print("Roughness = " + str(roughness#))
	print("Wrap = " + str(wrap))
	print("Scale = " + str(scale#))
	print("Points = " + str(terrain2D[t].points.length))
	print("")

    Sync()
loop

function GetUserInput(t)

	if GetRawKeyState(38)
		if GetRawKeyPressed(80)
			points=points<<1
			exitfunction 1
		endif
		if GetRawKeyState(82)
			inc roughness#, 0.001
			exitfunction 1
		endif
		if GetRawKeyState(83)
			inc scale#, 0.01
			exitfunction 1
		endif
	endif

	if GetRawKeyState(40)
		if GetRawKeyPressed(80)
			if points > 2
				points=points>>1
				exitfunction 1
			endif
		endif
		if GetRawKeyState(82)
			dec roughness#, 0.001
			exitfunction 1
		endif
		if GetRawKeyState(83)
			dec scale#, 0.01
			exitfunction 1
		endif
	endif

	if GetRawKeyPressed(70)
		CreateTerrainFlatSpot(t, random(0, terrain2D[t].points.length-10), random(3,10), -1)
		DrawTerrain( t, display.b, scale# )
		exitfunction 0
	endif

	if GetRawKeyPressed(87)
		wrap = not wrap
		exitfunction 1
	endif

	if GetRawKeyPressed(13)
		seed# = random(0, 1000) * 0.1
		exitfunction 1
	endif

endfunction 0

Oops!
I forgot about this. You will need to drop my display set up in there too:

+ Code Snippet

#constant VIRTUAL 0
#constant PERCENTAGE 1

type tDisplay
	dw as integer
	dh as integer
	l as integer
	t as integer
	r as integer
	b as integer
	w as integer
	h as integer
	cx as integer
	cy as integer
	aspect as float
	style as integer
endtype

global display as tDisplay



function initDisplay( style, x#, y# )

	display.dw = x#
	display.dh = y#
	display.aspect = (display.dw*1.0)/(display.dh*1.0)
	display.style = style

	SetWindowSize( x#, y#, 0 )

	if style = VIRTUAL
		SetVirtualResolution( display.dw, display.dh )
	else
		SetDisplayAspect( display.aspect )
	endif

	display.l = GetScreenBoundsLeft()
	display.r = GetScreenBoundsRight()
	display.t = GetScreenBoundsTop()
	display.b = GetScreenBoundsBottom()
	display.w = display.r - display.l
	display.h = display.b - display.t
	display.cx = display.w * 0.5
	display.cy = display.h * 0.5

	SetScissor( display.l, display.t, display.r, display.b )

endfunction

If you are going to use this in a game then I would recommend using a different method to draw it.

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

gwargl

9

Years of Service

User Offline

Joined: 31st Aug 2015

Location:

Posted: 1st Sep 2015 10:49

Link

Thanks for sharing !

Back to top

Profile PM

Sorry your browser is not supported!

AppGameKit Classic Chat / Sort of procedurally generated landscape?

Attachments