Sorry your browser is not supported!

`
` Ode Ragdoll Demo
` Author: Christian Ang
`

`
` Setup
Sync On
Sync Rate 60
Autocam Off
Disable Escapekey

`
` Ode Start
Ode Start

` Ground
Make Object Box 1,1000,10,1000
Ode Create Static Box 1

Make Object Box 2,100,10,100
Position Object 2,0,300,0
Rotate Object 2,20,45,0
Ode Create Static Box 2

Make Object Box 3,300,10,300
Position Object 3,0,150,50
Rotate Object 3,15,0,30
Ode Create Static Box 3

Make Object Box 4,500,10,500
Position Object 4,0,300,150
Rotate Object 4,90,0,0
Ode Create Static Box 4

Make Object Box 5,200,10,200
Position Object 5,0,200,150
Rotate Object 5,0,0,-45
Ode Create Static Box 5

`
` Create Ragdoll

For i=0 to 60
    makeRagdoll(rnd(1000)-500,rnd(1000),rnd(1000)-500)
Next i

Position Camera -500,400,-500
Point Camera 0,0,0

`
` Main Loop
Repeat

	Text 0,0,"FPS: "+str$(Screen Fps())
	Text 0,20,"Use Arrowkeys to move Around Scene"
	
	Control Camera Using Arrowkeys 0,5,2

` Update Physics
	Ode Update

`Sync
	Sync
Until escapekey()=1

Ode End

End

Function makeRagdoll(offX,offY,offZ)

` Head
	head=Find Free Object()
	Make Object Sphere head,20
	Position Object head,offX,200+offY,offZ
	Ode Create Dynamic Sphere head
	Ode Set Body Mass head,0.5

` Body
	body=Find Free Object()
	Make Object Box body,25,50,25
	Position Object body,offX,160+offY,offZ
	Ode Create Dynamic Box body
	Ode Set Body Mass body,0.5

` Left Upper Arm
	lUarm=Find Free Object()
	Make Object Box lUarm,25,12,12
	Position Object lUarm,-30+offX,185+offY,offZ
	Ode Create Dynamic Box lUarm
	Ode Set Body Mass lUarm,0.5

` Left Lower Arm
	lLarm=Find Free Object()
	Make Object Box lLarm,30,8,8
	Position Object lLarm,-60+offX,185+offY,offZ
	Ode Create Dynamic Box lLarm
	Ode Set Body Mass lLarm,0.5

` Right Upper Arm
	rUarm=Find Free Object()
	Make Object Box rUarm,25,12,12
	Position Object rUarm,30+offX,185+offY,offZ
	Ode Create Dynamic Box rUarm
	Ode Set Body Mass rUarm,0.5

` Right Lower Arm
	rLarm=Find Free Object()
	Make Object Box rLarm,30,8,8
	Position Object rLarm,60+offX,185+offY,offZ
	Ode Create Dynamic Box rLarm
	Ode Set Body Mass rLarm,0.5

` Left Upper Leg
	lUleg=Find Free Object()
	Make Object Box lUleg,12,30,12
	Position Object lUleg,-10+offX,115+offY,offZ
	Ode Create Dynamic Box lUleg
	Ode Set Body Mass lUleg,0.5

` Left Lower Leg
	lLleg=Find Free Object()
	Make Object Box lLleg,8,30,8
	Position Object lLleg,-10+offX,80+offY,offZ
	Ode Create Dynamic Box lLleg
	Ode Set Body Mass lLleg,0.5

` Right Upper Leg
	rUleg=Find Free Object()
	Make Object Box rUleg,12,30,12
	Position Object rUleg,10+offX,115+offY,offZ
	Ode Create Dynamic Box rUleg
	Ode Set Body Mass rUleg,0.5

` Right Lower Leg
	rLleg=Find Free Object()
	Make Object Box rLleg,8,30,8
	Position Object rLleg,10+offX,80+offY,offZ
	Ode Create Dynamic Box rLleg
	Ode Set Body Mass rLleg,0.5
	
`
` Attach Joints
	jG=ODE Find Free Joint Group()
	Ode Create Joint Group jG

` Attach Head to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,head,body
	Ode Set Ball Anchor i,offX,195+offY,offZ

