Rendering basic 3D using only DBP's 2D line command

Author

Message

lower logic

18

Years of Service

User Offline

Joined: 15th Jun 2006

Location:

Posted: 2nd Feb 2007 00:00 Edited at: 2nd Feb 2007 12:59

Link

This code snippet simulates 3D using just DBP's 2D lines for rendering. DX9 and OpenGL are of course much faster and have more functionality, but it was fun to make my own.
I get 50-70fps for the 432 lines that are drawn in the example.

I didn't add triangle support or a zbuffer because I don't think DBP would be able to compile it into fast enough code for any use (and I think it would be really hard to make a good zbuffer), but this example with lines is still interesting.

You can fly around using mouse look and WASD, and you can roll the camera using Q/E. The rotation method I used was YXZ.

Note I don't ever use DBP's camera or any objects.

Here is the code:

sync on
sync rate 0
cls
hide mouse
type vec3
   x as float
   y as float
   z as float
endtype

type vecvec3
   x as vec3
   y as vec3
   z as vec3
endtype

type camera_type
   angle as vec3 rem note: Y axis is the first angle (global), then X, then Z (relative/local)
   axis as vecvec3
   position as vec3
   fov as float
   aspect_ratio as float
endtype

global camera as camera_type
camera.fov=80
camera.aspect_ratio=(1.0*screen width())/screen height()
do
   cls
   cy#=cy#+mousemovex()*0.5
   cx#=cx#+mousemovey()*0.5
   camera.angle.y=curveangle(cy#,camera.angle.y,2)
   camera.angle.x=curveangle(cx#,camera.angle.x,2)
   camera.angle.z=camera.angle.z*0.99+(keystate(16)-keystate(18))
   update_camera()
   zmove#=(keystate(17)-keystate(31))*0.1
   xmove#=(keystate(32)-keystate(30))*0.1
   camera.position.x=camera.position.x+camera.axis.z.x*zmove#
   camera.position.y=camera.position.y+camera.axis.z.y*zmove#
   camera.position.z=camera.position.z+camera.axis.z.z*zmove#
   camera.position.x=camera.position.x+camera.axis.x.x*xmove#
   camera.position.y=camera.position.y+camera.axis.x.y*xmove#
   camera.position.z=camera.position.z+camera.axis.x.z*xmove#
   if camera.position.x<-30 then camera.position.x=-30
   if camera.position.y<-30 then camera.position.y=-30
   if camera.position.z<-30 then camera.position.z=-30
   if camera.position.x>30 then camera.position.x=30
   if camera.position.y>30 then camera.position.y=30
   if camera.position.z>30 then camera.position.z=30
   ink -1,0
   print "FPS:",screen fps()
   lock pixels
   for x=-6 to 6 step 6
      for y=-6 to 6 step 6
         for z=-6 to 6 step 6
            ink rgb((x+6)/12.0*255.0,(y+6)/12.0*255.0,(z+6)/12.0*255.0),0
            draw_line(-1+x,0+y,1+z,1+x,0+y,1+z)
            draw_line(-1+x,0+y,3+z,1+x,0+y,3+z)
            draw_line(-1+x,2+y,1+z,1+x,2+y,1+z)
            draw_line(-1+x,2+y,3+z,1+x,2+y,3+z)

draw_line(-1+x,0+y,1+z,-1+x,2+y,1+z)
            draw_line(-1+x,0+y,3+z,-1+x,2+y,3+z)
            draw_line(-1+x,0+y,1+z,-1+x,2+y,1+z)
            draw_line(-1+x,0+y,3+z,-1+x,2+y,3+z)

draw_line(1+x,0+y,1+z,1+x,2+y,1+z)
            draw_line(1+x,0+y,3+z,1+x,2+y,3+z)
            draw_line(1+x,0+y,1+z,1+x,2+y,1+z)
            draw_line(1+x,0+y,3+z,1+x,2+y,3+z)

draw_line(-1+x,0+y,1+z,-1+x,0+y,3+z)
            draw_line(1+x,0+y,1+z,1+x,0+y,3+z)
            draw_line(-1+x,2+y,1+z,-1+x,2+y,3+z)
            draw_line(1+x,2+y,1+z,1+x,2+y,3+z)
         next z
      next y
   next x
   unlock pixels
   sync
loop

function update_camera()
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)
endfunction

function draw_line(x0#,y0#,z0#,x1#,y1#,z1#)
   x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z
   x1#=x1#-camera.position.x:y1#=y1#-camera.position.y:z1#=z1#-camera.position.z

x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
   y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
   z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
   if z00#<=0 then exitfunction
   x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

x10#=x1#*camera.axis.x.x+y1#*camera.axis.x.y+z1#*camera.axis.x.z
   y10#=x1#*camera.axis.y.x+y1#*camera.axis.y.y+z1#*camera.axis.y.z
   z10#=x1#*camera.axis.z.x+y1#*camera.axis.z.y+z1#*camera.axis.z.z
   if z10#<=0 then exitfunction
   x1=(x10#/z10#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y1=(0-y10#/z10#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5
   line x0,y0,x1,y1
endfunction

+ Code Snippet

sync on
sync rate 0
cls
hide mouse
type vec3
   x as float
   y as float
   z as float
endtype

type vecvec3
   x as vec3
   y as vec3
   z as vec3
endtype

type camera_type
   angle as vec3 rem note: Y axis is the first angle (global), then X, then Z (relative/local)
   axis as vecvec3
   position as vec3
   fov as float
   aspect_ratio as float
endtype

global camera as camera_type
camera.fov=80
camera.aspect_ratio=(1.0*screen width())/screen height()
do
   cls
   cy#=cy#+mousemovex()*0.5
   cx#=cx#+mousemovey()*0.5
   camera.angle.y=curveangle(cy#,camera.angle.y,2)
   camera.angle.x=curveangle(cx#,camera.angle.x,2)
   camera.angle.z=camera.angle.z*0.99+(keystate(16)-keystate(18))
   update_camera()
   zmove#=(keystate(17)-keystate(31))*0.1
   xmove#=(keystate(32)-keystate(30))*0.1
   camera.position.x=camera.position.x+camera.axis.z.x*zmove#
   camera.position.y=camera.position.y+camera.axis.z.y*zmove#
   camera.position.z=camera.position.z+camera.axis.z.z*zmove#
   camera.position.x=camera.position.x+camera.axis.x.x*xmove#
   camera.position.y=camera.position.y+camera.axis.x.y*xmove#
   camera.position.z=camera.position.z+camera.axis.x.z*xmove#
   if camera.position.x<-30 then camera.position.x=-30
   if camera.position.y<-30 then camera.position.y=-30
   if camera.position.z<-30 then camera.position.z=-30
   if camera.position.x>30 then camera.position.x=30
   if camera.position.y>30 then camera.position.y=30
   if camera.position.z>30 then camera.position.z=30
   ink -1,0
   print "FPS:",screen fps()
   lock pixels
   for x=-6 to 6 step 6
      for y=-6 to 6 step 6
         for z=-6 to 6 step 6
            ink rgb((x+6)/12.0*255.0,(y+6)/12.0*255.0,(z+6)/12.0*255.0),0
            draw_line(-1+x,0+y,1+z,1+x,0+y,1+z)
            draw_line(-1+x,0+y,3+z,1+x,0+y,3+z)
            draw_line(-1+x,2+y,1+z,1+x,2+y,1+z)
            draw_line(-1+x,2+y,3+z,1+x,2+y,3+z)

            draw_line(-1+x,0+y,1+z,-1+x,2+y,1+z)
            draw_line(-1+x,0+y,3+z,-1+x,2+y,3+z)
            draw_line(-1+x,0+y,1+z,-1+x,2+y,1+z)
            draw_line(-1+x,0+y,3+z,-1+x,2+y,3+z)

            draw_line(1+x,0+y,1+z,1+x,2+y,1+z)
            draw_line(1+x,0+y,3+z,1+x,2+y,3+z)
            draw_line(1+x,0+y,1+z,1+x,2+y,1+z)
            draw_line(1+x,0+y,3+z,1+x,2+y,3+z)

            draw_line(-1+x,0+y,1+z,-1+x,0+y,3+z)
            draw_line(1+x,0+y,1+z,1+x,0+y,3+z)
            draw_line(-1+x,2+y,1+z,-1+x,2+y,3+z)
            draw_line(1+x,2+y,1+z,1+x,2+y,3+z)
         next z
      next y
   next x
   unlock pixels
   sync
loop

function update_camera()
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)
endfunction

function draw_line(x0#,y0#,z0#,x1#,y1#,z1#)
   x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z
   x1#=x1#-camera.position.x:y1#=y1#-camera.position.y:z1#=z1#-camera.position.z

   x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
   y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
   z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
   if z00#<=0 then exitfunction
   x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

   x10#=x1#*camera.axis.x.x+y1#*camera.axis.x.y+z1#*camera.axis.x.z
   y10#=x1#*camera.axis.y.x+y1#*camera.axis.y.y+z1#*camera.axis.y.z
   z10#=x1#*camera.axis.z.x+y1#*camera.axis.z.y+z1#*camera.axis.z.z
   if z10#<=0 then exitfunction
   x1=(x10#/z10#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y1=(0-y10#/z10#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5
   line x0,y0,x1,y1
endfunction

Edit:
1) Made the roll slowly spring back to 0 so you can't get confused/upside down as easily
2) Added some curveangle to the mouselook.
3) Realized the 3d world-space was being rendered upside down and fixed it

Back to top

Profile PM

Kohaku

20

Years of Service

User Offline

Joined: 3rd May 2004

Location: The not very United Kingdom

Posted: 2nd Feb 2007 01:09

Link

That's really impressive. Lines have never looked so good.

I wonder how much further you could take that.

You are not alone.

Back to top

Profile PM Website

Mistrel

Retired Moderator

19

Years of Service

User Offline

Joined: 9th Nov 2005

Location:

Posted: 2nd Feb 2007 02:12

Link

If you use Cloggy's d3dfunc dll you can make anti-aliased lines.

http://3dfolio.com

Back to top

Profile PM Email Website

lower logic

18

Years of Service

User Offline

Joined: 15th Jun 2006

Location:

Posted: 2nd Feb 2007 03:13 Edited at: 2nd Feb 2007 12:43

Link

Thanks. If I work on it more I could probably make my own "objects" with line data, rotation, scale, position, etc, using a type array. I think it would be fun to make some unusual effects/functionality such as a sort of black-hole space-warping effect, and edit the rendering function so that the lines are segmented so they could curve to the space warpage. I like the snippet because it shows how few lines of code are needed to create the illusion of 3D using just addition, multiplication, sine, cosine, tangent.

Back to top

Profile PM

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 2nd Feb 2007 20:22 Edited at: 2nd Feb 2007 20:25

Link

what? no occlusion? pfft noob!

nah just kidding, nice code. Definitely gonna have to study that.

if you use pixel lock/unlock you might get more speed out of the drawing.

Back to top

Profile PM Email Website

Kohaku

20

Years of Service

User Offline

Joined: 3rd May 2004

Location: The not very United Kingdom

Posted: 2nd Feb 2007 21:13

Link

He doesz0rz.

You are not alone.

Back to top

Profile PM Website

lower logic

18

Years of Service

User Offline

Joined: 15th Jun 2006

Location:

Posted: 2nd Feb 2007 22:47 Edited at: 2nd Feb 2007 22:54

Link

Here's how the code works:
1) update_camera() translates the camera's rotation into the x/y/z components of the x/y/z axes (9 variables altogether). Note I apply the rotation in the opposite order. It is YXZ rotation but I apply Z first, then X, then Y because it is easier that way.

rem Initialize the axes:
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
rem apply z rotation first
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
rem apply x rotation next
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
rem apply y rotation last
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)

+ Code Snippet

rem Initialize the axes:
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
rem apply z rotation first
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
rem apply x rotation next
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
rem apply y rotation last
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)

