How to start or do a laser beam project.. ;)

Author

Message

Sharp1959

8

Years of Service

User Offline

Joined: 26th Nov 2015

Location: U.S.A.

Posted: 8th Nov 2016 05:07 Edited at: 8th Nov 2016 05:12

Link

Hello everyone!

I looked at some old posts, but only found some really old DBPro ideas..on this I was looking
for AppGameKit 2 ideas ...

I would like to have a laser beam that I can set or point to a object (mirror)
and bounce off...but being really new to AppGameKit 2 I don't know where to start
I've spent several hours reading the different commands and docs and
even look at several example projects...but this idea just ...keeps
escaping me... ;(

The picture below is from a Corona SDK demo (example)

A picture is worth a ..well you know..

Many Thanks for any input

*AGK (Non-Steam) V2.0.21 * iMac (21.5-inch, Mid 2011) - Intel 2.5 GHz i5 Quad Core - 16 GB Ram - OS X - 10.11.6) El Capitan *

Attachments

Login to view attachments

Back to top

Profile PM

Markus

Valued Member

20

Years of Service

User Offline

Joined: 10th Apr 2004

Location: Germany

Posted: 8th Nov 2016 06:53

Link

its not agk but you can convert

'Reflection / 2D Raytracing

'M.Rauch 15.08.2013

'(Monkey Pro 73b)

Strict

Import mojo

Class Vector

Field x:Float
 Field y:Float
 Field z:Float
 
 Function Create:Vector(x:Float,y:Float,z:Float)
 
 	Local v:Vector=New Vector
 	
 	v.x=x
 	v.y=y
 	v.z=z
 	
 	Return v
 
 End
 
 Method Length:Float()

Return Sqrt(x*x + y*y + z*z)

End
 
 Method Length1:Vector()

Local v:Vector = Vector.Create(x,y,z)
		
		Local l:Float=v.Length()
		If l>0
		 v.x=v.x / l
		 v.y=v.y / l
		 v.z=v.z / l
		Endif
		
		Return v

End
 
 Function Sub:Vector(a:Vector , b:Vector)

'Delta
	
	Local v:Vector=New Vector

v.x = a.x - b.x
	v.y = a.y - b.y
	v.z = a.z - b.z

Return v

End

Method Sub:Vector(b:Vector)

'Delta
	
	Local v:Vector=New Vector

v.x = x - b.x
	v.y = y - b.y
	v.z = z - b.z

Return v

End

Method Add:Vector(b:Vector)

'Plus
	
	Local v:Vector=New Vector

v.x = x + b.x
	v.y = y + b.y
	v.z = z + b.z

Return v

End

Method Mul:Vector(b:Vector)

'*
	
	Local v:Vector=New Vector

v.x = x * b.x
	v.y = y * b.y
	v.z = z * b.z

Return v

End

Function Middle:Vector(a:Vector , b:Vector)

'Mitte
	
	Local m:Vector=New Vector

m.x = (a.x + b.x) / 2.0
	m.y = (a.y + b.y) / 2.0
	m.z = (a.z + b.z) / 2.0

Return m

End
 
 Method Draw:Void()
 
 	DrawOval(x-4,y-4,8,8)
 
 End

End

Class MyApp Extends App

Field walllist:List<Line> = New List<Line>
	Field once:Bool=true

Method OnCreate:Int()

Print "Device Screen Size "+DeviceWidth() + " x " + DeviceHeight()
	
		'wenn das bei HTML5 fehlt kein Bild nur weiß
				
		SetUpdateRate 30 'Render & Update identisch
		
		MakeWalls()
		
		Return 1
		
	End
	
	Method MakeWalls:void()

Local wall:Line
	  	wall=New Line
	  	wall.a=Vector.Create(10,DeviceHeight()-10,0)
		wall.b=Vector.Create(10,10,0)
		walllist.AddLast(wall)

wall=New Line
	  	wall.a=Vector.Create(10,10,0)
		wall.b=Vector.Create(DeviceWidth()-10,10,0)
		walllist.AddLast(wall)