` Attach Upper Arms to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,lUarm
	Ode Set Ball Anchor i,-15+offX,185+offY,offZ
	
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,rUarm
	Ode Set Ball Anchor i,15+offX,185+offY,offZ

` Attach Lower Arms to Body
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,lUarm,lLarm
	Ode Set Hinge Anchor i,-48+offX,185+offY,offZ
	Ode set Hinge Axis i,0,1,0
	
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,rUarm,rLarm
	Ode Set Hinge Anchor i,48+offX,185+offY,offZ
	Ode set Hinge Axis i,0,1,0

` Attach Upper Legs to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,lUleg
	Ode Set Ball Anchor i,-10+offX,135+offY,offZ
	
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,rUleg
	Ode Set Ball Anchor i,10+offX,135+offY,offZ

` Attach Lower Legs to Body
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,lUleg,lLleg
	Ode Set Hinge Anchor i,-10+offX,100+offY,offZ
	Ode set Hinge Axis i,1,0,0
	
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,rUleg,rLleg
	Ode Set Hinge Anchor i,10+offX,100+offY,offZ
	Ode set Hinge Axis i,1,0,0
	
EndFunction

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

ode start

`make the floor
make object box 1,150,10,100
ode create static box 1

`make a box
make object box 2,10,10,10
position object 2,-20,100,0
rotate object 2,20,30,40

`make a cylinder
make object cylinder 3,10
set object 3,1,1,0
position object 3,20,100,0
rotate object 3,20,30,40

`camera
position camera 0,150,-120
point camera 0,60,0

do
   set cursor 0,0
   print "Hit Space to drop objects"
   print "Notice that cylinder turns first to zero angle before it starts to fall."
   if spacekey() and sp=0
      ode create dynamic box 2
      ode create dynamic cylinder 3
      sp=1
   endif
   ode update
   sync
loop

end

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

`make some texture
cls rgb(255,128,0)
set text size 22
text 0,2," I I I"
get image 1,0,0,50,16

ode start

`make the floor
make object box 1,200,10,100
texture object 1,1
rotate object 1,0,0,330
ode create static box 1

`make two cylinders
make object cylinder 2,10
set object 2,1,1,0 `cull
position object 2,-40,90,-10
rotate object 2,90,0,0
texture object 2,1

make object cylinder 3,10
set object 3,1,1,0 `cull
position object 3,-40,90,10
rotate object 3,90,0,0
texture object 3,1

`camera
position camera 0,110,-120
point camera 0,40,0

do
   set cursor 0,0
   print "Hit Space to drop the objects"
   print "Notice that cylinders slide and not roll."
   if spacekey() and sp=0
      ode create dynamic cylinder 2
      ode create dynamic cylinder 3
      sp=1
   endif
   ode update
   sync
loop

end

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

`make some texture
cls rgb(255,128,0)
set text size 22
text 0,2," I I I"
get image 1,0,0,50,16

ode start

`make the floor
make object box 1,200,10,100
texture object 1,1
rotate object 1,0,0,330
ode create static box 1

`make two cylinders
make object cylinder 2,10
set object 2,1,1,0 `cull
position object 2,-40,90,-10
rotate object 2,90,0,0
texture object 2,1

make object cylinder 3,10
set object 3,1,1,0 `cull
position object 3,-40,90,10
rotate object 3,90,0,0
texture object 3,1

`camera
position camera 0,110,-120
point camera 0,40,0