2) draw_line() first subtracts the camera's position from the 2 x/y/z endpoints of the line.

+ Code Snippet

x0#=x0#-camera.position.x
y0#=y0#-camera.position.y
z0#=z0#-camera.position.z
x1#=x1#-camera.position.x
y1#=y1#-camera.position.y
z1#=z1#-camera.position.z

3) Next draw_line() transforms the 2 points to get the x/y/z points relative to the camera's rotation (using the camera's x/y/z axes calculated in update_camera()).

+ Code Snippet

   x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
   y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
   z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
   x10#=x1#*camera.axis.x.x+y1#*camera.axis.x.y+z1#*camera.axis.x.z
   y10#=x1#*camera.axis.y.x+y1#*camera.axis.y.y+z1#*camera.axis.y.z
   z10#=x1#*camera.axis.z.x+y1#*camera.axis.z.y+z1#*camera.axis.z.z

4) The ratio of the x/z and y/z calculate an x value and y value that are to be screen coordinates (but are not actual screen pixels yet).
5) These x and y values are then changed based on the FOV and aspect ratio.
6) Finally the x and y are mapped to their actual screen pixels. Steps 4-6 are combined into 1 command per coordinate in the actual code:

+ Code Snippet

   x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5
   x1=(x10#/z10#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y1=(0-y10#/z10#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

7) A line is drawn between these 2 points

