Sorry your browser is not supported!

sync on
sync rate 0
cls

dim swarm(6)
swarm(1)=rgb(255,0,0)
swarm(2)=rgb(0,255,0)
swarm(3)=rgb(0,0,255)
type entity_type
   x as float
   y as float
   r as float
   swarm_id
endtype

dim entity(100) as entity_type

type obstacle_type
   exist as boolean
   x as float
   y as float
   radius as float
endtype

dim obstacle(1000) as obstacle_type
for n=1 to 100
entity(n).x=rnd(screen width())
entity(n).y=rnd(screen height())
entity(n).r=rnd(360)
entity(n).swarm_id=rnd(2)+1
next n
rem speed of entities
speed#=200
turn_speed#=500
global time as float
time=0
timer0=timer()
global detection_distance=50
global seperation_distance=25
do
   cls
   time=(timer()-timer0)/1000.0
   timer0=timer()
   gosub ai
   gosub update_entities
   gosub draw_entities
   gosub obstacles
   sync
loop

obstacles:
ink -1,0
if mouseclick()=1 and mc=0
o=1
while obstacle(o).exist=1
inc o
endwhile
obstacle(o).exist=1
obstacle(o).x=mousex()
obstacle(o).y=mousey()
obstacle(o).radius=10
endif
mc=mouseclick()
for n=1 to 1000
if obstacle(n).exist=1
circle obstacle(n).x,obstacle(n).y,obstacle(n).radius
endif
next n
return

ai:
mmz=mousemovez()
if mmz>0
   seperation_distance=seperation_distance+5
endif
if mmz<0
   seperation_distance=seperation_distance-5
endif


for n=1 to 100
   rem this makes them want to continue going in their current direction.
   totalx#=10.0*cos(entity(n).r)
   totaly#=10.0*sin(entity(n).r)
   rem let them be influenced by the entities around them
   for n2=1 to 100
      d#=sqrt((entity(n).x-entity(n2).x)^2+(entity(n).y-entity(n2).y)^2)
      if d#<detection_distance
         if d#>seperation_distance
            if entity(n).swarm_id=entity(n2).swarm_id
               totalx#=totalx#+cos(entity(n2).r)
               totaly#=totaly#+sin(entity(n2).r)
               dx#=entity(n).x-entity(n2).x
               dy#=entity(n).y-entity(n2).y
               nx#=dx#/d#
               ny#=dy#/d#
               p#=(d#-seperation_distance)*0.01
               totalx#=totalx#-p#*nx#
               totaly#=totaly#-p#*ny#
            endif
         else
            dx#=entity(n).x-entity(n2).x
            dy#=entity(n).y-entity(n2).y
            nx#=dx#/d#
            ny#=dy#/d#
            p#=seperation_distance/d#
            if entity(n).swarm_id=entity(n2).swarm_id
               totalx#=totalx#+p#*nx#
               totaly#=totaly#+p#*ny#
            else
               totalx#=totalx#+0.01*p#*nx#
               totaly#=totaly#+0.01*p#*ny#
            endif
         endif
      endif
   next n2
   rem let them avoid walls
   for n2=1 to 1000
      if obstacle(n2).exist=1
         d#=sqrt((entity(n).x-obstacle(n2).x)^2+(entity(n).y-obstacle(n2).y)^2)-obstacle(n2).radius
         if d#<detection_distance
            dx#=entity(n).x-obstacle(n2).x
            dy#=entity(n).y-obstacle(n2).y
            length#=sqrt(dx#^2+dy#^2)
            nx#=dx#/length#
            ny#=dy#/length#
            p#=detection_distance/d#
            totalx#=totalx#+5*p#*nx#
            totaly#=totaly#+5*p#*ny#
         endif
      endif
   next n2
   rem let them be attracted to the cursor
   dx#=entity(n).x-mousex()
   dy#=entity(n).y-mousey()
   d#=sqrt(dx#^2+dy#^2)
   if d#<detection_distance
      nx#=dx#/d#
      ny#=dy#/d#
      if mouseclick()<>2
         totalx#=totalx#-nx#*10
         totaly#=totaly#-ny#*10
      else
         totalx#=totalx#+nx#*10
         totaly#=totaly#+ny#*10
      endif
   endif
   rem keep them in the screen
   if entity(n).x<detection_distance
      totalx#=totalx#+detection_distance/entity(n).x
   endif
   if entity(n).x>screen width()-detection_distance
      totalx#=totalx#-detection_distance/(screen width()-entity(n).x)
   endif
   if entity(n).y<detection_distance
      totaly#=totaly#+detection_distance/entity(n).y
   endif
   if entity(n).y>screen height()-detection_distance
      totaly#=totaly#-detection_distance/(screen height()-entity(n).y)
   endif
   rem make them turn
   ang#=wrapvalue(atanfull(totaly#,totalx#))
   entity(n).r=wrapvalue(entity(n).r)
   if entity(n).r-ang#<-180 then dec ang#,360
   if entity(n).r-ang#>180 then inc ang#,360
   if ang#>entity(n).r+turn_speed#*time
      entity(n).r=entity(n).r+turn_speed#*time
   else
      if ang#<entity(n).r-turn_speed#*time
         entity(n).r=entity(n).r-turn_speed#*time
      else
         entity(n).r=ang#
      endif
   endif
