Move object with mouse (3d) - GameCreators Forum

Author

Message

Blendman

10

Years of Service

User Offline

Joined: 17th Feb 2014

Location: Arkeos

Posted: 17th Feb 2018 09:52

Link

Hi
I know how to move an object in x/z plane, but i dont know how to move an object (x, y, z) with the mouse.
I would like the object stuck to the mouse position on the screen.
Do you have an idea how i can do that ?

Thanks.

AGK2 tier1 - http://www.dracaena-studio.com

Back to top

Profile PM Website

Bengismo

7

Years of Service

User Offline

Joined: 20th Nov 2017

Location: Yorkshire, England

Posted: 17th Feb 2018 16:19

Link

Basically you raycast to check if the user has clicked on the object you want to move then you raycast to a point on the ground and move it appropriately

I can do a quick example if necessary

Back to top

Profile PM

Bengismo

7

Years of Service

User Offline

Joined: 20th Nov 2017

Location: Yorkshire, England

Posted: 17th Feb 2018 16:22 Edited at: 17th Feb 2018 19:00

Link

There you go ....its all about raycasts and finding where the screen collides with the ground or some other plane

// Project: Move3D 
// Created: 2018-02-17
 
// show all errors
SetErrorMode(2)
 
// set window properties
SetWindowTitle( "Move3D" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window
 
// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
 
// Set camera variables
SetCameraPosition(1, -30, 30, -30)
SetCameraLookAt( 1, 0,0,0,0 )
 
//create the box
global box
box = CreateObjectBox(1,1,1)
SetObjectPosition(box,0,0.5,0)
SetObjectColor(box, 200,50,50,255)
 
//create the plane
global plane
plane = CreateObjectPlane(100,100)
SetObjectRotation(plane,90,0,0)
SetObjectColor(plane, 100,100,120,255)
 
do
    MoveCam()
    MoveBox()
 
 
    Print("Press Right Mouse to rotate camera")
    Print("Press Left Mouse on the box to move the box")
    Print("Use WSAD keys to move the camera around")
    Print("Rolling the mouse wheel moves the cube in y direction")
    Sync()
loop
 
 
 
Function MoveCam()
     
     
    global startx#
    global starty#
    global angx#
    global angy#
 
    global speed# = 4
     
    // move the camera
    if ( GetRawKeyState( 87 ) ) then MoveCameraLocalZ( 1, speed# )      // W key
    if ( GetRawKeyState( 83 ) ) then MoveCameraLocalZ( 1, -speed# )     // S key
 
    if ( GetRawKeyState( 65 ) ) then MoveCameraLocalX( 1, -speed# )
    if ( GetRawKeyState( 68 ) ) then MoveCameraLocalX( 1, speed# )
 
    if ( GetRawKeyState( 81 ) ) then MoveCameraLocalY( 1, -speed# )
    if ( GetRawKeyState( 69 ) ) then MoveCameraLocalY( 1, speed# )
     
     
    // rotate the camera
    if ( GetRawMouseRightPressed() )
        startx# = GetPointerX()
        starty# = GetPointerY()
        angx# = GetCameraAngleX(1)
        angy# = GetCameraAngleY(1)
        pressed = 1
    endif
 
    if ( GetRawMouseRightState() = 1 )
        fDiffX# = (GetPointerX() - startx#)/4.0
        fDiffY# = (GetPointerY() - starty#)/4.0
 
        newX# = angx# + fDiffY#
        if ( newX# > 89 ) then newX# = 89
        if ( newX# < -89 ) then newX# = -89
        SetCameraRotation( 1, newX#, angy# + fDiffX#, 0 )
    endif
     
endfunction
 
 
Function MoveBox()
     
    global MovingObject
     
    global StX#
    global StY#
    global StZ#
         
    global moveplane     
         
    // Check if the left mouse was pressed
    if ( GetRawMouseLeftPressed() )
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector of where we clicked
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // Check if the box was selected
        if( ObjectRayCast( box ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
            MovingObject = 1
            
            StX# = GetObjectRayCastX(0)
            StY# = GetObjectRayCastY(0)
            StZ# = GetObjectRayCastZ(0)
            
            moveplane = CreateObjectPlane(1000,1000)
            SetObjectPosition(moveplane,Stx#,sty#,stz#)
            //if GetRawKeyState(16) = 0
				SetObjectRotation(moveplane,90,0,0)
			//endif
            SetObjectVisible(moveplane, 0)
            
        else
			if(moveplane >=0)
				DeleteObject(moveplane)
				moveplane = -1
			endif
            MovingObject = 0
        endif
     
    endif
     
    if ( GetRawMouseLeftState() and moveplane>=0 )
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // Check where on the plane we holding the mouse
        if( ObjectRayCast( moveplane ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
             
            EndX# = GetObjectRayCastX(0)
            EndY# = GetObjectRayCastY(0)
            EndZ# = GetObjectRayCastZ(0)
         
            MoveObjectLocalX(box,EndX#-StX#)
            MoveObjectLocalY(box,EndY#-StY#)
            MoveObjectLocalZ(box,EndZ#-StZ#)
             
            StX# = EndX#
            StY# = EndY#
            StZ# = EndZ#
             
        endif
        
        
        MoveObjectLocalY(box,GetRawMouseWheelDelta()*0.25)
        
    
    else
			if(moveplane >=0)
				DeleteObject(moveplane)
				moveplane = -1
			endif
	endif
         
endfunction

+ Code Snippet


// Project: Move3D 
// Created: 2018-02-17
 
// show all errors
SetErrorMode(2)
 
// set window properties
SetWindowTitle( "Move3D" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window
 
// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
 
// Set camera variables
SetCameraPosition(1, -30, 30, -30)
SetCameraLookAt( 1, 0,0,0,0 )
 
//create the box
global box
box = CreateObjectBox(1,1,1)
SetObjectPosition(box,0,0.5,0)
SetObjectColor(box, 200,50,50,255)
 
//create the plane
global plane
plane = CreateObjectPlane(100,100)
SetObjectRotation(plane,90,0,0)
SetObjectColor(plane, 100,100,120,255)
 
do
    MoveCam()
    MoveBox()
 
 
    Print("Press Right Mouse to rotate camera")
    Print("Press Left Mouse on the box to move the box")
    Print("Use WSAD keys to move the camera around")
    Print("Rolling the mouse wheel moves the cube in y direction")
    Sync()
loop
 
 
 
Function MoveCam()
     
     
    global startx#
    global starty#
    global angx#
    global angy#
 
    global speed# = 4
     
    // move the camera
    if ( GetRawKeyState( 87 ) ) then MoveCameraLocalZ( 1, speed# )      // W key
    if ( GetRawKeyState( 83 ) ) then MoveCameraLocalZ( 1, -speed# )     // S key
 
    if ( GetRawKeyState( 65 ) ) then MoveCameraLocalX( 1, -speed# )
    if ( GetRawKeyState( 68 ) ) then MoveCameraLocalX( 1, speed# )
 
    if ( GetRawKeyState( 81 ) ) then MoveCameraLocalY( 1, -speed# )
    if ( GetRawKeyState( 69 ) ) then MoveCameraLocalY( 1, speed# )
     
     
    // rotate the camera
    if ( GetRawMouseRightPressed() )
        startx# = GetPointerX()
        starty# = GetPointerY()
        angx# = GetCameraAngleX(1)
        angy# = GetCameraAngleY(1)
        pressed = 1
    endif
 
    if ( GetRawMouseRightState() = 1 )
        fDiffX# = (GetPointerX() - startx#)/4.0
        fDiffY# = (GetPointerY() - starty#)/4.0
 
        newX# = angx# + fDiffY#
        if ( newX# > 89 ) then newX# = 89
        if ( newX# < -89 ) then newX# = -89
        SetCameraRotation( 1, newX#, angy# + fDiffX#, 0 )
    endif
     
endfunction
 
 
Function MoveBox()
     
    global MovingObject
     
    global StX#
    global StY#
    global StZ#
         
    global moveplane     
         
    // Check if the left mouse was pressed
    if ( GetRawMouseLeftPressed() )
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector of where we clicked
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // Check if the box was selected
        if( ObjectRayCast( box ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
            MovingObject = 1
            
            StX# = GetObjectRayCastX(0)
            StY# = GetObjectRayCastY(0)
            StZ# = GetObjectRayCastZ(0)
            
            moveplane = CreateObjectPlane(1000,1000)
            SetObjectPosition(moveplane,Stx#,sty#,stz#)
            //if GetRawKeyState(16) = 0
				SetObjectRotation(moveplane,90,0,0)
			//endif
            SetObjectVisible(moveplane, 0)
            
        else
			if(moveplane >=0)
				DeleteObject(moveplane)
				moveplane = -1
			endif
            MovingObject = 0
        endif
     
    endif
     
    if ( GetRawMouseLeftState() and moveplane>=0 )
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // Check where on the plane we holding the mouse
        if( ObjectRayCast( moveplane ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
             
            EndX# = GetObjectRayCastX(0)
            EndY# = GetObjectRayCastY(0)
            EndZ# = GetObjectRayCastZ(0)
         
            MoveObjectLocalX(box,EndX#-StX#)
            MoveObjectLocalY(box,EndY#-StY#)
            MoveObjectLocalZ(box,EndZ#-StZ#)
             
            StX# = EndX#
            StY# = EndY#
            StZ# = EndZ#
             
        endif
        
        
        MoveObjectLocalY(box,GetRawMouseWheelDelta()*0.25)
        
    
    else
			if(moveplane >=0)
				DeleteObject(moveplane)
				moveplane = -1
			endif
	endif
         
endfunction

EDITED to include Y movement from mouse wheel

Back to top

Profile PM

Blendman

10

Years of Service

User Offline

Joined: 17th Feb 2014

Location: Arkeos

Posted: 17th Feb 2018 17:23

Link

Hi

Thank you for your example. But what I would like is move the object in x, z AND Y .
In this example (it's like mine), I can't change the Y of the box.

So how can do that ?
Change X, Y? and Z with mouse. Set the object at the mouse position.

Another matter is : if you change the box size from 10,10,10 to 1,1,1 and click to select it, the box move but not at the mouse coordinates

.

AGK2 tier1 - http://www.dracaena-studio.com

Back to top

Profile PM Website

PHeMoX

6

Years of Service

User Offline

Joined: 9th Jan 2018

Location:

Posted: 17th Feb 2018 17:43

Link

Quote: "Another matter is : if you change the box size from 10,10,10 to 1,1,1 and click to select it, the box move but not at the mouse coordinates ."

Probably because the code doesn't transform the Pointerx and Pointery to actual world coordinates?

+ Code Snippet

    // get the position of the pointer (mouse)
        pointer_x = ScreenToWorldX (GetPointerX ( )) 
        pointer_y = ScreenToWorldY ( GetPointerY ( ))

Back to top

Profile PM

Bengismo

7

Years of Service

User Offline

Joined: 20th Nov 2017

Location: Yorkshire, England

Posted: 17th Feb 2018 17:50

Link

You only have X and Y mouse positions but you want to set X,Y AND Z and dont have enough inputs.... For any given position on the screen there are an infinate number of positions the obect can be at to be under the cursor. The real question is how do YOU want it to move?

If you want to move vertically then rotate the plane... you can have it in the X/Y plane and move it along that for vertical movement. You could only move the object vertically when the shift key is pressed so the user has height control separately.

You can get the original position and compare against that so that not matter what size the box is it always starts at the cursor.

Back to top

Profile PM

Bengismo

7

Years of Service

User Offline

Joined: 20th Nov 2017

Location: Yorkshire, England

Posted: 17th Feb 2018 17:53 Edited at: 17th Feb 2018 19:01

Link

Quote: "Probably because the code doesn't transform the Pointerx and Pointery to actual world coordinates?"

No its not that , its because the starting position of the raycast isnt stored in the StX#,Y#,Z# variables... The collision point is with the plane not the box. I was in a rush and just wanted to show the basic principle of 3D movement

I've edited the original code to allow Y movement using the mousewheel but x and z is moved with the pointer as before.

Back to top

Profile PM

PartTimeCoder

AGK Tool Maker

9

Years of Service

User Offline

Joined: 9th Mar 2015

Location: London UK

Posted: 17th Feb 2018 22:13

Link

@Blendman

use this example, use end_x#, end_y#, end_z# for your object position, job done!

https://www.appgamekit.com/documentation/Reference/3D/Get3DVectorXFromScreen.htm

Back to top

Profile PM

Blendman

10

Years of Service

User Offline

Joined: 17th Feb 2014

Location: Arkeos

Posted: 18th Feb 2018 08:49 Edited at: 18th Feb 2018 08:50

Link

Hi

Thank you very much for your answer.

@Bengismo, thanks for your example, i have modified it to get what I need

.

@PartTimeCoder : Thanks a lot

! that was what I need.

Here is the code To move an object in X/Y/Z with the mouse

:

// Project: Move3D 
// Created: 2018-02-17

// BY BenGismo, modified by Blendman, thanks to PartTimeCoder for help
 
 
// set window properties
SetWindowTitle( "Move Object 3D with mouse" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window
 
// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 0, 0, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
SetPrintSize(20)
SetAntialiasMode(1)
	
FoldStart // Constant , global 
	
#CONSTANT KEY_SHIFT        16		
#CONSTANT KEY_CONTROL      17
#CONSTANT KEY_ALT      	   18

Global Alt, ObjX, ObjY, ObjZ, MovingObject as integer
global startx#
global starty#
global angx#
global angy#

global speed# = 4
global StX#
global StY#
global StZ#
 
Foldend
 
 
// Set camera variables
SetCameraPosition(1, -60, 60, -60)
SetCameraLookAt( 1, 0,0,0,0 )
SetCamerarange(1,1,10000)
SetCameraFov(1, 70)
 
//create the box
global box
box = CreateObjectBox(10,10,10)
SetObjectPosition(box,0,5,0)
SetObjectColor(box, 200,50,50,255)
 
//create the plane
global plane
plane = CreateObjectPlane(1000,1000)
SetObjectRotation(plane,90,0,0)
SetObjectColor(plane, 100,100,120,255)

do
   
    MoveCam()
    MoveBox()
 
    Print("Press Middle Mouse to rotate camera")
    Print("Press Left Mouse on the box to move the box")
    Print("Use Arrow keys to move the camera around")
    Print("Box position : "+str(GetObjectX(box),0)+"/"+str(GetObjectY(box),0)+"/"+str(GetObjectZ(box),0))
    
    Sync()
    
loop
 
 
 
 
Function MoveCam()
     
     
    // move the camera
    if ( GetRawKeyState( 38 ) ) then MoveCameraLocalZ( 1, speed# )      
    if ( GetRawKeyState( 40 ) ) then MoveCameraLocalZ( 1, -speed# )     
 
    if ( GetRawKeyState( 37) ) then MoveCameraLocalX( 1, -speed# )
    if ( GetRawKeyState( 39 ) ) then MoveCameraLocalX( 1, speed# )
 
    if ( GetRawKeyState( 81 ) ) then MoveCameraLocalY( 1, -speed# )
    if ( GetRawKeyState( 69 ) ) then MoveCameraLocalY( 1, speed# )
    
   
     
    // rotate the camera
    if ( GetRawMouseMiddlePressed() )
        startx# = GetPointerX()
        starty# = GetPointerY()
        angx# = GetCameraAngleX(1)
        angy# = GetCameraAngleY(1)
        pressed = 1
    endif
 
    if ( GetRawMouseMiddleState() = 1 )
        fDiffX# = (GetPointerX() - startx#)/4.0
        fDiffY# = (GetPointerY() - starty#)/4.0
 
        newX# = angx# + fDiffY#
        if ( newX# > 89 ) then newX# = 89
        if ( newX# < -89 ) then newX# = -89
        SetCameraRotation( 1, newX#, angy# + fDiffX#, 0 )
        
    endif
     
     
endfunction
 
 
Function MoveBox()
     
    
     
    // Check if the left mouse was pressed
    
    if ( GetRawMouseLeftPressed() )
		
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector of where we clicked
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
        
        SetObjectColorEmissive(box, 0,0,0)
         
        // Check if the box was selected
        if( ObjectRayCast( box ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
            MovingObject = 1
            SetObjectColorEmissive(box, 255,0,0)
        else
            MovingObject = 0
        endif
		
	objx = GetObjectX(box)
        objy = GetObjectY(box)
        objz = GetObjectZ(box)
		
    endif
     
    if ( GetRawMouseLeftState() and MovingObject=1 )
        
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // MoveObject
        u =  GetDistance3D(camx#, camY#, camZ#, objx, objy, objz) // 100
        Print("Distance Camera to box:  "+str(u))
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) * u + GetCameraX(1) 
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) * u + GetCameraY(1) 
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) * u + GetCameraZ(1)

SetObjectPosition(box, VecX#, VecY#, VecZ#)
        
        
    endif
         
endfunction

function GetDistance3D(x1#,y1#,z1#,x2#,y2#,z2#)
	
	dx#=x1#-x2#
	dy#=y1#-y2#
	dz#=z1#-z2#
	distance# = sqrt(dx#*dx# + dy#*dy# + dz#*dz#)
	
endfunction distance#

+ Code Snippet



// Project: Move3D 
// Created: 2018-02-17

 // BY BenGismo, modified by Blendman, thanks to PartTimeCoder for help
 
 
// set window properties
SetWindowTitle( "Move Object 3D with mouse" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window
 
// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 0, 0, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
SetPrintSize(20)
SetAntialiasMode(1)
	
FoldStart // Constant , global 
	
#CONSTANT KEY_SHIFT        16		
#CONSTANT KEY_CONTROL      17
#CONSTANT KEY_ALT      	   18


Global Alt, ObjX, ObjY, ObjZ, MovingObject as integer
global startx#
global starty#
global angx#
global angy#

global speed# = 4
global StX#
global StY#
global StZ#
 
Foldend
 
 
// Set camera variables
SetCameraPosition(1, -60, 60, -60)
SetCameraLookAt( 1, 0,0,0,0 )
SetCamerarange(1,1,10000)
SetCameraFov(1, 70)
 
//create the box
global box
box = CreateObjectBox(10,10,10)
SetObjectPosition(box,0,5,0)
SetObjectColor(box, 200,50,50,255)
 
//create the plane
global plane
plane = CreateObjectPlane(1000,1000)
SetObjectRotation(plane,90,0,0)
SetObjectColor(plane, 100,100,120,255)

 
 
 
do
   
    MoveCam()
    MoveBox()
 
    Print("Press Middle Mouse to rotate camera")
    Print("Press Left Mouse on the box to move the box")
    Print("Use Arrow keys to move the camera around")
    Print("Box position : "+str(GetObjectX(box),0)+"/"+str(GetObjectY(box),0)+"/"+str(GetObjectZ(box),0))
    
    Sync()
    
loop
 
 
 
 
Function MoveCam()
     
     
    // move the camera
    if ( GetRawKeyState( 38 ) ) then MoveCameraLocalZ( 1, speed# )      
    if ( GetRawKeyState( 40 ) ) then MoveCameraLocalZ( 1, -speed# )     
 
    if ( GetRawKeyState( 37) ) then MoveCameraLocalX( 1, -speed# )
    if ( GetRawKeyState( 39 ) ) then MoveCameraLocalX( 1, speed# )
 
    if ( GetRawKeyState( 81 ) ) then MoveCameraLocalY( 1, -speed# )
    if ( GetRawKeyState( 69 ) ) then MoveCameraLocalY( 1, speed# )
    
   
     
    // rotate the camera
    if ( GetRawMouseMiddlePressed() )
        startx# = GetPointerX()
        starty# = GetPointerY()
        angx# = GetCameraAngleX(1)
        angy# = GetCameraAngleY(1)
        pressed = 1
    endif
 
    if ( GetRawMouseMiddleState() = 1 )
        fDiffX# = (GetPointerX() - startx#)/4.0
        fDiffY# = (GetPointerY() - starty#)/4.0
 
        newX# = angx# + fDiffY#
        if ( newX# > 89 ) then newX# = 89
        if ( newX# < -89 ) then newX# = -89
        SetCameraRotation( 1, newX#, angy# + fDiffX#, 0 )
        
    endif
     
     
endfunction
 
 
Function MoveBox()
     
    
     
    // Check if the left mouse was pressed
    
    if ( GetRawMouseLeftPressed() )
		
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        // Get 3D vector of where we clicked
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) *1000
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) *1000
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) *1000
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
        
        SetObjectColorEmissive(box, 0,0,0)
         
        // Check if the box was selected
        if( ObjectRayCast( box ,CamX#,CamY#,CamZ#,CamX#+VecX#,CamY#+VecY#,CamZ#+VecZ#))
            MovingObject = 1
            SetObjectColorEmissive(box, 255,0,0)
        else
            MovingObject = 0
        endif
		
	objx = GetObjectX(box)
        objy = GetObjectY(box)
        objz = GetObjectZ(box)
		
    endif
     
    if ( GetRawMouseLeftState() and MovingObject=1 )
        
        mousex# = GetPointerX()
        mousey# = GetPointerY()
         
        CamX# = GetCameraX(1)
        CamY# = GetCameraY(1)
        CamZ# = GetCameraZ(1)
         
        // MoveObject
        u =  GetDistance3D(camx#, camY#, camZ#, objx, objy, objz) // 100
        Print("Distance Camera to box:  "+str(u))
        VecX# = Get3DVectorXFromScreen( mousex#, mousey# ) * u + GetCameraX(1) 
        VecY# = Get3DVectorYFromScreen( mousex#, mousey# ) * u + GetCameraY(1) 
        VecZ# = Get3DVectorZFromScreen( mousex#, mousey# ) * u + GetCameraZ(1) 

        SetObjectPosition(box, VecX#, VecY#, VecZ#)
        
        
    endif
         
endfunction


function GetDistance3D(x1#,y1#,z1#,x2#,y2#,z2#)
	
	dx#=x1#-x2#
	dy#=y1#-y2#
	dz#=z1#-z2#
	distance# = sqrt(dx#*dx# + dy#*dy# + dz#*dz#)
	
endfunction distance#

AGK2 tier1 - http://www.dracaena-studio.com

Back to top

Profile PM Website

Sorry your browser is not supported!

Newcomers AppGameKit Corner / Move object with mouse (3d)