The IDE alone is reason good enough to update from v1 to v2.
As for fonts, as have been mentioned, these need be imported into your project. First you need convert a font from its native vector-based format (typically TrueType or OpenType) using a tool such as the one CJB linked to or
UO Bitmap Font Creator. Anyway, using such a tool you'll make a .png font-image and an accompanying text-file that you need save in your projects "../media" folder.
Next you need import that font-image into your project. Within AppGameKit (both 1 and 2) there is a host of commands available to manipulate the output of the font-formatted text. An example code importing a font-image named "arial.png" and then writing "Hello World" with changing character colours in a pulsating effect:
width = 1280
height = 720
SetVirtualResolution(width, height)
SetDisplayAspect(height / width)
SetSyncRate(25, 0)
loadImage(1, "Arial.png")
createText(1, "Hello World")
textDraw(1, 1, 0, 0, 0, 60, width/2, height/2)
SetTextAlignment(1, 1) // center the text
setTextColorAlpha(1, 0) // have it start as transparant
colour = 0
direction = 0
char = 0
alphaCounter = 0
repeat
// fading in and changing colour
if alphaCounter < 256
SetTextCharColor(1, char, 192, colour, 0, alphaCounter)
else
SetTextCharColor(1, char, 192, colour, 0, 255)
endif
// selecting next character, resetting to start if need be
inc char
if char = 11
char = 0
endif
// upping the alpha for the fade-in
inc alphaCounter, 4
// going slowly up, and then quickly down again for a pulsating effect
select direction
case 0
inc colour, 6
if colour => 255
colour = 255
direction = 1
endif
endCase
case 1
dec colour, 48
if colour =< 0
colour = 0
direction = 0
endif
endCase
endselect
sync()
// Repeats until pressing left mouse
until GetPointerPressed() = 1
// a function to set up the text for you, convenient when having many strings to display.
function textDraw(tID, tFont, tRed, tGreen, tBlue, tSize, tPosX, tPosY)
SetTextFontImage(tID, tFont)
//SetTextExtendedFontImage(tID, tFont) // optional, for special characters like æøå
SetTextColor(tID, tRed, tGreen, tBlue, 255)
SetTextSize(tID, tSize)
SetTextPosition(tID, tPosX, tPosY)
SetTextDepth(tID, 1)
SetTextVisible(tID, 1)
endFunction