Sorry your browser is not supported!

// Project: UncleM_ProjectileMotion
// Created: 2015-08-01
// Demonstrates simple projectile motion using basic physics calculations
// by: Uncle Martin

// set window properties
SetWindowTitle( "UncleM_ProjectileMotion" )
SetWindowSize( 1024, 768, 0 )
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )

// Create an object for projectile
Image = LoadImage("Ball1.png")
Sprite = CreateSprite(Image)

// Set constants
#constant GroundY# = 400
#constant StartX# = 20
#constant VelUp# = 20.0
#constant VelFwd# = 6.0
#constant GravityY# = 1.0
#constant FrictionX# = 0.05
#constant Bounce = 0

// Position
y# = GroundY#
x# = StartX#

// Velocity
yVel# = 0.0
xVel# = 0.0

// Acceleration
yAcc# = -GravityY#
xAcc# = 0.0

repeat

	// Draw ground line
	DrawLine(0, GroundY#+50, 1023, GroundY#+50, 0,255,0)

	// Apply impulse to object when triggered
	if (GetRawKeyPressed(32)) // Space Bar pressed
		yVel# = VelUp#
		xVel# = VelFwd#
	endif

	// Integrate object position based on velocities
	y# = y# - yVel#
	x# = x# + xVel#

	// Position the object
	SetSpriteX(Sprite, x#)
	SetSpriteY(Sprite, y#)

	// Integrate velocity based on accelerations
	xVel# = xVel# + xAcc#
	yVel# = yVel# + yAcc#

	if (Bounce)
		// Bouncing
		// Trigger an impulse a liitle smaller when object hits floor
		If y# > GroundY#-5
			y# = GroundY#
			xVel# = (1.0-FrictionX#)*xVel#
			yVel# = -yVel# * .7
		endif
	else
		// Flopping
		// Freeze the object when it hits the ground
		If y# > GroundY#-5
			y# = GroundY#
			xVel# = (1.0-FrictionX#)*xVel#
			yVel# = 0.0
		endif
	endif

    Print( ScreenFPS() )
    Sync()

until GetRawKeyState(27) // Esc

// AGK 2.0.14b
// Project: Throw It 
// MR 10.10.2015

spr=CreateSprite(0)
SetSpriteSize(spr,10,10)
SetSpritePositionByOffset(spr,50,50)
SetSpriteColor(spr,255,0,0,255)

sprground=createsprite(0)
SetSpriteSize(sprground,100,5)
SetSpritePosition(sprground,0,50+5)
SetSpriteColor(sprground,192,128,64,255)

Type TThrow	
	action as integer
	spr as integer
	xstart as float
	ystart as float
	xdistance as float
	angle as float
	dir	as float
	flyingheight as float
endtype

throw as TThrow
throw.spr=spr

do

	print("Click beside Sprite")

	if GetPointerPressed()
		throw.xstart=GetSpriteXByOffset(throw.spr)
		throw.ystart=GetSpriteYByOffset(throw.spr)
		throw.angle=0
		throw.action=1
		if GetPointerX()<throw.xstart then throw.dir =  1		
		if GetPointerX()>throw.xstart then throw.dir = -1
		throw.xdistance = 20.0 
		throw.flyingheight= 5.0
	endif

	ThrowIt(throw)

    Sync()
loop
end

function ThrowIt(throw ref as TThrow)

	//print(throw.action)

	if throw.action=0 then exitfunction
	
	throw.angle = throw.angle + (360.0 / 60.0) //degrees per second (at 60 FPS)
	
	//print(throw.angle)
	
	if throw.angle => 180.0 then throw.action=0
		
	x# = throw.xstart + sin((throw.angle / 2.0) * throw.dir ) * throw.xdistance 
	y# = throw.ystart - sin(throw.angle) * throw.flyingheight
	
	if x#<GetSpriteWidth(throw.spr)/2.0 then x#=GetSpriteWidth(throw.spr)/2.0
	if x#>GetVirtualWidth()-GetSpriteWidth(throw.spr)/2.0 then x#=GetVirtualWidth()-GetSpriteWidth(throw.spr)/2.0
	
	SetSpritePositionByOffset(throw.spr,x#,y#)
	
endfunction

// set window properties
SetWindowTitle( "Throw" )
SetWindowSize( 1280, 800, 0 )

// set display properties
SetDisplayAspect(-1)

global Player
global Enemy
global ground
global collide
global gcollide
global throw = 0
global ythrow# = -5.0
global grav# = 0.09
global Eyspeed# = 0.0
global Eyvelocity# = 88.0
global x1# = 0

CreatePlayer()
CreateEnemy()
CreateGround()

Efeet# = GetSpriteHeight(Enemy)

do

EfeetPos# = GetSpriteY(Enemy)+Efeet#

//Fix Enemy Position On the Ground
if EfeetPos# >= GetSpriteY(ground)
	collide = 1
	Eyspeed# = 0
	Eyvelocity# = 88.0 //Set Enemy Y to 72 (On top of Ground)
else
	collide = 0
	Eyspeed# = Eyspeed# + grav#
endif

//Get Collision Between Player and Enemy
collide = GetSpriteCollision(Player,Enemy)

//Get Collision Between Enemy and Ground
gcollide = GetSpriteCollision(Enemy,ground)

//Move Player To Direction
if GetRawKeyState(37) = 1
	SetSpriteX(Player,GetSpriteX(Player)-0.3)
elseif GetRawKeyState(39) = 1
	SetSpriteX(Player,GetSpriteX(Player)+0.3)	
endif

if collide = 1
	X1# = GetSpriteX(Enemy) // 30
	y1# = GetSpriteY(Enemy)
	Eyspeed# = -1.5
	throw = 1
endif

if throw = 1
	if GetSpriteX(Enemy) <= (X1#+20)
		SetSpritePosition(Enemy,GetSpriteX(enemy)+0.5,GetSpriteY(enemy))		
	else
		throw = 0
                if GetSpriteX(Enemy) >= (X1#+20) then SetSPriteX(Enemy,X1#+20)
	endif
endif

Eyvelocity# = Eyvelocity# + Eyspeed#
SetSpritePosition(Enemy,GetSpriteX(Enemy),Eyvelocity#)

    Print(throw)
    Print(GetSpriteX(Enemy))
    Print("collide: " + str(collide))
    Sync()
loop


//================================ Functions
Function CreatePlayer()
	Player = CreateSprite(0)
	SetSpriteSize(Player,5,-1)
	SetSpritePosition(Player,10,88)
	SetSPriteColor(Player,162,162,162,255)
EndFunction

Function CreateEnemy()
	Enemy = CreateSprite(0)
	SetSpriteSize(Enemy,5,-1)
	SetSpritePosition(Enemy,30,88)
	SetSPriteColor(Enemy,181,70,73,255)
EndFunction

Function CreateGround()
	ground = CreateSprite(0)
	SetSpriteSize(ground,100,4)
	SetSpritePosition(ground,0,96)
EndFunction