wall=New Line
		wall.a=Vector.Create(DeviceWidth()-10,10,0)
	  	wall.b=Vector.Create(DeviceWidth()-10,DeviceHeight()-10,0)
		walllist.AddLast(wall)

wall=New Line
	  	wall.a=Vector.Create(DeviceWidth()-10,DeviceHeight()-10,0)
		wall.b=Vector.Create(10,DeviceHeight()-10,0)
		walllist.AddLast(wall)

const s:Float=10.0
		For Local w:Float=0 To 360.0-s Step s
			Local p1:Vector=Vector.Create(100.0+Sin(w  )*40,100.0+Cos(w  )*40,0)
			Local p2:Vector=Vector.Create(100.0+Sin(w+s)*40,100.0+Cos(w+s)*40,0)
			wall=Line.Create(p1,p2)
			walllist.AddLast(wall)
		Next

For Local w:Float=0 To 360.0-s Step s
			Local p1:Vector=Vector.Create(100.0+Sin(w  )*40,300.0+Cos(w  )*40,0)
			Local p2:Vector=Vector.Create(100.0+Sin(w+s)*40,300.0+Cos(w+s)*40,0)
			wall=Line.Create(p1,p2)
			walllist.AddLast(wall)
		Next

End
	
	Method RenderWalls:void()

'-------------------- paint walls

SetColor 128,128,128
	 	For Local wall:Line=Eachin walllist
		 	wall.DrawNormal(5.0)
		Next
	 	SetColor 255,255,255
	 	For Local wall:Line=Eachin walllist
		 	wall.Draw()	  	  
		Next

End
	
	Method OnUpdate:Int()

Return 1

End

Method OnRender:Int()

PushMatrix

If once
			'once=False
		  	Cls 0,0,0
			 
		 	RenderWalls()
		 	 		
		Endif
	 	 
	 	'-------------------- start ray
			
	 	Local ray:Line=New Line
	 	ray.a=Vector.Create(DeviceWidth()/2,DeviceHeight()/2,0)
	 	ray.b=Vector.Create(TouchX(),TouchY(),0).Sub(ray.a).Length1().Mul(Vector.Create(1000.0,1000.0,1000.0)).Add(ray.a)
	 	
	 	'-------------------- ray trace / Raytracing
	 	 
	 	Ray.Trace(ray,walllist,10) 'with trace depth limit	
	 		
		PopMatrix
	 
	 Return 1

End

Class Ray

Function Trace:Void(ray:Line,lines:List<Line>,depth:int)
	
		depth=depth-1
		If depth=0 Then Return
		 	
	 	Local l:Float=1000000.0
		Local newray:Line=null
	 	
	 	For Local wall:Line=Eachin lines
	 		
			Local hit:Vector = LineLine.Intersection(ray,wall)
			If hit
				'SetColor 255,0,0
				'hit.Draw()
	
				'surface Normal
				Local n:Vector=wall.Normal()
				
				'Direction
				Local dir:Vector=ray.Direction()
				
				'Reflect Direction
				Local o:Vector=New Vector
				Local op:Float =2.0 * (dir.x*n.x + dir.y*n.y + dir.z*n.z)
				o.x=dir.x - (op * n.x)
				o.y=dir.y - (op * n.y)
				o.z=dir.z - (op * n.z)
				
				If hit.Sub(ray.a).Length() <l Then 'find the nearest
					l=hit.Sub(ray.a).Length()
				
					ray.b=hit 'shorten the ray
				
					'Reflected Line
					'Start from End To New Point
					newray=New Line
					newray.a=Vector.Create(hit.x+n.x*0.5,hit.y+n.y*0.5,hit.z+n.z*0.5) 'else we hit direct the same wall, we start a little bit up ( sonst trift man die gleiche Mauer wieder)
					newray.b=Vector.Create(hit.x+o.x*10000.0,hit.y+o.y*10000.0,hit.z+o.z*10000.0) 'länge 10000 weiter
					
				Endif
											
			 Endif
		 
		 Next
		 
		 SetColor 255,255,0
	 	 ray.Draw()

