Creating a single model from multiple objects?

Author

Message

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 17th Apr 2016 14:12

Link

Hi,

Is there a way to turn my individually textured and positioned models in to a single object? I've experimented with the mesh commands, looked at the help files, and searched the forum, but am yet to find a working solution.

My goal is to simply cut down on the number of objects drawn/in memory and whilst I intend to use single objects for levels in future, I'm currently using hundreds of individual cubes to create a retro stylised dungeon.

I did experiment with a culling routine but this only resulted in a gain of around 3fps as the game was still having to deal with the same number of objects.

Any help would be greatly appreciated.

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 19th Apr 2016 23:33

Link

Are you using a single image across all the objects?

If you have all your level objects using the same image it will be very easy to merge it all as one object. I can give you some solutions if thats the case.

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 21st Apr 2016 07:08

Link

I'm using individual textures, but even if I could combine objects of the same texture I would see my map made up of 10 objects rather than 1000.

I'd be grateful for any help.

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 21st Apr 2016 15:53

Link

Are your objects made from agk commands or loaded in?

If loaded in and you can save as obj files i can writeup some quick code for you to merge them together. How are your levels drawn currently?

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 21st Apr 2016 21:27

Link

My levels are created by placing sprites on a grid. Each co-ordinate is then checked, with the image found dictating which object to create in 3D space. The objects are AppGameKit cubes and plains, though I could create suitable .obj models. I have considered re-creating my map in a model editor, but with very little time for development at the moment, a code based solution would be preferable.

My current map runs at 30fps on my Galaxy S5, but is about half the size (possibly only a third) of what I'd expect a full production level to be. However, running the same amount of entities with a map made from a single object runs at 60fps.

Thanks for your time and interest!

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 22nd Apr 2016 00:43

Link

Perfect! I can help then

If you can send me a 2d map example i will write some code for you to convert it to a 3d map single model . once you see what i writeup for ya you should easily be able to add more custom shapes

Back to top

Profile PM Email Website

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 23rd Apr 2016 15:48

Link

actually... I've been thinking about this and thought maybe i should just release an update to my drawing program. post some videos on how it works etc. My drawing app has gotten very powerfull over the years and i see it very usefull for designing worlds or levels for agk even though it was built with darkbasic. File output is obj but if you are interested in using my objects included plugin for agk i also have a binary 3d format that can be saved as a fraction the size of an obj. Also that objects included functions i made also has code in there to build raw objects from scratch.

the trick i use is to build an obj file then load it back in. So really all you need to understand is the obj file format. Have some basic 3d knowledge how 3d is constructed.
i guess they made some commands to edit raw model info using memblocks but i havent looked into that at all.

soo... let me know what would help you the most and i'll see what i can do.

in the meantime i will upload my drawing app and make some videos using it.

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 24th Apr 2016 21:58

Link

Hi,

This code takes data created in AGK's Placement Editor to create a 3D map. Objects are setup according to the image found, with different i.d. variables used to set the object ranges.

I thought I'd be able to combine the objects in to a single mesh after being created, before moving on to the next group of objects, but I've been unsuccessful so far. I really appreciate your time with this.

file = OpenToRead( file$ )
vMode$ = ReadLine( file )
displayWidth$ = ReadLine( file )
displayHeight$ = ReadLine( file )
screenWidth$ = ReadLine( file )
screenHeight$ = ReadLine( file )
screenX$ = ReadLine( file )
screenY$ = ReadLine( file )
width# = Val( displayWidth$ )
height# = Val( displayHeight$ )
temp$ = ReadLine( file )
temp$ = ReadLine( file )
temp$ = ReadLine( file )
x$ = ReadLine( file )
y$ = ReadLine( file )
mediaCount$ = ReadLine( file )
g_iMediaCount = Val( mediaCount$ ) - 1
For i = 0 To Val( mediaCount$ ) - 1
  g_MediaList[ i ].file = ReadLine( file )
  g_MediaList[ i ].image = LoadImage( g_MediaList[ i ].file )
Next i
entityCount$ = ReadLine( file )

` object numbers to start with.
id = 1000

` read the file and use the images to create the map and entities.
For i = 0 To Val( entityCount$ ) - 1

image$  = ReadLine( file )
  index$  = ReadLine( file )
  x$ = ReadLine( file )
  y$ = ReadLine( file )
  percentageX$ = ReadLine( file )
  percentageY$ = ReadLine( file )
  percentageWidth$ = ReadLine( file )
  percentageHeight$ = ReadLine( file )
  locked$ = ReadLine( file )
  depth$ = ReadLine( file )
  properties$ = ReadLine( file )
  scaleX$ = ReadLine( file )
  scaleY$ = ReadLine( file )
  angle$ = ReadLine( file )
  mirror$ = ReadLine( file )
  flip$ = ReadLine( file )
  index = Val( index$ )

` the walls.
  If image$ = "wall 01.png"
    CreateObjectBox( id, 64, 64, 64 )
    SetObjectImage( id, g_MediaList[ index ].image, 0 )
    SetImageMagFilter( g_MediaList[ index ].image, 0 )
    SetObjectPosition( id, val( x$ ), 32, val( y$ ) )
    ` increase the object number.
    id = id + 1
  EndIf

`convert objects in to a single model?!

Next i

CloseFile(file)

+ Code Snippet

file = OpenToRead( file$ )
vMode$ = ReadLine( file )
displayWidth$ = ReadLine( file )
displayHeight$ = ReadLine( file )
screenWidth$ = ReadLine( file )
screenHeight$ = ReadLine( file )
screenX$ = ReadLine( file )
screenY$ = ReadLine( file )
width# = Val( displayWidth$ )
height# = Val( displayHeight$ )
temp$ = ReadLine( file )
temp$ = ReadLine( file )
temp$ = ReadLine( file )
x$ = ReadLine( file )
y$ = ReadLine( file )
mediaCount$ = ReadLine( file )
g_iMediaCount = Val( mediaCount$ ) - 1
For i = 0 To Val( mediaCount$ ) - 1
  g_MediaList[ i ].file = ReadLine( file )
  g_MediaList[ i ].image = LoadImage( g_MediaList[ i ].file )
Next i
entityCount$ = ReadLine( file )


` object numbers to start with.
id = 1000


