Resolution Pick Snippet... - GameCreators Forum

Author

Message

Nicholas Thompson

21

Years of Service

User Offline

Joined: 6th Sep 2004

Location: Bognor Regis, UK

Posted: 16th Sep 2006 02:25

Link

For my Settlers Of Catan WIP, I've made a simple resolution picker (for the beta versions)...

+ Code Snippet

function SetResolution()
   sync off
   PERFORM CHECKLIST FOR DISPLAY MODES
   sel = 1
   do
      cls

      print " - SELECT RESOLUTION - "

      for i = 1 to CHECKLIST QUANTITY()
         if i = sel then ink 0x00FF00, 0xFFFFFF else ink 0xFFFFFF, 0xFFFFFF
         print checklist string$(i)
      next i

      if upkey() or downkey()
         if upkey() then dec sel
         if downkey() then inc sel
         if sel < 1 then sel = 1 else if sel > checklist quantity() then sel = checklist quantity()
      endif

      while upkey() or downkey() : endwhile

      if returnkey() then exit
   loop

   set display mode checklist value a(sel), checklist value b(sel), checklist value c(sel)
   set camera aspect (1.0 * checklist value a(sel)) / (1.0 * checklist value b(sel))
endfunction

Question: What should the default resolution be and how would I get it to chose it without assuming that res is possible?

Also - does anyone know a neat and simple way of having it so holding the button down makes the choice step in a controllable way (like once every 0.5 seconds?) - like Windows does if you hold a key down... There is a short pause and then repetition (but not at the max speed of your computer!!)

I hope this is usefull to someone...

[center]

Back to top

Profile PM Email Website

Agent Dink

22

Years of Service

User Offline

Joined: 30th Mar 2004

Location:

Posted: 16th Sep 2006 06:06

Link

Well, I'd say 1024 x 768 x 32 is a good middle of the road resolution to go with, but can't DBP return the desktop resolution? If so just have your game default to the desktop resolution.

Sometimes the only way over a wall is to pile up enough bodies to climb over - Dave W.

Back to top

Profile PM

Uncle Sam

20

Years of Service

User Offline

Joined: 23rd Jul 2005

Location: West Coast, USA

Posted: 16th Sep 2006 08:31

Link

Quote: "Question: What should the default resolution be and how would I get it to chose it without assuming that res is possible?"

+ Code Snippet

if check display mode(1024,768,32)=1 then set display mode 1024,768,32

Quote: "Also - does anyone know a neat and simple way of having it so holding the button down makes the choice step in a controllable way (like once every 0.5 seconds?) - like Windows does if you hold a key down... There is a short pause and then repetition (but not at the max speed of your computer!!)"

This shouldnt be too hard. I'll use the control key for an example:

+ Code Snippet

if controlkey()=1
    if firstpress=1 or controlcounter>10
        firstpress=0
        rem do what ever you want here
    endif
    inc controlcounter
else
    firstpress=1
    controlcounter=0
endif

Change the "10" to make the delay longer or shorter.

Uncle Sam
Nvidia Geforce 7600 GS 256MB PCIEx, 2.66 GHZ Pentium 4 proccessor, 768MB RAM
Need particles? Click here!

Back to top

Profile PM Email

Scraggle

Moderator

22

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 16th Sep 2006 11:05 Edited at: 16th Sep 2006 11:17

Link

Uncle Sam is almost there. The problem with that code is that it will have a different delay speed depending on the frame rate. Instead you need to use a timer to control the delay.
Here:

+ Code Snippet

Delay = 1000
BackDrop on
Sync on

do
	text 0,0,str$(Number)
	
	if spacekey()
		if SpacePressed = 0
			SpacePressed = Timer()
			inc Number
		endif
		
		if Timer() - SpacePressed > Delay 
			SpacePressed = 0
		endif
		
	else
		SpacePressed = 0	
	endif
	
	sync
loop

