Sorry your browser is not supported!

// pass the mouse over the sphere, the blue box shows the direction of the
// ray cast collision normal


// make a sphere (will automatically be placed at 0,0,0)
CreateObjectSphere(1,50,48,48)
// CreateObjectBox(1,40,40,40)

// create a blue box that will show the direction of the ray cast normal
CreateObjectBox(2,1,1,20)
SetObjectColor(2,0,0,255,255)

// position the camera and have it look at the centre of the "map"
cam_x# = 100
cam_y# = 100
cam_z# = -100
SetCameraPosition(1,cam_x#,cam_y#,cam_z#)
SetCameraLookAt(1,0,0,0,0)

do

	// get the position of the pointer (mouse)
	pointer_x = GetPointerX()
	pointer_y = GetPointerY()

	// get the x, y and z unit vectors based on the pointer position
	unit_x# = Get3DVectorXFromScreen(pointer_x,pointer_y)
	unit_y# = Get3DVectorYFromScreen(pointer_x,pointer_y)
	unit_z# = Get3DVectorZFromScreen(pointer_x,pointer_y)

	// calculate the start of the ray cast, which is the unit vector + the camera position
	start_x# = unit_x# + cam_x#
	start_y# = unit_y# + cam_y#
	start_z# = unit_z# + cam_z#

	// calculate the end of the vector, which is the unit vector multiplied by the length of the ray cast and then add the camera position to it
	end_x# = 800*unit_x# + cam_x#
	end_y# = 800*unit_y# + cam_y#
	end_z# = 800*unit_z# + cam_z#


	// only ray cast against the sphere
	if ObjectRayCast(1,start_x#,start_y#,start_z#,end_x#,end_y#,end_z#) = 1

		// get the coordinates of the intersect
		intersect_x# = GetObjectRayCastX(0)
		intersect_y# = GetObjectRayCastY(0)
		intersect_z# = GetObjectRayCastZ(0)

		// get the ray cast normal
		normal_x# = GetObjectRayCastNormalX(0)
		normal_y# = GetObjectRayCastNormalY(0)
		normal_z# = GetObjectRayCastNormalZ(0)

		// position the blue box at the intersect point and orientate to point in the direction of the normal
		SetObjectPosition(2,intersect_x#,intersect_y#,intersect_z#)
		SetObjectLookAt(2,intersect_x#+normal_x#,intersect_y#+normal_y#,intersect_z#+normal_z#,0)

		// if the ray cast intersects the sphere then show the blue box
		SetObjectVisible(2,1)

		print("normal_x# : " + str(normal_x#))
		print("normal_y# : " + str(normal_y#))
		print("normal_z# : " + str(normal_z#))

	else

		// if the ray cast does not intersect the sphere then hide the blue box
		SetObjectVisible(2,0)

	endif

	sync()

loop

rem
rem AGK Application 2017.05.15
rem 3D Shooter decal
rem MR 16.05.2017

rem Landscape App
SetDisplayAspect( 4.0/3.0 )

setdefaultwrapu(0)
setdefaultwrapv(0)

//------------------------------------------ Cam

cameraID=1
SetCameraRange( cameraID, 1, 1000 )
SetCameraPosition( cameraID, 0,2,-10 )
SetCameraLookAt( cameraID, 0, 0, 5, 0 )

//------------------------------------------ Light

SetSunActive(1)
SetSunColor(255, 255, 255)
SetSunDirection(0, -1, 1)

//------------------------------------------ Ground

iGround=CreateObjectBox( 100, 0.01, 100 )
SetObjectCollisionMode( iGround, 1 ) //<<<<
SetObjectColor( iGround, 128,255,128,255 )
SetObjectLightMode(iGround,1)

//------------------------------------------ Cube

iBox=CreateObjectBox( 1, 1, 1 )
SetObjectPosition( iBox, 0, 0.5, 4 ) //+1
SetObjectCollisionMode( iBox, 1 ) //<<<<
SetObjectColor( iBox, 255,255,255,255 )

SetObjectLightMode(iBox,1)

RotateObjectLocalY( iBox, 45 )

//------------------------------------------ Image decal

imgBlood=loadimage("Blood.png")

//------------------------------------------ Scope

imgScope=loadimage("Scope.png")
sprScope=createsprite(imgScope)
setspritesize(sprScope,4,4)

//------------------------------------------

do

 cx#=GetCameraX(1)
 cy#=GetCameray(1)
 cz#=GetCameraz(1)

 mx#=getpointerx()
 my#=getpointery()

 sx#=Get3DVectorXFromScreen(mx#,my#)*1000.0
 sy#=Get3DVectorYFromScreen(mx#,my#)*1000.0
 sz#=Get3DVectorZFromScreen(mx#,my#)*1000.0

 ObjectRayCast(0,cx#,cy#,cz#,sx#,sy#,sz#)
 n=GetObjectRayCastNumHits()
 print(n)
 for i=0 to n-1
  obj = GetObjectRayCastHitID(i)
  x#=GetObjectRayCastx(i)
  y#=GetObjectRayCastY(i)
  z#=GetObjectRayCastz(i)
  nx#=GetObjectRayCastNormalX(i)
  ny#=GetObjectRayCastNormalY(i)
  nz#=GetObjectRayCastNormalZ(i)
  tx#=GetScreenXFrom3D(x#,y#,z#)
  ty#=GetScreenYFrom3D(x#,y#,z#)
  setspritepositionbyoffset(sprScope,tx#,ty#)
 next

 if getpointerpressed()=1
    iBlood=createobjectplane(0.5,0.5)
    SetObjectLightMode(iBlood,1)
    SetObjectPosition(iBlood,x#+nx#*0.1,y#+ny#*0.1,z#+nz#*0.1)
    SetObjectLookAt(iBlood,x#+nx#*1.0,y#+ny#*1.0,z#+nz#*1.0,0)
    SetObjectTransparency( iBlood, 1 )
    setobjectimage(iBlood,imgBlood,0)
    SetObjectCollisionMode( iBlood, 0 ) //<<<<
 endif

 Sync()
loop
end