Here's a couple of simple tread mark ideas. Nothing fancy, but with a little adaptation, lighting effects, and fading, they can be effective. The same technique can be used for footprints.
Snippet 1 - Disappearing treads
rem tank treads - disappearing
rem latch
rem oct 14, 2006
autocam off
sync on
sync rate 60
rem create texture
ink 0,0
box 0,0,128,128
ink RGB(128,64,0),0
box 20,0,40,128
box 88,0,108,128
get image 1,0,0,128,128
ink rgb(255,255,255),0
rem make ground
make matrix 1,10000,10000,50,50
rem create vehicle
make object cube 2,64
position object 2,5000,32,5000
rem make tread plane
for obj = 3 to 4
make object plain obj,64,64
xrotate object obj,90
fix object pivot obj
`SET OBJECT Object Number, Wireframe, Transparency, Cull
set object obj,1,0,0
texture object obj,1
next obj
rem position one tread under vehicle, position other behind
position object 3,5000,0,5000
position object 4,5000,0,5000-64
rem position camera
position camera 5000,400,5000
xrotate camera 90
rem establish current position
oldx#=object position x(2)
oldy#=object position y(2)
oldz#=object position z(2)
obj=3
do
rem flag to switch treads
flag=0
rem move vehicle
if upkey()=1 then speed#=speed#+.3
if upkey()=0 then speed#=speed#-.1
if speed# <=0 then speed#=0
if speed# >= 5 then speed# = 5
if leftkey()=1 then turn object left 2,2
if rightkey()=1 then turn object right 2,2
rem update position
move object 2,speed#
x#=object position x(2)
y#=object position y(2)
z#=object position z(2)
rem move camera
position camera x#,400,z#
rem orient tread under vehicle to vehicle position
point object obj,x#,0,z#
rem if the vehicle has moved far enough, switch tread objects
distance#=sqrt(((x#-oldx#)^2)+((z#-oldz#)^2))
if distance# > 64
if obj = 3
obj =4
position object obj,x#,0,z#
flag = 1
endif
if obj = 4 and flag = 0
obj = 3
position object obj,x#,0,z#
endif
oldx#=x#
oldy#=y#
oldz#=z#
endif
sync
loop
Snippet 2 - Continuous treads
rem tank treads - continous
rem latch
rem oct 14, 2006
autocam off
sync on
sync rate 60
rem create texture
ink 0,0
box 0,0,128,128
ink RGB(128,64,0),0
box 20,0,40,128
box 88,0,108,128
get image 1,0,0,128,128
ink rgb(255,255,255),0
rem make ground
make matrix 1,10000,10000,50,50
rem create vehicle
make object cube 2,64
position object 2,5000,32,5000
rem position camera
position camera 5000,400,5000
xrotate camera 90
rem start creating new objects at this number
obj=5
do
rem move vehicle
if upkey()=1 then speed#=speed#+.3
if upkey()=0 then speed#=speed#-.1
if speed# <=0 then speed#=0
if speed# >= 5 then speed# = 5
if leftkey()=1 then turn object left 2,2
if rightkey()=1 then turn object right 2,2
rem update position
move object 2,speed#
x#=object position x(2)
y#=object position y(2)
z#=object position z(2)
rem move camera
position camera x#,400,z#
rem make endless series of tire treads
if speed# > 0
inc obj
make object plain obj,64,8
xrotate object obj,90
fix object pivot obj
`SET OBJECT Object Number, Wireframe, Transparency, Cull
set object obj,1,0,0
texture object obj,1
rem orient tread under vehicle to vehicle position
position object obj,x#,0,z#
set object to object orientation obj,2
endif
sync
loop
With snippet 2, you'll need to limit the production of additional tread objects at some value, and fade out and delete the ones already created.
Enjoy your day.