+ Code Snippet

   line x0,y0,x1,y1

Back to top

Profile PM

HyperByte

17

Years of Service

User Offline

Joined: 3rd Jan 2007

Location: in a small kola bear costume

Posted: 2nd Feb 2007 23:08

Link

thats awsome

On a scale from one to ten one being very smart and ten being an absolute genius your none of the above

Back to top

Profile PM Email

Brain111

17

Years of Service

User Offline

Joined: 5th Feb 2007

Location: In my own little world.

Posted: 7th Feb 2007 03:24

Link

Awesome, man... You should try to make a simple game that uses that type of stuff. Just like a fly-through-a-tunnel-and-don't-run-into-stuff type of game, or something like that. That would be awesome.

Back to top

Profile PM

Terrorist Zero

18

Years of Service

User Offline

Joined: 29th Aug 2006

Location: Teh YouKai

Posted: 8th Feb 2007 19:34

Link

Elite - Remake

That's some seriously good coding!

www.tornupgaming.com
The home of free games and game projects.

Back to top

Profile PM Email Website

Sixty Squares

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Somewhere in the world

Posted: 12th Feb 2007 03:07

Link

That is amazing! Seriously, it is one of the best code snippets I have ever seen! NICE!

Back to top

Profile PM Email

Xeridox