'do the same again
		 If newray<>Null
						newray.a.Draw()
		 				Ray.Trace(newray,lines,depth)
		 Endif		 
	
	End
	
End

Class Line

Field a:Vector
	Field b:Vector
	
	Function Create:Line(a:Vector,b:Vector)
	
		Local l:Line= New Line
		l.a=a
		l.b=b
	
		Return l 
	
	end
	
	Method Draw:Void()
		DrawLine(a.x , a.y , b.x , b.y )
	End	
	
	Method DrawNormal:Void(l:Float)

Local m:Vector=Vector.Middle(a,b)
		Local n:Vector=Normal()
		
		DrawLine(m.x , m.y , m.x + n.x*l , m.y + n.y*l )

End

Method Normal:Vector()
	
		'Normale der Linie!
	
		'define dx=x2-x1 And dy=y2-y1		
		'the normals are (-dy, dx) And (dy, -dx)
		
		Local d:Vector=b.Sub(a).Length1()
		
		Return Vector.Create(-d.y,d.x,0)
	
	End
	
	Method Direction:Vector()
				
		Return b.Sub(a).Length1()

End
	
	Method Length:Float()
	
		'Länge Linie

Return b.Sub(a).Length()

End
	
End

Class LineLine

Function Intersection:Vector(line1:Line,line2:Line)     
		
        Local p:Vector=Null

Local x1:Float=line1.a.x
		Local y1:Float=line1.a.y
		Local x2:Float=line1.b.x
		Local y2:Float=line1.b.y

Local x3:Float=line2.a.x
		Local y3:Float=line2.a.y
		Local x4:Float=line2.b.x
		Local y4:Float=line2.b.y

Local bx:Float = x2 - x1
		Local by:Float = y2 - y1

Local dx:Float = x4 - x3
		Local dy:Float = y4 - y3
		
		Local b_dot_d_perp:Float = bx * dy - by * dx
		If b_dot_d_perp = 0.0 Then Return Null
  
		Local cx:Float = x3 - x1
	  	Local cy:Float = y3 - y1
	  	
	  	Local t:Float = (cx * dy - cy * dx) / b_dot_d_perp
	  	If (t < 0.0) Or (t > 1.0) Then	Return Null
	  	
	  	Local u:Float = (cx * by - cy * bx) / b_dot_d_perp
	  	If (u < 0.0) Or (u > 1.0) Then Return Null
	  	
  		p=Vector.Create(x1+t*bx, y1+t*by,0)
  
		Return p
		
	End

End

Function Main:Int()

Local myApp:MyApp = New MyApp
	
	Return 1
	
End

+ Code Snippet


'Reflection / 2D Raytracing

'M.Rauch 15.08.2013

'(Monkey Pro 73b)

Strict

Import mojo

Class Vector

 Field x:Float
 Field y:Float
 Field z:Float
 
 Function Create:Vector(x:Float,y:Float,z:Float)
 
 	Local v:Vector=New Vector
 	
 	v.x=x
 	v.y=y
 	v.z=z
 	
 	Return v
 
 End
 
 Method Length:Float()

	Return Sqrt(x*x + y*y + z*z)

 End
 
 Method Length1:Vector()

	Local v:Vector = Vector.Create(x,y,z)
		
		Local l:Float=v.Length()
		If l>0
		 v.x=v.x / l
		 v.y=v.y / l
		 v.z=v.z / l
		Endif
		
		Return v

 End
 
 Function Sub:Vector(a:Vector , b:Vector)

	'Delta
	
	Local v:Vector=New Vector

	v.x = a.x - b.x
	v.y = a.y - b.y
	v.z = a.z - b.z

	Return v 

 End

 Method Sub:Vector(b:Vector)

	'Delta
	
	Local v:Vector=New Vector

	v.x = x - b.x
	v.y = y - b.y
	v.z = z - b.z

	Return v 

 End

 Method Add:Vector(b:Vector)

	'Plus
	
	Local v:Vector=New Vector

	v.x = x + b.x
	v.y = y + b.y
	v.z = z + b.z

	Return v 

 End

 Method Mul:Vector(b:Vector)

	'*
	
	Local v:Vector=New Vector

	v.x = x * b.x
	v.y = y * b.y
	v.z = z * b.z

	Return v 

 End

 Function Middle:Vector(a:Vector , b:Vector)

	'Mitte
	
	Local m:Vector=New Vector

	m.x = (a.x + b.x) / 2.0
	m.y = (a.y + b.y) / 2.0
	m.z = (a.z + b.z) / 2.0

	Return m 

 End
 
 Method Draw:Void()
 
 	DrawOval(x-4,y-4,8,8)
 
 End

