Sorry your browser is not supported!

`»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»
`» 04-08-2003 // 19:11:45                                                       »
`»                          code made by Atreides                               »
`»                          I hope that you will                                »
`»                         enjoy this small code :)                             »
`»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»

autocam off
set display mode 1024,768,16
sync on
sync rate 50
set text size 18

remstart
création d'un bitmap pour créer des textures ; c'est mieux que joindre des tonnes d'images
à la source, et, finalement, pas besoin de super belles textures pour un exemple ;)
remend
create bitmap 1,128,128
set current bitmap 1
for x=1 to 128
   for y = 1 to 128
      dot x,y,rgb(rnd(255),rnd(255),rnd(255))
   next y
next x
get image 1,1,1,128,128
set current bitmap 0

rem création de l'objet joueur ; je prend une sphère et pas un cylindre comme dans Climber ^^
make object sphere 1,5
texture object 1,1
position object 1,0,15,0


rem le sol
make object box 2,250,4,250
texture object 2,1

rem des boîtes, placées de manière à ce que le joueur ne puisse être en contacte avec elles
rem et un autre objet, sinon il y aura un bug (c'est la version rapide de ce système, la
rem version lente mais permettant d'avoir des collisions avec plusieurs objets est pour
rem très bientôt, mais n'importe qui peut la coder soi-même ;)
make object box 3,20,40,20
position object 3,15,35,0
texture object 3,1

make object cube 4,18
position object 4,0,20,30
texture object 4,1

make object cube 5,16
position object 5,0,30,90
texture object 5,1

make object cube 6,14
position object 6,-60,40,90
texture object 6,1

make object cube 7,12
position object 7,-120,50,90
texture object 7,1


do
rem on demande les coordonnées de l'objet
x# = object position x(1)
y# = object position y(1)+grav# : rem plus grav# => l'objet doit tomber ;)
z# = object position z(1)
rem gestion de la gravité ; 0.1 ou 0.0981 ? bah j'ai juste mis ça pask j'aime G (y parait
rem que les filles aiment bien qu'on sache où est le point G ... mé ceci est pour une
rem autre leçon ;) )
dec grav#,0.0981

rem mouvements de l'objet : il vaut mieux modifier les coordonnées
if upkey()=1 then x# = x# + sin(object angle y(1))
if upkey()=1 then z# = z# + cos(object angle y(1))
if downkey()=1 then x# = x# - sin(object angle y(1))
if downkey()=1 then z# = z# - cos(object angle y(1))
if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-3)
if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+3)
position object 1,x#,y#,z#
rem vous n'avez jamais rêvé de voler ?
if controlkey()=1 then grav# = 0.5
rem caméra
set camera to follow x#,object position y(1),z#,object angle y(1),50,object position y(1)+10,10,0
point camera x#,y#,z#


rem on détecte s'il y a collision ; si coll > 0, alors il y en a une
coll = object collision(1,0)
if coll > 0
   rem il vaut mieux prendre des variables que refaire les calculs, c'est plus rapide et plus lisible
   dax# = dax(1,coll)
   ax# = ax(coll)
   day# = day(1,coll)
   ay# = ay(coll)
   daz# = daz(1,coll)
   az# = az(coll)
   rem on regarde si c'est en-dessus de la boîte
   if dax# > (360 - ax#) or dax# < ax#
      if daz# >= (360 - az#) or daz# =< az#
         rem on positionne l'objet par rapport à la position Y de l'objet qu'il touche,
         rem moins deux choses : la moitié de la taille de l'objet coll et la moitié de
         rem la taille de l'objet 1 .. je vous laisse deviner pkoi ;)
         rem le -0.01 c'est pour qu'il y aie toujours un contacte ; enlevez-le et observez ;)
         y# = object position y(coll) + (object size y(coll)/2) + (object size y(1)/2) - 0.01
         position object 1,x#,y#,z#
         grav# = 0
         if spacekey()=1 then grav# = 3
      endif
   endif
   rem on regarde si on lui touche la face .. il me faudrait un dé pour trouver :)
   rem la face X + 1
   if daz# > az# and daz# < (180-az#)
      if day# > ay# and day# < (180-ay#)
         rem on modifie la position X comme on avait fait pour Y ci-dessus, mais on ne touche
         rem pas à la gravité
         x# = object position x(coll) + (object size x(coll)/2) + (object size x(1)/2)
         position object 1,x#,y#,z#
      endif
   endif
   rem si on touche la face x - 1
   if daz# < (360-az#) and daz# > (180+az#)
      if day# < (360-ay#) and day# > (180+ay#)
         rem pas beosin d'explications supplémentaires ? non, je ne pense pas
         x# = object position x(coll) - (object size x(coll)/2) - (object size x(1)/2)
         position object 1,x#,y#,z#
      endif
   endif
   rem face z - 1
   if dax# < (360-ax#) and dax# > (180+ax#)
      if day# < (180+ay#) and day# > (180-ay#)
         z# = object position z(coll) - (object size z(coll)/2) - (object size z(1)/2)
         position object 1,x#,y#,z#
      endif
   endif
   rem la face Z + 1
   if dax# > ax# and dax# < (180-ax#)
      if day# > (360-ay#) or day# < ay#
         z# = object position z(coll) + (object size z(coll)/2) + (object size z(1)/2)
         position object 1,x#,y#,z#
      endif
   endif
   rem plus que la face inférieur :]
   if daz# < (180+az#) and daz# > (180-az#)
      if dax# < (180+ax#) and dax# > (180-ax#)
         rem -0.01 pour que le contacte se coupe, sinon, avec grav# = 0, on reste collé ;)
         y# = object position y(coll) - (object size y(coll)/2) - (object size y(1)/2) -0.01
         position object 1,x#,y#,z#
         rem mais attention, quand on s'éclate au plafond, on retombe tout de suite
         rem sauf dans les dessins animés, quand le héro passe à travers le toit ;)
         grav# = 0
      endif
   endif