do
   set cursor 0,0
   print "Hit Space to drop the objects"
   print "Notice that cylinders slide and not roll."
   if spacekey() and sp=0
      ode create dynamic cylinder 2
      ode create dynamic cylinder 3
      
      Ode Set Body Mass 2,5.0
      ode set contact fdir1 2, 20.0
      
      `bigger friction and mass for this one
      Ode Set Body Mass 3,25.0
      ode set contact fdir1 3, 180.0
      
       
      sp=1
   endif
   ode update
   sync
loop

end

Sync On
Sync Rate 60

Ode Start

Make Object Box 1,100,10,100
Ode Create Static Box 1

Make Object Cube 2,10
Position Object 2,0,10,0
Ode Create Dynamic Box 2

Make Object Sphere 3,2
Color Object 3,rgb(120,0,0)

Position Camera -50,20,-120

Do

    Text 0,0,"RayCast Demo - Use Spacekey to move cube up - FPS: "+str$(screen fps())
    
    Text 0,20,"Raycast Hit: "+str$(Ode RayCast(2,-8,-5,0,2,10,0,50))
    Text 0,40,"RayCast Position X: "+str$(Ode Get RayCast Position X())
    Text 0,60,"RayCast Position Y: "+str$(Ode Get RayCast Position Y())
    Text 0,80,"RayCast Position Z: "+str$(Ode Get RayCast Position Z())
    Text 0,100,"RayCast Normal X: "+str$(Ode Get RayCast Normal X())
    Text 0,120,"RayCast Normal Y: "+str$(Ode Get RayCast Normal Y())
    Text 0,140,"RayCast Normal Z: "+str$(Ode Get RayCast Normal Z())
    Text 0,160,"RayCast Depth: "+str$(Ode Get RayCast Depth())
    
    Position Object 3,Ode Get RayCast Position X(),Ode Get RayCast Position Y(),Ode Get RayCast Position Z()
    Point Camera Object Position X(2),Object Position Y(2),Object Position Z(2)
    
    if spacekey()=1 then Ode Set Linear Velocity 2,0,10,0
    
    Ode Update
    Sync
Loop

sync on : sync rate 60

ode start

make object box 1, 100,50,100
make object box 2, 50,80,50
position object 2, 0,100,0
ode create static box 1
ode create dynamic box 2


position camera 0, 0,50,-100

do
    ode update
    sync
loop
end

sync on : sync rate 60
autocam off
randomize timer( )

ode start

createWorldObjects( )


position camera 0, 0,100,-150
point camera 0, 0,0,0
keypress = 0
destroytime = timer( )

do
    if scancode( ) > 0
        if keypress = 0 and timer( ) - destroytime >= 5000
            keypress = 1
            destroytime = timer( )
            destroyWorldObjects( )
            sync
            createWorldObjects( )
        endif
    else
        keypress = 0
    endif
    
    text 5,5,"ATTACK OF THE GIANT ICECUBE"
    text 5,25,"press any key to play again"

    ode update
    sync
loop
end


function createWorldObjects( )
    ode set world gravity 0,((-1)*rnd(20))-3,0

    make object box 1, 1000,10,1000
    color object 1, 0xFF004400
    ode create static box 1
    
    make object cube 2, rnd(80)+20
    ghost object on 2, 3
    rotate object 2, rnd(360),rnd(360),rnd(360)
    position object 2, 0,200,0
    ode create dynamic box 2
    ode set body mass 2, rnd(500000)+8000
    
    for k = 0 to 2
        for i = 0 to 8
            for j = 0 to 8
                obj = (k*81)+(9*i)+j+3
                make object box obj, 10,15,10
                yrotate object obj, rnd(360)
                position object obj, j*15 - 60, 12.5+(15*k), i*15 - 60
                set object diffuse obj, rgb(rnd(255),rnd(255),rnd(255))
                ode create dynamic box obj
                ode set body mass obj, rnd(200)+1
                ode set contact fdir1 obj, 50000
            next j
        next i
    next k
endfunction

function destroyWorldObjects( )
    for i = 1 to 245
        ode destroy object i
        delete object i
    next i
endfunction

sync on
sync rate 60
randomize timer()


ode start
ode set world gravity 0.0,-9.81,0.0
rem Don't know exactly what it is
ode set world step 0.07
ode set world erp (0.2)*2.5
ode set world cfm (10^-5)*2.5

rem ground
make object box 1,400,10,400
ODE CREATE STATIC BOX 1
ode set contact fdir1 1, 2

rem objects
maxi=25
for o=2 to maxi
   create_object(o,rnd(1))
next o

rem shadows
set shadow position 0,-150,400,-200
set point light 0,-150,400,-200


do


   text 0,0,"Mouse buttons to play :)"

   mx=mousex()
   my=mousey()

   rem rotate/move camera
   ax#=wrapvalue(ax#+mousemovey()*0.2)
   ay#=wrapvalue(ay#+mousemovex()*0.2)
   rotate camera ax#,ay#,0
   move camera (upkey()-downkey())*5

   rem cam coords
   cx#=camera position x()
   cy#=camera position y()
   cz#=camera position z()

   rem TURN
   if mouseclick()=1
      if mc=0
         mc=1
         rem select an object
         pick=pick object(mx,my,2,maxi)
         if pick>0
            rem random angular velocity
            ODE SET ANGULAR VELOCITY pick,rnd(2.0)-1,rnd(2.0)-1,rnd(2.0)-1
         endif
      endif
   else
      mc=0
   endif

   rem DRAG
   if mouseclick()=2
      drag=1

      if lmc=0
         rem if we haven't got any object
         lmc=1
         rem pick an object
         pick=pick object(mx,my,2,maxi)
         if pick>0
            rem distance camera/object
            dist#=sqrt( (cx#-object position x(pick))^2+(cy#-object position y(pick))^2+(cz#-object position z(pick))^2 )
         endif
      endif
      if pick>0
         rem 3d mouse (based on the distance between the cam and the object)
         pick screen mx,my,dist#
         realx#=cx#+get pick vector x()
         realy#=cy#+get pick vector y()
         realz#=cz#+get pick vector z()
         rem distance object/mouse
         movex#=(realx#-object position x(pick))
         movey#=(realy#-object position y(pick))
         movez#=(realz#-object position z(pick))
         rem set the velocity
         ODE SET LINEAR VELOCITY pick,movex#,movey#,movez#
      endif
   else
      lmc=0
      drag=0
   endif

   rem move the object
   dist#=dist#+mousemovez()/10.0

   ode update

   sync
loop

function create_object(obj,t)

   x=rnd(300)-150
   y=rnd(100)+100
   z=rnd(300)-150

   colour=rgb(rnd(255),rnd(255),rnd(255))

   select t
      case 0

         sizex=20+rnd(40)
         sizey=20+rnd(40)
         sizez=20+rnd(40)
         mass#=(sizex*sizey*sizez)^(1.0/3.0)

         make object box obj,sizex,sizey,sizez
         position object obj,x,y,z
         ode create dynamic box obj
      endcase
      case 1
         size=rnd(10)+10 : mass#=size/10.0
         make object sphere obj,size
         position object obj,x,y,z
         ode create dynamic sphere obj
      endcase
   endselect
   ODE SET BODY MASS obj,mass#/30.0
   ode set contact fdir1 obj, 1+rnd(5)

   color object obj,colour
   set shadow shading on obj,-1,400,1
endfunction

` Ode Plane2D Joint Test
` Author: Christian Ang

` Plane2D will constraint object to z == 0