21

Years of Service

User Offline

Joined: 19th May 2003

Playing: Scrap Mechanic

Posted: 18th Feb 2007 17:42

Link

I was wondering what it would take to do something like this in DBPro...

Very impressive.

Now, try texturing and occluding, lightmapping, etc., etc.

Kidding

This is an awesome snippet!

Darin Snow
Xeridox Entertainment

Back to top

Profile PM Email Website

Aaron Miller

18

Years of Service

User Offline

Joined: 25th Feb 2006

Playing: osu!

Posted: 24th Feb 2007 10:12

Link

Lower Logic,

Do you mind if I convert that into an actual renderer?

It would be free, and credit would definately be given to you.

Please note, however, the renderer will not be a DBPro renderer, but an actual library for C++ (Perhaps, or a DLL), which renders to a window.

Cheers,

-db

Enter my forums here.

Back to top

Profile PM Email Website

Whong

20

Years of Service

User Offline

Joined: 15th Jul 2004

Location: Turku Finland

Posted: 24th Feb 2007 10:55

Link

Looks cool!

Great snippet!

Click to hear more about these spectacular programs for special effects!

Back to top

Profile PM Email

Aaron Miller

18

Years of Service

User Offline

Joined: 25th Feb 2006

Playing: osu!

Posted: 28th Feb 2007 02:06

Link

Hello. I have found this section of a site, which may be very useful

Learn to make a solid fill triangle

Learn how to make a gaurad filled triangle

Learn how to apply a texture to a triangle

Cheers,

-db

Enter my forums here.

Back to top

Profile PM Email Website

lower logic

18

Years of Service

User Offline

Joined: 15th Jun 2006

Location:

Posted: 28th Feb 2007 04:08

Link

DB user 2006+, sure you can use it. Though if you're going to be doing 3D rendering, I'd recomend something faster like OpenGL or DirectX.

Back to top

Profile PM

Aaron Miller

18

Years of Service

User Offline

Joined: 25th Feb 2006

Playing: osu!

Posted: 2nd Mar 2007 08:34

Link

Indeed OpenGL and Direct3D are faster. However, Im interested in this because ive always wanted to make my own 3D Renderer.... Every day I get more interested in something more advanced, or difficult.

Thank you.

Cheers,

-db

Enter my forums here.

Back to top

Profile PM Email Website

VR2

19

Years of Service

User Offline

Joined: 14th Mar 2005

Location:

Posted: 2nd Mar 2007 13:49

Link

Hey, nice work!

I can relate to how you feel about this project, as a couple of years ago I wrote something very similar in DB (to prototype), C++ (to get more speed), Javascript (just for a laugh to see if it could be done), C# (to use as a Web Control) and eventually Java (because C# Web Controls are .... lacking shall we say?) and was immensly proud of it

.

During the iterations of development I added a bunch of stuff like 3d model loading (from xml), culling (object and face), lighting (point and directional), collision detection/response (ellip to polygon soup) and a scene graph...

...so for an idea of where you might want to take take this, here's a couple of Applet demos I made at the time:

Platformer: http://www.victory-road.co.uk/HTML3D/Level3.html
Racer: http://www.victory-road.co.uk/HTML3D/VRProto.html
Shooter: http://www.victory-road.co.uk/HTML3D/RedDoor.html

Notice the LACK of a decent Z-buffer - I used the "Painters" algorithm where you sort the triangles based on distance from the camera, which sounds ok but isn't very accurate.

