Nick, here's a scaled explosion with shock wave. It's the one I used in my compo entry, minus sound. Press the spacebar to see it -JerBil
Rem Project: Explosion
Rem Created: 11/8/2004 12:24:34 AM
Rem ***** Main Source File *****
Rem ****JerBil's Standard SetUp*******
Set Display Mode 800,600,32
Color BackDrop 0,RGB(20,20,40)
BackDrop On
Set Ambient Light 20
AutoCam Off
`explosion & shock wave
explosion=1
shock_wave=2
shock_scale=100
`explosion
make object sphere explosion,2,28,28
color object explosion,RGB(20,20,0)
set object emissive explosion,RGB(255,255,0)
scale object explosion,shock_scale,shock_scale,shock_scale
ghost object on explosion,0
hide object explosion
`shock wave for explosion
clone object shock_wave,explosion
color object shock_wave,RGB(20,20,0)
set object emissive shock_wave,RGB(100,120,255)
ghost object on shock_wave,1
hide object shock_wave
Sync On
Position Camera 0,2,-20
Point Camera 0,0,0,0
frameTime# = 1.0
startTime = timer()
Do
frameTime# = (frameTime# * 0.5) + ((timer() - startTime) * 0.5)
startTime = timer()
if spacekey()
while spacekey()
endwhile
exA=1
exL=timer()
endif
`show explosion
if exA=1 and timer()-exL>50
show object explosion
show object shock_wave
exA=2
endif
`-----------------------------------------------------------------------------------------------
`scale explosion & shock wave
if exA=2 and shock_scale<1000
inc shock_scale,frameTime# * 1.1
scale object explosion,shock_scale,shock_scale,shock_scale
scale object shock_wave,shock_scale*2,2,shock_scale*2
endif
`-----------------------------------------------------------------------------------------------
`end shock wave
if exA=2 and shock_scale>950
exA=0
shock_scale=100
hide object shock_wave
hide object explosion
scale object explosion,shock_scale,shock_scale,shock_scale
scale object shock_wave,shock_scale,shock_scale,shock_scale
endif
`-------------------------------------------------------------------------------------------------
Sync
Loop