endif
sync
loop

remstart
les trois premières fonctions trouvent des angles depuis le centre de l'objet vers une de
leurs arêtes, d'après leurs tailles
les trois autres fonctions regardent les angles entre deux objets
les résultats de calculs avec ces valeurs permettent de trouver quelle face de l'objet est
touchée.
remend
function ax(obj)
sz# = object size z(obj)/2
sy# = object size y(obj)/2
if sz# > 0
   if sy# > 0 then angle# = atan(sz#/sy#)
   if sy# < 0 then angle# = 90 + atan(sz#/abs(sy#))
   if sy# = 0 then angle# = 90
endif
if sz# < 0
   if sy# > 0 then angle# = 360 - atan(abs(sz#)/sy#)
   if sy# < 0 then angle# = 180 + atan(sz#/sy#)
   if sy# = 0 then angle# = 270
endif
if sz# = 0
   if sy# > 0 then angle# = 0
   if sy# < 0 then angle# = 180
endif
endfunction angle#

function ay(obj)
sx# = object size x(obj)/2
sz# = object size z(obj)/2
if sx# > 0
   if sz# > 0 then angle# = atan(sx#/sz#)
   if sz# < 0 then angle# = 180 + atan(sx#/abs(sz#))
   if sz# = 0 then angle# = 90
endif
if sx# < 0
   if sz# > 0 then angle# = 360 - atan(abs(sx#)/sz#)
   if sz# < 0 then angle# = 180 + atan(sx#/sz#)
   if sz# = 0 then angle# = 270
endif
if sx# = 0
   if sz# > 0 then angle# = 0
   if sz# < 0 then angle# = 180
endif
endfunction angle#

function az(obj)
sx# = object size x(obj)/2
sy# = object size y(obj)/2
if sx# > 0
   if sy# > 0 then angle# = atan(sx#/sy#)
   if sy# < 0 then angle# = 180 - atan(sx#/abs(sy#))
   if sy# = 0 then angle# = 90
endif
if sx# < 0
   if sy# > 0 then angle# = 360 - atan(abs(sx#)/sy#)
   if sy# < 0 then angle# = 180 + atan(sx#/sy#)
   if sy# = 0 then angle# = 270
endif
if sx# = 0
   if sy# > 0 then angle# = 0
   if sy# < 0 then angle# = 180
endif
endfunction angle#

function dax(a,b)
y1# = object position y(a)
z1# = object position z(a)
y2# = object position y(b)
z2# = object position z(b)
disty# = y1# - y2#
distz# = z1# - z2#
if disty# > 0
   if distz# > 0 then angle# = atan(distz#/disty#)
   if distz# < 0 then angle# = 360 - atan(abs(distz#)/disty#)
   if distz# = 0 then angle# = 0
endif
if disty# < 0
   if distz# > 0 then angle# = 180 - atan(distz#/abs(disty#))
   if distz# < 0 then angle# = 180 + atan(distz#/disty#)
   if distz# = 0 then angle# = 180
endif
if disty# = 0
   if distz# > 0 then angle# = 0
   if distz# < 0 then angle# = 180
endif
endfunction angle#

function day(a,b)
x1# = object position x(a)
z1# = object position z(a)
x2# = object position x(b)
z2# = object position z(b)
distx# = x1# - x2#
distz# = z1# - z2#
if distx# > 0
   if distz# > 0 then angle# = atan(distx#/distz#)
   if distz# < 0 then angle# = 180 - atan(distx#/abs(distz#))
   if distz# = 0 then angle# = 0
endif
if distx# < 0
   if distz# > 0 then angle# = 360 - atan(abs(distx#)/distz#)
   if distz# < 0 then angle# = 180 + atan(distx#/distz#)
   if distz# = 0 then angle# = 180
endif
if distx# = 0
   if distz# > 0 then angle# = 0
   if distz# < 0 then angle# = 180
endif
endfunction angle#

function daz(a,b)
x1# = object position x(a)
y1# = object position y(a)
x2# = object position x(b)
y2# = object position y(b)
distx# = x1# - x2#
disty# = y1# - y2#
if distx# > 0
   if disty# > 0 then angle# = atan(distx#/disty#)
   if disty# < 0 then angle# = 180 - atan(distx#/abs(disty#))
   if disty# = 0 then angle# = 0
endif
if distx# < 0
   if disty# > 0 then angle# = 360 - atan(abs(distx#)/disty#)
   if disty# < 0 then angle# = 180 + atan(distx#/disty#)
   if disty# = 0 then angle# = 180
endif
if distx# = 0
   if disty# > 0 then angle# = 0
   if disty# < 0 then angle# = 180
endif
endfunction angle#