End

Class MyApp Extends App

	Field walllist:List<Line> = New List<Line>
	Field once:Bool=true

	Method OnCreate:Int()

		Print "Device Screen Size "+DeviceWidth() + " x " + DeviceHeight()
	
		'wenn das bei HTML5 fehlt kein Bild nur weiß
				
		SetUpdateRate 30 'Render & Update identisch
		
		MakeWalls()
		
		Return 1
		
	End
	
	Method MakeWalls:void()

	  	Local wall:Line
	  	wall=New Line
	  	wall.a=Vector.Create(10,DeviceHeight()-10,0)
		wall.b=Vector.Create(10,10,0)
		walllist.AddLast(wall)

	  	wall=New Line
	  	wall.a=Vector.Create(10,10,0)
		wall.b=Vector.Create(DeviceWidth()-10,10,0)
		walllist.AddLast(wall)

	  	wall=New Line
		wall.a=Vector.Create(DeviceWidth()-10,10,0)
	  	wall.b=Vector.Create(DeviceWidth()-10,DeviceHeight()-10,0)
		walllist.AddLast(wall)

	  	wall=New Line
	  	wall.a=Vector.Create(DeviceWidth()-10,DeviceHeight()-10,0)
		wall.b=Vector.Create(10,DeviceHeight()-10,0)
		walllist.AddLast(wall)

		const s:Float=10.0
		For Local w:Float=0 To 360.0-s Step s
			Local p1:Vector=Vector.Create(100.0+Sin(w  )*40,100.0+Cos(w  )*40,0)
			Local p2:Vector=Vector.Create(100.0+Sin(w+s)*40,100.0+Cos(w+s)*40,0)
			wall=Line.Create(p1,p2)
			walllist.AddLast(wall)
		Next

		For Local w:Float=0 To 360.0-s Step s
			Local p1:Vector=Vector.Create(100.0+Sin(w  )*40,300.0+Cos(w  )*40,0)
			Local p2:Vector=Vector.Create(100.0+Sin(w+s)*40,300.0+Cos(w+s)*40,0)
			wall=Line.Create(p1,p2)
			walllist.AddLast(wall)
		Next

	End
	
	Method RenderWalls:void()

	 	'-------------------- paint walls

	 	SetColor 128,128,128
	 	For Local wall:Line=Eachin walllist
		 	wall.DrawNormal(5.0)
		Next
	 	SetColor 255,255,255
	 	For Local wall:Line=Eachin walllist
		 	wall.Draw()	  	  
		Next

	End
	
	Method OnUpdate:Int()

		Return 1

	End

	Method OnRender:Int()

	  	PushMatrix

		If once
			'once=False
		  	Cls 0,0,0
			 
		 	RenderWalls()
		 	 		
		Endif
	 	 
	 	'-------------------- start ray
			
	 	Local ray:Line=New Line
	 	ray.a=Vector.Create(DeviceWidth()/2,DeviceHeight()/2,0)
	 	ray.b=Vector.Create(TouchX(),TouchY(),0).Sub(ray.a).Length1().Mul(Vector.Create(1000.0,1000.0,1000.0)).Add(ray.a)
	 	
	 	'-------------------- ray trace / Raytracing
	 	 
	 	Ray.Trace(ray,walllist,10) 'with trace depth limit	
	 		
		PopMatrix
	 
	 Return 1

	End

