Sorry your browser is not supported!

vs_1_1
//-------------------------------
//Constant registers
//-------------------------------
// c0-c3 - world*view*proj
// c8 - light position(In object space)
// c10 - vPosViewer(In object space)
def c6, -1, 0, 0, 0 // helper constant
def c7, 2, -1, 0, 0 // helper constant
//------------------------------
// Input registers
//------------------------------
dcl_position v0
dcl_tangent v1
dcl_binormal v2
dcl_normal v3
dcl_texcoord v4
//------------------------------
// output position 
//------------------------------
//
m4x4 oPos, v0, c0 
//------------------------------
// Compute the tangent space matrix to transform from object space to tangent space
//------------------------------
//
mad r7.xyz, c7.x, v1, c7.y //bias vector tangent to (-1,1)
mad r8.xyz, c7.x, v2, c7.y //bias vector binormal to (-1,1)
mad r9.xyz, c7.x, v3, c7.y //bias vector normal to (-1,1)
//------------------------------
// Compute L vector in tangent space
//------------------------------
//
add r10, -v0, c8 // light position - vPos
dp3 r7.w, r10, r10 // Normalize (lightpostion-vPos)
rsq r7.w, r7.w
mul r11.xyz, r10, r7.w
m3x3 oT2.xyz, r11, r7 // t2 = L vector in tangent space
//------------------------------
// Compute H vector in tangent space
//------------------------------
//
add r4, -v0, c4 // V vector
add r6, r10, r4 // L + V
dp3 r6.w, r6, r6 // Normalize (L+V)
rsq r6.w, r6.w
mul r5.xyz, r6, r6.w
m3x3 oT3.xyz, r5, r7 // t3 = H vector in tangent space 
//------------------------------
// output texture coordinates 
//------------------------------
//
mov oT0.xy, v4 // t0 = texture coordinate
mov oT1.xy, v4 // t1 = texture coordinate

ps_1_1
//-------------------------------
//Constant registers
//-------------------------------
// c1 - lightColor
def c0, 4.0f, 1.0f, 0.0f, -0.75f // Helper constant
//------------------------------
// Load textures
//------------------------------
//
tex t0 // Normal
tex t1 // diffuse
tex t2 // L
tex t3 // H
//------------------------------
// compute output color
//------------------------------
//
dp3_sat r1.xyzw,t3_bx2,t0_bx2 // max(0,dot(N,H))
dp3_sat r0.rgb,t2_bx2,t0_bx2 // max(0,dot(N,L))
+mad_x4_sat r1.w,r1.w,r1.w,c0.w // specular = saturate(4*(dot(N,H)^2-0.75))
mul r1.w,r1.w,r1.w // specular = specular*specular
mul r0.rgb,r0,t1 // diffuse = dot(N,L)*diffuse texture map
+mul_x2_sat r1.w,r1.w,t0.w // specular = saturate(specular*2*gloss map)
add_sat r0.rgb,r0,r1.w // specular + diffuse
mul r0.rgb,r0,c1 // (specular+diffuse)*lightColor
+mov r0.a,t1.a // alpha output = alpha diffuse map for transparency

vs.1.1
// tranform position
m4x4 oPos,v0,c4
     
// tsb generation      
m3x3 r3,v8,c0            //gen normal
m3x3 r5,v3,c0            //gen tangent

// gen binormal via Cross product
mul r0,-r3.zxyw,r5.yzxw;
mad r4,-r3.yzxw,r5.zxyw,-r0;

// specular
m4x4 r2,v0,c0            //transform position
// get a vector toward the camera
add r2,-r2,c24

dp3 r11.x,  r2.xyz,r2.xyz   //load the square into r11
rsq r11.xyz,r11.x         //get the inverse of the square
mul r2.xyz, r2.xyz,r11.xyz   //multiply, r0 = -(camera vector)
add r2.xyz,r2.xyz,-c16      //get half angle
   
// normalize
dp3 r11.x,r2.xyz,r2.xyz      //load the square into r1
rsq r11.xyz,r11.x         //get the inverse of the square
mul r2.xyz,r2.xyz,r11.xyz   //multiply, r2 = HalfAngle

// transform the half angle vector
dp3 r8.x,r3,r2
dp3 r8.y,r4,r2
dp3 r8.z,r5,r2
     
// half-angle in oD1  
mad oD1.xyz,   r8.xyz,c20,c20   //mutiply by a half, add half   
      
// tex coords   
mov oT0.xy,   v7.xy
mov oT1.xy,   v7.xy