Ah. Inside the map drawing function you can reset the maps y coordinate when it goes over the maps y coordinate max.
This works in both Classic and Pro:
` Turn on syncing
sync rate 0
sync on
` Dimensionalize the map array
dim Map(19,14)
` Make a random map
for y=0 to 14
for x=0 to 19
Map(x,y)=rnd(9)+1
next x
next y
` Change the last line of the map to 1's
for t=0 to 19
Map(t,14)=1
next t
` Create 10 tiles
for t=1 to 10
ink rgb(rnd(255),rnd(255),rnd(255)),0
box 0,0,32,32
get image t,0,0,32,32,1
next t
` Set the starting map coordinates
MX=0:MY=0
` Create a timer
tim=timer()
do
` Check if the timer is up
if timer()>tim+100
` Call the show map function with the map coordinates
ShowMap(MX,MY)
` Increase the map y coordinate
inc MY
` Reset map y coordinate if the map goes over
if MY=15 then MY=0
` Reset timer
tim=timer()
endif
` Update the screen
sync
loop
function ShowMap(StartX,StartY)
` Set the map coordinates to the starting map coordinates
MapX=StartX
MapY=StartY
` Make y equal every 32nd pixel down the screen
for y=0 to 448 step 32
` Make x equal every 32nd pixel across the screen
for x=0 to 608 step 32
` Paste the tile at the current screen coordinates
paste image Map(MapX,MapY),x,y
` Increase map x coordinate
inc MapX
next x
` Reset map x coordinate
MapX=StartX
` Increase map y coordindate
inc MapY
` Reset map y coordinate if it goes over
if MapY=15 then MapY=0
next y
endfunction
