Collision Problem - GameCreators Forum

Author

Message

dmurphy

14

Years of Service

User Offline

Joined: 2nd Oct 2009

Location:

Posted: 2nd Oct 2009 22:16

Link

Hey my game is a physics game and so far i've made Earth and the Sun. I'm trying to make it so that if the ship (a cube) hits the sun or the earth it goes back to the starting point. The problem is that it works with the sun but not the earth. Any suggestions?
[sync on
sync rate 60
autocam off
randomize timer()
hide mouse
backdrop off

load image "images/space.jpg",1
load image "images/explosion.jpg",2
load image "images/earth.jpg",3

MySpeed = -25
MyAcceleration = 0.0

fuel = 100

set camera range 20,1000000

make object cube 1,5
set object collision on 1
set object collision to boxes 1

make object sphere 4,-1000000
texture object 4,1

rem Planets
for t = 1 to 2
make object sphere t + 1 ,1000
set object collision on t + 1
set object collision to spheres t + 1
next t

texture object 2,2
position object 2,10000,0,0

texture object 3,3
position object 3,2500,0,0
scale object 3,25,25,25

MainSection:
do
set cursor 10,10
print "Fuel:",fuel
box 10,30,fuel*6.3,40

if upkey()=1 then pitch object down 1,1
if downkey()=1 then pitch object up 1,1
if leftkey()=1 then turn object left 1,1
if rightkey()=1 then turn object right 1,1
if spacekey()=1 then move object 1,0-MySpeed
if inkey$() = "a" then roll object left 1,1
if inkey$() = "d" then roll object right 1,1
if inkey$() = "s" then move object 1,MySpeed

position camera object position x(1),object position y(1),object position z(1)
set camera to object orientation 1
pitch camera down 20
move camera -25

if fuel < 0 then fuel = 0

if fuel > 0
if inkey$() = "l"
ghost object on 4
dec fuel
myspeed = -100
endif
endif

if fuel = 0
ghost object off 4
myspeed = -25
endif

for t = 1 to 2 : rem If I hit one of the little fruits
if Object collision(1,t + 1)>0
position object 1, 0, 30, 300
endif
next t

sync
loop
]

Candy = good!

Back to top

Profile PM Email

TheComet

16

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 3rd Oct 2009 13:34

Link

Hello!

Please use code boxes... They make it much easier to read your code:

+ Code Snippet

code here

Just highlight your code and hit the "code" button in the message edit box.

Indenting your code will help you a lot too. Your code looks something like this:

+ Code Snippet

load image "moo!.bmp",1
make object box 1,10,10,10
texture object 1,1
make object sphere 2,5
position object 2,3,3,3
for t=3 to 5
make object cylinder t,5
position object t,6,6,6
next t
do
move object 1,5
move object 2,3
for t=3 to 5
move object t,8
next t
if t=5
print "I like chocolate..."
print "mhhhh.... CHOCOLATE!!! "
else
print "blow it out your ass"
endif
sync
loop

I indent it after every if, do, for, while, repeat, open to read, open to write and else. Doesn't it look better this way?

+ Code Snippet

load image "moo!.bmp",1
make object box 1,10,10,10
texture object 1,1
make object sphere 2,5
position object 2,3,3,3
for t=3 to 5
   make object cylinder t,5
   position object t,6,6,6
next t
do
   move object 1,5
   move object 2,3
   for t=3 to 5
      move object t,8
   next t
   if t=5
      print "I like chocolate..."
      print "mhhhh.... CHOCOLATE!!! "
   else
      print "blow it out your ass"
   endif
   sync
loop

You only need to add comments and then your code will be perfect:

+ Code Snippet

rem load texture and make a player
load image "moo!.bmp",1
make object box 1,10,10,10
texture object 1,1

rem make a planet and position
make object sphere 2,5
position object 2,3,3,3

rem make 3 stars
for t=3 to 5
   make object cylinder t,5
   position object t,6,6,6
next t

rem main loop
do

   rem move player and planet
   move object 1,5
   move object 2,3

   rem move stars
   for t=3 to 5
      move object t,8
   next t

   rem print some stuff that makes no sense at all
   if t=5
      print "I like chocolate..."
      print "mhhhh.... CHOCOLATE!!! "
   else
      print "blow it out your ass"
   endif

   rem refresh screen
   sync

rem end of main loop
loop

Now, to your problem.

I can't quite see why it isn't working, since I haven't approached collision with DBC commands for a long time. However, I suggest to try the following:

