Problem regarding move camera left from IAN M's plugin

Author

Message

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 20th Nov 2015 12:22

Link

DBPRO compile the code when i am using the following codes: move camera left and move camera right, but the application doesn't run.

Any ideas on how can fix this?

Thank You!

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 20th Nov 2015 16:36 Edited at: 20th Nov 2015 16:39

Link

If those are the only functions causing the problem. You can use this instead.

+ Code Snippet

function MoveCameraRight(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   rotate camera camID, 0, wrapvalue(sy+90), sz
   move camera camID, dist
   rotate camera camID, sx, sy, sz
endfunction

function MoveCameraLeft(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   rotate camera camID, 0, wrapvalue(sy-90), sz
   move camera camID, dist
   rotate camera camID, sx, sy, sz
endfunction

Back to top

Profile PM Email

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 20th Nov 2015 17:04

Link

This works extremely well!

Can you explain the code so i better understand it? I am stuck at "rotate camera camID, 0, wrapvalue(sy+90), sz"

Why do we put twice rotate camera?

Thank you very much.

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 20th Nov 2015 17:29 Edited at: 20th Nov 2015 17:40

Link

The directions right, left, forward and backward are typically on the x/z plain. The Move Camera function will move the camera forward. By rotating it 90 degrees on the y axis then moving the camera the specified distance and then setting the camera angles back, effectively moves the camera right.

Back to top

Profile PM Email

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 20th Nov 2015 17:43

Link

Actually this may be better.

+ Code Snippet

function MoveCameraRight(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   rotate camera camID, 0, wrapvalue(sy+90), 0
   move camera camID, dist
   rotate camera camID, sx, sy, sz
endfunction

function MoveCameraLeft(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   rotate camera camID, 0, wrapvalue(sy-90), 0
   move camera camID, dist
   rotate camera camID, sx, sy, sz
endfunction

Back to top

Profile PM Email

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 20th Nov 2015 18:01

Link

I understand partially but i still don't understand fully why rotate camera 0, 0, wrapvalue(cammovy# -90), cammovz# and why rotate camera 0, cammovx#, cammovy#, cammovz# .

why is there -90 and twice.

Sorry for the inconvenience.

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 20th Nov 2015 18:40

Link

Now I’m confused. Maybe this will help.

function MoveCameraRight(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

` store camera angles
   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

` rotate camera right: +90. set x and z angles to 0(see next comment)
   rotate camera camID, 0, wrapvalue(sy+90), 0
   ` move camera forward on the x/z plain only
   move camera camID, dist
   ` restore camera angles
   rotate camera camID, sx, sy, sz
endfunction

function MoveCameraLeft(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

` store camera angls
   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

` rotate camera left: -90. set x and z angles to 0(see next comment)
   rotate camera camID, 0, wrapvalue(sy-90), 0
   ` move camera forward on the x/z plain only
   move camera camID, dist
   ` restore camera angles
   rotate camera camID, sx, sy, sz
endfunction

+ Code Snippet

function MoveCameraRight(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   ` store camera angles
   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   ` rotate camera right: +90. set x and z angles to 0(see next comment)
   rotate camera camID, 0, wrapvalue(sy+90), 0
   ` move camera forward on the x/z plain only
   move camera camID, dist
   ` restore camera angles
   rotate camera camID, sx, sy, sz
endfunction

function MoveCameraLeft(camID as integer, dist as float)
   local sx as float
   local sy as float
   local sz as float

   ` store camera angls
   sx = camera angle x(camID)
   sy = camera angle y(camID)
   sz = camera angle z(camID)

   ` rotate camera left: -90. set x and z angles to 0(see next comment)
   rotate camera camID, 0, wrapvalue(sy-90), 0
   ` move camera forward on the x/z plain only
   move camera camID, dist
   ` restore camera angles
   rotate camera camID, sx, sy, sz
endfunction

Back to top

Profile PM Email

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 23rd Nov 2015 12:55

Link

Yep, thats more like it.

I do have another question, i am controlling the camera using those WASD keys and the mouse through this code:

+ Code Snippet

if mouseclick() = 2	
	hide mouse
	x# = x# + mousemovey() / 1.5
	y# = y# + mousemovex() / 1.5
	xrotate camera 0, x#
	yrotate camera 0, y#
	else
	show mouse
	mousemovey() = 0
	mousemovex() = 0
	ENDIF

This is present in multiple functions. Every time when i am exiting one function and it get in another, the camera jumps in other angle instantly when i am pressing the right click mouse button. I want to stay in the same angle when i exited the function.

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 23rd Nov 2015 18:35

Link

Your function seems sound in itself. If you could work up a quick snippet demonstrating the problem, it would be easier to solve.

Back to top

Profile PM Email

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 24th Nov 2015 12:01

Link

Alright, this is the code example with the mouse control over the camera code:

+ Code Snippet

sync on
sync rate 60

backdrop on 0
color backdrop 0, rgb(0,0,0)

make object cube 1, 25

disable escapekey

do
	
	text 5,5, "PRESS ENTER TO ENTER ANOTHER FUNCTION"
	
	if mouseclick() = 2	
	hide mouse
	x# = x# + mousemovey() / 1.5
	y# = y# + mousemovex() / 1.5
	xrotate camera 0, x#
	yrotate camera 0, y#
	else
	show mouse
	mousemovey() = 0
	mousemovex() = 0
	ENDIF
	
	if returnkey() = 1
	anotherfunction()
	ENDIF
	
	
	
	
	
	sync
LOOP

function anotherfunction()
	
	
	
	do
		
	
	text 5,5, "PRESS ESCAPE TO EXIT ANOTHER FUNCTION"
	
	if mouseclick() = 2	
	hide mouse
	x# = x# + mousemovey() / 1.5
	y# = y# + mousemovex() / 1.5
	xrotate camera 0, x#
	yrotate camera 0, y#
	else
	show mouse
	mousemovey() = 0
	mousemovex() = 0
	ENDIF
		
		
	if keystate(1) = 1
	exit
	ENDIF
		
		
		sync
LOOP
	
	
	
ENDFUNCTION

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

Cescano

9

Years of Service

User Offline

Joined: 4th Sep 2014

Location: Italy

Posted: 24th Nov 2015 18:28 Edited at: 24th Nov 2015 18:41

Link

By using "mousemovey() = 0" you are not resetting the movement, so it keeps tracking the movement of your mouse, and when you come back with the rotation of the camera it will jump because the value is big.

try to do this instead:

+ Code Snippet

if mouseclick() = 2 
    hide mouse
    mouseMovX#= mousemovex() / 1.5
    mouseMovY#= mousemovey() / 1.5
    x#= wrapvalue(x#+mouseMovX#)
    y#= wrapvalue(y#+mouseMovY#)
    xrotate camera 0, x#
    yrotate camera 0, y#
else
    show mouse
    mouseMovX#= mousemovex()
    mouseMovY#= mousemovey()
endif

Remember to set mouseMovX# and mouseMovY# as globals.

Also if you keep aligned "if" "else" and "endif" the code will be more readable.

Edit:

I have also changed the code to add the wrapvalue command so that when the rotation goes over 360 degrees it will restart to count from 0.

Example: 350 +50 will not be 400 degrees (which would be wrong as rotation degrees goes up to 360) but the new value will be 40 degrees.

Back to top

Profile PM Website

WickedX

15

Years of Service

User Offline

Joined: 8th Feb 2009

Location: A Mile High

Posted: 24th Nov 2015 18:51

Link

If you are just wanting both scenes to share the same camera angles, you need to make the x# and y# variables global. I have rewritten your code in this snippet demonstrating this solution.

global g_StateFlag as integer
global g_OldKey as integer
global g_CamAngX as float
global g_CamAngY as float

gosub _Init

do
   CamControl()

text 5,5, "PRESS SPACE TO ENTER TO CHANGE SCENE. PRESS ESC TO EXIT."

if (keystate(1))
      g_StateFlag = 0
   endif

select g_StateFlag
      case 1:
         Scene1()
      endcase
      case 2:
         Scene2()
      endcase
      case default:
         exit
      endcase
   endselect

sync
loop

end

_Init:
   disable escapekey

sync on
   sync rate 60

backdrop on
   color backdrop 0

make object cube 1, 25
   color object 1, 0xFFFF0000

make object cube 2, 25
   color object 2, 0xFF0000FF
   hide object 2

g_StateFlag = 1
return

function CamControl()
   if (mouseclick()=2)
      hide mouse
      g_CamAngX = g_CamAngX+mousemovey()/1.5
      g_CamAngY = g_CamAngY+mousemovex()/1.5
      xrotate camera 0, g_CamAngX
      yrotate camera 0, g_CamAngY
    else
      show mouse
      mousemovey() = 0
      mousemovex() = 0
    endif
endfunction

function GetKey()
   local Key as integer

Key = scancode()

if (Key=g_OldKey)
      Key = 0
   else
      g_OldKey = Key
   endif
endfunction Key

function Scene1()
   if (GetKey()=57)
      g_StateFlag = 2
      hide object 1
      show object 2
   endif
endfunction

function Scene2()
   if (GetKey()=57)
      g_StateFlag = 1
      hide object 2
      show object 1
   endif
endfunction

+ Code Snippet

global g_StateFlag as integer
global g_OldKey as integer
global g_CamAngX as float
global g_CamAngY as float

gosub _Init

do
   CamControl()

   text 5,5, "PRESS SPACE TO ENTER TO CHANGE SCENE. PRESS ESC TO EXIT."

   if (keystate(1))
      g_StateFlag = 0
   endif

   select g_StateFlag
      case 1:
         Scene1()
      endcase
      case 2:
         Scene2()
      endcase
      case default:
         exit
      endcase
   endselect

   sync
loop

end

_Init:
   disable escapekey

   sync on
   sync rate 60

   backdrop on
   color backdrop 0

   make object cube 1, 25
   color object 1, 0xFFFF0000

   make object cube 2, 25
   color object 2, 0xFF0000FF
   hide object 2

   g_StateFlag = 1
return

function CamControl()
   if (mouseclick()=2)
      hide mouse
      g_CamAngX = g_CamAngX+mousemovey()/1.5
      g_CamAngY = g_CamAngY+mousemovex()/1.5
      xrotate camera 0, g_CamAngX
      yrotate camera 0, g_CamAngY
    else
      show mouse
      mousemovey() = 0
      mousemovex() = 0
    endif
endfunction

function GetKey()
   local Key as integer

   Key = scancode()

   if (Key=g_OldKey)
      Key = 0
   else
      g_OldKey = Key
   endif
endfunction Key

function Scene1()
   if (GetKey()=57)
      g_StateFlag = 2
      hide object 1
      show object 2
   endif
endfunction

function Scene2()
   if (GetKey()=57)
      g_StateFlag = 1
      hide object 2
      show object 1
   endif
endfunction

However, if you want to preserve the camera angles for each scene, you’ll need to store the camera angles for each scene globally. Something like this.

type t_CAMANG
   x as float
   y as float
   z as float
endtype

dim g_CamAng(1) as t_CAMANG

global g_StateFlag as integer
global g_OldKey as integer

gosub _Init

do
   CamControl()

text 5,5, "PRESS SPACE TO ENTER TO CHANGE SCENE. PRESS ESC TO EXIT."

if (keystate(1))
      g_StateFlag = 0
   endif

select g_StateFlag
      case 1:
         Scene1()
      endcase
      case 2:
         Scene2()
      endcase
      case default:
         exit
      endcase
   endselect

sync
loop

end

_Init:
   disable escapekey

sync on
   sync rate 60

backdrop on
   color backdrop 0

make object cube 1, 25
   color object 1, 0xFFFF0000

make object cube 2, 25
   color object 2, 0xFF0000FF
   hide object 2

for i=0 to 1
      g_CamAng(i).x = camera angle x()
      g_CamAng(i).y = camera angle y()
      g_CamAng(i).x = camera angle z()
   next i

g_StateFlag = 1
return

function CamControl()
   if (mouseclick()=2)
      hide mouse
      g_CamAng(g_StateFlag-1).x = g_CamAng(g_StateFlag-1).x+mousemovey()/1.5
      g_CamAng(g_StateFlag-1).y = g_CamAng(g_StateFlag-1).y+mousemovex()/1.5
      xrotate camera 0, g_CamAng(g_StateFlag-1).x
      yrotate camera 0, g_CamAng(g_StateFlag-1).y
    else
      show mouse
      mousemovey() = 0
      mousemovex() = 0
    endif
endfunction

function GetKey()
   local Key as integer

Key = scancode()

if (Key=g_OldKey)
      Key = 0
   else
      g_OldKey = Key
   endif
endfunction Key

function Scene1()
   if (GetKey()=57)
      g_StateFlag = 2
      hide object 1
      show object 2
      rotate camera g_CamAng(g_StateFlag-1).x, g_CamAng(g_StateFlag-1).y, 0
   endif
endfunction

function Scene2()
   if (GetKey()=57)
      g_StateFlag = 1
      hide object 2
      show object 1
      rotate camera g_CamAng(g_StateFlag-1).x, g_CamAng(g_StateFlag-1).y, 0
   endif
endfunction

+ Code Snippet

type t_CAMANG
   x as float
   y as float
   z as float
endtype

dim g_CamAng(1) as t_CAMANG

global g_StateFlag as integer
global g_OldKey as integer

gosub _Init

do
   CamControl()

   text 5,5, "PRESS SPACE TO ENTER TO CHANGE SCENE. PRESS ESC TO EXIT."

   if (keystate(1))
      g_StateFlag = 0
   endif

   select g_StateFlag
      case 1:
         Scene1()
      endcase
      case 2:
         Scene2()
      endcase
      case default:
         exit
      endcase
   endselect

   sync
loop

end

_Init:
   disable escapekey

   sync on
   sync rate 60

   backdrop on
   color backdrop 0

   make object cube 1, 25
   color object 1, 0xFFFF0000

   make object cube 2, 25
   color object 2, 0xFF0000FF
   hide object 2

   for i=0 to 1
      g_CamAng(i).x = camera angle x()
      g_CamAng(i).y = camera angle y()
      g_CamAng(i).x = camera angle z()
   next i

   g_StateFlag = 1
return

function CamControl()
   if (mouseclick()=2)
      hide mouse
      g_CamAng(g_StateFlag-1).x = g_CamAng(g_StateFlag-1).x+mousemovey()/1.5
      g_CamAng(g_StateFlag-1).y = g_CamAng(g_StateFlag-1).y+mousemovex()/1.5
      xrotate camera 0, g_CamAng(g_StateFlag-1).x
      yrotate camera 0, g_CamAng(g_StateFlag-1).y
    else
      show mouse
      mousemovey() = 0
      mousemovex() = 0
    endif
endfunction

function GetKey()
   local Key as integer

   Key = scancode()

   if (Key=g_OldKey)
      Key = 0
   else
      g_OldKey = Key
   endif
endfunction Key

function Scene1()
   if (GetKey()=57)
      g_StateFlag = 2
      hide object 1
      show object 2
      rotate camera g_CamAng(g_StateFlag-1).x, g_CamAng(g_StateFlag-1).y, 0
   endif
endfunction

function Scene2()
   if (GetKey()=57)
      g_StateFlag = 1
      hide object 2
      show object 1
      rotate camera g_CamAng(g_StateFlag-1).x, g_CamAng(g_StateFlag-1).y, 0
   endif
endfunction

Back to top

Profile PM Email

MateiSoft Romania

10

Years of Service

User Offline

Joined: 16th Oct 2013

Location:

Posted: 24th Nov 2015 20:23

Link

Hello Cescano, Hello, WickedX,

Well, problem solved, thank you for your awesome help!

The problem was as WickedX said, to make x# and y# as globals, i totally forgot about that and that is the simplest and logical explanation, to make them global to read the values throughout the entire application.

Thank You again!

Alex Matei CEO
www.alexmatei.com

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Problem regarding move camera left from IAN M's plugin