<EDIT>
Didnt understand your question at first. No no, what AUTOCAM does is it automatically repositions/rotates the camera to be able to see any new objects created. So if you were to make a new object inside the loop, then the camera would reposition itself it AUTOCAM is on. This is usually not what most programmers want as they would rather control the camera themselves to get the desired effect, so to do this you just throw an AUTOCAM OFF command at the top of your code and you'll be set. Look it up in the help files for more info'.
</EDIT>
If you want to change the camera positioning during the loop, (so moving it uo with the upkey and down with the downkey) you would put the camera command in the loop along with the appropriate checks. Here's a simple program that'll get you started with the camera commands:
SYNC ON:SYNC RATE 0: HIDE MOUSE
`Create a sphere
MAKE OBJECT SPHERE 1,10
`Create a matrix to give us a sense of direction
MAKE MATRIX 1,1000,1000,10,10
POSITION MATRIX 1,-500,0,-500
`Position the camera at it's starting point and point it towards the player
POSITION CAMERA 0,100,-300
POINT CAMERA 0,0,0
`Start Main Loop
DO
`Controls:
`Camera Mode: 1 Switches to Manual Control, 2 Switches to Computer Control.
IF KEYSTATE(2)=1 THEN Mode = 0
IF KEYSTATE(3)=1 THEN Mode = 1
IF Mode = 0
`Camera Panning:
IF UPKEY()=1 THEN POSITION CAMERA CAMERA POSITION X(), CAMERA POSITION Y()+1, CAMERA POSITION Z()
IF DOWNKEY()=1 THEN POSITION CAMERA CAMERA POSITION X(), CAMERA POSITION Y()-1, CAMERA POSITION Z()
IF LEFTKEY()=1 THEN POSITION CAMERA CAMERA POSITION X()-1, CAMERA POSITION Y(), CAMERA POSITION Z()
IF RIGHTKEY()=1 THEN POSITION CAMERA CAMERA POSITION X()+1, CAMERA POSITION Y(), CAMERA POSITION Z()
`Camera Rotation
IF KEYSTATE(17)=1 THEN XROTATE CAMERA WRAPVALUE(CAMERA ANGLE X()+.5)
IF KEYSTATE(31)=1 THEN XROTATE CAMERA WRAPVALUE(CAMERA ANGLE X()-.5)
IF KEYSTATE(30)=1 THEN YROTATE CAMERA WRAPVALUE(CAMERA ANGLE Y()-.5)
IF KEYSTATE(32)=1 THEN YROTATE CAMERA WRAPVALUE(CAMERA ANGLE Y()+.5)
ELSE
POSITION CAMERA 0,100,-300
POINT CAMERA 0,0,0
ENDIF
`Sync the screen and end the loop
SYNC
LOOP
Controls:
Arrow Keys Pan the Camera Up, Left, Down, Right. WSAD Rotates camera up down left right. Pressing 1 will turn manual mode on (default) which allows you to control the camera by using the above keys, pressing 2 turns automatic mode on disallowing you to control the camera and positioning the camera/pointing the camera at a preset location.
Play with the code, the camera commands aren't that hard to get used to. Very similar to the object commands.