+ Code Snippet

texture object 2,2
position object 2,10000,0,0

texture object 3,3
position object 3,2500,0,0
scale object 3,25,25,25

I think that code is causing it. You should set up collision after you set your objects size and position. So scaling object 3 might be disabling the collision or doing something weird to it.

I would also try checking if your ship is really heading towards the planet it should be colliding with.

Also try setting the collision off for object 4, your sky:

+ Code Snippet

set object collision off 4

I hope you find the error and I could help!

TheComet

Make the paths of your enemies easier with WaypointPro!

Back to top

Profile PM Email Website

dmurphy

14

Years of Service

User Offline

Joined: 2nd Oct 2009

Location:

Posted: 7th Oct 2009 05:19

Link

i tried but it didnt work so this is what i have now after trying

REM *****************************************
` *** TITLE - The Theoretical Universe
` *** VERSION - 1.0.0 LAST UPDATED - 10.5.2009
` *** DEVELOPER - Andrew Murphy
` *** DATE CREATED - 9.22.2009
` ***
REM *** START SYSTEM SETUP SECTION

sync on
sync rate 60
autocam off
randomize timer()
hide mouse
backdrop off

rem Load Images
load image "images/space.jpg",1
load image "images/explosion.jpg",2
load image "images/earth.jpg",3

rem Set Variables
Mytimer = 5000
MySpeed = 25
fuel = 1000
set camera range 20,1000000

rem False Main Character : Box used as object 1 for simplicity
make object cube 1,5
set object collision on 1
set object collision to boxes 1

rem Actual Main Character : Model of a spaceship (More Complex)
`load object "models/Jet Fighter 2/L-Jet Fighter 2-Move.x",1
`rotate object 1,0,180,0
`fix object pivot 1
`position object 1,0,30,300
`scale object 1,50,50,50
`set object collision on 1
`make object collision box 1,-3,-3,-3,3,3,3,0

rem Planets
   for p = 2 to 3
      make object sphere p,250
      set object collision on p
   next p

rem the Sun
   texture object 2,2
   position object 2,10000,0,0
   scale object 2,400,400,400
   set object collision to spheres 2

rem the Earth
   texture object 3,3
   position object 3,2500,0,0
   set object collision to spheres 3

rem Background
make object sphere 4,-1000000
texture object 4,1
set object collision off 4

do

rem Set Variables
   opx# = object position x(1)
   opy# = object position y(1)
   opz# = object position z(1)

rem Fuel Bar
   set cursor 10,10
   print "Fuel:",fuel/10
   box 10,30,fuel*.63,40

rem Controls
   if upkey()=1 then pitch object down 1,1
   if downkey()=1 then pitch object up 1,1
   if leftkey()=1 then turn object left 1,1
   if rightkey()=1 then turn object right 1,1
   if spacekey()=1 then move object 1,MySpeed
   if inkey$() = "a" then roll object left 1,1
   if inkey$() = "d" then roll object right 1,1
   if inkey$() = "s" then move object 1,0-MySpeed

rem Camera Settings
   position camera object position x(1),object position y(1),object position z(1)
   set camera to object orientation 1
   pitch camera down 20
   move camera -25

rem Lightspeed Settings
   if fuel < 0 then fuel = 0

if fuel > 0
      if inkey$() = "l"
         ghost object on 4
         dec fuel
         move object 1,250
      endif
   endif

if fuel = 0
      ghost object off 4
   endif

rem Collision
   if object collision(1,2) = 1
      then position object 1,opx#,opy#,opz#
   endif

if object collision(1,3) = 1
      then position object 1,opx#,opy#,opz#
   endif

sync
loop

+ Code Snippet

sync on
sync rate 60
autocam off
randomize timer()
hide mouse
backdrop off

rem Load Images
load image "images/space.jpg",1
load image "images/explosion.jpg",2
load image "images/earth.jpg",3

rem Set Variables
Mytimer = 5000
MySpeed = 25
fuel = 1000
set camera range 20,1000000

rem False Main Character : Box used as object 1 for simplicity
make object cube 1,5
set object collision on 1
set object collision to boxes 1

