Sorry your browser is not supported!

Rem Project: hud
Rem Created: 09/11/2004 23:43:07

Rem ***** Main Source File *****

`This is the default camera field of view
#constant cameraFOV 61.9621391296

sync on
autocam off
backdrop on
color backdrop 0

`create text image for hud
create bitmap 1,450,92
set current bitmap 1
cls rgb(200,100,0)
ink rgb(255,255,255),0
line 0,0,448,0
line 0,0,0,90
line 0,90,448,90
line 448,0,448,90
ink rgb(0,0,150),rgb(200,100,0)
text 0,5," MakeHudObject - By Jason Clogg"
text 0,20," Code will position a plain at the correct position"
text 0,35," To display at exact size. E.G. a 50x50 plain will"
text 0,50," take up 50x50 pixels on screen"
text 0,65," Works for any resolution."
get image 1,0,0,449,91,1
set current bitmap 0
delete bitmap 1
position camera 0,0,0

MakeHudObject(1,1,450,92,0,0,1,1)      `Top Left
MakeHudObject(2,1,450,92,573,675,1,1)  `Bottom Right

do
   sync
loop

function MakeHudObject(object,image,xsize,ysize,xpos,ypos,ghost,transparency)

`object=Object Number
`image=Image to use as texture
`xsize=X Size of texture image
`ysize=Y Size of texture image
`xpos=X Position on object in screen pixels
`ypos=Y Position on object in screen pixels
`ghost=Ghost object. 1=ghost on
`transparency=Use Alpha for transparency 1=transparency

`The objects are placed by top left corner rather than center as this make positioning easy.

dist#=(screen height()/2)/tan(cameraFOV/2)

make object plain object,xsize,ysize
texture object object,image

if ghost=1 then ghost object on object
if transparency=1 then set object transparency object,2

set object filter object,0                   `Do Not MipMap
set object light object,0                    `Do not be affected by light

xpos=(xpos-screen width()/2)+xsize/2         `Adjust position relative to screen pixels
ypos=((ypos*-1)+screen height()/2)-ysize/2

position object object,xpos,ypos,dist#
lock object on object

endfunction

MakeHudObject(2,1,450,92,screen width()-451,screen height()-93,1,1)  `Bottom Right

Rem Project: HUD
Rem Created: 08/04/2005 08:00:30

Rem ***** Main Source File *****


#CONSTANT cameraFOV 61.9621391296

Global BaseX
Global BaseY
Global ZDist#

autocam off
set display mode 640,480,32:sync on:sync rate 30

Rem This object is just here to show the camera is moving

make object cube 200,10
position object 200,0,0,60
yrotate object 200,45

rem Initialize HUD

gosub SetGlobals
gosub MakeHudObjects

do

rem Roll the camera just to show hud positioning is constant

pitch camera up 1
roll camera left 1
turn camera right 1

rem Now update the hud postion relative to the screen position
gosub UpdateHud

text 0,0,"FPS="+str$(screen fps())

rem Show the selected Hud Object.
rem this is where you the plains are better than sprites,
rem as you can detect when the mouse is over them with a single command.

text 0,15,str$(pick object(mousex(),mousey(),1,3))

sync

loop

SetGlobals:
rem Distance from camera to make plain be scaled to exact pixel size ie a 10x10 plain
rem takes up 10x 10 pixels on screen
ZDist#=(screen height()/2)/TAN(cameraFOV/2)

`Set variables needed to convert objects x and y position to screen positions
BaseX=0-screen width()/2
BaseY=screen height()/2

return

MakeHudObjects:

make object plain 1,50,200
make object plain 2,100,100
make object plain 3,200,50

Rem Obviously you would normally texture the plains.

return

UpdateHud:
Rem This code will place the hud objects on screen in actual screen x and y positions

HudPosition(1,screen width()-50,0,50,200,0)
HudPosition(2,screen width()/2-50,screen Height()/2-50,100,100,1)
HudPosition(3,0,screen height()-50,200,50,0)

return

Function HudPosition(obj,x,y,width,height,ghost)
Rem HudPosition - Position a plain on the screen
Rem Parameters - obj = Plain object number
Rem            X = Screen X position
Rem              Y = Screen Y position
Rem              hidth = Object Width
Rem       hieght = Object Height
Rem       Ghost = ghost the plain


cpx#=camera position x()
cpy#=camera position y()
cpz#=camera position z()

rem Place object at camera position

position object obj,cpx#,cpy#,cpz#

rem Orient the object to the camera and face object towards camera

set object to camera orientation obj
turn object left obj,180

rem Move object to pixel perfect distance

move object obj,zDist#*-1

rem And postion it to screen co-ords

move object left obj,BaseX+x+(width/2)
move object up obj,BaseY-y-(height/2)

rem Ensure it appears on top of everything else

disable object zdepth obj

rem Don't mipmap object texture. Plains will appear textured like sprites

set object filter obj,0


rem Ghost object if required
rem Ghosting only works if object is set to be effected by lighting

if ghost=1
   set object light obj,1
   ghost object on obj
else
rem Don't react to any lights in the scene.
rem This stops the hud changing brightness as the camera position
rem is changed. The problem is that it stops ghosting working.
   set object light obj,0
   ghost object off obj
endif

EndFunction