Sorry your browser is not supported!

// Input sliders demo
// Germán Fabregat - 2015
#include "slider.agc"

// Tamaño pantalla
#constant pantX		480
#constant pantY		800

SetVirtualResolution(pantX, pantY) 

img = LoadImage("fondo.png")
backSpr = CreateSprite (img)
SetSpriteSize (backSpr, pantX, pantY)

// Create sliders
sr = CreateSlider(80,  60, "R", 0, 255)
sg = CreateSlider(80, 140, "G", 0, 255)
sb = CreateSlider(80, 220, "B", 0, 255)

do
	UpdateSlider(sr)
	UpdateSlider(sg)
	UpdateSlider(sb)
	r = GetSliderVal(sr)
	g = GetSliderVal(sg)
	b = GetSliderVal(sb)
	SetSliderTextColor(sr, r, 0, 0, 255)
	SetSliderTextColor(sg, 0, g, 0, 255)
	SetSliderTextColor(sb, 0, 0, b, 255)
	cr = MakeColor(r, 0, 0)
	cg = MakeColor(0, g, 0)
	cb = MakeColor(0, 0, b)
	ct = MakeColor(r, g, b)
	DrawBox( 35, 450, 165, 550, cr, cr, cr, cr, 1) 
	DrawBox( 175, 450, 305, 550, cg, cg, cg, cg, 1) 
	DrawBox( 315, 450, 445, 550, cb, cb, cb, cb, 1) 
	DrawBox( 35, 560, 445, 660, ct, ct, ct, ct, 1) 
	Sync()
loop

// Slider data type
TYPE slider
	min as integer			// Minimum value
	max as integer			// Maximum value
	sprCursor as integer	// Cursor sprite
	sprBar as integer		// Bar sprite
	x as integer			// Horizontal position
	y as integer			// Vertical position
	pos as integer			// Cursor position
	last as integer			// Last position when dragging
	title$ as string		// Title string
	text as integer			// Text to show the value

endtype

// Constants for the slider system
#constant sliderMax	9		// Last slider number
#constant sliderH	64		// Slider heigth = cursor height
#constant sliderW	300		// Slider width
#constant slCurH	64		// Cursor height
#constant slCurW	32		// and width
#constant slBarH	8		// Bar height
#constant slBarW	256		// and width
#constant slTxSize	20		// Text size
#constant slThreshH	5		// Threshold to auto release the cursor when dragging (vertical)
#constant slThreshW	15		// Threshold to auto release the cursor when dragging (horizontal)
// System variables
global sliders as slider[10]		// Slider array
global slUsed as integer[10]		// We can erase any
global slCursorImage = -1			// images ids
global slBarImage = -1
global sliderNum = 0				// Current slider number



// Creates a fixed size slider at position x, y
// Displaying text as title and generating value
// between min and max
// Returns the integer id of the slider
function CreateSlider(x, y, text$, min, max)
	temp as slider
	
	// If we have free slots 
	if sliderNum < sliderMax
		// load the images and init the system
		// if it is not yet done
		if slCursorImage = - 1 
			slCursorImage = LoadImage("sliderCursor.png")
			slBarImage = LoadImage("sliderBar.png")
			// If it is the first time we have not 
			// deleted slots. So we assign the first
			// and mark the rest as unused
			num = sliderNum
			for i = 1 to 9
				slUsed[i] = 0
			next i
		else
			num = 0
			while slUsed[num] = 1
				num = num + 1
			endwhile
		endif
                sliderNum = sliderNum + 1 // We add a slider in both cases
		// We have the number, mark it as used
		slUsed[num] = 1
		// create the sprites
		spr = CreateSprite(slCursorImage) 
		SetSpriteX(spr, x) // Not yet down
		SetSpriteY(spr, y) 
		SetSpriteSize(spr, slCurW, slCurH)
		SetSpriteDepth (spr, 9) 
		temp.sprCursor = spr
		spr = CreateSprite(slBarImage) 
		SetSpriteX(spr, x + slCurW / 2) // Not yet down
		SetSpriteY(spr, y + (sliderH - slBarH) / 2) 
		SetSpriteSize(spr, slBarW, slBarH)
		temp.sprBar = spr
		// Create and assing the text
		t = CreateText(text$ + ":" + str(min))
		SetTextSize(t, slTxSize)
		SetTextPosition(t, x + slBarW + slCurW + 2, y + (sliderH - slTxSize) / 2)
		SetTextColor(t, 60, 60, 60, 255)
		temp.title$ = text$
		temp.text = t
		// Assign the rest of variables
		temp.x = x
		temp.y = y
		temp.pos = 0
		temp.min = min
		temp.max = max
		temp.last = -1
		// Put it in the array
		sliders[num] = temp
	else
	// return -1 if not
		num = -1
	endif
	
