Sorry your browser is not supported!

remstart
	Press the Home key to define which key to track
	Press any key other than Home, Esc, or End to begin tracking
	Press End to clear defined tracking key
remend

sync on: sync rate 120
cls

type metakey state1 state2 press$ scan ink$ endtype

remstart
	Type metakey tracks the state of a keyboard key.  
	The combination of state1 and state2 determines the press$ state.
	00 = open
    10 = pressed
    11 = held
    01 = released
	press$ is tracked here as a string for the sake of the example; it may be better as an integer for use in a program.
	scan is the scancode of the key being tracked.
	ink$ is the inkey$ string for the key being tracked.
remend

numkeys = 2 `Change to alter number of keys to track

dim keys(numkeys) as metakey `Array to hold our metakeys

for current = 1 to numkeys
	gosub _end_track `initialize array
next current

rem In game implementation, the keys array would be explicitly defined to contain keys used by the game.

do
    cls
    set cursor 0,0
    for current = 1 to numkeys
    	print current,") Tracking scancode(): ",keys(current).scan,", inkey$(): ",keys(current).ink$
    	print "   open: ",keys(current).press$ = "open"
    	print "   pressed: ",keys(current).press$ = "pressed"
    	print "   held: ",keys(current).press$ = "held"
    	print "   released: ",keys(current).press$ = "released"
    	print ""  
    	
    	if scancode() = 199 and keys(current).scan = 0 `Home
        	repeat : until scancode() <> 199 `Wait for key release       	
        	gosub _start_track      
    	endif
    	if scancode() = 207 and keys(current).scan <> 0 `End
    		repeat : until scancode() <> 207 `Wait for key release      
        	gosub _end_track      
    	endif    
    	if keys(current).scan <> 0 then gosub _track_key
    next current
sync
loop

_start_track: `Define a key for the metakey
	wait key
	keys(current).scan = scancode()
	keys(current).ink$ = inkey$()
return

_end_track: `Set the metakey states to default
	keys(current).scan = 0
	keys(current).ink$ = "None"
	keys(current).state1 = 0
	keys(current).state2 = 0
	keys(current).press$ = ""
return

_track_key:	`Define the metakey states
	if keystate(keys(current).scan)=1
        if keys(current).state1 = 1 and keys(current).state2 = 0
            keys(current).press$ = "held" : keys(current).state2 = 1   
        endif
        if keys(current).state1 = 0 and keys(current).state2 = 0
            keys(current).press$ = "pressed" : keys(current).state1 = 1               
        endif
    endif    
    if keystate(keys(current).scan) = 0
        if keys(current).state1 = 0 and keys(current).state2 = 1
            keys(current).press$ = "open" : keys(current).state2 = 0
        endif
        if keys(current).state1 = 1 and keys(current).state2 = 1
            keys(current).press$ = "released" : keys(current).state1 = 0   
        endif
    endif
return

set window on
sync on
user32=1
load dll "user32.dll",user32

a=65
do
   cls
   result=call dll(user32,"GetAsyncKeyState",a)

      if result < 0
         print "A key is pressed"
         wait 100
      else
         print "A key is released"
      endif

      if result & 1
         print "A key was previously down"
         wait 100
      else
         print "A key was previously up"
         wait 100
      endif

   sync
loop

Rem Key Click CONSTANTS
#CONSTANT KEY_Q      16
#CONSTANT KEY_W      17
#CONSTANT KEY_E      18
#CONSTANT KEY_R      19
#CONSTANT KEY_T      20
#CONSTANT KEY_Y      21
#CONSTANT KEY_U      22
#CONSTANT KEY_I      23
#CONSTANT KEY_O      24
#CONSTANT KEY_P      25
#CONSTANT KEY_A      30
#CONSTANT KEY_S      31
#CONSTANT KEY_D      32
#CONSTANT KEY_F      33
#CONSTANT KEY_G      34
#CONSTANT KEY_H      35
#CONSTANT KEY_J      36
#CONSTANT KEY_K      37
#CONSTANT KEY_L      38
#CONSTANT KEY_Z      44
#CONSTANT KEY_X      45
#CONSTANT KEY_C      46
#CONSTANT KEY_V      47
#CONSTANT KEY_B      48
#CONSTANT KEY_N      49
#CONSTANT KEY_M      50
#CONSTANT KEY_ESCAPE  1
#CONSTANT KEY_TAB    15
#CONSTANT KEY_RETURN 28
#CONSTANT KEY_SPACE  57
#CONSTANT KEY_F1     59
#CONSTANT KEY_F2     60
#CONSTANT KEY_F3     61
#CONSTANT KEY_F4     62
#CONSTANT KEY_F5     63
#CONSTANT KEY_F6     64
#CONSTANT KEY_F7     65
#CONSTANT KEY_F8     66
#CONSTANT KEY_F9     67
#CONSTANT KEY_F10    68
#CONSTANT KEY_F11    87
#CONSTANT KEY_F12    88

Rem Key Types
Type keyType
   click    As Byte
   clicked  As Byte
   switch   As Byte
EndType

GLOBAL key_lastClicked As Integer

REM ARRAYS
DIM key(255) As keyType
   REM SET SPECIAL KEYS (SWITCH NUMBERS)
   For i = 1 to 255
      key(i).switch = 1
   Next i
   key(KEY_F1).switch = 4

Sync On
Do
   GOSUB lblr_keyStateWatch
   GOSUB lblr_keyStateHandleClicked
   CLS
      Text 0, 0, "Happens only once when you click the ENTERKEY      "+Str$(var1)
      Text 0, 12, "Happens during the keystate of ENTERKEY is active      "+Str$(var2)
      Text 0, 24, "Press F1 key to see different states of F1 key       "+state$

Sync
Loop
End

lblr_keyStateWatch:
`Watch Keyboard Inputs
For i = 1 to 255
   If keyState(i) > 0 And key(i).click = 0 Then key(i).click = 1
      If key(i).click = 1
         GOSUB lblr_keyStateHandleClick
         key(i).click = 2
            key_lastClicked = i
            Inc key(i).clicked
            If key(i).clicked > key(i).switch Then key(i).clicked = 0
      EndIf
   If keyState(i) = 0 Then key(i).click = 0
Next i
RETURN

lblr_keyStateHandleClick:
   If key(KEY_RETURN).click = 1
      Inc var1, 1
   endIf
RETURN

lblr_keyStateHandleClicked:
   If key(KEY_RETURN).clicked = 1
      Inc var2, 1
   EndIf

   If key(KEY_F1).clicked = 0
      state$ = "0"
   EndIf
   If key(KEY_F1).clicked = 1
      state$ = "1"
   EndIf
   If key(KEY_F1).clicked = 2
      state$ = "2"
   EndIf
   If key(KEY_F1).clicked = 3
      state$ = "3"
   EndIf
   If key(KEY_F1).clicked = 4
      state$ = "4"
   EndIf
RETURN