It all looks so basic by todays DX10 standards but the satisfaction in doing it all yourself makes it all worthwhile

Back to top

Profile PM Website

Image All

18

Years of Service

User Offline

Joined: 30th Dec 2005

Location: Home

Posted: 10th Mar 2007 20:13

Link

I played the platformer, closed the tab and now the music won't stop playing

Back to top

Profile PM Email

Roxas

19

Years of Service

User Offline

Joined: 11th Nov 2005

Location: http://forum.thegamecreators.com

Posted: 10th Mar 2007 20:57

Link

WTF the music keeps playing -.-

Back to top

Profile PM Email

VR2

19

Years of Service

User Offline

Joined: 14th Mar 2005

Location:

Posted: 10th Mar 2007 22:58

Link

I just noticed that - sorry guys its a bug.

Still, jolly little number, no? It's from Croc.

I'd suggest just running one of the other two demos, that will stop the music from the first (and correctly dispose when finished).

Back to top

Profile PM Website

Diggsey

18

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 11th Mar 2007 19:23

Link

If you want to do a z-buffer, heres an easy way:

1) make an array of values, the size of the screen
2) When drawing a triangle, work out the z as well as the UV
3) Put the Z value into the array of depths
4) Only draw a dot or do 3 when the z value is less than the one currently in the array

A way for optimisation would be to use an array 1/4 of the screen size, but the lines will be more jagged when surrfaces overlap.

If you want to beat DBPros transparency issues, (but use loads of memory!) you can do this:

1) Make a 2d array of lists of rgba values instead of using the screen
2) Instead of using dot, insert an item into the correct list, each list sorted by zdepth
3) When finished, draw each item in each list to its screen pixel in the order it is in the list, (Including alpha values)

VISIT MY WEBSITE!

Back to top

Profile PM Email Website

VR2

19

Years of Service

User Offline

Joined: 14th Mar 2005

Location:

Posted: 14th Mar 2007 13:08

Link

Quote: "If you want to do a z-buffer, heres an easy way:

1) make an array of values, the size of the screen
2) When drawing a triangle, work out the z as well as the UV
3) Put the Z value into the array of depths
4) Only draw a dot or do 3 when the z value is less than the one currently in the array

A way for optimisation would be to use an array 1/4 of the screen size, but the lines will be more jagged when surrfaces overlap.
"

Nice one, Diggsey except, in my case, and I'm sure with alot of others, the approach you're advocating assumes that triangles are drawn per pixel, when in actual fact all implementations would use a native "FillPolygon" or "DrawPolygon" or "DrawLine" type of API call (this is not HW accelerated so we need all the speed we can get!)

It seemed to me that Z-buffering would mean writing a custom scan line renderer, testing every pixel for z values (as you say) and if you're gonna do that, then you may as well do texturing as well...and that would have meant texture coordinates for verts, meaning(ie - it's a bit of a can of worms needing a radical amount of work and possibly chocking the entire pipeline in the process).

Back to top

Profile PM Website

Turoid

21

Years of Service

User Offline

Joined: 1st Nov 2003

Location: The Netherlands

Posted: 14th Mar 2007 21:32

Link

awesome

http://www.darkbasic.nl/

Back to top

Profile PM

Roxas

19

Years of Service

User Offline

Joined: 11th Nov 2005

Location: http://forum.thegamecreators.com

Posted: 14th Mar 2007 22:16

Link

Hehee.. Got little speed boost with d3d.. 350 was static and 1000+ some times.. And dint change the code only the line command with d3d_line and the ink rgb with d3d_color and removed () bracets but i also modifed the code here's my try