rem Actual Main Character : Model of a spaceship (More Complex)
`load object "models/Jet Fighter 2/L-Jet Fighter 2-Move.x",1
`rotate object 1,0,180,0
`fix object pivot 1
`position object 1,0,30,300
`scale object 1,50,50,50
`set object collision on 1
`make object collision box 1,-3,-3,-3,3,3,3,0

rem Planets
   for p = 2 to 3
      make object sphere p,250
      set object collision on p
   next p

rem the Sun
   texture object 2,2
   position object 2,10000,0,0
   scale object 2,400,400,400
   set object collision to spheres 2

rem the Earth
   texture object 3,3
   position object 3,2500,0,0
   set object collision to spheres 3

rem Background
make object sphere 4,-1000000
texture object 4,1
set object collision off 4

do

rem Set Variables
   opx# = object position x(1)
   opy# = object position y(1)
   opz# = object position z(1)

rem Fuel Bar
   set cursor 10,10
   print "Fuel:",fuel/10
   box 10,30,fuel*.63,40

rem Controls
   if upkey()=1 then pitch object down 1,1
   if downkey()=1 then pitch object up 1,1
   if leftkey()=1 then turn object left 1,1
   if rightkey()=1 then turn object right 1,1
   if spacekey()=1 then move object 1,MySpeed
   if inkey$() = "a" then roll object left 1,1
   if inkey$() = "d" then roll object right 1,1
   if inkey$() = "s" then move object 1,0-MySpeed

rem Camera Settings
   position camera object position x(1),object position y(1),object position z(1)
   set camera to object orientation 1
   pitch camera down 20
   move camera -25

rem Lightspeed Settings
   if fuel < 0 then fuel = 0

   if fuel > 0
      if inkey$() = "l"
         ghost object on 4
         dec fuel
         move object 1,250
      endif
   endif

   if fuel = 0
      ghost object off 4
   endif

rem Collision
   if object collision(1,2) = 1
      then position object 1,opx#,opy#,opz#
   endif

   if object collision(1,3) = 1
      then position object 1,opx#,opy#,opz#
   endif

sync
loop

i dunno whats wrong

also attached is the model of the ship

Candy = good!

Attachments

Login to view attachments

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 8th Oct 2009 02:31 Edited at: 8th Oct 2009 02:35

Link

Like thecomet said, scaling an object can mess up the collision.

Here's a few guide lines to follow:

* For whatever object(s) you want to have collision, always use SET OBJECT COLLISION ON <object number>

* After object collision is turned on, then set the type of collision : BOXES, SPHERES, POLYGONS.

* For any objects that you do not want to have tested for collision, SET OBJECT COLLISION OFF <object number>

* Don't use SET GLOBAL COLLISION OFF or SET GLOBAL COLLISION ON . They are buggy commands and may not behave as expected.

* If and After you scale an object, turn collision OFF, then turn collision ON, then set it's collision to boxes, spheres or polygons.

* An alternative to using SET OBJECT COLLISION TO BOXES ,POLYGONS, or SPHERES, is MAKE OBJECT COLLISION BOX. It tends to be much faster for collision testing - though it can be less accurate for objects with many limbs. Also be aware that MAKE OBEJECT COLLISION BOX collision will only be tested against other objects that have used MAKE OBJECT COLLISION BOX or areas enclosed in a static collision box.

As far as your code, you may want to be careful with gigantic camera ranges like

set camera range 20,1000000

Also be aware that the 20 means anything closer than 20 units to the camera will not be drawn and 1000000 is a very far distance for rendering.

For your collision test:

+ Code Snippet

rem Collision
   if object collision(1,2) = 1
      then position object 1,opx#,opy#,opz#
   endif

   if object collision(1,3) = 1
      then position object 1,opx#,opy#,opz#
   endif

perhaps try setting the return of object collision() to a variable:

+ Code Snippet

rem Collision
   for coltest=2 to 3
      bang=object collision(1,coltest)
      if bang
         position object 1,opx#,opy#,opz#
         exit
         rem this exits the loop as soon as there is collision
      endif
   next coltest

Or instead of testing each object 1 at a time, you can use a collision test with all objects coliding with object 1 by using object collision(1,0):

+ Code Snippet

rem Collision
   bang=object collision(1,0)
   if bang then position object 1,opx#,opy#,opz#

[EDIT]
One other thing, this:

+ Code Snippet

   if object collision(1,2) = 1
      then position object 1,opx#,opy#,opz#
   endif

is an error. THEN should not be at the biginning of the next line if you are using and if endif block. THEN only appears if the IF clause is on the same line:

+ Code Snippet

if choice=1 then do something

Your original block should read:

+ Code Snippet

   if object collision(1,2) = 1
      position object 1,opx#,opy#,opz#
   endif

Enjoy your day.

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Discussion / Collision Problem

Attachments