Sync On
Sync Rate 60

Ode Start

Make Object Cube 1,10
Ode Create Dynamic Box 1

Ode Create Joint Group 1
Ode Create Plane2d Joint 1,1 

Ode Attach Joint 1,1,0

Make Object Box 2,100,10,100
Position Object 2,0,-50,0
Xrotate Object 2,-60
Ode Create Static Box 2

Position Camera 0,0,-200


do

    Control Camera Using Arrowkeys 0,5,2

    ode update
    sync
loop

ODE SET HINGE PARAM joint, param, value
ODE GET HINGE PARAM joint, param
ODE SET SLIDER PARAM joint, param, value
ODE GET SLIDER PARAM joint, param
ODE SET UNIVERSAL PARAM joint, param, value
ODE GET UNIVERSAL PARAM joint, param
ODE SET HINGE2 PARAM joint, param, value
ODE GET HINGE2 PARAM joint, param
ODE SET PR PARAM joint, param, value
ODE GET PR PARAM joint, param
ODE SET PU PARAM joint, param, value
ODE GET PU PARAM joint, param
ODE SET AMOTOR PARAM joint, param, value
ODE GET AMOTOR PARAM joint, param
ODE SET LMOTOR PARAM joint, param, value
ODE GET LMOTOR PARAM joint, param
ODE SET PISTON PARAM joint, param, value
ODE GET PISTON PARAM joint, param

` Ode Joint Feedback Test
` Author: Christian Ang

` Sync
Sync On
Sync Rate 60
Autocam Off

` Start Ode
Ode Start

` Create a Jointed Object [ Bridge ]
Ode Create Joint Group 1

For i=1 to 6
    Make Object Box i,10,2,50
    Position Object i,-70+i*20,-20,0
    Ode Create Dynamic Box i
    Ode Set Body Mass i,700.0
    Ode Create Hinge Joint i,1
    Ode Set Hinge Anchor i,-80+i*20,-20,0
    Ode Set Hinge Axis i,0,1,0
    Ode Attach Joint i,i,i-1
    Ode Set Joint Feedback i
Next i

Ode Create Hinge Joint 7,1
Ode Set Hinge Anchor 7,60,-20,0
Ode Set Hinge Axis 7,0,1,0
Ode Attach Joint 7,6,0
Ode Set Joint Feedback 7

` Floor
Make Object Box 100,100,20,100
Position Object 100,0,-50,0
Ode Create Static Box 100