End

Class Ray

	Function Trace:Void(ray:Line,lines:List<Line>,depth:int)
	
		depth=depth-1
		If depth=0 Then Return
		 	
	 	Local l:Float=1000000.0
		Local newray:Line=null
	 	
	 	For Local wall:Line=Eachin lines
	 		
			Local hit:Vector = LineLine.Intersection(ray,wall)
			If hit
				'SetColor 255,0,0
				'hit.Draw()
	
				'surface Normal
				Local n:Vector=wall.Normal()
				
				'Direction
				Local dir:Vector=ray.Direction()
				
				'Reflect Direction
				Local o:Vector=New Vector
				Local op:Float =2.0 * (dir.x*n.x + dir.y*n.y + dir.z*n.z)
				o.x=dir.x - (op * n.x)
				o.y=dir.y - (op * n.y)
				o.z=dir.z - (op * n.z)
				
				If hit.Sub(ray.a).Length() <l Then 'find the nearest
					l=hit.Sub(ray.a).Length()
				
					ray.b=hit 'shorten the ray
				
					'Reflected Line
					'Start from End To New Point
					newray=New Line
					newray.a=Vector.Create(hit.x+n.x*0.5,hit.y+n.y*0.5,hit.z+n.z*0.5) 'else we hit direct the same wall, we start a little bit up ( sonst trift man die gleiche Mauer wieder)
					newray.b=Vector.Create(hit.x+o.x*10000.0,hit.y+o.y*10000.0,hit.z+o.z*10000.0) 'länge 10000 weiter
					
				Endif
											
			 Endif
		 
		 Next
		 
		 SetColor 255,255,0
	 	 ray.Draw()

		 'do the same again
		 If newray<>Null
						newray.a.Draw()
		 				Ray.Trace(newray,lines,depth)
		 Endif		 
	
	End
	
End

Class Line

	Field a:Vector
	Field b:Vector
	
	Function Create:Line(a:Vector,b:Vector)
	
		Local l:Line= New Line
		l.a=a
		l.b=b
	
		Return l 
	
	end
	
	Method Draw:Void()
		DrawLine(a.x , a.y , b.x , b.y )
	End	
	
	Method DrawNormal:Void(l:Float)

		Local m:Vector=Vector.Middle(a,b)
		Local n:Vector=Normal()
		
		DrawLine(m.x , m.y , m.x + n.x*l , m.y + n.y*l )

	End

	Method Normal:Vector()
	
		'Normale der Linie!
	
		'define dx=x2-x1 And dy=y2-y1		
		'the normals are (-dy, dx) And (dy, -dx)
		
		Local d:Vector=b.Sub(a).Length1()
		
		Return Vector.Create(-d.y,d.x,0)
	
	End
	
	Method Direction:Vector()
				
		Return b.Sub(a).Length1()

	End
	
	Method Length:Float()
	
		'Länge Linie

		Return b.Sub(a).Length()

	End
	
End

Class LineLine

	Function Intersection:Vector(line1:Line,line2:Line)     
		
        Local p:Vector=Null

		Local x1:Float=line1.a.x
		Local y1:Float=line1.a.y
		Local x2:Float=line1.b.x
		Local y2:Float=line1.b.y

		Local x3:Float=line2.a.x
		Local y3:Float=line2.a.y
		Local x4:Float=line2.b.x
		Local y4:Float=line2.b.y

		Local bx:Float = x2 - x1
		Local by:Float = y2 - y1

		Local dx:Float = x4 - x3
		Local dy:Float = y4 - y3
		
		Local b_dot_d_perp:Float = bx * dy - by * dx
		If b_dot_d_perp = 0.0 Then Return Null
  
		Local cx:Float = x3 - x1
	  	Local cy:Float = y3 - y1
	  	
	  	Local t:Float = (cx * dy - cy * dx) / b_dot_d_perp
	  	If (t < 0.0) Or (t > 1.0) Then	Return Null
	  	
	  	Local u:Float = (cx * by - cy * bx) / b_dot_d_perp
	  	If (u < 0.0) Or (u > 1.0) Then Return Null
	  	
  		p=Vector.Create(x1+t*bx, y1+t*by,0)
  
		Return p
		
	End