` read the file and use the images to create the map and entities.
For i = 0 To Val( entityCount$ ) - 1


  image$  = ReadLine( file )
  index$  = ReadLine( file )
  x$ = ReadLine( file )
  y$ = ReadLine( file )
  percentageX$ = ReadLine( file )
  percentageY$ = ReadLine( file )
  percentageWidth$ = ReadLine( file )
  percentageHeight$ = ReadLine( file )
  locked$ = ReadLine( file )
  depth$ = ReadLine( file )
  properties$ = ReadLine( file )
  scaleX$ = ReadLine( file )
  scaleY$ = ReadLine( file )
  angle$ = ReadLine( file )
  mirror$ = ReadLine( file )
  flip$ = ReadLine( file )
  index = Val( index$ )


  ` the walls.
  If image$ = "wall 01.png"
    CreateObjectBox( id, 64, 64, 64 )
    SetObjectImage( id, g_MediaList[ index ].image, 0 )
    SetImageMagFilter( g_MediaList[ index ].image, 0 )
    SetObjectPosition( id, val( x$ ), 32, val( y$ ) )
    ` increase the object number.
    id = id + 1
  EndIf


  `convert objects in to a single model?!


Next i


CloseFile(file)

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 24th Apr 2016 22:23

Link

so this code is only using boxes? do you also have something for floors and ceiling? if so we can cut down on these walls significantly.

I will write up some code to generate the 3d shapes combined as 1 object but it will be up to you to use these functions to create your scene. Give me a few hours to test out some code then i will upload it.

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 24th Apr 2016 22:52

Link

That's extremely kind, and very much appreciated. Thank you. I'd be more than happy to credit you in any suitable project, should you care to share your name along with any code.

I use the same method for setting up all objects in a level, but use plain objects instead of boxes for everything that isn't a wall or a door, as you can see in the screenshot below.

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 02:07 Edited at: 25th Apr 2016 04:05

Link

here is the example of creating a scene from scratch and using a single atlas texture.

now use this code to build the level.... but if you have objects like doors they should be separate objects. Also be sure to turn off collision on your character block or it will collide with itself when you do sphere collision checks.

if you know some simple geometry shapes you could easily add more things to it using code as i did.
any more help needed...please let me know. Im fairly knowledgeable with 3d construction.

this is the code...but download the attachment so you get the image too.

// Created: 2016-04-24

// set window properties
SetWindowTitle( "customshapes" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )

createpointlight(1,0,0,0,500,255,255,255)

setfogmode(1)
setfogrange(1000,10000)
setfogcolor(0,0,0)

//change this to sync rate 0 if you wanna see how fast it can go
setsyncrate(60,1)
//this will initialize the memory to do the job
init_objectcreation()
//this will assign tile types with known texture uv mapping
init_tiletypes()

//lets make a dummy scene
dim scene[64,1,64] //x,y,z

//lets just load a single image in.  you can add 32x32 image tiles to this one and
//split it with code so its usable.  I have used a minecraft texture skin so you can
//see how uv mapping can be interchanged

//for simplicity i will just use 3 tiles   1=floor and 2=cubed wall with grass top
for x=1 to 64 step 1
	for z=1 to 64 step 1
		tp=1 //floor type
		if z=1 or z=64 or x=1 or x=64 then tp=2 //wall type
		// lets randomly plug walls in
		a=random(1,100)
		if a=<20 then tp=2
		scene[x,0,z]=tp
	next z
next x

//ok so we got some sort of random scene with blocks in it
//lets count all the 3d data then construct it

//this could be optimized to save on further geometry not needing to be drawn... but for now try this.
//i dont want to make it too complicated to follow.

//ok count data
max_vertexcount=0
max_indexcount=0
for x=1 to 64 step 1
	for z=1 to 64 step 1
		rd=scene[x,0,z]
		if rd=1 
			max_vertexcount=max_vertexcount+4 //floor object
			max_indexcount=max_indexcount+6
		endif
		
		if rd=2 
			max_vertexcount=max_vertexcount+4 //wall cubed object **this could be optimized fyi**
			max_indexcount=max_indexcount+6
			
			
			//put some top grass on those walls for fun
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
		endif
	next z
next x

//ok lets actually build the model now :)
loadimage(1,"test.png",0)  //this file has up to 256 images each 32x32
setimagemagfilter(1,0)
setimageminfilter(1,0)

//make the array for scene single object
makenewobject(max_vertexcount,max_indexcount,max_vertexcount,max_vertexcount)

global vertex=0
global index=0