Position Camera 0,20,-200

j=1

` Create Array to save joint stress time
Dim stress(7) as integer

` Main Loop
Do
    
    ` Show Joint Feedback
    if leftkey()=1 and r=0 and j>1 then dec j:r=1
    if rightkey()=1 and r=0 and j<7 then inc j:r=1
    if scancode()=0 then r=0
    
    Text 0,0,"Switch Joint with left/right keys - Drop boxes with Space - Break selected joint with Enter"
    Text 0,20,"--Joint Information--"
    Text 0,40,"ID: "+str$(j)
    Text 0,60,"Body 1: "+str$(Ode Get Joint Body(j,0))
    Text 0,80,"Body 2: "+str$(Ode Get Joint Body(j,1))
    Text 0,100,"A1X: "+str$(Ode Get Hinge Anchor X(j,1))
    Text 0,120,"A1Y: "+str$(Ode Get Hinge Anchor Y(j,1))
    Text 0,140,"A1Z: "+str$(Ode Get Hinge Anchor Z(j,1))
    Text 0,160,"A2X: "+str$(Ode Get Hinge Anchor X(j,2))
    Text 0,180,"A2Y: "+str$(Ode Get Hinge Anchor Y(j,2))
    Text 0,200,"A2Z: "+str$(Ode Get Hinge Anchor Z(j,2))
    Text 0,220,"AxisX:"+str$(Ode Get Hinge Axis X(j))
    Text 0,240,"AxisY:"+str$(Ode Get Hinge Axis Y(j))
    Text 0,260,"AxisZ:"+str$(Ode Get Hinge Axis Z(j))
    
    Text 250,20,"--Joint Feedback Info--"
    Text 250,40,"B1FX: "+str$(Ode Get Joint Feedback Force X(j,1))
    Text 250,60,"B1FY: "+str$(Ode Get Joint Feedback Force Y(j,1))
    Text 250,80,"B1FZ: "+str$(Ode Get Joint Feedback Force Z(j,1))
    Text 250,100,"B2FX: "+str$(Ode Get Joint Feedback Force X(j,2))
    Text 250,120,"B2FY: "+str$(Ode Get Joint Feedback Force Y(j,2))
    Text 250,140,"B2FZ: "+str$(Ode Get Joint Feedback Force Z(j,2))
    Text 250,160,"B1TX: "+str$(Ode Get Joint Feedback Torque X(j,1))
    Text 250,180,"B1TY: "+str$(Ode Get Joint Feedback Torque Y(j,1))
    Text 250,200,"B1TZ: "+str$(Ode Get Joint Feedback Torque Z(j,1))
    Text 250,220,"B2TX: "+str$(Ode Get Joint Feedback Torque X(j,2))
    Text 250,240,"B2TY: "+str$(Ode Get Joint Feedback Torque Y(j,2))
    Text 250,260,"B2TZ: "+str$(Ode Get Joint Feedback Torque Z(j,2))
    
    remstart - not totally working right yet so disabled for now
    ` If object force is too much for to long then break joint
    For k=1 to 7
        If Ode Get Joint Feedback Force Y(j,1) > 50000.0
            stress(k)=stress(k)+1
        Endif
        if stress(k)=60
            Ode Attach Joint k,0,0
        Endif
    Next k
    remend
    
    ` Allow them to snap bridge at joints
    If returnkey()=1 and r=0
        a = Ode Get Joint Body(j,0)
        b = Ode Get Joint Body(j,1)
        Ode Attach Joint j,0,0
        ` Because it is disabled after detach; reactive
        if a > 0 then Ode Set Linear Velocity a,0,0,0
        if b > 0 then Ode Set Linear Velocity b,0,0,0
        r=1
    Endif
    
    ` Create a Box to drop onto the bridge
    If spacekey()=1 and r=0
        i=FindFreeObj()
        Make Object Cube i,25
        Position Object i,0,100,0
        Ode Create Dynamic Box i
        Ode Set Body Mass i,1500.0
        r=1
    Endif

    ` Update Physics
    Ode Update

    ` Sync
    Sync
Loop

Function FindFreeObj()
    repeat
        inc i
    until Object Exist(i)=0
EndFunction i