3D Object angle calculation for balls - help!

Author

Message

TheComet

17

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 23rd Feb 2009 16:52

Link

Hello everyone!

I am trying to make a program where you drop a ball at the top of the 3d object and it rolls down. Unfortunately, I am having problems...

First of all, here is my code:

rem setup screen
set display mode 800,600,32
sync on
sync rate 60
backdrop on
color backdrop 0
hide mouse

rem load sparky
#include "sparky.dba"
load dll "DBCcollision.dll",1

rem load a level
load object "slide.x",1
SetupComplexObjectDBC(1,1,2)
UpdateObjectDBC(1)

rem load ball
make object sphere 2,10
position object 2,20-(object size x(1)/2),object size y(1),(object size z(1)/2)-20

rem main loop
dist=200
height#=100
angle#=345
do

if spacekey()=1 then position object 2,20-(object size x(1)/2),object size y(1),(object size z(1)/2)-20:grav#=0

rem control camera
   angle#=wrapvalue(angle#+mousemovex())
   inc height#,mousemovey()
   if upkey()=1 then dec dist,5
   if downkey()=1 then inc dist,5
   set camera to follow 0,0,0,angle#,dist,height#,10,0
   point camera 0,0,0

rem get ball positions
   x#=object position x(2)
   y#=object position y(2)
   z#=object position z(2)

rem gravity
   dec grav#,0.1
   inc y#,grav#