next n
return

update_entities:
for n=1 to 100
entity(n).x=entity(n).x+speed#*time*cos(entity(n).r)
entity(n).y=entity(n).y+speed#*time*sin(entity(n).r)
entity(n).r=entity(n).r+(rnd(100)-50)*0.00001
if entity(n).x>screen width()-1 then entity(n).x=screen width()-1
if entity(n).x<1 then entity(n).x=1
if entity(n).y>screen height()-1 then entity(n).y=screen height()-1
if entity(n).y<1 then entity(n).y=1

next n
return
draw_entities:
l#=10
for n=1 to 100
c=swarm(entity(n).swarm_id)
ink c,0
line entity(n).x,entity(n).y,entity(n).x+l#*cos(entity(n).r),entity(n).y+l#*sin(entity(n).r)
`circle entity(n).x,entity(n).y,seperation_distance
`circle entity(n).x,entity(n).y,detection_distance
next n
return

sync on
sync rate 0
cls
hide mouse
tilesize=10
gw=screen width()/tilesize
gh=screen height()/tilesize
dim grid(gw,gh) as float
global scout_amount
scout_amount=6
type scout_type
x as float
y as float
r as float
target_exist
targetx as float
targety as float
endtype
dim scout(scout_amount) as scout_type
for s=1 to scout_amount
scout(s).x=rnd(screen width())
scout(s).y=rnd(screen height())
scout(s).r=rnd(359)
next s
speed#=2
length#=4.0
sightrange=3
do
   cls
   gosub display_grid
   gosub ai
   sync
loop
ai:
for s=1 to scout_amount
   gx=scout(s).x/tilesize
   gy=scout(s).y/tilesize
   for x=gx-sightrange to gx+sightrange
   for y=gy-sightrange to gy+sightrange
   if x>=0 and y>=0 and x<gw and y<gh
      if (x-gx+0.0)^2+(y-gy+0.0)^2<=sightrange^2
         grid(x,y)=255
      endif
   endif
   next y
   next x
   if scout(s).target_exist=0
      mostwanted#=0
      for x=0 to gw-1
         for y=0 to gh-1
            if x<>gx and y<>gy
               good=1
               for s2=1 to scout_amount
                  if s2<>s
                     if abs(0.0+scout(s2).targetx/tilesize-x)<sightrange*1.5 and abs(0.0+scout(s2).targety/tilesize-y)<sightrange*1.5
                        good=0
                     endif
                  endif
               next s2
               if good=1
                  want#=(1.0/(grid(x,y)*5+0.1))/((0.0+x-gx)^2+(0.0+y-gy)^2+100.0)
                  if want#>mostwanted#
                     mostwanted#=want#
                     wantx=x
                     wanty=y
                  endif
               endif
            endif
         next y
      next x
      scout(s).target_exist=1
      scout(s).targetx=tilesize*wantx+tilesize*0.5
      scout(s).targety=tilesize*wanty+tilesize*0.5
  endif
   if scout(s).target_exist=1
      scout(s).r=atanfull(scout(s).targety-scout(s).y,scout(s).targetx-scout(s).x)
      scout(s).x=scout(s).x+speed#*cos(scout(s).r)
      scout(s).y=scout(s).y+speed#*sin(scout(s).r)
      if sqrt((scout(s).targety-scout(s).y)^2+(scout(s).targetx-scout(s).x)^2)<0.5*tilesize
         scout(s).target_exist=0
      endif
   endif
   ink rgb(0,0,255),0
   line scout(s).x,scout(s).y,scout(s).x+length#*cos(scout(s).r),scout(s).y+length#*sin(scout(s).r)
 `  line scout(s).x,scout(s).y,scout(s).targetx,scout(s).targety
next s

return

display_grid:
   for x=0 to gw-1
      for y=0 to gh-1
         if grid(x,y)>0 then grid(x,y)=grid(x,y)-0.1
         ink rgb(grid(x,y),grid(x,y),grid(x,y)),0
         box x*tilesize,y*tilesize,x*tilesize+tilesize,y*tilesize+tilesize
      next y
   next x
return