endfunction num

// Deletes the slider with the given id
function DeleteSlider(num)
	
	if num <= sliderMax and slUsed[num] = 1
		slUsed[num] = 0
		sliderNum = sliderNum - 1
		DeleteSprite(sliders[num].sprCursor)
		DeleteSprite(sliders[num].sprBar)
		DeleteText(sliders[num].text)
	endif
	
endfunction

// Returns the integer value of the slider
function GetSliderVal(num)
	value as integer
	
	value = 0
	if num <= sliderMax and slUsed[num] = 1
		value = sliders[num].min + sliders[num].pos * (sliders[num].max - sliders[num].min) / (slBarW - 1)
	endif
	
endfunction value

// Needed to recalculate the position of the cursor and
// value of the slider, and to react to touchs - mouse.
// Should be called once each sync loop
function UpdateSlider(num)
	
	cx as integer
	cy as integer
	incx as integer
	
	if sliders[num].last = -1
		if GetPointerPressed() = 1
			// Get the data of the event if any
			cx = GetPointerX()
			cy = GetPointerY()
			spr = GetSpriteHit(cx, cy)
			// If we are hit we keep the exact point
			if spr = sliders[num].sprCursor then sliders[num].last = cx - (sliders[num].x + sliders[num].pos)
		endif
	else
		if GetPointerReleased() = 1
			sliders[num].last = -1
		else
			// Update pos
			cx = GetPointerX()
			cy = GetPointerY()
			// Verifiy range in Y. Release if too far
			if sliders[num].y - cy > slThreshH or cy - sliders[num].y - slCurH > slThreshH
				sliders[num].last = -1
			else
				incx = cx - (sliders[num].pos + sliders[num].x) - sliders[num].last
				sliders[num].pos = sliders[num].pos + incx
				// Verify range in X. Correct and release if too far
				if sliders[num].pos > slBarW - 1
					if sliders[num].pos - slBarW + 1 > slThreshW then sliders[num].last = -1
					sliders[num].pos = slBarW - 1	
				elseif sliders[num].pos < 0
					if 0 - sliders[num].pos > slThreshW then sliders[num].last = -1
					sliders[num].pos = 0	
				endif
				// Update sprite position
				SetSpriteX(sliders[num].sprCursor, sliders[num].pos + sliders[num].x)
				// Update text
				SetTextString(sliders[num].text, sliders[num].title$ + ":" + str(GetSliderVal(num)))
			endif
		endif
	endif

endfunction

// Sets the image of the cursor
function SetSliderCursorImage(num, img)
	
	if num <= sliderMax and slUsed[num] = 1
		SetSpriteImage(sliders[num].sprCursor, img)
	endif
	
endfunction

// Sets the image of the bar
function SetSliderBarImage(num, img)
	
	if num <= sliderMax and slUsed[num] = 1
		SetSpriteImage(sliders[num].sprBar, img)
	endif
	
endfunction

// Sets the color of the text
function SetSliderTextColor(num, iRed, iGreen, iBlue, iAlpha)
	
	if num <= sliderMax and slUsed[num] = 1
		SetTextColor(sliders[num].text, iRed, iGreen, iBlue, iAlpha)
	endif
	
endfunction

// Sets the title text of the slider
function SetSliderTitle(num, title$)
	
	if num <= sliderMax and slUsed[num] = 1
		sliders[num].title$ = title$
	endif
	
endfunction
	