for x=1 to 64 step 1
	for z=1 to 64 step 1
		rd=scene[x,0,z]
		usescalex=100
		usescaley=100
		if rd=1 
			add_floor(vertex,index,1,usescalex,usescaley,usescalex,x,1,z) //( vertex,index,uvmap id,scalex,scaley,scalez,x grid,ygrid,zgrid)
			vertex=vertex+4 //floor object
			index=index+6// increase counters
		endif
		
		if rd=2 
			//grass top
			add_floor(vertex,index,3,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //floor object
			index=index+6
			
			addwall_front(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_back(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_right(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_left(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //demensions
			vertex=vertex+4 //wall object
			index=index+6
		endif
	next z
next x

//ok final stage...  the object is in the array 
//lets save it as an object file and load it back in.
savenewobject(2,"mytempobject.obj",1,1)  //saved it and loaded it into id#2
setobjectposition(2,-1000,0,1000)
setobjectimage(2,1,0)
setcamerarange(1,1,20000)

//run collision simulation
testcollision()

end

function testcollision()
createobjectbox(1,50,50,50) //this will be our test character
setobjectposition(1,500,500,500)
setobjectcollisionmode(1,0) //shut off collision detection for this object
setobjectrotation(1,0,180,0)
global gravity#=0.0
global onground=0
do
 rem Old position
 oldx#=Getobjectx(1)
 oldy#=Getobjecty(1)
 oldz#=Getobjectz(1)
 
 if ( GetRawKeyState( 87 ) ) then Moveobjectlocalz(1,12) //"w" to walk forward
 if ( GetRawKeyState( 83 ) ) then Moveobjectlocalz( 1, -12 ) // "s" to walk back
 if ( GetRawKeyState( 65 ) ) then rotateobjectlocaly(1,-6) //"a" turn
 if ( GetRawKeyState( 68 ) ) then rotateobjectlocaly(1,6) //"d"
 
 
 if getrawkeystate(32) and onground=1 then gravity#=30.0 // " " [spacekey to jump]
 
 gravity#=gravity#-3.0
 if onground=1 and gravity#<-2.0 then gravity#=-2.0
 if gravity#<-30 then gravity#=-30

newx#=getobjectx(1)
 newy#=getobjecty(1)+gravity#
 newz#=getobjectz(1)
 
 
 if ObjectSphereSlide(0,oldx#,oldy#,oldz#,newx#,newy#,newz#,35.0)>0
	newx#=GetObjectRayCastSlideX(0)
	//newy#=GetObjectRayCastSlideY(0)
	newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 onground=0
 //floor
 if ObjectSphereSlide(0,newx#,oldy#-45,newz#,newx#,newy#-45,newz#,20.0)>0
	//newx#=GetObjectRayCastSlideX(0)
	newy#=GetObjectRayCastSlideY(0)+45
	if gravity#<0.0 then gravity#=0.0
	onground=1
	//newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 
  //ceiling
 if ObjectSphereSlide(0,newx#,oldy#+45,newz#,newx#,newy#+45,newz#,20.0)>0
	//newx#=GetObjectRayCastSlideX(0)
	newy#=GetObjectRayCastSlideY(0)-45
	if gravity#>0.0 then gravity#=0.0
	onground=0
	//newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 
 
 setobjectposition(1,newx#,newy#,newz#)
 //setobjectposition(1,newx#,newy#,newz#)
 oldx#=newx#
 oldy#=newy#
 oldz#=newz#
	setcameraposition(1,oldx#,oldy#+150,oldz#)
	setcamerarotation(1,0,getobjectangley(1),0)
	movecameralocalz(1,-100)

newx#=getcamerax(1)
	newy#=getcameray(1)
	newz#=getcameraz(1)
	
	
setcameralookat(1,oldx#,oldy#+120,oldz#,0)
//setcamerarotation(1,getcameraanglex(1),getobjectangley(1),getcameraanglez(1))
 
	print( screenfps())
   setpointlightposition(1,oldx#,oldy#,oldz#)
    sync()
loop

endfunction

function add_floor(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0

//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
//uv mapping

//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)

//normals
//this is a floor so should just point up
setvertexdatanormals(v,0.0,1.0,0.0)
setvertexdatanormals(v+1,0.0,1.0,0.0)
setvertexdatanormals(v+2,0.0,1.0,0.0)
setvertexdatanormals(v+3,0.0,1.0,0.0)

//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction

function addwall_front(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//
setvertexdatanormals(v,0.0,0.0,1.0)
setvertexdatanormals(v+1,0.0,0.0,1.0)
setvertexdatanormals(v+2,0.0,0.0,1.0)
setvertexdatanormals(v+3,0.0,0.0,1.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v+2)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v)
//face 2
setindexdata2(i+3,v+3)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v)
//we got a square
//thats it
endfunction

function addwall_back(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//
setvertexdatanormals(v,0.0,0.0,-1.0)
setvertexdatanormals(v+1,0.0,0.0,-1.0)
setvertexdatanormals(v+2,0.0,0.0,-1.0)
setvertexdatanormals(v+3,0.0,0.0,-1.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction

function addwall_right(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,-lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//this is a floor so should just point up
setvertexdatanormals(v,-1.0,0.0,0.0)
setvertexdatanormals(v+1,-1.0,0.0,0.0)
setvertexdatanormals(v+2,-1.0,0.0,0.0)
setvertexdatanormals(v+3,-1.0,0.0,0.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction

function addwall_left(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//this is a floor so should just point up
setvertexdatanormals(v,1.0,0.0,0.0)
setvertexdatanormals(v+1,1.0,0.0,0.0)
setvertexdatanormals(v+2,1.0,0.0,0.0)
setvertexdatanormals(v+3,1.0,0.0,0.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v+2)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v)
//face 2
setindexdata2(i+3,v+3)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v)
//we got a square
//thats it
endfunction

function init_tiletypes()
dim uv_mapper#[256,4]
//assign tile 1 floor uv mapping
//this example image is 512x512 with 32x32 tiles that are 16x16 grid
//floor 1 (dirt)
uv_mapper#[1,1]=(32.000/512.00)
uv_mapper#[1,2]=1.000
uv_mapper#[1,3]=(63.000/512.00)
uv_mapper#[1,4]=1.0-(31.000/512.00)

//wall 1
uv_mapper#[2,1]=96.000/512.000
uv_mapper#[2,2]=1.000
uv_mapper#[2,3]=127.000/512.000
uv_mapper#[2,4]=1.0-(31.000/512.000)

//floor 2 grass
uv_mapper#[3,1]=(0.000/512.00)
uv_mapper#[3,2]=1.000
uv_mapper#[3,3]=(31.000/512.00)
uv_mapper#[3,4]=1.0-(31.000/512.00)

endfunction

function init_objectcreation()
dim edit_object1#[2,2]
dim edit_objectn1#[2,2]
dim edit_objectuv1#[2,2]
dim edit_object2[2,2]
global max_vertexcount
global max_normalscount
global max_uvcount
max_vertexcount=0
max_normalscount=0
max_uvcount=0
global max_indexcount
max_indexcount=0
endfunction

function makenewobject(vertex_cnt,index_cnt,normal_cnt,uv_cnt)
if vertex_cnt-1<2 then exitfunction
if index_cnt-1<2 then exitfunction
dim edit_object1#[vertex_cnt-1,2]
dim edit_object2[index_cnt-1,2]
max_vertexcount=vertex_cnt-1
max_indexcount=index_cnt-1
dim edit_objectn1#[normal_cnt-1,2]
dim edit_objectuv1#[uv_cnt-1,2]
max_normalscount=normal_cnt-1
max_uvcount=uv_cnt-1
endfunction

function setvertexdataposition(vertex,x#,y#,z#)
if vertex>max_vertexcount then exitfunction
if vertex<0 then exitfunction
edit_object1#[vertex,0]=x#
edit_object1#[vertex,1]=y#
edit_object1#[vertex,2]=z#
endfunction

function setvertexdatanormals(vertex,x#,y#,z#)
if vertex>max_normalscount then exitfunction
if vertex<0 then exitfunction
edit_objectn1#[vertex,0]=x#
edit_objectn1#[vertex,1]=y#
edit_objectn1#[vertex,2]=z#
endfunction

function setvertexdatauv(vertex,u#,v#,w#)
if vertex>max_uvcount then exitfunction 
if vertex<0 then exitfunction 
edit_objectuv1#[vertex,0]=u#
edit_objectuv1#[vertex,1]=v#
edit_objectuv1#[vertex,2]=w#
endfunction

function setindexdata(index,v1,s)
if index<0 then exitfunction 
if index>max_indexcount then exitfunction 
if v1<0 then exitfunction 
edit_object2[index,s]=v1
endfunction

function setindexdata2(index,v1)
if index<0 then exitfunction
if index>max_indexcount then exitfunction
if v1<0 then exitfunction
//if v1>max_vertexcount then exitfunction
for s=0 to 2 step 1
edit_object2[index,s]=v1
next s
endfunction

function savenewobject(object_number,filename$,flag1,flag2)
//flag1 1 = overwrite existing file
//flag1 <>0 = fail if file exists
//flag2 load it in after saving it =1
if getfileexists(filename$)=1 and flag1<>1 then exitfunction
if max_vertexcount<2 then exitfunction
if max_indexcount<2 then exitfunction
//ok lets write the file
if getfileexists(filename$)=1 then deletefile(filename$)
    opentowrite(1,filename$)
        writeline(1,"# agk easy editable object format")
        writeline(1,"# "+str(max_vertexcount+1)+" vertex positions" )
        stp=-1
        for v=0 to max_vertexcount step 1
            writeline(1,"v "+str(edit_object1#[v,0])+" "+str(edit_object1#[v,1])+" "+str(edit_object1#[v,2]))
        next v

writeline(1,"# "+str(max_uvcount+1)+" uv coordinates" )
        for v=0 to max_uvcount step 1
            writeline(1,"vt "+str(edit_objectuv1#[v,0])+" "+str(edit_objectuv1#[v,1])+" "+str(edit_objectuv1#[v,2]))
        next v
        writeline(1,"# "+str(max_normalscount+1)+" vertex normals" )
        for v=0 to max_normalscount step 1
            writeline(1,"vn "+str(edit_objectn1#[v,0])+" "+str(edit_objectn1#[v,1])+" "+str(edit_objectn1#[v,2]))
        next v
        ind_count=(max_indexcount+1)/3
        writeline(1,"# Mesh 'object_name' with "+str(ind_count)+" faces" )
        writeline(1,"# " ) // normally would specify material name but agk ignores this
        writeline(1,"g object_name")
        for i=0 to max_indexcount step 3
            index1=edit_object2[i,0]+1
            index2=edit_object2[i+1,0]+1
            index3=edit_object2[i+2,0]+1
            
            index4=edit_object2[i,1]+1
            index5=edit_object2[i+1,1]+1
            index6=edit_object2[i+2,1]+1
            
            index7=edit_object2[i,2]+1
            index8=edit_object2[i+1,2]+1
            index9=edit_object2[i+2,2]+1
            
            writeline(1,"f "+str(index1)+"/"+str(index4)+"/"+str(index7)+" "+str(index2)+"/"+str(index5)+"/"+str(index8)+" "+str(index3)+"/"+str(index6)+"/"+str(index9))
        next i
        writeline(1,"# thats it ")
        //message("saved something?")
    closefile(1)
if flag2=1
    if getobjectexists(object_number)=1 then deleteobject(object_number)
    loadobject(object_number,filename$)
endif
endfunction

+ Code Snippet

// Created: 2016-04-24

// set window properties
SetWindowTitle( "customshapes" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )

createpointlight(1,0,0,0,500,255,255,255)

setfogmode(1)
setfogrange(1000,10000)
setfogcolor(0,0,0)

//change this to sync rate 0 if you wanna see how fast it can go
setsyncrate(60,1)
//this will initialize the memory to do the job
init_objectcreation()
//this will assign tile types with known texture uv mapping
init_tiletypes()

//lets make a dummy scene
dim scene[64,1,64] //x,y,z

//lets just load a single image in.  you can add 32x32 image tiles to this one and
//split it with code so its usable.  I have used a minecraft texture skin so you can
//see how uv mapping can be interchanged


//for simplicity i will just use 3 tiles   1=floor and 2=cubed wall with grass top
for x=1 to 64 step 1
	for z=1 to 64 step 1
		tp=1 //floor type
		if z=1 or z=64 or x=1 or x=64 then tp=2 //wall type
		// lets randomly plug walls in
		a=random(1,100)
		if a=<20 then tp=2
		scene[x,0,z]=tp
	next z
next x


//ok so we got some sort of random scene with blocks in it
//lets count all the 3d data then construct it

//this could be optimized to save on further geometry not needing to be drawn... but for now try this.
//i dont want to make it too complicated to follow.

//ok count data
max_vertexcount=0
max_indexcount=0
for x=1 to 64 step 1
	for z=1 to 64 step 1
		rd=scene[x,0,z]
		if rd=1 
			max_vertexcount=max_vertexcount+4 //floor object
			max_indexcount=max_indexcount+6
		endif
		
		if rd=2 
			max_vertexcount=max_vertexcount+4 //wall cubed object **this could be optimized fyi**
			max_indexcount=max_indexcount+6
			
			
			//put some top grass on those walls for fun
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
		endif
	next z
next x

//ok lets actually build the model now :)
loadimage(1,"test.png",0)  //this file has up to 256 images each 32x32
setimagemagfilter(1,0)
setimageminfilter(1,0)

//make the array for scene single object
makenewobject(max_vertexcount,max_indexcount,max_vertexcount,max_vertexcount)


global vertex=0
global index=0

for x=1 to 64 step 1
	for z=1 to 64 step 1
		rd=scene[x,0,z]
		usescalex=100
		usescaley=100
		if rd=1 
			add_floor(vertex,index,1,usescalex,usescaley,usescalex,x,1,z) //( vertex,index,uvmap id,scalex,scaley,scalez,x grid,ygrid,zgrid)
			vertex=vertex+4 //floor object
			index=index+6// increase counters
		endif
		
		if rd=2 
			//grass top
			add_floor(vertex,index,3,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //floor object
			index=index+6
			
			addwall_front(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_back(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_right(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_left(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //demensions
			vertex=vertex+4 //wall object
			index=index+6
		endif
	next z
next x


//ok final stage...  the object is in the array 
//lets save it as an object file and load it back in.
savenewobject(2,"mytempobject.obj",1,1)  //saved it and loaded it into id#2
setobjectposition(2,-1000,0,1000)
setobjectimage(2,1,0)
setcamerarange(1,1,20000)



//run collision simulation
testcollision()

end






function testcollision()
createobjectbox(1,50,50,50) //this will be our test character
setobjectposition(1,500,500,500)
setobjectcollisionmode(1,0) //shut off collision detection for this object
setobjectrotation(1,0,180,0)
global gravity#=0.0
global onground=0
do
 rem Old position
 oldx#=Getobjectx(1)
 oldy#=Getobjecty(1)
 oldz#=Getobjectz(1)
 
 if ( GetRawKeyState( 87 ) ) then Moveobjectlocalz(1,12) //"w" to walk forward
 if ( GetRawKeyState( 83 ) ) then Moveobjectlocalz( 1, -12 ) // "s" to walk back
 if ( GetRawKeyState( 65 ) ) then rotateobjectlocaly(1,-6) //"a" turn
 if ( GetRawKeyState( 68 ) ) then rotateobjectlocaly(1,6) //"d"
 
 
 if getrawkeystate(32) and onground=1 then gravity#=30.0 // " " [spacekey to jump]
 
 gravity#=gravity#-3.0
 if onground=1 and gravity#<-2.0 then gravity#=-2.0
 if gravity#<-30 then gravity#=-30

 newx#=getobjectx(1)
 newy#=getobjecty(1)+gravity#
 newz#=getobjectz(1)
 
 
 if ObjectSphereSlide(0,oldx#,oldy#,oldz#,newx#,newy#,newz#,35.0)>0
	newx#=GetObjectRayCastSlideX(0)
	//newy#=GetObjectRayCastSlideY(0)
	newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 onground=0
 //floor
 if ObjectSphereSlide(0,newx#,oldy#-45,newz#,newx#,newy#-45,newz#,20.0)>0
	//newx#=GetObjectRayCastSlideX(0)
	newy#=GetObjectRayCastSlideY(0)+45
	if gravity#<0.0 then gravity#=0.0
	onground=1
	//newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 
  //ceiling
 if ObjectSphereSlide(0,newx#,oldy#+45,newz#,newx#,newy#+45,newz#,20.0)>0
	//newx#=GetObjectRayCastSlideX(0)
	newy#=GetObjectRayCastSlideY(0)-45
	if gravity#>0.0 then gravity#=0.0
	onground=0
	//newz#=GetObjectRayCastSlideZ(0)
	setobjectposition(1,newx#,newy#,newz#)
 endif
 
 
 setobjectposition(1,newx#,newy#,newz#)
 //setobjectposition(1,newx#,newy#,newz#)
 oldx#=newx#
 oldy#=newy#
 oldz#=newz#
	setcameraposition(1,oldx#,oldy#+150,oldz#)
	setcamerarotation(1,0,getobjectangley(1),0)
	movecameralocalz(1,-100)

	newx#=getcamerax(1)
	newy#=getcameray(1)
	newz#=getcameraz(1)
	
	
setcameralookat(1,oldx#,oldy#+120,oldz#,0)
//setcamerarotation(1,getcameraanglex(1),getobjectangley(1),getcameraanglez(1))
 
	print( screenfps())
   setpointlightposition(1,oldx#,oldy#,oldz#)
    sync()
loop

endfunction



function add_floor(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0

//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
//uv mapping

//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)

//normals
//this is a floor so should just point up
setvertexdatanormals(v,0.0,1.0,0.0)
setvertexdatanormals(v+1,0.0,1.0,0.0)
setvertexdatanormals(v+2,0.0,1.0,0.0)
setvertexdatanormals(v+3,0.0,1.0,0.0)

//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction

function addwall_front(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//
setvertexdatanormals(v,0.0,0.0,1.0)
setvertexdatanormals(v+1,0.0,0.0,1.0)
setvertexdatanormals(v+2,0.0,0.0,1.0)
setvertexdatanormals(v+3,0.0,0.0,1.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v+2)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v)
//face 2
setindexdata2(i+3,v+3)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v)
//we got a square
//thats it
endfunction

function addwall_back(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//
setvertexdatanormals(v,0.0,0.0,-1.0)
setvertexdatanormals(v+1,0.0,0.0,-1.0)
setvertexdatanormals(v+2,0.0,0.0,-1.0)
setvertexdatanormals(v+3,0.0,0.0,-1.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction


function addwall_right(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,-lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,-lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,-lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,-lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//this is a floor so should just point up
setvertexdatanormals(v,-1.0,0.0,0.0)
setvertexdatanormals(v+1,-1.0,0.0,0.0)
setvertexdatanormals(v+2,-1.0,0.0,0.0)
setvertexdatanormals(v+3,-1.0,0.0,0.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square
//thats it
endfunction



function addwall_left(v,i,rd,sx,sy,sz,x,y,z)
lengthx#=sx/2.0
lengthy#=sy/2.0
lengthz#=sz/2.0
//vertex data
setvertexdataposition(v,lengthx#+(x*sx),lengthy#+(y*sy),lengthz#+(z*sz))
setvertexdataposition(v+1,lengthx#+(x*sx),lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+2,lengthx#+(x*sx),-lengthy#+(y*sy),-lengthz#+(z*sz))
setvertexdataposition(v+3,lengthx#+(x*sx),-lengthy#+(y*sy),lengthz#+(z*sz))
//uv mapping
//using uv mapper 1 id (dirt)
setvertexdatauv(v,uv_mapper#[rd,1],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+1,uv_mapper#[rd,3],uv_mapper#[rd,2],0.0)
setvertexdatauv(v+2,uv_mapper#[rd,3],uv_mapper#[rd,4],0.0)
setvertexdatauv(v+3,uv_mapper#[rd,1],uv_mapper#[rd,4],0.0)
//normals
//this is a floor so should just point up
setvertexdatanormals(v,1.0,0.0,0.0)
setvertexdatanormals(v+1,1.0,0.0,0.0)
setvertexdatanormals(v+2,1.0,0.0,0.0)
setvertexdatanormals(v+3,1.0,0.0,0.0)
//final stage index the triangles
//what connects to what...
//face 1
setindexdata2(i,v+2)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v)
//face 2
setindexdata2(i+3,v+3)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v)
//we got a square
//thats it
endfunction


function init_tiletypes()
dim uv_mapper#[256,4]
//assign tile 1 floor uv mapping
//this example image is 512x512 with 32x32 tiles that are 16x16 grid
//floor 1 (dirt)
uv_mapper#[1,1]=(32.000/512.00)
uv_mapper#[1,2]=1.000
uv_mapper#[1,3]=(63.000/512.00)
uv_mapper#[1,4]=1.0-(31.000/512.00)

//wall 1
uv_mapper#[2,1]=96.000/512.000
uv_mapper#[2,2]=1.000
uv_mapper#[2,3]=127.000/512.000
uv_mapper#[2,4]=1.0-(31.000/512.000)

//floor 2 grass
uv_mapper#[3,1]=(0.000/512.00)
uv_mapper#[3,2]=1.000
uv_mapper#[3,3]=(31.000/512.00)
uv_mapper#[3,4]=1.0-(31.000/512.00)

	
endfunction


function init_objectcreation()
dim edit_object1#[2,2]
dim edit_objectn1#[2,2]
dim edit_objectuv1#[2,2]
dim edit_object2[2,2]
global max_vertexcount
global max_normalscount
global max_uvcount
max_vertexcount=0
max_normalscount=0
max_uvcount=0
global max_indexcount
max_indexcount=0
endfunction


function makenewobject(vertex_cnt,index_cnt,normal_cnt,uv_cnt)
if vertex_cnt-1<2 then exitfunction
if index_cnt-1<2 then exitfunction
dim edit_object1#[vertex_cnt-1,2]
dim edit_object2[index_cnt-1,2]
max_vertexcount=vertex_cnt-1
max_indexcount=index_cnt-1
dim edit_objectn1#[normal_cnt-1,2]
dim edit_objectuv1#[uv_cnt-1,2]
max_normalscount=normal_cnt-1
max_uvcount=uv_cnt-1
endfunction

function setvertexdataposition(vertex,x#,y#,z#)
if vertex>max_vertexcount then exitfunction
if vertex<0 then exitfunction
edit_object1#[vertex,0]=x#
edit_object1#[vertex,1]=y#
edit_object1#[vertex,2]=z#
endfunction

function setvertexdatanormals(vertex,x#,y#,z#)
if vertex>max_normalscount then exitfunction
if vertex<0 then exitfunction
edit_objectn1#[vertex,0]=x#
edit_objectn1#[vertex,1]=y#
edit_objectn1#[vertex,2]=z#
endfunction

function setvertexdatauv(vertex,u#,v#,w#)
if vertex>max_uvcount then exitfunction 
if vertex<0 then exitfunction 
edit_objectuv1#[vertex,0]=u#
edit_objectuv1#[vertex,1]=v#
edit_objectuv1#[vertex,2]=w#
endfunction

function setindexdata(index,v1,s)
if index<0 then exitfunction 
if index>max_indexcount then exitfunction 
if v1<0 then exitfunction 
edit_object2[index,s]=v1
endfunction

function setindexdata2(index,v1)
if index<0 then exitfunction
if index>max_indexcount then exitfunction
if v1<0 then exitfunction
//if v1>max_vertexcount then exitfunction
for s=0 to 2 step 1
edit_object2[index,s]=v1
next s
endfunction 


function savenewobject(object_number,filename$,flag1,flag2)
//flag1 1 = overwrite existing file
//flag1 <>0 = fail if file exists
//flag2 load it in after saving it =1
if getfileexists(filename$)=1 and flag1<>1 then exitfunction
if max_vertexcount<2 then exitfunction
if max_indexcount<2 then exitfunction
//ok lets write the file
if getfileexists(filename$)=1 then deletefile(filename$)
    opentowrite(1,filename$)
        writeline(1,"# agk easy editable object format")
        writeline(1,"# "+str(max_vertexcount+1)+" vertex positions" )
        stp=-1
        for v=0 to max_vertexcount step 1
            writeline(1,"v "+str(edit_object1#[v,0])+" "+str(edit_object1#[v,1])+" "+str(edit_object1#[v,2]))
        next v

        writeline(1,"# "+str(max_uvcount+1)+" uv coordinates" )
        for v=0 to max_uvcount step 1
            writeline(1,"vt "+str(edit_objectuv1#[v,0])+" "+str(edit_objectuv1#[v,1])+" "+str(edit_objectuv1#[v,2]))
        next v
        writeline(1,"# "+str(max_normalscount+1)+" vertex normals" )
        for v=0 to max_normalscount step 1
            writeline(1,"vn "+str(edit_objectn1#[v,0])+" "+str(edit_objectn1#[v,1])+" "+str(edit_objectn1#[v,2]))
        next v
        ind_count=(max_indexcount+1)/3
        writeline(1,"# Mesh 'object_name' with "+str(ind_count)+" faces" )
        writeline(1,"# " ) // normally would specify material name but agk ignores this
        writeline(1,"g object_name")
        for i=0 to max_indexcount step 3
            index1=edit_object2[i,0]+1
            index2=edit_object2[i+1,0]+1
            index3=edit_object2[i+2,0]+1
            
            index4=edit_object2[i,1]+1
            index5=edit_object2[i+1,1]+1
            index6=edit_object2[i+2,1]+1
            
            index7=edit_object2[i,2]+1
            index8=edit_object2[i+1,2]+1
            index9=edit_object2[i+2,2]+1
            
            writeline(1,"f "+str(index1)+"/"+str(index4)+"/"+str(index7)+" "+str(index2)+"/"+str(index5)+"/"+str(index8)+" "+str(index3)+"/"+str(index6)+"/"+str(index9))
        next i
        writeline(1,"# thats it ")
        //message("saved something?")
    closefile(1)
if flag2=1
    if getobjectexists(object_number)=1 then deleteobject(object_number)
    loadobject(object_number,filename$)
endif
endfunction

Attachments

Login to view attachments

Back to top

Profile PM Email Website

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 02:22 Edited at: 25th Apr 2016 03:52

Link

oh....when i say it could be optimized this is what i mean.

if a wall is joining another wall you currently have 2 extra wall faces being drawn that do not need to be drawn. This would need to be checked while counting array size and also again when you build the scene.

i didnt add a ceiling to that code but it is the exact same code for the floor except we need to change the triangles so they are flipped.

simply copy the floor function and change the normals to -1 on y axis and change

+ Code Snippet

//face 1
setindexdata2(i,v)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v+2)
//face 2
setindexdata2(i+3,v)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v+3)
//we got a square

to this to flip the faces

+ Code Snippet

//face 1
setindexdata2(i,v+2)
setindexdata2(i+1,v+1)
setindexdata2(i+2,v)
//face 2
setindexdata2(i+3,v+3)
setindexdata2(i+4,v+2)
setindexdata2(i+5,v)
//we got a square

dont forget the normals as the light reflection will be backwards if you dont change it.

if you like... i can code a better function for picking uv mapping if you want. for now its just setup to the exact pixel x,y start to x,y end. images on the vertical side are flipped so you need to say the top of the image is equal to 1.0 then subtract. [0.0 to 1.0] is the range of your texture loaded.

(this scene below is just 1 single object with 1 single texture) 64x64=4096 combined into 1

Attachments

Login to view attachments

Back to top

Profile PM Email Website

Blendman

10

Years of Service

User Offline

Joined: 17th Feb 2014

Location: Arkeos

Posted: 25th Apr 2016 10:16 Edited at: 25th Apr 2016 10:28

Link

Hi SoftMotion3D

Do you think it's possible to load several .obj file, merge them and save the result (merged object) in one .obj file ?

I use a lot af "parts of objects" (several .obj files) to create differents "objects" (made with all parts) in the game, but I would like to save first all the "big objects" and then load them in my game.

Example :
The parts (each part is an .obj file)

The object created with the parts, in my game (but all part are just cloneobject with original parts, so i would like to save the object created with its parts, and load only the saved new object )

Do you think it's possible ?
If yes, it would be awesome

. I could create a lot of differents objects with just a few parts : objects, plants, trees, mecanics, machines, house, and so...

AGK2 tier1 - http://www.dracaena-studio.com

Back to top

Profile PM Website

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 13:28

Link

Yup this is very possible. First you will need to make an atlas texture and i could writeup some code to combine the obj files together to form a single object. The frame rate will be very suprizing when it only needs to draw a single object for the scene.

What are you using for the level editor?

Im thinking you want to use these parts to make single objects... Is that correct? I made a tool that does this already... It just needs a help video to go withit. Ill make the help video tonight and post it with tool.

Back to top

Profile PM Email Website

Blendman

10

Years of Service

User Offline

Joined: 17th Feb 2014

Location: Arkeos

Posted: 25th Apr 2016 13:54 Edited at: 25th Apr 2016 13:55

Link

Quote: "What are you using for the level editor?"

I use Blender to create my level for the moment. May be, if Guru2agk is ready and great, I will use it ^^.

Quote: "Im thinking you want to use these parts to make single objects... Is that correct? "

YEs.
When installing the game, I would like to create all the single objects (from parts), and when loading the game, I will load those single objects.

So with a very little sized application, I could have a lot of differents objects, but with a good framerate

.
For the moment, because i only use the parts, the frame rate isn't as good as it could be with 1000 single objects loaded (made with 10 différents parts) instead of 10000 parts (1000 X10) .

Im' really interesing by the technic to create the object dynamically in the game and saved in the media (write), not create the objects to place it in the media folder(read) of the apk., because, I can create the object in blender directly if it's what I would like ^^).

AGK2 tier1 - http://www.dracaena-studio.com

Back to top

Profile PM Website

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 17:19

Link

Are your objects all using the same image id?

The first thing you need to do is create an atlas texture that has all the needed images.

Second i can put some code together that can merge them as 1 and remap the objects uv if nessesary. Then using simular code for darkhalo2k we can save it as a temp object just to load it back in as a single object.

Are your obj files triangular or quads? My code works for triangle only.

Back to top

Profile PM Email Website

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 19:20

Link

I also have a binary format that i put together that is a small fraction the size of an obj file. Using this could be great cause you can extract it to obj files on the device after installing.

I have a scene i drew for my game thats 2mb as an obj file. Saved as my binary file its only 256k roughly.

Soo if space is a problem you could look at doing that also.

Let me know what ya need or want to try.

How did you makeout with my example darkhalo2k?

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 25th Apr 2016 21:22

Link

Thank you so much for sharing, SoftMotion3D. I've given the code a quick read through, and may try to create a simple map editor around it rather than trying to adapt my current code to suit.

Thanks again. You're a real credit to the community!

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 25th Apr 2016 21:53

Link

Ah thats great to hear. Let me add 1 more thing to this. I will post code to turn an obj file to agk code so you can use other shapes in your program if you want to build scenes this way.

So the same way this program makes a floor could be a new function to create a custom loaded shape. Ill make it so it produces a text file you can just add back in as code to draw the object no longer needing the obj file.

Ill write this up tonight and post it. I think blendman could find use for this function writer also if he wants to make scenes with just code.

Back to top

Profile PM Email Website

DARKHALO2K

21

Years of Service

User Offline

Joined: 4th Sep 2003

Location: UK

Posted: 25th Apr 2016 22:08

Link

That would be brilliant, thank you. Again, I really appreciate your support and generosity, and if you'd care to share your name with me either here or in an email then I'd be sure to credit you in any project derived from this code.

Back to top

Profile PM Email

SoftMotion3D

AGK Developer

19

Years of Service

User Offline

Joined: 24th Aug 2005

Location: Calgary,Alberta

Posted: 26th Apr 2016 01:25 Edited at: 26th Apr 2016 01:31

Link

this piece of code is a master piece!

// Project: customshapes 
// Created: 2016-04-24

// set window properties
SetWindowTitle( "customshapes" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )

createpointlight(1,0,0,0,500,255,255,255)

setfogmode(1)
setfogrange(1000,10000)
setfogcolor(0,0,0)

//change this to sync rate 0 if you wanna see how fast it can go
setsyncrate(30,1)
//this will initialize the memory to do the job
init_objectcreation()
//this will assign tile types with known texture uv mapping
init_tiletypes()

//lets make a dummy scene
dim scene[64,1,64] //x,y,z

//lets just load a single image in.  you can add 32x32 image tiles to this one and
//split it with code so its usable.  I have used a minecraft texture skin so you can
//see how uv mapping can be interchanged

//for simplicity i will just use 3 tiles   1=floor and 2=cubed wall with grass top
for x=1 to 64 step 1
	for z=1 to 64 step 1
		tp=1 //floor type
		if z=1 or z=64 or x=1 or x=64 then tp=2 //wall type
		// lets randomly plug walls in
		a=random(1,100)
		if a=<20 then tp=random(2,3)
		scene[x,0,z]=tp
	next z
next x

//comment this next stuff out if your not creating a new function file

//*************************************************************
//loadobj(1,"testcylinder.obj")
//
//createobjectfunctionfile("mynewfunction.txt","add_dirtcylinder")
//end
// find this file in the appdata folder under media
//**************************************************************

//ok so we got some sort of random scene with blocks in it
//lets count all the 3d data then construct it

//this could be optimized to save on further geometry not needing to be drawn... but for now try this.
//i dont want to make it too complicated to follow.

//ok count data
max_vertexcount=0
max_indexcount=0
for x=1 to 64 step 1
	for z=1 to 64 step 1
		rd=scene[x,0,z]
		if rd=1 
			max_vertexcount=max_vertexcount+4 //floor object
			max_indexcount=max_indexcount+6
		endif
		
		if rd=2 
			max_vertexcount=max_vertexcount+4 //wall cubed object **this could be optimized fyi**
			max_indexcount=max_indexcount+6
			
			
			//put some top grass on those walls for fun
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
			max_vertexcount=max_vertexcount+4 //wall object
			max_indexcount=max_indexcount+6
		endif
		
		 
		if rd=3 //the created function file 
			//vertex=vertex+52
			//index=index+132  
			
			//change this to use your code or whatever
			max_vertexcount=max_vertexcount+52
			max_indexcount=max_indexcount+132
		endif
		
		
	next z
next x

//ok lets actually build the model now :)
loadimage(1,"test.png",0)  //this file has up to 256 images each 32x32
setimagemagfilter(1,0)
setimageminfilter(1,0)

//make the array for scene single object
makenewobject(max_vertexcount,max_indexcount,max_vertexcount,max_vertexcount)

global vertex=0
global index=0

for x=1 to 64 step 1
	for z=1 to 64 step 1
		
		y=1
		rd=scene[x,0,z]
		usescalex=100
		usescaley=100
		//dont change scale 4 now
		if rd=1 
			add_floor(vertex,index,1,usescalex,usescaley,usescalex,x,1,z) //( vertex,index,uvmap id,scalex,scaley,scalez,x grid,ygrid,zgrid)
			vertex=vertex+4 //floor object
			index=index+6// increase counters
		endif
		
		if rd=2 
			//grass top
			add_floor(vertex,index,3,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //floor object
			index=index+6
			
			addwall_front(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_back(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_right(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //dimensions
			vertex=vertex+4 //wall object
			index=index+6
			
			addwall_left(vertex,index,2,usescalex,usescaley,usescalex,x,2,z) //demensions
			vertex=vertex+4 //wall object
			index=index+6
		endif
		
		if rd=3 //again this is from the function file generated shape
			//run function first before adding values
			add_dirtcylinder(vertex,index,x*usescalex,y*usescaley+100,z*usescalex)
			vertex=vertex+52
			index=index+132  
			
		endif
		
	next z
next x