(Need Cloggy's d3d Plugin)

sync on
sync rate 0
cls
hide mouse
type vec3
   x as float
   y as float
   z as float
endtype

type vecvec3
   x as vec3
   y as vec3
   z as vec3
endtype

type camera_type
   angle as vec3 rem note: Y axis is the first angle (global), then X, then Z (relative/local)
   axis as vecvec3
   position as vec3
   fov as float
   aspect_ratio as float
endtype

global xmove#
   global zmove#
   global cx#
   global cy#

global camera as camera_type
camera.fov=80
camera.aspect_ratio=(1.0*screen width())/screen height()
do
   cls

Control_Camera()

print "FPS:",screen fps()

lock pixels
   Cube3d(0,0,0)
   Cube3d(10,10,10)
   Pyramid3d(-10,-10,-10,0)
   Pyramid3d(-20,-20,-20,10)
   Circle3d(20,20,20,0)
   unlock pixels

fastsync
loop

Function Cube3d(x#,y#,z#)
draw_line(-1+6+x#,0+6+y#,1+6+z#,1+6+x#,0+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,1+6+x#,0+6+y#,3+6+z#)
draw_line(-1+6+x#,2+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,2+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)

draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,-1+6+x#,2+6+y#,3+6+z#)
draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,-1+6+x#,2+6+y#,3+6+z#)

draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(1+6+x#,0+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)
draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(1+6+x#,0+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)

draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,0+6+y#,3+6+z#)
draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,0+6+y#,3+6+z#)
draw_line(-1+6+x#,2+6+y#,1+6+z#,-1+6+x#,2+6+y#,3+6+z#)
draw_line(1+6+x#,2+6+y#,1+6+z#,1+6+x#,2+6+y#,3+6+z#)
endfunction

Function Pyramid3d(x#,y#,z#,size)
draw_line(x#,y#,z#,2+size+x#,-4-size+y#,2+size+z#)
draw_line(x#,y#,z#,-2-size+x#,-4-size+y#,-2-size+z#)
draw_line(x#,y#,z#,2+size+x#,-4-size+y#,-2-size+z#)
draw_line(x#,y#,z#,-2-size+x#,-4-size+y#,2+size+z#)

draw_line(2+size+x#,-4-size+y#,2+size+z#,2+size+x#,-4-size+y#,-2-size+z#)
draw_line(-2-size+x#,-4-size+y#,-2-size+z#,-2-size+x#,-4-size+y#,2+size+z#)
draw_line(2+size+x#,-4-size+y#,2+size+z#,-2-size+x#,-4-size+y#,2+size+z#)
draw_line(-2-size+x#,-4-size+y#,-2-size+z#,2+size+x#,-4-size+y#,-2-size+z#)
endfunction

Function Circle3d(x0#,y0#,z0#,size)
size=size+6

x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z

x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
if z00#<=0 then exitfunction
x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

d3d_circle x0,y0,size,0
endfunction

Function Control_Camera()
   cy#=cy#+mousemovex()*0.5
   cx#=cx#+mousemovey()*0.5
   camera.angle.y=curveangle(cy#,camera.angle.y,2)
   camera.angle.x=curveangle(cx#,camera.angle.x,2)
   camera.angle.z=camera.angle.z*0.99+(keystate(16)-keystate(18))
   update_camera()
   zmove#=(keystate(17)-keystate(31))*0.1
   xmove#=(keystate(32)-keystate(30))*0.1
   camera.position.x=camera.position.x+camera.axis.z.x*zmove#
   camera.position.y=camera.position.y+camera.axis.z.y*zmove#
   camera.position.z=camera.position.z+camera.axis.z.z*zmove#
   camera.position.x=camera.position.x+camera.axis.x.x*xmove#
   camera.position.y=camera.position.y+camera.axis.x.y*xmove#
   camera.position.z=camera.position.z+camera.axis.x.z*xmove#

if camera.position.x<-30 then camera.position.x=-30
   if camera.position.y<-30 then camera.position.y=-30
   if camera.position.z<-30 then camera.position.z=-30
   if camera.position.x>30 then camera.position.x=30
   if camera.position.y>30 then camera.position.y=30
   if camera.position.z>30 then camera.position.z=30
endfunction

function update_camera()
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)
endfunction

function draw_line(x0#,y0#,z0#,x1#,y1#,z1#)
   x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z
   x1#=x1#-camera.position.x:y1#=y1#-camera.position.y:z1#=z1#-camera.position.z

x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
   y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
   z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
   if z00#<=0 then exitfunction
   x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

x10#=x1#*camera.axis.x.x+y1#*camera.axis.x.y+z1#*camera.axis.x.z
   y10#=x1#*camera.axis.y.x+y1#*camera.axis.y.y+z1#*camera.axis.y.z
   z10#=x1#*camera.axis.z.x+y1#*camera.axis.z.y+z1#*camera.axis.z.z
   if z10#<=0 then exitfunction
   x1=(x10#/z10#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y1=(0-y10#/z10#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5
   d3d_line x0,y0,x1,y1
endfunction

+ Code Snippet

sync on
sync rate 0
cls
hide mouse
type vec3
   x as float
   y as float
   z as float
endtype

type vecvec3
   x as vec3
   y as vec3
   z as vec3
endtype

type camera_type
   angle as vec3 rem note: Y axis is the first angle (global), then X, then Z (relative/local)
   axis as vecvec3
   position as vec3
   fov as float
   aspect_ratio as float
endtype

   global xmove#
   global zmove#
   global cx#
   global cy#

global camera as camera_type
camera.fov=80
camera.aspect_ratio=(1.0*screen width())/screen height()
do
   cls

   Control_Camera()

   print "FPS:",screen fps()

   lock pixels
   Cube3d(0,0,0)
   Cube3d(10,10,10)
   Pyramid3d(-10,-10,-10,0)
   Pyramid3d(-20,-20,-20,10)
   Circle3d(20,20,20,0)
   unlock pixels

   fastsync
loop

Function Cube3d(x#,y#,z#)
draw_line(-1+6+x#,0+6+y#,1+6+z#,1+6+x#,0+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,1+6+x#,0+6+y#,3+6+z#)
draw_line(-1+6+x#,2+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,2+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)

draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,-1+6+x#,2+6+y#,3+6+z#)
draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,2+6+y#,1+6+z#)
draw_line(-1+6+x#,0+6+y#,3+6+z#,-1+6+x#,2+6+y#,3+6+z#)

draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(1+6+x#,0+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)
draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,2+6+y#,1+6+z#)
draw_line(1+6+x#,0+6+y#,3+6+z#,1+6+x#,2+6+y#,3+6+z#)

draw_line(-1+6+x#,0+6+y#,1+6+z#,-1+6+x#,0+6+y#,3+6+z#)
draw_line(1+6+x#,0+6+y#,1+6+z#,1+6+x#,0+6+y#,3+6+z#)
draw_line(-1+6+x#,2+6+y#,1+6+z#,-1+6+x#,2+6+y#,3+6+z#)
draw_line(1+6+x#,2+6+y#,1+6+z#,1+6+x#,2+6+y#,3+6+z#)
endfunction

Function Pyramid3d(x#,y#,z#,size)
draw_line(x#,y#,z#,2+size+x#,-4-size+y#,2+size+z#)
draw_line(x#,y#,z#,-2-size+x#,-4-size+y#,-2-size+z#)
draw_line(x#,y#,z#,2+size+x#,-4-size+y#,-2-size+z#)
draw_line(x#,y#,z#,-2-size+x#,-4-size+y#,2+size+z#)

draw_line(2+size+x#,-4-size+y#,2+size+z#,2+size+x#,-4-size+y#,-2-size+z#)
draw_line(-2-size+x#,-4-size+y#,-2-size+z#,-2-size+x#,-4-size+y#,2+size+z#)
draw_line(2+size+x#,-4-size+y#,2+size+z#,-2-size+x#,-4-size+y#,2+size+z#)
draw_line(-2-size+x#,-4-size+y#,-2-size+z#,2+size+x#,-4-size+y#,-2-size+z#)
endfunction

Function Circle3d(x0#,y0#,z0#,size)
size=size+6

x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z

x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
if z00#<=0 then exitfunction
x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

d3d_circle x0,y0,size,0
endfunction

Function Control_Camera()
   cy#=cy#+mousemovex()*0.5
   cx#=cx#+mousemovey()*0.5
   camera.angle.y=curveangle(cy#,camera.angle.y,2)
   camera.angle.x=curveangle(cx#,camera.angle.x,2)
   camera.angle.z=camera.angle.z*0.99+(keystate(16)-keystate(18))
   update_camera()
   zmove#=(keystate(17)-keystate(31))*0.1
   xmove#=(keystate(32)-keystate(30))*0.1
   camera.position.x=camera.position.x+camera.axis.z.x*zmove#
   camera.position.y=camera.position.y+camera.axis.z.y*zmove#
   camera.position.z=camera.position.z+camera.axis.z.z*zmove#
   camera.position.x=camera.position.x+camera.axis.x.x*xmove#
   camera.position.y=camera.position.y+camera.axis.x.y*xmove#
   camera.position.z=camera.position.z+camera.axis.x.z*xmove#

   if camera.position.x<-30 then camera.position.x=-30
   if camera.position.y<-30 then camera.position.y=-30
   if camera.position.z<-30 then camera.position.z=-30
   if camera.position.x>30 then camera.position.x=30
   if camera.position.y>30 then camera.position.y=30
   if camera.position.z>30 then camera.position.z=30
endfunction


function update_camera()
   xx0#=1:xy0#=0:xz1#=0:yx0#=0:yy0#=1:yz1#=0:zx2#=0:zy1#=0:zz1#=1
   xx2#=xx0#*cos(camera.angle.z):xy1#=xx0#*sin(camera.angle.z)
   yx2#=-yy0#*sin(camera.angle.z):yy1#=yy0#*cos(camera.angle.z)
   xy2#=xy1#*cos(camera.angle.x)-xz1#*sin(camera.angle.x)
   xz2#=xz1#*cos(camera.angle.x)+xy1#*sin(camera.angle.x)
   yy2#=yy1#*cos(camera.angle.x)-yz1#*sin(camera.angle.x)
   yz2#=yz1#*cos(camera.angle.x)+yy1#*sin(camera.angle.x)
   zy2#=zy1#*cos(camera.angle.x)-zz1#*sin(camera.angle.x)
   zz2#=zz1#*cos(camera.angle.x)+zy1#*sin(camera.angle.x)
   camera.axis.x.x=xx2#*cos(camera.angle.y)+xz2#*sin(camera.angle.y)
   camera.axis.x.y=xy2#
   camera.axis.x.z=xz2#*cos(camera.angle.y)-xx2#*sin(camera.angle.y)
   camera.axis.y.x=yx2#*cos(camera.angle.y)+yz2#*sin(camera.angle.y)
   camera.axis.y.y=yy2#
   camera.axis.y.z=yz2#*cos(camera.angle.y)-yx2#*sin(camera.angle.y)
   camera.axis.z.x=zx2#*cos(camera.angle.y)+zz2#*sin(camera.angle.y)
   camera.axis.z.y=zy2#
   camera.axis.z.z=zz2#*cos(camera.angle.y)-zx2#*sin(camera.angle.y)
endfunction

function draw_line(x0#,y0#,z0#,x1#,y1#,z1#)
   x0#=x0#-camera.position.x:y0#=y0#-camera.position.y:z0#=z0#-camera.position.z
   x1#=x1#-camera.position.x:y1#=y1#-camera.position.y:z1#=z1#-camera.position.z

   x00#=x0#*camera.axis.x.x+y0#*camera.axis.x.y+z0#*camera.axis.x.z
   y00#=x0#*camera.axis.y.x+y0#*camera.axis.y.y+z0#*camera.axis.y.z
   z00#=x0#*camera.axis.z.x+y0#*camera.axis.z.y+z0#*camera.axis.z.z
   if z00#<=0 then exitfunction
   x0=(x00#/z00#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y0=(0-y00#/z00#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5

   x10#=x1#*camera.axis.x.x+y1#*camera.axis.x.y+z1#*camera.axis.x.z
   y10#=x1#*camera.axis.y.x+y1#*camera.axis.y.y+z1#*camera.axis.y.z
   z10#=x1#*camera.axis.z.x+y1#*camera.axis.z.y+z1#*camera.axis.z.z
   if z10#<=0 then exitfunction
   x1=(x10#/z10#)/tan(camera.fov*0.5)*screen width()*0.5+screen width()*0.5
   y1=(0-y10#/z10#)/tan(camera.fov*0.5)*camera.aspect_ratio*screen height()*0.5+screen height()*0.5
   d3d_line x0,y0,x1,y1
endfunction

Back to top

Profile PM Email

dark coder

22

Years of Service

User Offline

Joined: 6th Oct 2002

Location: Japan

Posted: 19th Mar 2007 10:47

Link

I made the code render triangles, and added support for objects and a few other things and thought it was worthy of a new topic, http://forum.thegamecreators.com/?m=forum_view&t=102348&b=6&p=0

Back to top

Profile PM Email

Turoid

21

Years of Service

User Offline

Joined: 1st Nov 2003

Location: The Netherlands

Posted: 2nd Apr 2007 12:33

Link

@lower logic:
I sort of grabbed your code and converted it into c++.. worked perfect

Here's a video of it:

http://smg.photobucket.com/albums/v679/jopiedopie/?action=view¤t=3ddml.flv

I am awesome and always right.

Back to top

Profile PM

TEH_CODERER

21

Years of Service

User Offline

Joined: 12th Nov 2003

Location: Right behind you!

Posted: 2nd Apr 2007 14:05

Link

Cool, following the link though showed some of your other pics and this one is just about the coolest thing i have ever seen!
http://smg.photobucket.com/albums/v679/jopiedopie/?action=view¤t=bar.jpg

Back to top

Profile PM Email

Turoid

21

Years of Service

User Offline

Joined: 1st Nov 2003

Location: The Netherlands

Posted: 3rd Apr 2007 10:26

Link

thank you

I am awesome and always right.

Back to top

Profile PM

Sorry your browser is not supported!

Code Snippets / Rendering basic 3D using only DBP's 2D line command