function calcColour(ret# as float, c ref as tColour)
	
	f = floor(ret# / 16.66667)
	p# = (ret# - (f * 16.66667)) / 16.66667

	select f
		
		case 0
			c.r = 255
			c.g = p# * 255
			c.b = 0
		endcase
		
		case 1
			c.r = 255 - (255 * p#)
			c.g = 255
			c.b = 0
		endcase
		
		case 2
			c.r = 0
			c.g = 255
			c.b = p# * 255
		endcase
		
		case 3
			c.r = 0
			c.g = 255 - (255 * p#)
			c.b = 255
		endcase
		
		case 4
			c.r = p# * 255
			c.g = 0
			c.b = 255
		endcase
		
		case 5
			c.r = 255
			c.g = 0
			c.b = 255 - (255 * p#)
		endcase
		
	endselect

endfunction

							if light# > 50
								l# = ((light# - 50) / 50)
								cr2 = gColour.r + ((255 - gColour.r) * l#)
								cg2 = gColour.g + ((255 - gColour.g) * l#)
								cb2 = gColour.b + ((255 - gColour.b) * l#)
							else
								l# = (50 - light#) / 50
								cr2 = gColour.r - (l# * gColour.r)
								cg2 = gColour.g - (l# * gColour.g)
								cb2 = gColour.b - (l# * gColour.b)
							endif

// Input sliders demo
// Germán Fabregat - 2015
#include "slider.agc"

// Tamaño pantalla
#constant pantX		480
#constant pantY		800

SetVirtualResolution(pantX, pantY) 

img = LoadImage("fondo.png")
backSpr = CreateSprite (img)
SetSpriteSize (backSpr, pantX, pantY)

// Create sliders
sr = CreateSlider(80,  60, "R", 0, 255)
sg = CreateSlider(80, 140, "G", 0, 255)
sb = CreateSlider(80, 220, "B", 0, 255)
sa = CreateSlider(80, 300, "A", 0, 255)

// Create sprites
sprR = CreateSprite(0)
SetSpriteSize(sprR, 130, 100)
SetSpriteColor(sprR, 0, 0, 0, 255)
SetSpritePosition(sprR, 35, 450)
sprG = CreateSprite(0)
SetSpriteSize(sprG, 130, 100)
SetSpriteColor(sprG, 0, 0, 0, 255)
SetSpritePosition(sprG, 175, 450)
sprB = CreateSprite(0)
SetSpriteSize(sprB, 130, 100)
SetSpriteColor(sprB, 0, 0, 0, 255)
SetSpritePosition(sprB, 315, 450)
sprT1 = CreateSprite(0)
SetSpriteSize(sprT1, 205, 100)
SetSpriteColor(sprT1, 0, 0, 0, 0)
SetSpritePosition(sprT1, 35, 560)
sprT2 = CreateSprite(0)
SetSpriteSize(sprT2, 205, 100)
SetSpriteColor(sprT2, 0, 0, 0, 255)
SetSpritePosition(sprT2, 240, 560)
SetSpriteDepth(sprT2, 5)
// Checkered flag
img = LoadImage("chk.png")
sprChk = CreateSprite(img)
SetSpriteSize(sprChk, 205, 100)
SetSpritePosition(sprChk, 240, 560)

// Color Hex text
t = CreateText("00000000")
SetTextSize(t, 40)
SetTextPosition(t, 140, 680)
SetTextColor(t, 0, 0, 0, 255)
do
	UpdateSlider(sr)
	UpdateSlider(sg)
	UpdateSlider(sb)
	UpdateSlider(sa)
	r = GetSliderVal(sr)
	g = GetSliderVal(sg)
	b = GetSliderVal(sb)
	a = GetSliderVal(sa)
	SetSliderTextColor(sr, r, 0, 0, 255)
	SetSliderTextColor(sg, 0, g, 0, 255)
	SetSliderTextColor(sb, 0, 0, b, 255)
	SetSliderTextColor(sa, r, g, b, a)
	text$ = ItoHex(a, 2) + ItoHex(r, 2) + ItoHex(g, 2) + ItoHex(b, 2)
	SetTextString(t, text$)
	SetSpriteColor(sprR, r, 0, 0, 255)
	SetSpriteColor(sprG, 0, g, 0, 255)
	SetSpriteColor(sprB, 0, 0, b, 255)
	SetSpriteColor(sprT1, r, g, b, 255)
	SetSpriteColor(sprT2, r, g, b, a)
	Sync()
loop

// Returns a string of at least pos characters
// with the hex value of v
function ItoHex(v, pos)
	
	ret$ as string
	l as integer
	
	ret$ = Hex(v)
	l = Len(ret$)
	while l < pos
		ret$ = "0" + ret$
		l = l + 1
	endwhile
	
endfunction ret$