rem collision with ground
   col=IntersectObjectDBC(1,0,x#,y#,z#,x#,y#-5,z#,2)
   if col
      y#=GetStaticCollisionY()+5
      grav#=0
   endif

rem get X heights
   col=IntersectObjectDBC(1,0,x#-5,y#,z#,x#-5,y#-10,z#,2)
   if col
      y1#=GetStaticCollisionY()
   else
      y1#=-60000
   endif
   if y1#!-60000
      col=IntersectObjectDBC(1,0,x#+5,y#,z#,x#+5,y#-10,z#,2)
      if col
         y2#=GetStaticCollisionY()
      else
         y2#=-60000
         y1#=-60000
      endif
   endif

rem calculate slope X
   if y1#!-60000
      dif1#=y2#-y1#
      anglex#=atanfull(10,dif1#)
   endif

rem get Z heights
   col=IntersectObjectDBC(1,0,x#,y#,z#-5,x#,y#-10,z#-5,2)
   if col
      y1#=GetStaticCollisionY()
   else
      y1#=-60000
   endif
   if y1#!-60000
      col=IntersectObjectDBC(1,0,x#,y#,z#+5,x#,y#-10,z#+5,2)
      if col
         y2#=GetStaticCollisionY()
      else
         y2#=-60000
         y1#=-60000
      endif
   endif

rem calculate slope Z
   if y1#!-60000
      dif2#=y2#-y1#
      anglez#=atanfull(10,dif2#)
   endif

rem calculate angle ball has to be rotated
   angley#=atanfull(anglex#,anglez#)

rem calculate speed
   dspeed#=abs((dif1#/8)+(dif2#/8))
   speed#=curvevalue(dspeed#,speed#,30)

rem move ball
   x#=newxvalue(x#,angley#,dspeed#)
   z#=newzvalue(z#,angley#,dspeed#)

rem update object
   position object 2,x#,y#,z#

rem refresh screen
   sync

rem end of main loop
loop

+ Code Snippet

rem setup screen
set display mode 800,600,32
sync on
sync rate 60
backdrop on
color backdrop 0
hide mouse

rem load sparky
#include "sparky.dba"
load dll "DBCcollision.dll",1

rem load a level
load object "slide.x",1
SetupComplexObjectDBC(1,1,2)
UpdateObjectDBC(1)

rem load ball
make object sphere 2,10
position object 2,20-(object size x(1)/2),object size y(1),(object size z(1)/2)-20

rem main loop
dist=200
height#=100
angle#=345
do

   if spacekey()=1 then position object 2,20-(object size x(1)/2),object size y(1),(object size z(1)/2)-20:grav#=0

   rem control camera
   angle#=wrapvalue(angle#+mousemovex())
   inc height#,mousemovey()
   if upkey()=1 then dec dist,5
   if downkey()=1 then inc dist,5
   set camera to follow 0,0,0,angle#,dist,height#,10,0
   point camera 0,0,0

   rem get ball positions
   x#=object position x(2)
   y#=object position y(2)
   z#=object position z(2)

   rem gravity
   dec grav#,0.1
   inc y#,grav#

   rem collision with ground
   col=IntersectObjectDBC(1,0,x#,y#,z#,x#,y#-5,z#,2)
   if col
      y#=GetStaticCollisionY()+5
      grav#=0
   endif

   rem get X heights
   col=IntersectObjectDBC(1,0,x#-5,y#,z#,x#-5,y#-10,z#,2)
   if col
      y1#=GetStaticCollisionY()
   else
      y1#=-60000
   endif
   if y1#!-60000
      col=IntersectObjectDBC(1,0,x#+5,y#,z#,x#+5,y#-10,z#,2)
      if col
         y2#=GetStaticCollisionY()
      else
         y2#=-60000
         y1#=-60000
      endif
   endif

   rem calculate slope X
   if y1#!-60000
      dif1#=y2#-y1#
      anglex#=atanfull(10,dif1#)
   endif

   rem get Z heights
   col=IntersectObjectDBC(1,0,x#,y#,z#-5,x#,y#-10,z#-5,2)
   if col
      y1#=GetStaticCollisionY()
   else
      y1#=-60000
   endif
   if y1#!-60000
      col=IntersectObjectDBC(1,0,x#,y#,z#+5,x#,y#-10,z#+5,2)
      if col
         y2#=GetStaticCollisionY()
      else
         y2#=-60000
         y1#=-60000
      endif
   endif

   rem calculate slope Z
   if y1#!-60000
      dif2#=y2#-y1#
      anglez#=atanfull(10,dif2#)
   endif

   rem calculate angle ball has to be rotated
   angley#=atanfull(anglex#,anglez#)

   rem calculate speed
   dspeed#=abs((dif1#/8)+(dif2#/8))
   speed#=curvevalue(dspeed#,speed#,30)

   rem move ball
   x#=newxvalue(x#,angley#,dspeed#)
   z#=newzvalue(z#,angley#,dspeed#)

   rem update object
   position object 2,x#,y#,z#

   rem refresh screen
   sync

rem end of main loop
loop

You will need to download the attached file for the media and sparky's dll.

What my program does, is it gets the height of the ground on the left and right side of the ball, subtracts those values to get the difference, and uses ATANFULL() to calculate the tilt of the slope on the x axis. The same with the Z axis, I get the height in front and behind the ball, subtract and use ATANFULL() to calculate the tilt of the slope on the z axis.

Now, what I am having problems with, is to figure what Y angle the sphere has to point to move in the right direction. I thought of using ATANFULL(anglex#,anglez#), but am not sure if that is the correct way of doing that. If you download the file, you will see that the sphere just rolls in one direction, off the side of the level and never to be seen again.

I appreciate any help or input from anyone!

TheComet

Ah yeah, for those that download it, mouse to view, up and down key to zoom and space to re-spawn the ball.

Peachy, and the Chaos of the Gems

Attachments

Login to view attachments

Back to top

Profile PM Email Website

Latch

18

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 24th Feb 2009 23:45

Link

Well, my understanding of slope is that it's the rise/run or height divided by length or y2-y1/x2-x1 . So in your atan formulas, the height portion should be the first parameter to get the tilt:

+ Code Snippet

   rem calculate slope X
   if y1#!-60000
      dif1#=y2#-y1#
      anglex#=atanfull(10,dif1#)
   endif

could be

+ Code Snippet

rem assuming that 10 is the size of the sphere and therefore
rem the length of z2-z1 and x2-x1 are always 10...
anglex#=atanfull(dif1#,10)

Also, since a positive x rotation is a pitch down and a negetive x rotation is a pitch up, you have to make sure that dif1# is a subtraction of the rear value - the front value:
y2=height at z-5 , y1=height at z+5
dif1#=y2-y1

And for z rotation it's right-left
y2=height at x+5 , y1=height at x-5

If you intend to "roll" sphere, you should use a pivot object that never gets rotated and either use a limb or a glued object as the rolling object. If you rotate the object itself, it's angles will all change and won't be the same as the slope calculations.

Quote: "Now, what I am having problems with, is to figure what Y angle the sphere has to point to move in the right direction"

You'll have to get the heights around the sphere based on what direction it is facing. That means find x and z using newxvalue and newzvalue and the objects y angle. Find the y heights. Always rotate the sphere towards the lowest y. The rate at which you rotate the sphere will add realism and that can be determined by the slope - don't need th the angle of the slope in this case. The higher the absolute value of the slope abs(y2-y1/x2-x1 or y2-y1/z2-z1) the faster the yrotation towards that lowest value. While you are rotating the sphere, you are repositioning it in the y direction it is facing. Use a height percentage and gravity and friction to determine the speed of forward movement.

Enjoy your day.

Back to top

Profile PM

TheComet

17

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 6th Mar 2009 14:27

Link

Thank you for answering Latch! (I didn't really expect anyone else

)

I still don't quite understand the second thing to figure out how to rotate the ball in the right direction. If I rotate to the lowest point, (I assume you look at the height at the front, left, back and right), won't it just rotate either to 0°, 45°, 90°, 135°, 180°, 225°, 270°, 315°, and 345°?

I will not be "rolling" the ball, but I know about the glue object trick(got it from you in the first place). I'm not sure if you played super mario 64 on the Nintendo 64, but I want to make a slide just like in that game and with the same physics.

TheComet

Peachy, and the Chaos of the Gems

Back to top

Profile PM Email Website

Latch

18

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 6th Mar 2009 17:05

Link

Here's a quick example of what I was basically talking about. However, for coding speeds sake I knocked it together using a matrix, and I didn't use slope. You still could use slope and it would give a better representation of how fast to make the sphere slide. I just compared the different heights and move the sphere to the lowest point based on whatever direction it is facing.

Quote: "(I assume you look at the height at the front, left, back and right), won't it just rotate either to 0°, 45°, 90°, 135°, 180°, 225°, 270°, 315°, and 345"

°

Nope because I'm figuring out tthe left right front and back based on the direction the sphere is facing so it's not always N S E and W. If I rotated in 45 degree increments, then I suppose it would be as you said.

The sphere slides without changing it's facing (y angle) . I change the y angle by steering with the mouse. The Sphere won't slide as long as you are moving it with the arrow keys.

Try out the example. It should give you an idea of what I am talking about. Again, I didn't use the slope, I just used what side was the lowest.

rem move to lowest point
rem by latch
rem 03/06/2009

sync on
sync rate 60
hide mouse

make matrix 1,10000,10000,20,20
randomize matrix 1,700

rem make a sphere
make object sphere 1,50
ht#=get ground height(1,5000,5000)
position object 1,5000,ht#+26,5000

do
   gosub _move_sphere

sync
loop

_move_sphere:
   yang#=wrapvalue(object angle y(1)+mousemovex())
   yrotate object 1,yang#
   if upkey()|downkey()
      newx#=newxvalue(object position x(1),yang#,((upkey()-downkey())*10))
      newz#=newzvalue(object position z(1),yang#,((upkey()-downkey())*10))
      newy#=get ground height(1,newx#,newz#)
      position object 1,newx#,newy#+26,newz#
   else
      rem not moving the sphere so let it slide towards the lowest point
      leftx#=newxvalue(object position x(1),wrapvalue(yang#-90),5)
      leftz#=newzvalue(object position z(1),wrapvalue(yang#-90),5)
      lefty#=get ground height(1,leftx#,leftz#)

rightx#=newxvalue(object position x(1),wrapvalue(yang#+90),5)
      rightz#=newzvalue(object position z(1),wrapvalue(yang#+90),5)
      righty#=get ground height(1,rightx#,rightz#)

frontx#=newxvalue(object position x(1),wrapvalue(yang#),5)
      frontz#=newzvalue(object position z(1),wrapvalue(yang#),5)
      fronty#=get ground height(1,frontx#,frontz#)

backx#=newxvalue(object position x(1),wrapvalue(yang#-180),5)
      backz#=newzvalue(object position z(1),wrapvalue(yang#-180),5)
      backy#=get ground height(1,backx#,backz#)

rem since I don't care about rolling the sphere, I'll just
      rem have it slide towards the lowest point
      lr#=abs(lefty#)+abs(righty#)
      fb#=abs(fronty#)+abs(backy#)

rem if front and back is than left right, then sliding
      rem front or back takes dominance
      if lr# < fb#
         if lefty# < righty#
            position object 1,leftx#,lefty#+26,leftz#
         else
            position object 1,rightx#,righty#+26,rightz#
         endif
      else
         if fronty# < backy#
            position object 1,frontx#,fronty#+26,frontz#
         else
            position object 1,backx#,backy#+26,backz#
         endif
      endif
   endif

objx#=object position x(1)
   objy#=object position y(1)
   objz#=object position z(1)

set camera to follow objx#,objy#,objz#,yang#,500,200+objy#,10,1

return

+ Code Snippet

rem move to lowest point
rem by latch
rem 03/06/2009

sync on
sync rate 60
hide mouse

make matrix 1,10000,10000,20,20
randomize matrix 1,700

rem make a sphere
make object sphere 1,50
ht#=get ground height(1,5000,5000)
position object 1,5000,ht#+26,5000


do
   gosub _move_sphere

   sync
loop

_move_sphere:
   yang#=wrapvalue(object angle y(1)+mousemovex())
   yrotate object 1,yang#
   if upkey()|downkey()
      newx#=newxvalue(object position x(1),yang#,((upkey()-downkey())*10))
      newz#=newzvalue(object position z(1),yang#,((upkey()-downkey())*10))
      newy#=get ground height(1,newx#,newz#)
      position object 1,newx#,newy#+26,newz#
   else
      rem not moving the sphere so let it slide towards the lowest point
      leftx#=newxvalue(object position x(1),wrapvalue(yang#-90),5)
      leftz#=newzvalue(object position z(1),wrapvalue(yang#-90),5)
      lefty#=get ground height(1,leftx#,leftz#)

      rightx#=newxvalue(object position x(1),wrapvalue(yang#+90),5)
      rightz#=newzvalue(object position z(1),wrapvalue(yang#+90),5)
      righty#=get ground height(1,rightx#,rightz#)

      frontx#=newxvalue(object position x(1),wrapvalue(yang#),5)
      frontz#=newzvalue(object position z(1),wrapvalue(yang#),5)
      fronty#=get ground height(1,frontx#,frontz#)

      backx#=newxvalue(object position x(1),wrapvalue(yang#-180),5)
      backz#=newzvalue(object position z(1),wrapvalue(yang#-180),5)
      backy#=get ground height(1,backx#,backz#)

      rem since I don't care about rolling the sphere, I'll just
      rem have it slide towards the lowest point
      lr#=abs(lefty#)+abs(righty#)
      fb#=abs(fronty#)+abs(backy#)

      rem if front and back is than left right, then sliding
      rem front or back takes dominance
      if lr# < fb#
         if lefty# < righty#
            position object 1,leftx#,lefty#+26,leftz#
         else
            position object 1,rightx#,righty#+26,rightz#
         endif
      else
         if fronty# < backy#
            position object 1,frontx#,fronty#+26,frontz#
         else
            position object 1,backx#,backy#+26,backz#
         endif
      endif
   endif

   objx#=object position x(1)
   objy#=object position y(1)
   objz#=object position z(1)

   set camera to follow objx#,objy#,objz#,yang#,500,200+objy#,10,1

return

Enjoy your day.

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Discussion / 3D Object angle calculation for balls - help!

Attachments