Change the variable 'Delay' to adjust the delay in milliseconds (1000 = 1 second)

As for the default resolution; it is unlikley that many people will be using less than 1024 x 768 but there will still be some out there. I would say go with 800 x 600 as a default but give the user the option to increase it.

Better still would be to set the resolution to the users desktop resolution, like this:

+ Code Snippet

set display mode get display width(), get display height(), get display depth()

You will need an external plug-in to do it. The Enhancement Pack has the commands you need but there are free alternatives around that will do the job. IanM's Matrix plug-in is one of many that spring to mind (and is too damn useful not to have installed!).

Back to top

Profile PM Email

Lord Raoul

23

Years of Service

User Offline

Joined: 26th Oct 2002

Location:

Posted: 16th Sep 2006 15:21

Link

Just a thought of mine, I am not a fan of the forcing the player to run the game at desktop resolution idea.

To me it seems flawed in that quite often desktop resolution is higher than you would use in a game, for example my "desktop" resolution is 1440*900, and I'm fairly sure if a game ran at that resolution then it would be slowed down considerably.

Don't know if it's just me and my friends that do that, but perhaps if you are going to make it detect the desktop resolution then make that the default one but allow it to be changed ingame incase it is unsuitable?

Back to top

Profile PM

JerBil

22

Years of Service

User Offline

Joined: 8th May 2004

Location: Somewhere along the Z axis...

Posted: 16th Sep 2006 20:58

Link

They should have at least the option to run at desktop resolution,
since any images at that res will not be stretched and won't look crappy.

Ad Astra Per Asper

Back to top

Profile PM Email

spooky

23

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 17th Sep 2006 00:02

Link

Here's some code that will grab desktop size;

+ Code Snippet

global desktop_width
global desktop_height
global desktop_depth

get_desktop_size()

print "W = ";desktop_width
print "H = ";desktop_height
print "D = ";desktop_depth

wait key
end

function get_desktop_size()
   SM_CXSCREEN = 0
   SM_CYSCREEN = 1
   BITSPIXEL = 12
   hdc as dword
   dll_1=free_dll()
   load dll "user32.dll",dll_1
   dll_2=free_dll()
   load dll "gdi32.dll",dll_2
   desktop_width=call dll(dll_1,"GetSystemMetrics",SM_CXSCREEN)
   desktop_height=call dll(dll_1,"GetSystemMetrics",SM_CYSCREEN)
   hdc=call dll(dll_1, "GetDC", 0)
   desktop_depth=call dll(dll_2, "GetDeviceCaps", hdc, BITSPIXEL)
   call dll dll_1, "ReleaseDC", 0, hdc
   delete dll dll_2
   delete dll dll_1
endfunction

function free_dll()
   repeat
      inc n
   until dll exist(n)=0
endfunction n

Boo!

Back to top

Profile PM Website

Scraggle

Moderator

22

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 17th Sep 2006 00:04

Link

There you go! Spooky has saved you the trouble of downloading IanM's plug-in.

However ... I still recommend that you download it, because it has a lot more functionality than desktop dimensions and is very, very useful!

Back to top

Profile PM Email

Uncle Sam

20

Years of Service

User Offline

Joined: 23rd Jul 2005

Location: West Coast, USA

Posted: 17th Sep 2006 01:18

Link

Heh, I thought of that, but I just assumed he was going to lock the framerate.

Uncle Sam
Nvidia Geforce 7600 GS 256MB PCIEx, 2.66 GHZ Pentium 4 proccessor, 768MB RAM
Need particles? Click here!

Back to top

Profile PM Email

Profit

20

Years of Service

User Offline

Joined: 19th Feb 2006

Location: United States

Posted: 17th Sep 2006 03:08 Edited at: 17th Sep 2006 03:49

Link

Uncle Sam, you make a pretty reasonable point there.

common people are walking in line.

Mitsu Fly Ride.

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Resolution Pick Snippet...