Sorry your browser is not supported!

Width# = 640.0 : Height# = 480.0
Set Display Mode Int( Width# ), Int( Height# ), 32
Backdrop On : Color Backdrop 0 : Sync On : Sync Rate 0 : Sync : Autocam Off
Set Camera Aspect Width# / Height#
Reload Display Pointer 

Load Image "wall_U4_05.bmp", 1
Load Image "niro.jpg", 2
Load Image "Sand.jpg", 3

Set Ambient Light 12

SetupBloom()

Obj = MakeSegment( 1, 0.0, 0.0, 0.0, 0.0, 3, 1, 2, RGB( 128, 128, 255 ) )

Position Camera 0.0, 10.0, 43.0

Do 
   X# = 0.0 + 10.0 * Sin( Timer() * 0.0125 ) 
   Z# = 0.0 + 10.0 * Cos( Timer() * 0.0125 ) 
   Position Camera X#, 10.0, Z#
   Point Camera 0.0, 10.0, 0.0
   
   Text 0, 0, Str$( Screen FPS() )
   
   UpdateBloom()
Loop




Function SetupBloom()
   Global ScreenQuadImage
   Global ScreenQuad
   Global BloomCam = 1
   Global BloomEffect = 1
   Global QuadEffect = 1
   ScreenQuadImage = GetBlankImgNo() : Make Camera BloomCam : Color Backdrop BloomCam, 0 : Load Camera Effect "post-bloom.fx", BloomEffect, 0 : Set Camera Effect BloomCam, BloomEffect, ScreenQuadImage
   ScreenQuad = GetBlankObjNo() : Make Object Plain ScreenQuad, 2, 2, 1 : Load Effect "quad.fx", QuadEffect, 0 : Set Object Effect ScreenQuad, QuadEffect
   Null = Make Vector4( 1 ) : Set Vector4 1, Int( Width# / 2.0 ), Int( Height# / 2.0 ), 0, 0 : Set Effect Constant Vector QuadEffect, "ViewSize", 1 : Null = Delete Vector4( 1 ) : Texture Object ScreenQuad, 0, ScreenQuadImage
EndFunction




Function UpdateBloom()
   If Not BloomCam Then ExitFunction
   If Not ScreenQuad Then ExitFunction
   Position Camera BloomCam, Camera Position X( 0 ), Camera Position Y( 0 ), Camera Position Z( 0 )
   Rotate Camera BloomCam, Camera Angle X( 0 ), Camera Angle Y( 0 ), Camera Angle Z( 0 )
   Hide Object ScreenQuad
   Sync Camera BloomCam
   Show Object ScreenQuad

   Sync Camera 0
   Paste Image ScreenQuadImage, 0, 0
EndFunction




Function MakeSegment( SegType, X#, Y#, Z#, YAng#, FloorTex, WallTex, CeilingTex, LightCol )
   Length# = 60.0 : TexScale# = Length# / 20.0
   
   Obj1 = GetBlankObjNo() : Make Object Plain Obj1, 20.01, Length# : Position Object Obj1, X#, Y#, Z# : XRotate Object Obj1, 90 : Fix Object Pivot Obj1 : YRotate Object Obj1, YAng# : Texture Object Obj1, FloorTex : Scale Object Texture Obj1, 1, TexScale#
   Obj = GetBlankObjNo() : Make Object Plain Obj, 19.01, Length# : Position Object Obj, X#, Y# + 20, Z# : XRotate Object Obj, 90 : Fix Object Pivot Obj : YRotate Object Obj, YAng# : Texture Object Obj, CeilingTex : Scale Object Texture Obj, 1, TexScale#
   Obj = GetBlankObjNo() : Make Object Plain Obj, Length#, 19.51 : Position Object Obj, X#, Y# + 9.75, Z# : YRotate Object Obj, 90 : Fix Object Pivot Obj : YRotate Object Obj, YAng# : Move Object Left Obj, 10.0 : Texture Object Obj, WallTex : Scale Object Texture Obj, TexScale#, 1
   Obj = GetBlankObjNo() : Make Object Plain Obj, Length#, 19.51 : Position Object Obj, X#, Y# + 9.75, Z# : YRotate Object Obj, 90 : Fix Object Pivot Obj : YRotate Object Obj, YAng# : Move Object Right Obj, 10.0 : Texture Object Obj, WallTex : Scale Object Texture Obj, TexScale#, 1
   Obj = GetBlankObjNo() : Make Object Plain Obj, Length#, 0.7 : Position Object Obj, X#, Y# + 19.755, Z# : YRotate Object Obj, 90 : XRotate Object Obj, 45 : Fix Object Pivot Obj : YRotate Object Obj, YAng# : Move Object Left Obj, 9.75 : Set Object Emissive Obj, LightCol
   Obj = GetBlankObjNo() : Make Object Plain Obj, Length#, 0.7 : Position Object Obj, X#, Y# + 19.755, Z# : YRotate Object Obj, 90 : XRotate Object Obj, 135 : Fix Object Pivot Obj : YRotate Object Obj, YAng# : Move Object Right Obj, 9.75 : Set Object Emissive Obj, LightCol
EndFunction Obj1

Rem Project: Dark Basic Pro Project
Rem Created: Wednesday, November 03, 2010

Rem ***** Main Source File *****

Global BloomShaderEffectID as integer = 22
Global QuadShaderEffectID as integer = 23

Global FullScreenShaderPlane as integer = 5000
Global FullscreenShaderImage as integer = 2
Global BackdropColor as dword
BackdropColor = rgb(40,40,40)  // the camera 0 backdrop is not usedm this variable is for setting the bloom camera backdrop to the same value as camera 0.

Global NrOfbjects as integer = 100

Sync On

Set Display Mode  1024,768,32,0
Reload Display Pointer   // Needed for fullscreen shaders to work properly

Color Backdrop BackdropColor
Set Ambient Light 10
Position Light 0, 1000,500,1000

InitFullscreenShaders()

For i = 1 to NrOfbjects
	Make Object Box i,10,10,10
	Position Object  i, rnd(200)-100,rnd(200)-120,rnd(200)-100
	Color Object  i, rgb(rnd(155)+100,rnd(155)+100,rnd(155)+100)
	Set Object Ambience  i , 20
NEXT

Do
	
	Control Camera Using Arrowkeys  0,2,2
	Text 0,0, Str$(Screen Fps())
	// Move Objects and stuff here...
	
	UpdateFullScreenShaders()
		
	Sync
	
Loop

Function InitFullscreenShaders()
	
	Local TempVector as integer = 5000

	// Make the "bloom camera" and set the backdrop color
	Make Camera 1
	Color Backdrop 1, BackdropColor
	
	// load the bloom shader as a camera effect and set the "bloom camera" to draw on "FullscreenShaderImage"
	Load Camera Effect  "post-bloom.fx",BloomShaderEffectID,0
	Set Camera Effect  1,BloomShaderEffectID,FullscreenShaderImage
	
	// FullScreenShaderPlane is the "canvas" where the camera image is drawn and later displayed.
	Make Object Plain FullScreenShaderPlane,2,2,1
	Set Object Radius FullScreenShaderPlane,-1

	// Load and apply the quad shader to the "canvas" plane. The quad shader aligns the "canvas" plane to point at the camera and stretches it across the screen.
	Load Effect "quad.fx",QuadShaderEffectID,0
	Set Object Effect FullScreenShaderPlane,QuadShaderEffectID

	// We need to set the "ViewSize" variable in the bloom shader so it knows how large our screen is.
	null = Make Vector4(TempVector)
	Set Vector4 TempVector, Screen Width(), Screen Height(),0,0
	Set Camera Effect Constant Vector BloomShaderEffectID,"ViewSize",TempVector
	null = Delete Vector4(TempVector)

	// Texture the quad (canvas) plane with the image from the bloom camera.
	Texture Object FullScreenShaderPlane,0, FullscreenShaderImage
	
	

EndFunction

Function UpdateFullScreenShaders()

	// Before "sync" the bloom camera is placed at the correct position to view the scene.
    position camera 1,camera position x(0),camera position y(0),camera position z(0)
	rotate camera 1,camera angle x(0),camera angle y(0),camera angle z(0)

	// Show all objects to the bloom camera. and hide the "canvas" plane so the bloom camera will not see it
	ShowObjectsForFullscreenShader()
	hide object FullScreenShaderPlane
	
	// Sync the bloom camera and hide all objects again, performance degrades if both cameras has to draw all objects.
	sync camera 1
    HideObjectsForFullscreenShader()
    //  show the "canvas plane".
	show object FullScreenShaderPlane

	// Tell the "Sync" command to only sync camera 0 from here on.
	sync mask %001

EndFunction

Function HideObjectsForFullscreenShader()

	// All objects in the scene has to be hidden after the scene has been drawn to the bloom camera.
	// Performance degrades if objects are drawn to both cameras.
	For i = 1 To NrOfbjects
		IF Object Exist(i)
			Hide Object  i
		Endif
	Next
	
endfunction

Function ShowObjectsForFullscreenShader()

	// Show all objects (to the bloom camera only)
	For i = 1 To NrOfbjects
		If Object Exist(i)
			Show Object i
		Endif
	Next

Endfunction