End

Function Main:Int()

	Local myApp:MyApp = New MyApp
	
	Return 1
	
End

single reflection in agk

rem
rem AGK Application 2.0.21
rem MR
SetDisplayAspect( 4.0/3.0 )

type TVector
    x as float
    y as float
    z as float
endtype

do
 Print("Reflection")
 //--------------------
 //Norface Normal
 n as TVector
 n.x=-1
 n.y=0
 n.z=0
 //n.x=0
 //n.y=-1
 //--------------------

//Line Start
 p1 as TVector
 p1.x=50
 p1.y=50
 p1.z=0

//Line End
 p2 as TVector
 p2.x=GetPointerX()
 p2.y=GetPointerY()
 p2.z=50

//Delta
 d as TVector
 d.x=p2.x-p1.x
 d.y=p2.y-p1.y
 d.z=p2.z-p1.z
 l#=sqrt(d.x*d.x + d.y*d.y + d.z*d.z)   //length

//Direction
 dir as TVector
 dir.x=d.x/l#
 dir.y=d.y/l#
 dir.z=d.z/l#

DrawLine(p1.x , p1.y , p2.x , p2.y , 255,255,0)

//Reflect Direction
 o as TVector
 op# =2.0 * (dir.x*n.x + dir.y*n.y + dir.z*n.z)
 o.x=dir.x - (op# * n.x)
 o.y=dir.y - (op# * n.y)
 o.z=dir.z - (op# * n.z)

//Start from End to New Point
 p1.x=p2.x+o.x*100.0
 p1.y=p2.y+o.y*100.0
 p1.z=p2.z+o.z*100.0

//Reflected Line
 DrawLine(p1.x , p1.y , p2.x , p2.y , 255,0,0)

//Normal
 DrawLine(p2.x , p2.y , p2.x + n.x*10.0 , p2.y + n.y*10.0 , 192,192,192)

Sync()
loop

+ Code Snippet

rem
rem AGK Application 2.0.21
rem MR
SetDisplayAspect( 4.0/3.0 )

type TVector
    x as float
    y as float
    z as float
endtype

do
 Print("Reflection")
 //--------------------
 //Norface Normal
 n as TVector
 n.x=-1
 n.y=0
 n.z=0
 //n.x=0
 //n.y=-1
 //--------------------

 //Line Start
 p1 as TVector
 p1.x=50
 p1.y=50
 p1.z=0

 //Line End
 p2 as TVector
 p2.x=GetPointerX()
 p2.y=GetPointerY()
 p2.z=50

 //Delta
 d as TVector
 d.x=p2.x-p1.x
 d.y=p2.y-p1.y
 d.z=p2.z-p1.z
 l#=sqrt(d.x*d.x + d.y*d.y + d.z*d.z)   //length

 //Direction
 dir as TVector
 dir.x=d.x/l#
 dir.y=d.y/l#
 dir.z=d.z/l#

 DrawLine(p1.x , p1.y , p2.x , p2.y , 255,255,0)

 //Reflect Direction
 o as TVector
 op# =2.0 * (dir.x*n.x + dir.y*n.y + dir.z*n.z)
 o.x=dir.x - (op# * n.x)
 o.y=dir.y - (op# * n.y)
 o.z=dir.z - (op# * n.z)

 //Start from End to New Point
 p1.x=p2.x+o.x*100.0
 p1.y=p2.y+o.y*100.0
 p1.z=p2.z+o.z*100.0

 //Reflected Line
 DrawLine(p1.x , p1.y , p2.x , p2.y , 255,0,0)

 //Normal
 DrawLine(p2.x , p2.y , p2.x + n.x*10.0 , p2.y + n.y*10.0 , 192,192,192)

 Sync()
loop

AGK (Steam) V2.0.21 : Windows 10 Pro 64 Bit : AMD (16.6) Radeon R7 265 : Mac mini OS Sierra (10.12)

Attachments

Login to view attachments

Back to top

Profile PM Email

Sharp1959

8

Years of Service

User Offline

Joined: 26th Nov 2015

Location: U.S.A.

Posted: 8th Nov 2016 07:50

Link

Thanks @Markus...bbbbbut...not quite what I was looking for (Good stuff tho!)
I have seen that Monkey code before and it's good but it
don't convert to AppGameKit 2 very well ...the commands for that
type of usage is just not there...in AGK...wish it were that easy..

I did happen to locate a thread by Phaelax over here
that was pretty darn cool... !!

https://forum.thegamecreators.com/thread/216169

Thats really close to what I'm looking for...

I wonder if Phaelax will chime in... ?

Maybe shed some light on the laser stump...

Thanks

*AGK (Non-Steam) V2.0.21 * iMac (21.5-inch, Mid 2011) - Intel 2.5 GHz i5 Quad Core - 16 GB Ram - OS X - 10.11.6) El Capitan *

Back to top

Profile PM

Markus

Valued Member

20

Years of Service

User Offline

Joined: 10th Apr 2004

Location: Germany

Posted: 8th Nov 2016 09:16

Link

ok, below this monkey code was a single reflection in agk, you saw?

AGK (Steam) V2.0.21 : Windows 10 Pro 64 Bit : AMD (16.6) Radeon R7 265 : Mac mini OS Sierra (10.12)

Back to top

Profile PM Email

damothegreat

User Banned

Posted: 8th Nov 2016 16:43

Link

Ill have a go at this one, cause I been thinking of doing a laser game too in the future

Come back to you soon with some code

Damo

Using Tier 1 AppGameKit V2
Started coding with AMOS

Back to top

Profile

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 8th Nov 2016 19:36

Link

Someone looking for me?

"I like offending people, because I think people who get offended should be offended." - Linus Torvalds

Back to top

Profile PM Email Website

damothegreat

User Banned

Posted: 8th Nov 2016 20:48

Link

Ill provide my thoughts on a little psedo coding of the idea

1. A laser potentially requires a start and an end - so at least have a type [array] using "x","y","endx","endy"
best to be an array type - so that we can add laser joints onto each other when we add a mirror

do

2. Draw the laser line from its x,y,endx,endy

3. Add a mirror rectangle on the mouse pointer via the getpointerx and getpointery commands

4. Check collisions with mouse pointer (mirror) and the laser line created at point 2

5.a if collides with the line (laser), then decrease / increase the laser to its strength length from the starting point to the mouse position
and add the end cords to the mouse position and create a new laser beam with the starting position of the previous lasers endx,endy points

5 b if not collided with the mirror (mouse) then reset its back length back to its original positions.

6. Get some geometry figures set out according to the angle of the rectangle mirror - use of SIN and COS will do this trick

7. If right mouse button is pressed, then rotates the mirror's angle and calculate using step 6

8 If the left mouse button is pressed, then add the mirror to the screen at the getpointerx, getpointery locations and calculiate the
lasers new end points according to the maths that we identify in step 6

loop

Laser using array TYPE x,y,endx,endy - array cause we could have multiple of them via step 5a

Damo

Using Tier 1 AppGameKit V2
Started coding with AMOS

Back to top

Profile

Sharp1959

8

Years of Service

User Offline

Joined: 26th Nov 2015

Location: U.S.A.

Posted: 9th Nov 2016 08:55

Link

Hi All,

Yes @Phaelax, I was wondering if you could shed a little light on
how you accomplished the effect here in this WIP you posted?

https://forum.thegamecreators.com/thread/216169

The effect is awesome, and was right down the the same alley I was
looking to do..

Any help or hints would be appreciated.

Respectfully

*AGK (Non-Steam) V2.0.21 * iMac (21.5-inch, Mid 2011) - Intel 2.5 GHz i5 Quad Core - 16 GB Ram - OS X - 10.11.6) El Capitan *

Back to top

Profile PM

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 9th Nov 2016 19:16 Edited at: 9th Nov 2016 19:18

Link

I'll try to find the code tonight when I get home. But here's an explanation.

1. The laser and mirror are just line segments.
2. Do an intersection test of the two lines.
3. Laser is represented by line segment AB, the mirror is CD.

n = [(D.x-C.x) * (A.y-C.y)] - [(D.y-C.y) * (A.x-C.x)]
d = [(D.y-C.y) * (B.x-A.x)] - [(D.x-C.x) * (B.y-A.y)]
t = n / d

t is the intersection time along AB when it intersection CD.

Because the equations work in regards to infinite lines rather than fixed segments, we must check the intersection time is between
0 and 1. If so, then the laser intersects the line representing the mirror. But to make sure it's within the boundaries of the
mirror, we must repeat the above equation but flip-flop the variables so the time index is in reference to CD instead. If that too
is within the 0 to 1 range then we know for sure the laser and mirror intersect.

4. Calculate the point of intersection, P.

P.x = A.x + (B.x - A.x)*t
P.y = A.y + (B.y - A.y)*t

5. Calculate the reflection vector for the laser.

I = normalize AB as a direction vector
N = normal of CD
R = reflection vector (direction of laser after hitting mirror)

R = 2N*(N · I) - I

To calculate the normal of the mirror, form CD into a direction vector then invert the components like so:

J = D-C
N.x = -J.y
N.y = J.x

6. Find some measurements.

Length of laser beam from A to B:
olength = sqrt((B.x-A.x)^2 + (B.y-A.y)^2)

Length of laser from source (A) to mirror (P):
mlength = oLength * t

Remainder of laser after reflection (P to ?)
rLength = oLength - mLength

7. Draw the laser
The first part of the laser goes from A (the source) to I*length (the point of impact on the mirror). If you're just drawing lines
you can simply just draw a line from A to P. But what about the reflection? That's why we calculated a length.
R is the normalized direction vector of the laser's relfection on the mirror. rLength is the length of that reflection. So your
reflection line goes from P to P + R*rLength.

8. What if I have multiple mirrors?

Multiple mirrors is simple to handle, but requires slightly more than just looping through each mirror. A mirror can cause the
laser to reflect back off another that it may have already hit. Therefore, you must loop through all mirrors repeatedly until a
certain condition is met. If you have an infinite length laser, then you want to stop checking for reflections after so many have
been hit. Otherwise, there's a risk for an infinite loop due to the reflections. Ever heard of an infinity mirror? Another
condition which should be considered for all scenarios is when the laser goes off screen. At that moment, stop checking, unless
your laser can reflect off the sides of your screen.
Loop through all your mirrors. You can't simply stop once an intersection is detected because the laser could go through multiple
mirrors. So check all of them and keep track of the intersection time (t) with the lowest value. That's the first mirror hit.
Perform the steps above. Draw the laser from A to P. The newly reflected laser is now P (A) to P+R*rLength (B). Every time a
reflection occurs, rLength will get smaller and smaller. If that length becomes less than 5px (or whatever limit you decide) then
stop your loop. If you are doing an infinite laser, then length can be whatever you want, just make sure it's long enough it can
reach any mirror.

"I like offending people, because I think people who get offended should be offended." - Linus Torvalds

Back to top

Profile PM Email Website

Sorry your browser is not supported!

AppGameKit Classic Chat / How to start or do a laser beam project.. ;)

Attachments

Attachments