There does seem to be a couple missing, probably due to cutting and pasting, so here it is again :
remstart
This is a collection of screen wipes
Written by N. Kingsley
remend
function verticalWipe(x as integer, y as integer, r as integer, g as integer, b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for loop=0 to y step 2
line 0,loop,x,loop
line 0,y-loop-1,x,y-loop-1
sync
next loop
endfunction
function horizontalWipe(x as integer, y as integer, r as integer, g as integer, b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for loop=0 to x step 2
line loop,0,loop,y
line x-loop-1,0,x-loop-1,y
sync
next loop
endfunction
function boxWipe(x as integer, y as integer, r as integer, g as integer, b as integer)
halfX=x>>1
halfY=y>>1
xloop=0
ink rgb(r,g,b),rgb(r,g,b)
for yloop=0 to y
box halfX-xloop,halfY-yloop,halfX+xloop,halfY+yloop
sync
inc xloop
if xloop>halfX then exitfunction
next yloop
endfunction
function diagonalWipeL(x as integer,y as integer,r as integer,g as integer,b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for xloop=0 to x<<1 step 2
line xloop,0,0,xloop
line x-xloop-1,y,x,y-xloop-1
sync
next xloop
endfunction
function diagonalWipeR(x as integer,y as integer,r as integer,g as integer,b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for xloop=0 to x<<1 step 2
line x-xloop,0,x,xloop
line xloop+1,y,0,(y-xloop)-1
sync
next xloop
endfunction
function verticalSplitWipe(x as integer,y as integer,r as integer,g as integer,b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for yloop=0 to y step 2
line 0,yloop,(x>>1)+1,yloop
line x,y-yloop-1,x>>1,y-yloop-1
sync
next yloop
for yloop=0 to y step 2
line 0,y-yloop-1,(x>>1)+1,y-yloop-1
line x,yloop,x>>1,yloop
sync
next yloop
endfunction
function horizontalSplitWipe(x as integer,y as integer,r as integer,g as integer,b as integer)
ink rgb(r,g,b),rgb(r,g,b)
for xloop=0 to x step 2
line xloop,0,xloop,(y>>1)+1
line x-xloop-1,y,x-xloop-1,y>>1
sync
next xloop
for xloop=0 to x step 2
line xloop,y,xloop,y>>1
line x-xloop-1,0,x-xloop-1,(y>>1)+1
sync
next xloop
endfunction
Yes, I really am THAT good...