Movement problem (W,A,S,D not working properly)

Author

Message

Reality Forgotten

FPSC Reloaded TGC Backer

18

Years of Service

User Offline

Joined: 28th Dec 2005

Location: Wichita Falls TX

Posted: 3rd Feb 2007 18:08

Link

Language type: DBPro

Here's the problem:

After placing this snippet. I get the mouse to do what I want it to.

+ Code Snippet

rotate camera camera angle x(0)+(mousemovey()/2.0),camera angle y(0)+(mousemovex()/2.0),0

After palcing this Snippet, I can not get the camera to move. It will move a very tiny bit but always resets to the origional camera position stated upon creating the camera.

+ Code Snippet

if keystate(17) then position camera newxvalue(camera position x(),camera angle y(),1),camera position y(),newzvalue(camera position z(),camera angle y(),1)
if keystate(30) then position camera newxvalue(camera position x(),wrapvalue(camera angle y()+270),1),camera position y(),newzvalue(camera position z(),wrapvalue(camera angle y()+270),1)
if keystate(31) then position camera newxvalue(camera position x(),wrapvalue(camera angle y()+180),1),camera position y(),newzvalue(camera position z(),wrapvalue(camera angle y()+180),1)
if keystate(32) then position camera newxvalue(camera position x(),wrapvalue(camera angle y()+90),1),camera position y(),newzvalue(camera position z(),wrapvalue(camera angle y()+90),1)

I searched the forums and spent the last 3 hours reading. I can not find a solution to my problem. At first I was thinking maybe the camera is stuck in the floor of the model. I dismissed that when I reposition the camera above the floor.

Thanks in advance!

Regards,
RF

Back to top

Profile PM Email

Reality Forgotten

FPSC Reloaded TGC Backer

18

Years of Service

User Offline

Joined: 28th Dec 2005

Location: Wichita Falls TX

Posted: 3rd Feb 2007 18:18

Link

Ok, I removed the "Position Camera" snippet. and the W,A,S,D commands work now. My next questions is how do I get the mouse to affect the position of the camera?

Point: If I'm holding the fwd (W) key and I rotate the mouse to face the ground, How would I get the camera to follow and travel towards the ground?

Regards,
RF

Back to top

Profile PM Email

Dr Manette

18

Years of Service

User Offline

Joined: 17th Jan 2006

Location: BioFox Games hq

Posted: 3rd Feb 2007 21:35

Link

This is how I move (mouse and keyboard movement):

+ Code Snippet

rem mouse movement
cx#=wrapvalue(cx#+mousemovey())
cy#=wrapvalue(cy#+mousemovex())
rotate camera cx#,cy#,0

rem move camera
if keystate(17)
   move camera 9
endif
if keystate(31)
   move camera -9
endif
if keystate(32)
   xrotate camera 0: yrotate camera cy# + 90: move camera 9: xrotate camera cx#: yrotate camera cy#
endif
if keystate(30)
   xrotate camera 0: yrotate camera cy# - 90: move camera 9: xrotate camera cx#: yrotate camera cy#
endif

Bio Fox...four guys, one computer, games like nobody's business. Join our forum: http://www.biofox.aceboard.com

Back to top

Profile PM Email Website

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 3rd Feb 2007 21:56 Edited at: 3rd Feb 2007 21:58

Link

Heres a function that'll handle it all, just fill in the parameters:

+ Code Snippet

FUNCTION handleCamera(cam, moveSpeed#, lookSensitivity#)
   ROTATE CAMERA CAMERA ANGLE X(cam) + (MOUSEMOVEY() * lookSensitivity#), CAMERA ANGLE Y(cam) + (MOUSEMOVEX() * lookSensitivity#), 0
   MOVE CAMERA cam,(KEYSTATE(17)-KEYSTATE(31)) * moveSpeed#
ENDFUNCTION

If you're wondering how the movement line works, just follow it through. When you check if a key is pressed, you'll get either a 1 (pressed) or a 0 (depressed). If you subtract the W key's state from the S key's state, you'll get either -1 (If the S key is pressed and the W key isnt), 1 (If the W key is pressed and the S key isnt), or 0 (if no keys are pressed).

You also know that the MOVE CAMERA command accepts a positive or negative value, positive moving the camera forward, and negative moving the camera backward.

Putting that together, if we move our camera by a value of WKey - SKey, it'll move forward at 1 unit/loop when the W key is pressed, and backward at -1 units/loop when the S key is pressed. Similarily, it wont move when neither key is pressed, or when both keys are pressed.

Finally, we multiply the value returned from that little formula (WKey - SKey) by the moveSpeed# variable. So if you want the camera to move at 0.5 units/loop, you set moveSpeed# to 0.5.

Here's a test program to experiment with:

+ Code Snippet

`Main settings
SYNC ON:SYNC RATE 0:AUTOCAM OFF:HIDE MOUSE

`Make a matrix, purely for visual effects, not needed
MAKE MATRIX 1,1000,1000,10,10
POSITION MATRIX 1,-500,0,-500

`Start the main loop
DO

   `Handle camera movement using our function
   handleCamera(0,0.5,0.1)

   `Refresh the screen
   SYNC

`Repeat
LOOP

`Declare the handleCamera function (always declare functions after your program's main loop).
FUNCTION handleCamera(cam, moveSpeed#, lookSensitivity#)
   ROTATE CAMERA CAMERA ANGLE X(cam) + (MOUSEMOVEY() * lookSensitivity#), CAMERA ANGLE Y(cam) + (MOUSEMOVEX() * lookSensitivity#), 0
   MOVE CAMERA cam,(KEYSTATE(17)-KEYSTATE(31)) * moveSpeed#
ENDFUNCTION

Hope that helps clear things up a bit,
- RUC'

:: Check out the new FPS Tutorial's Progress at http://www.freewebs.com/ruccus
along with code, media, and more.

Back to top

Profile PM Email Website

Reality Forgotten

FPSC Reloaded TGC Backer

18

Years of Service

User Offline

Joined: 28th Dec 2005

Location: Wichita Falls TX

Posted: 4th Feb 2007 02:48

Link

@Dr Manette- Thank you! This Fixed my problem.

@Ruccus- Thank you! I am going to mess around with that test program so that I may gain a little better understanding of things.

Regards,
RF

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / Movement problem (W,A,S,D not working properly)