Sorry your browser is not supported!

// you need create toolbar gadget first 

load image "0.bmp", 60
addToolbarButtonFromImage toolbar, 60, 0, "DBpro image 1"

load image "1.bmp", 50
addToolbarButtonFromImage toolbar, 50, 1, "DBpro image 2"

// this file found bluegui original files
#include "gui.dba"

normalwindow = CreateWindow(100,100,150,150, "Test normal window 1", WINDOW_NORMAL, 0, 1, 0)
// removing minimize button normalwindow
removeminimizebutton normalwindow 

password = CreateEdit(5,15,110,25,0,normalwindow)
           setPasswordOnly password, 1


number = CreateEdit(5,45,110,25,0,normalwindow)
           setNumberOnly number, 1

date = CreateDatePick(5,75,110,25,normalwindow)

normalwindow2 = CreateWindow(100,400,150,150, "Test normal window 2", WINDOW_NORMAL, 0, 1, 0)
// removing minimize button normalwindow 2
removemaximizebutton normalwindow2

fixedwindow = CreateWindow(400,100,150,150, "Test fixed window", WINDOW_FIXED, 0, 1, 0)

removeclosebutton fixedwindow

toolwindow = CreateWindow(700,100,150,150, "Test tool window ", WINDOW_NORMAL, WINDOW_TOOLWINDOW, 1, 0)


// creating horizontal toolbar to toolwindows
toolbar = CreateToolbar(16,0, toolwindow)
          addStandardToolbarButtons toolbar 
          addToolbarButton toolbar,TOOLBAR_NEW, 0 
          addToolbarButton toolbar,TOOLBAR_OPEN, 0
          addToolbarButton toolbar,TOOLBAR_SAVE, 0

// creating vetical toolbar to fixedwindows . addStandardToolbarButtons works only 16pix mode
toolbar = CreateToolbar(16,1, fixedwindow)
          addStandardToolbarButtons toolbar 
          addToolbarButton toolbar,TOOLBAR_NEW, 0 
          addToolbarButton toolbar,TOOLBAR_OPEN, 0
          addToolbarButton toolbar,TOOLBAR_SAVE, 0
          
// creating horizontal toolbar to mainwindow 32x32 size . cant only use own images . you need own bitmap         
toolbar2 = CreateToolbar(32,0, 0)
          addToolbarButton toolbar2,"0.bmp", 0
          addToolbarButton toolbar2,"0.bmp", 0 
          addToolbarButton toolbar2,"0.bmp", 0 

toolbar3 = CreateToolbar(32,1, normalwindow2)
          addToolbarButton toolbar3,"0.bmp", 0
          addToolbarButton toolbar3,"0.bmp", 0 
          addToolbarButton toolbar3,"0.bmp", 0            


menu = CreateMenu(0)
       addmenuitem menu, "Menu 1", 1
            menu1 = CreateSubmenu(menu, 1)
                     addmenuitem menu1, "Menu 1 - sub 1", 10
                     addmenuitem menu1, "Menu 1 - sub 2", 11
                     
       addmenuitem menu, "Menu 2", 2
            menu2 = CreateSubmenu(menu, 2)
                     addmenuitem menu2, "Menu 2 - sub 1", 20
                     addmenuitem menu2, "Menu 2 - sub 2", 21
                             
       addmenuitem menu, "Menu 3", 3 
            menu3 = CreateSubmenu(menu, 3)
                     addmenuitem menu3, "Menu 3 - sub 1", 30
                     addmenuitem menu3, "Menu 3 - sub 2", 31     
 
   
do
    getevent
    ES = eventsource() : ET = eventType()
    ED = eventData()    
    CC = gadgetClicked()     
    
    set cursor 0,50
    print "Event source: ",ES 
    print "Event type: ", ET
    print "Event data: ", ED
    print "Gadget clicked: ",CC
    
loop

`Gadget Constants (gui.dba)
`==========================
`Robert Knight 2006
`BlueGUI v2. edition



`Information about this file
`==========================

`Constants give names to numbers.  For example, after clicking on a gadget, eventType() will return 514 (which
`can also be written as 0x202).  This number isn't very helpful if you are trying to remember it to use in an 
`IF statement, or if you are trying to understand some code you wrote previously.  Hence this file provides the constant
`MOUSE_CLICK=0x202.  In your code you can simply do:

`If eventType()=MOUSE_CLICK
`...
`Endif

`Which is far more readable, especially when you come back to look at code you have not been working on for a while

`How to include this file
`==========================
`You do not *have* to use this file, but it is strongly recommended.  In order to use this file, you can either put
`#include "gui.dba" 
`at the top of your main source file, or you can use the Browse button on the Files tab (normal editor) or the Browse button
`above the includes list on the Project tab (BlueIDE)

`This is used so you can tell if the gui.dba file was included or not
#constant GUI_CONSTANTS 1

`eventType() Constants
`===========================================================================================================================
`These are the different types of messages which eventType() can return.
`[Advanced Users:  These are the same as the WM_XXX messages used by the Windows API.  For some messages the eventData() and
`eventDataEx() information may be changed by the DLL to make it more convenient for users]

#constant _COMMAND           0x111
#constant MOUSE_CLICK       0x202
#constant LEFTBUTTON_UP     0x202
#constant RIGHTMOUSE_CLICK  0x205
#constant RIGHTBUTTON_UP    0x205
#constant MOUSE_MOVE        0x200
#constant GADGET_TIMER      0x113
`old value - #constant MENU_CLICK        0x111
#constant TOOLBAR_CLICK     0x111
#constant HOTKEY            0x312
#constant LEFTBUTTON_DOWN   513
#constant RIGHTBUTTON_DOWN  0x204
#constant KEYDOWN           0x100
#constant KEYUP             0x101
`old value - #constant COMBOBOX_CHANGE   0x111
`old value - #constant TREEVIEW_CHANGE   0x111
#constant LOSEFOCUS         0x8
#constant GADGET_SIZING     0x214
#constant GADGET_SIZE       0x5
#constant WINDOW_CLOSE      0x10
#constant LEFTBUTTON_DOUBLECLICK 0x203

#constant MENU_CLICK        0x0400+1
#constant COMBOBOX_CHANGE   0x0400+3
#constant TREEVIEW_CHANGE   0x0400+4

`setPanelBorderStyle Constants
`===========================================================================================================================
`These values are passed as the borderStyle parameter of setPanelBorderStyle to set the appearence of a panel gadget

#constant BORDER_NONE       0
#constant BORDER_FLAT       1
#constant BORDER_3D         2
#constant BORDER_SUNKEN     3

`setGadgetAlign Constants
`===========================================================================================================================
`These values set how the gadget auto-aligns to its parent

#constant ALIGN_NONE        0
#constant ALIGN_ALL         1
#constant ALIGN_TOP         2
#constant ALIGN_LEFT        3
#constant ALIGN_RIGHT       4
#constant ALIGN_BOTTOM      5

`Standard Toolbar Buttons
`===========================================================================================================================
`These are the values you pass to addButton to add standard buttons like file open / save, cut/copy/paste etc. to a toolbar
`gadget.
`In order to use these, you must call addStandardButtons immediately after you create the toolbar, eg:
`
`toolbar=createToolbar(0)
`addStandardButtons toolbar
`addButton toolbar,TOOLBAR_OPEN,0

#constant TOOLBAR_CUT          0
#constant TOOLBAR_COPY         1
#constant TOOLBAR_PASTE        2
#constant TOOLBAR_UNDO         3
#constant TOOLBAR_REDO         4
#constant TOOLBAR_DELETE       5
#constant TOOLBAR_NEW          6
#constant TOOLBAR_OPEN         7
#constant TOOLBAR_SAVE         8
#constant TOOLBAR_PRINTPREVIEW 9
#constant TOOLBAR_PROPERTIES   10
#constant TOOLBAR_HELP         11
#constant TOOLBAR_FIND         12
#constant TOOLBAR_REPLACE      13
#constant TOOLBAR_PRINT        14

`createWindow Style Options
`===========================================================================================================================
`These values are passed to createWindow to set the style and appearence of the window.  
`Generally speaking, the only values you will normally need to use are WINDOW_NORMAL or WINDOW_FIXED for the styles parameter,
`and either 0 or WINDOW_TOOLWINDOW for the extraStyles parameter.
`If you want to put multiple styles together, just add them! (see WINDOW_NORMAL comment below)

`styles
`******

`Gives the window a titlebar
#constant WINDOW_TITLEBAR      12582912 
`With the exception of toolwindows, 
`this also adds a system menu and icon to the window               
#constant WINDOW_CLOSEBUTTON   524288			
`Windows with a maximize button must also have a close button								 
#constant WINDOW_MAXBUTTON     65536
`Windows with a minimize button must also have a close button		
#constant WINDOW_MINBUTTON     131072
`Allows the user to drag the edges of the window to resize it		
#constant WINDOW_RESIZEABLE    262144			
`A window with no border
#constant WINDOW_NOBORDER      -2147483648

`extraStyles
`***********
`Like a normal window, but with a thinner frame and no system menu - usually used for floating toolboxes.
#constant WINDOW_TOOLWINDOW    128	

`standard styles (created from ones above)
`*****************************************
`A normal resizeable window with close,min & max buttons
`WINDOW_TITLEBAR+WINDOW_CLOSEBUTTON+WINDOW_MAXBUTTON+WINDOW_MINBUTTON+WINDOW_RESIZEABLE
#constant WINDOW_NORMAL        13565952

`A dialog-type window with a caption and close button but a fixed size
`WINDOW_TITLEBAR+WINDOW_CLOSEBUTTON
#constant WINDOW_FIXED         13107200

#constant WINDOW_OVR           0


`setListViewStyle Viewing Mode Options
`===========================================================================================================================
`Listview gadgets are highly flexible, and have several different ways in which they can display information.  These are the 
`different possible viewing style values

#constant LISTVIEW_ICON        0 `Big icons with captions underneath, ideal for texture/model browsers etc
#constant LISTVIEW_REPORT      1 `A table where each item can have additional information (subitems) listed as well
#constant LISTVIEW_LIST        3 `Small icons with captions to their right.

function neverCalled()
  delete memblock 0
endfunction

load image "pic1.png", 44
load image "pic2.png", 45

`Create a canvas gadget which fills the window
canvas=createCanvas(0,0,800,600,0)


`Draw our background
color=90
for x=0 to 640
    if x mod 4 = 0 then inc color : setDrawingColor canvas,rgb(color,color,color),0,0
    drawLine canvas,x,0,x,480
    
next x


drawimage canvas, 50,50, 44
drawimage canvas, 350,50, 45

paintGadget canvas

do
    
loop

// need gui.dba for MENU_CLICK and WINDOW_FIXED

#constant MAINMENU_BT1         1
#constant MAINMENU_BT2         2
#constant MAINMENU_BT3         3

#constant CHILDWINMENU_BT1         4
#constant CHILDWINMENU_BT2         5
#constant CHILDWINMENU_BT3         6

#constant CHILDWINMENU_BT4         7
#constant CHILDWINMENU_BT5         8
#constant CHILDWINMENU_BT6         9

menu = CreateMenu(0)
       addmenuitem menu, "mainmenu", MAINMENU_BT1
       
submenu = createSubMenu(menu, MAINMENU_BT1) 
       addmenuitem submenu, "Button 2", MAINMENU_BT2
       addmenuitem submenu, "Button 3", MAINMENU_BT3

win = CreateWindow(200,200, 200,200, "CHILD WIN", WINDOW_FIXED, 0, 1, 0)
CHILDmenu = CreateMenu(win)
       addmenuitem CHILDmenu, "Button 4", CHILDWINMENU_BT1
       addmenuitem CHILDmenu, "Button 5", CHILDWINMENU_BT2
       addmenuitem CHILDmenu, "CHILDmenu", CHILDWINMENU_BT3
       
subCHILDmenu = createSubMenu(CHILDmenu, CHILDWINMENU_BT3) 
       addmenuitem subCHILDmenu, "Button 7", CHILDWINMENU_BT4
       addmenuitem subCHILDmenu, "Button 8", CHILDWINMENU_BT5
       addmenuitem subCHILDmenu, "Button 9", CHILDWINMENU_BT6

do
    getevent
    ET = EventType() : ED = EventData()
    
    if ET = MENU_CLICK
        
        if ED > 0 then message "CLICK MENU", "Menu button num: "+str$(ED)+" has clicked"
            
    endif
    
loop

   
video = createVideo(300,50,600,600,"C:\WINDOWS\clock.avi",0)
        playvideo video,0,-1,3

       do
       loop

p = CreatePanel(10,10,40*10,40*10,_MW)

c = CreateToolbar(40*10,0,p)
   
   // enabling toolbar multiline 
   AllowToolbarMultiline c, 1

for i = 0 to 99
    addtoolbarbutton c, "1.bmp", 0, "Toolbar button : "+str$(i)
next i    
    

do
    getevent
    ES = EventSource() : ET = EventType() : ED = EventData()
    
    if ET = MOUSE_CLICK and ES = c then Message "Toolbar", "You clicked toolbar button : "+str$(getToolbarItem(c) )
    if escapekey() = 1 then end

loop   

Function getCharPosFromMouse(handle)
  `*************************************************************************************************************************************************************
  `Returns the character position that the mouse is over within a (rich)edit gadget
  `handle    BlueGUI handle to the edit/richedit gadget
  
  #constant EM_CHARFROMPOS   215
  
  local char as integer
  
  pointlPtr=alloc zeroed(8)                                                             `Allocate memory for POINTL structure with mouse coordinates
  poke dword pointlPtr,  mousePosX(handle)                                              `Insert gadget x,y mouse coordinates into structure
  poke dword pointlPtr+4,mousePosY(handle)  
  char=call dll(_USER32,"SendMessageA",gadgetHandle(handle),EM_CHARFROMPOS,0,pointlPtr) `Get character position of mouse cursor in gadget
  free pointlPtr                                                                        `Free POINTL struct memory
EndFunction char

Function getSysColor(index)
  `*************************************************************************************************************************************************************
  `Returns a windows system colour for various gui elements
  `index   The colour required (see constants below)
  
  #constant COLOR_SCROLLBAR           0
  #constant COLOR_BACKGROUND          1
  #constant COLOR_ACTIVECAPTION       2
  #constant COLOR_INACTIVECAPTION     3
  #constant COLOR_MENU                4
  #constant COLOR_WINDOW              5
  #constant COLOR_WINDOWFRAME         6
  #constant COLOR_MENUTEXT            7
  #constant COLOR_WINDOWTEXT          8
  #constant COLOR_CAPTIONTEXT         9
  #constant COLOR_ACTIVEBORDER        10
  #constant COLOR_INACTIVEBORDER      11
  #constant COLOR_APPWORKSPACE        12
  #constant COLOR_HIGHLIGHT           13
  #constant COLOR_HIGHLIGHTTEXT       14
  #constant COLOR_BTNFACE             15
  #constant COLOR_BTNSHADOW           16
  #constant COLOR_GRAYTEXT            17
  #constant COLOR_BTNTEXT             18
  #constant COLOR_INACTIVECAPTIONTEXT 19
  #constant COLOR_BTNHIGHLIGHT        20

  colour=call dll(_USER32,"GetSysColor",index)
  
EndFunction colour

Function getLineFromChar(handle,char)
  `*************************************************************************************************************************************************************
  `Returns the line number in an edit gadget that contains the specified character number
  `handle    BlueGUI handle to the edit/richedit gadget
  `char      Character number within the richedit that we wish to find the line number of
  
  #constant EM_EXLINEFROMCHAR   1078
  
  local lineNum as integer
  
  lineNum=call dll(_USER32,"SendMessageA",gadgetHandle(handle),EM_EXLINEFROMCHAR,0,char) 
EndFunction lineNum

Function searchListView(lvHandle,txt$)
  `*************************************************************************************************************************************************************
  `Searches the listview for matching text. (Using Windows API, can only search the main item text)    *** Unused atm
  `Returns the matching row (or -1 for not found)
  `lvHandle   Handle to the listview to search
  `txt$       Text to search for (case insensitive)
  
  #constant LVFI_PARAM              0x0001
  #constant LVFI_STRING             0x0002
  #constant LVFI_SUBSTRING          0x0004
  #constant LVFI_PARTIAL            0x0008
  #constant LVFI_WRAP               0x0020
  #constant LVFI_NEARESTXY          0x0040

  #constant LVM_FINDITEMA           0x1000+13
  #constant LVM_FINDITEM            4179
  
  `LVFINDINFO structure offsets
  #constant lv_size         24  `Size of structure
  #constant lv_flags        0   `Integer
  #constant lv_psz          4   `IntPtr
  #constant lv_lParam       8   `IntPtr
  #constant lv_pt           12  `Point
  #constant lv_vkDirection  20  `UInteger  

  txtPtr=alloc string(txt$)
  lvPtr=alloc zeroed(lv_size)
  poke dword lvPtr+lv_flags,LVFI_STRING          `Searching for string (case insensitive)
  poke dword lvPtr+lv_psz  ,txtPtr               `Text to search for (null terminated)
  result=call dll(_USER32,"SendMessageA",gadgetHandle(lvHandle),LVM_FINDITEMA,-1,lvPtr) 
  free lvPtr
  free txtPtr
        
EndFunction result

Function comboSelectString(handle,string$)
  `*************************************************************************************************************************************************************
  `Finds a matching string in a combo box list and selects it if found.
  `Returns the 0 based index of the item selected if found, or -1 (CB_ERR) if not found
  `handle    BlueGUI handle to the combobox containing the item to select
  `string$   Case-insensitive string of the text to be searched/selected
  
  #constant CB_SELECTSTRING  0x014D

  result=call dll(_USER32,"SendMessageA",gadgetHandle(handle),CB_SELECTSTRING,-1,get string ptr(string$))  
    
EndFunction result

Function getComboDroppedStatus(handle)
  `*************************************************************************************************************************************************************
  `Checks if the passed combo box handle has it's drop-down listview active at the moment
  `Returns _TRUE or _FALSE
  `handle    BlueGUI handle to the combobox we want to check

  #constant CB_GETDROPPEDSTATE   0x0157
  
  result=call dll(_USER32,"SendMessageA",gadgetHandle(handle),CB_GETDROPPEDSTATE,0,0)    `Send message to get dropped status
  
EndFunction result

Function setListviewSortArrow(lvHandle,numCol,col,sort)
  `************************************************************************************************************************************************
  `Sets listview header sort order arrow on target column. Any arrows in other columns are removed
  `lvHandle    BlueGUI handle to the target listview
  `numCol      Total number of columns in the listview (or max column that could need clearing)
  `col         Target column to set sort arrow on
  `sort        Sort arrow status for target column - _SORT_ASCEND, _SORT_DESCEND or _FALSE to turn off

  `HDITEM structure offsets
  #constant HDITEM_size        48    `Byte size of structure
  #constant HDITEM_mask        0
  #constant HDITEM_cxy         4
  #constant HDITEM_pszText     8
  #constant HDITEM_hbm         12
  #constant HDITEM_cchTextMax  16
  #constant HDITEM_fmt         20
  #constant HDITEM_lParam      24
  #constant HDITEM_iImage      28  `if _WIN32_IE >= 0x0300
  #constant HDITEM_iOrder      32  `if _WIN32_IE >= 0x0300
  #constant HDITEM_type        36  `if _WIN32_IE >= 0x0500
  #constant HDITEM_pvFilter    40  `if _WIN32_IE >= 0x0500
  #constant HDITEM_state       44  `if _WIN32_WINNT >= 0x0600

  #constant HDI_FORMAT  0x0004

  #constant HDF_SORTDOWN            0x0200
  #constant HDF_SORTUP              0x0400
  #constant HDF_BITMAP_ON_RIGHT     0x1000
  #constant HDF_FIXEDWIDTH          0x0100

  #constant HDM_GETITEMA            0x1200+3
  #constant HDM_SETITEMA            0x1200+4
  
  `www.koders.com/cpp/fid76EFA04AF4CC1C46232188A23FA8F78653E77B7F.aspx  
  `http://msdn.microsoft.com/en-us/library/windows/desktop/bb775247%28v=vs.85%29.aspx

  lvHeader=getListViewHeaderHandle(lvHandle)                                        `Get windows handle to target listview header gadget
  hdItemPtr=alloc zeroed(HDITEM_size)                                               `Reserve space for HDITEM structure
  poke dword hdItemPtr+HDITEM_mask,HDI_FORMAT                                       `Always getting/setting just the format flags
  
  `Need to go through all columns, turn off any sort arrows for all except target column
  for c=0 to numCol
    success=call dll(_USER32,"SendMessageA",lvHeader,HDM_GETITEMA,c,hdItemPtr)      `Get existing HDI_FORMAT flags for this column
    if success=_TRUE
      fmt=peek dword(hdItemPtr+HDITEM_fmt) || HDF_SORTDOWN || HDF_SORTUP            `Force sort arrow flags up & down both on initially
      if c<>col or sort<>_SORT_DESCEND then fmt=fmt ~~ HDF_SORTDOWN                 `If not target column or didn't specify sort down then XOR to remove it
      if c<>col or sort<>_SORT_ASCEND  then fmt=fmt ~~ HDF_SORTUP                   `and same for sort up flag
      poke dword hdItemPtr+HDITEM_fmt,fmt                                           `Put new format flags back into structure
      success=call dll(_USER32,"SendMessageA",lvHeader,HDM_SETITEMA,c,hdItemPtr)    `Apply them to column
    endif
  next c

  free hdItemPtr                                                                    `Clear HDITEM structure memory
  
EndFunction

Function getListViewHeaderClicked(lvHandle)
  `*************************************************************************************************************************************************************
  `Detect if clicked on headings for listview - change sort order (BlueGUI does not detect clicks in listview headings)
  `Returns the listview header clicked on (0 based), or -1 for no clicks
  `lvHandle    BlueGUI handle to the listview headers to check
  
  if mousePosY(lvHandle)>0 then if GOT_FOCUS=_TRUE                                  `Only do detailed checks if actually over target listview & got focus
    if mousePosY(lvHandle)<listViewItemY(lvHandle,getListViewTopItem(lvHandle),0)   `Check if mouse cursor is within heading area for listview
      lmb=call dll(_USER32,"GetAsyncKeyState",_VK_LBUTTON)                          `Get left mouse button status (VK_LBUTTON)
      if lmb=-32767                                                                 `Return code for LMB clicked
        headCol=listViewSubItemFromPoint(lvHandle,mousePosX(lvHandle),15)           `Get back which column header user clicked on
        ExitFunction headCol
      endif
    endif
  endif
     
EndFunction -1
 
Function getListViewRowHeight(handle)
  `*************************************************************************************************************************************************************
  `Returns the height of a single listview row in pixels
  `handle    BlueGUI handle of the target listview gadget

  #constant LVM_FIRST        0x1000
  #constant LVM_GETITEMRECT  0x1000+14
    
  local hgt as dword = 0                                                                  `Will stored the calculated height if successful
  
  ptrRect=alloc zeroed(16)                                                                `Allocate memory for a RECT structure (LVIR_BOUNDS=0 so no need to set it)
  result=call dll(_USER32,"SendMessageA",gadgetHandle(handle),LVM_GETITEMRECT,0,ptrRect)  `Send message to get item rectangle bounds
  if result<>0 then hgt=peek dword(ptrRect+12)-peek dword(ptrRect+4)                      `Calculate height from bounds
  free ptrRect                                                                            `Free RECT structure memory
EndFunction hgt

Function getListViewItemsPerPage(handle)
  `*************************************************************************************************************************************************************
  `Gets and returns the number of listview items visible per page. (In report or list mode)   In icon mode, returns total number of items
  `handle    BlueGUI handle to the listview 
  
  #constant LVM_GETCOUNTPERPAGE     0x1000+40

  result=call dll(_USER32,"SendMessageA",gadgetHandle(handle),LVM_GETCOUNTPERPAGE,0,0)    `Send message to get number of fully visible rows
  
EndFunction result

Function getListViewHeaderHandle(handle)
  `*************************************************************************************************************************************************************
  `Gets & returns the Windows Handle to a listview header gadget. 
  `BlueGUI does not expose this gadget and can't check for events on it.
  `handle    BlueGUI handle to the listview we want to retrieve the header of
  
  #constant LVM_GETHEADER  0x101f
  
  hWnd=call dll(_USER32,"SendMessageA",gadgetHandle(handle),LVM_GETHEADER,0,0)             `Send message to get handle to listview header
  
EndFunction hWnd

Function getListViewTopItem(handle)
  `*************************************************************************************************************************************************************
  `Returns the index of the topmost visible item in the listview
  `handle    Handle of the target listview gadget

  #constant LVM_GETTOPINDEX  0x1000+39
  
  result=call dll(_USER32,"SendMessageA",gadgetHandle(handle),LVM_GETTOPINDEX,0,0)        `Send message to get topmost visible item index
EndFunction result

Function modifyWindowStyle(hWnd,onStyles,offStyles)
  `************************************************************************************************************************************************************
  `Modifies the window styles using parameters passed
  `hWnd        Windows handle to window to be modified
  `onStyles    Style parameters to turn ON
  `offStyles   and ones to turn OFF
  
  `Window styles that can be turned on/off
  #constant WS_OVERLAPPED       0x00000000
  #constant WS_POPUP            0x80000000
  #constant WS_CHILD            0x40000000
  #constant WS_MINIMIZE         0x20000000
  #constant WS_VISIBLE          0x10000000
  #constant WS_DISABLED         0x08000000
  #constant WS_CLIPSIBLINGS     0x04000000
  #constant WS_CLIPCHILDREN     0x02000000
  #constant WS_MAXIMIZE         0x01000000
  #constant WS_CAPTION          0x00C00000   
  #constant WS_BORDER           0x00800000
  #constant WS_DLGFRAME         0x00400000
  #constant WS_VSCROLL          0x00200000
  #constant WS_HSCROLL          0x00100000
  #constant WS_SYSMENU          0x00080000
  #constant WS_THICKFRAME       0x00040000
  #constant WS_GROUP            0x00020000
  #constant WS_TABSTOP          0x00010000
  #constant WS_MAXIMIZEBOX      0x00010000

  `Message to change styles
  #constant GWL_STYLE           -16 
  
  local styles as dword
  
  styles=call dll(_USER32,"GetWindowLongA",hWnd,GWL_STYLE)              `Get current window styles
  if styles>0
    styles=styles || onStyles                                           `Modify current styles to turn ON all styles passed (logical OR)
    styles=styles || offStyles                                          `Make sure all OFF styles are set to ON status
    styles=styles ~~ offStyles                                          `Then XOR to force them all OFF
    result=call dll(_USER32,"SetWindowLongA",hWnd,GWL_STYLE,styles)     `Update window styles
  else
    Msg("Warn: Could not get window styles in `modifyWindowStyle()`",0)
  endif
  
EndFunction

function drawCanvasWuLine(handle,x1,y1,x2,y2,col)
  `************************************************************************************************************************************************************
  `Draw an anti-aliased line. Can be drawn over any background image and blended in
  `handle    BlueGUI handle to the canvas gadget
  `x1,y1     Line start coordinate
  `x2,y2     and end coordinate
  `col       RGB colour for the line
  
  dx#=x2-x1 : dy#=y2-y1                                                        `X & Y length of the line. (delta)
        
  if abs(dx#)>abs(dy#)                                                         `dx bigger so is a horizontal line
    if x2<x1 then tmp=x1 : x1=x2 : x2=tmp : tmp=y1 : y1=y2 : y2=tmp            `Always want to move x positive when drawing so swap if needed
    gradient#=dy#/dx#                                                          `Line gradient with respect to X
    y#=y1
    for x=x1 to x2                                                             `Loop through all x line pixel positions
      drawCanvasPixel(handle,x,y#,col,255*(1-(y#-int(y#))))                    `Draw pixel at x,y, brightness depending on fractional Y component
      drawCanvasPixel(handle,x,y#+1,col,255*(y#-int(y#)))
      y#=y#+gradient#                                                          `Increment y position by fractional gradient (compared to x gradient=1)
    next x
  else                                                                         `Handle vertical lines
    if y2<y1 then tmp=x1 : x1=x2 : x2=tmp : tmp=y1 : y1=y2 : y2=tmp
    gradient#=dx#/dy#
    x#=x1
    for y=y1 to y2
      drawCanvasPixel(handle,x#,y,col,255*(1-(x#-int(x#))))
      drawCanvasPixel(handle,x#+1,y,col,255*(x#-int(x#)))
      x#=x#+gradient#
    next y
  endif
EndFunction

Function drawCanvasPixel(handle,x,y,col,alfa)
  `************************************************************************************************************************************************************
  `Plots a single pixel with alpha transparency (Takes into account the existing pixel)
  `handle   BlueGUI handle to the canvas gadget
  `x,y      Canvas pixel coordinates to plot
  `col      Desired RGB colour of pixel
  `alfa     Alpha level (0-255)
  
  pix=getPoint(handle,x,y)                                `Get existing pixel at x,y coord
  r=(rgbr(col)*alfa+rgbr(pix)*(255-alfa))/256             `Calc new rgb values based on existing pix, new colour & alpha level
  g=(rgbg(col)*alfa+rgbg(pix)*(255-alfa))/256
  b=(rgbb(col)*alfa+rgbb(pix)*(255-alfa))/256
  drawPoint handle,x,y,rgb(r,g,b)                         `Plot new pixel colour
EndFunction

Function setButtonState(handle,state)
  `*************************************************************************************************************************************************************
  `Sets the state of a button to look as if user is holding mouse down on it (ie. Currently being clicked)
  `Unused at the moment
  `handle    BlueGUI handle to the button to change
  `state     True or False state to apply to the button
  
  #constant BM_SETSTATE          0x00f3
  call dll _USER32,"SendMessageA",gadgetHandle(handle),BM_SETSTATE,state
  
EndFunction

Function screenTextWidth(wd$,font)
  `*************************************************************************************************************************************************************
  `Calculates the pixel width of text by checking it on the main window Device Context
  `wd$       Text to be measured
  `font      BlueGUI font to use

  hDC=call dll(_USER32,"GetDC",windowHandle(GUI.main))     `Get handle to main window DC
  `Create a windows font for the DC with the same properties as our BlueGUI font. Don't use anti-aliasing for accurate measuring.
  hFont=createFontIndirect(hDC,getFontName(font),getFontSize(font),isFontBold(font),isFontItalic(font),isFontUnderLined(font),NONANTIALIASED_QUALITY)
  hOrigFont=call dll(_GDI32,"SelectObject",hDC,hFont)     `Select font into the DC and store the DCs original default font handle
  
  sizePtr=alloc zeroed(8)                                                                   `Allocate memory for a SIZE structure
  result=call dll(_GDI32,"GetTextExtentPoint32A",hDC,get string ptr(wd$),len(wd$),sizePtr)
  xSize=peek dword(sizePtr)                                                                 `Get X size
  free sizePtr                                                                              `Free SIZE structure memory
  result=call dll(_GDI32,"SelectObject",hDC,hOrigFont)                                      `Select the default font back into the DC
  result=call dll(_GDI32,"DeleteObject",hFont)                                              `Delete our custom font 
  result=call dll(_USER32,"ReleaseDC",windowHandle(GUI.main),hDC)                           `Release DC of main window back
  
EndFunction xSize

Function createFontIndirect(hDC,fontName$,size,bold,italic,underline,quality)
  `*************************************************************************************************************************************************************
  `Creates a windows font in the selected DC and returns a handle for it
  `*** Mostly duplicated from the Printer PRT_SetFont() function
  `hDC         Handle to the device context where the font is to be created in
  `fontName$   Name of the font (eg. Arial)
  `size        Point size
  `bold        Flags for font parameters
  `italic
  `underline
  `quality     Anti-aliasing setting for the font. Commonly DEFAULT_QUALITY or NONANTIALIASED_QUALITY (for screen font width checking)
  
  `Convert passed parameters into ones suitable for the LOGFONT structure
  logPixY=call dll(_GDI32,"GetDeviceCaps",hDC,GDC_LOGPIXELSY)                            `Get number of logical vert pix per inch 
  if logPixY=0 then Msg("Fatal: GetDeviceCaps failed in createFontIndirect().",0)
  height=-(size*logPixY)/72                                                              `Calculate pixel height for specified point size
  if bold=_TRUE then weight=FW_BOLD else weight=FW_NORMAL                                `Convert bold selection into correct format

  `Create the new font as specified
  lfPtr=alloc zeroed(60)                                                                 `Allocate memory for LOGFONT structure
  poke dword  lfPtr+lfHeight,        height
  poke dword  lfPtr+lfWeight,        weight
  poke byte   lfPtr+lfItalic,        italic
  poke byte   lfPtr+lfUnderline,     underline
  poke byte   lfPtr+lfCharSet,       ANSI_CHARSET
  poke byte   lfPtr+lfOutPrecision,  OUT_DEFAULT_PRECIS
  poke byte   lfPtr+lfClipPrecision, CLIP_DEFAULT_PRECIS
  poke byte   lfPtr+lfQuality,       quality 
  poke byte   lfPtr+lfPitchAndFamily,DEFAULT_PITCH+FF_DONTCARE
  poke string lfPtr+lfFaceName,      fontName$,31                                       `Copy font name into structure (Max 31 characters + NULL) 

  hFont=call dll(_GDI32,"CreateFontIndirectA",lfPtr)                                    `Create font using LOGFONT structure as defaults
  free lfPtr                                                                            `Free LOGFONT structure memory
  if hFont=0 then Msg("Fatal: Font creation failed in createFontIndirect().",0)
EndFunction hFont

Function scrollToCaret(handle)
  `*************************************************************************************************************************************************************
  `Scrolls the displayable portion of an edit/richedit to the current cursor position. Cursor position must already be set with `selSelPos`
  `handle    BlueGUI handle to the richedit gadget to scroll.
  
  `Rich/edit messages
  #constant EM_SCROLLCARET  0x00B7
  
  actGadget=activeGadget()                                                       `Save current active window
  activateGadget handle                                                          `Make this edit gadget active (EM_SCROLLCARET only works if has focus)
  call dll _USER32,"SendMessageA",gadgetHandle(handle),EM_SCROLLCARET,0,0        `Make sure caret is visible in richedit window
  activateGadget actGadget                                                       `Give original active window focus back
EndFunction

Function setCueBannerText(handle,txt$)
  `*************************************************************************************************************************************************************
  `Inserts a cue banner string into the specified edit gadget.
  `handle   BlueGUI handle to the edit gadget
  `txt$     String to be inserted as cue banner
  
  #constant EM_SETCUEBANNER 0x1501

  local stringPtr as dword
  stringPtr=alloc zeroed(2*len(txt$)+2)                                                  `Reserve enough mem for unicode string & terminating bytes
  
  for char=1 to len(txt$)
    poke word stringPtr+((char-1)*2),asc(mid$(txt$,char))                                `Copy string into unicode string buffer
  next char
  call dll _USER32,"SendMessageA",gadgetHandle(handle),EM_SETCUEBANNER,_FALSE,stringPtr  `Set cuebanner text from unicode string buffer
  free stringPtr                                                                         `Release buffer memory
EndFunction

Function clearListView(handle,reEnable)
  `*************************************************************************************************************************************************************
  `Clears the listview passed by handle of all items
  `handle      BlueGUI handle to the listview to be cleared
  `reEnable    Flags TRUE/FALSE whether to re-enable listview updates after clearing
  
  setAutoUpdate handle,_FALSE                                 `Disable updating for speed

  lvItems=getListViewItemCount(handle)-1
  if lvItems>=0
    for count=lvItems to 0 step -1
      removeListViewItem handle,count                         `Remove last item
    next count
  endif
  
  if reEnable=_TRUE 
    setAutoUpdate handle,_TRUE                                `Re-enable auto-updating
    paintGadget handle                                        `Make sure gadget painted now is cleared
  endif
  
EndFunction

Function clearComboListBox(handle)
  `*************************************************************************************************************************************************************
  `Clears the combobox or listbox passed by handle of all items
  `handle    BlueGUI handle to the combo/listbox to be cleared
  
  setAutoUpdate handle,_FALSE              `Disable updating for speed
  while itemCount(handle)>0                `Loop while still got some items 
    removeItem handle,itemCount(handle)-1  `Remove last item
  endWhile
  setAutoUpdate handle,_TRUE               `Re-enable auto-updating
  paintGadget handle                       `Make sure gadget painted now is cleared
  
EndFunction

Function getModified(handle)
  `*************************************************************************************************************************************************************************************************************************************
  `Finds out if an edit or richedit has been modified (by the user) since created, or the last EM_SETMODIFY message
  `Note: Any changes made by BlueGUI commands (such as setGadgetText) will NOT set the modified flag. *** SOME PROGRAMATIC CHANGES *DO* SET MODIFIED FLAG ***
  `handle      BlueGUI handle to the edit gadget to be checked
  
  #constant EM_GETMODIFY            184
  modified=call dll(_USER32,"SendMessageA",gadgetHandle(handle),EM_GETMODIFY,0,0)       `Get modified status of desired edit gadget
  modified=(modified<>0)                                                                `Limit to 0 or 1 (true or false) return values
EndFunction modified

Function setModified(handle,modifiedFlag)
  `*************************************************************************************************************************************************************************************************************************************
  `Sets the modified status of an edit/richedit gadget.
  `handle          BlueGUI handle to the gadget to be set
  `modifiedFlag    _TRUE or _FALSE flag to indicate modified status to set
 
  #constant EM_SETMODIFY            185
  call dll _USER32,"SendMessageA",gadgetHandle(handle),EM_SETMODIFY,modifiedFlag,0      `Set desired modified status to edit gadget
EndFunction

Function selectedText(handle)
  `****************************************************************************************************************************************************
  `Returns the text of the selected item in a combobox or listbox
  `handle   BlueGUI handle to the combobox or listbox
    
  st$=itemText(handle,selectedItem(handle))
EndFunction st$

`Paddy Example
`A Tabbed Text Editor
`Demonstrates usage of tabs gadget, toolbar, menus, open/save dialogs
`====================================================================

sync off



type TEditArea
   handle `Handle to edit gadget
   used `Boolean value set to 1 when this edit has content
   tabId `ID of tab for this edit
endtype

global main :`Handle of main window

global tabs : `Handle of document selection tabs
global dim edit(32) as TEditArea :`Handle of edit gadgets which make up the documents
global toolbar : `Handle of toolbar gadget

`Menu handles
global mainMenu
global fileMenu
global viewMenu
global helpMenu

`Status variables
global currentEdit : `Handle of active edit gadget
global numUntitledDocs : `Number of open documents with "Untitled..." style names

// main=createGadgetFromWindow(mainWindow())

`Create user interface
createUI()
`Setup vars
currentEdit=edit(0).handle
edit(0).used=1
numUntitledDocs=1


`setAutoUpdate tabs,0

applyFont edit(0).handle,x

`MAIN LOOP
do
   `Retrieve information about events
   getEvent

   `Menu Event
   if eventType()=MENU_CLICK
      select eventData()
         case 4 : eventNew()  : endcase
         case 5 : eventOpen() : endcase
         case 6 : eventSave() : endcase
         case 7 : end : endcase
         case 9 : message "About","Paddy - A Tabbed Text Editor.  Version 1" : endcase
         case 8 : toolbarToggle() : endcase
         case 10 : eventClose() : endcase
      endselect
   endif
   `Toolbar Event
   if eventType()=MOUSE_CLICK and eventSource()=toolbar
      select getToolbarItem(toolbar)
         case 0 : eventNew() : endcase
         case 1 : eventOpen() : endcase
         case 3 : eventSave() : endcase
         case 4 : eventClose() : endcase
      endselect
   endif
   `Tab Event
   if eventType()=MOUSE_CLICK and eventSource()=tabs
      switch(tabToIndex(selectedTab(tabs)))
   endif
   `Edit Event
   if eventType()=KEYDOWN
      isEdit=0
      for i=0 to 32
         if eventSource()=edit(i).handle then isEdit=1
      next i
      `Only act if the gadget is an edit
      if isEdit
         `Add a little start to indicate that the gadget has been modified
         if left$(tabCaption(tabs,selectedTab(tabs)),1)<>"*"
            changeTab tabs,selectedTab(tabs),"*"+tabCaption(tabs,selectedTab(tabs))
         endif
      endif
   endif

   `Main Window Events

   `Close App
   if eventType()=WINDOW_CLOSE then end
   `Prevent change of window size
   if eventType()=GADGET_SIZING and eventSource()=main then resizeGadget main,641,480
loop



function createUI()

win=createWindow(0,0,256,256,"hej",0,0,0,0)

tabs=createTabs(0,26,635,400,0,win)

font=createFont("Courier New",10,0,0,0)

addTab tabs,"Untitled 1"

toolbar=createToolbar(18,0,win)
addStandardToolbarButtons toolbar
addToolbarButton toolbar,TOOLBAR_NEW,0

endfunction

function eventNew()
   inc numUntitledDocs

   `Create new tab
   addTab tabs,"Untitled "+str$(numUntitledDocs)

   `Get a spare array index
   index=findEdit()
   edit(index).tabId=tabCount(tabs)-1
   edit(index).used=1

   `Switch to view
   switch(index)
endfunction

function eventOpen()
   local filename as string=""
   local basename as string=""
   local fileText as string=""

   filename=openDialog("Open a File","All Files (*.*)|*.*")

   nameLen=len(filename)
   basename=right$(filename,nameLen-instrRev(filename,"\"))

   if filename<>""
      `Create new tab
      eventNew()
      `Set its caption
      changeTab tabs,selectedTab(tabs),basename
      `Load text into edit control

      open to read 1,filename
         `Use a for...next loop because repeat...until loops are VERY, VERY slow.
         for i=0 to 10
            read string 1,tmp$

            if fileText=""
               fileText=tmp$
            else
               fileText=fileText+chr$(13)+chr$(10)+tmp$
            endif

            if file end(1) : i=10 : else : i=0 : endif
         next i

      close file 1

      setGadgetText currentEdit,fileText
   endif
endfunction

function eventSave()
   local filename as string=""
   local basename as string=""

   filename=saveDialog("Save a File","Text Files (*.txt)|*.txt|All Files (*.*)|*.*")
   nameLen=len(fileName)

   if filename<>""
      if file exist(filename) then delete file fileName

      open to write 1,filename
      write string 1,getGadgetText(currentEdit)
      close file 1

      basename=right$(filename,nameLen-instrRev(filename,"\"))
      changeTab tabs,selectedTab(tabs),basename
   endif
endfunction

function toolbarToggle()
   toolbarShown=not getMenuItemChecked(viewMenu,8)
   setMenuItemChecked viewMenu,8,toolbarShown

   if toolbarShown
      setGadgetVisible toolbar,1
      positionGadget tabs,0,26

      resizeGadget tabs,gadgetWidth(tabs),gadgetHeight(tabs)-26

      for i=0 to 32
         resizeGadget edit(i).handle,gadgetWidth(edit(i).handle),gadgetHeight(edit(i).handle)-26
      next i
   else
      setGadgetVisible toolbar,0
      positionGadget tabs,0,0
      resizeGadget tabs,gadgetWidth(tabs),gadgetHeight(tabs)+26

      for i=0 to 32
         resizeGadget edit(i).handle,gadgetWidth(edit(i).handle),gadgetHeight(edit(i).handle)+26
      next i
   endif

endfunction
function findEdit()
   for i=0 to 32
      if edit(i).used=0 then exitfunction i
   next i
endfunction c

`Hide the current document and active another document - called when the user closes a document or clicks on a tab
function switch(editIndex)

   setGadgetVisible currentEdit,0
   setGadgetVisible edit(editIndex).handle,1
   currentEdit=edit(editIndex).handle
   selectTab tabs,edit(editIndex).tabId

endfunction
`Get the TEditArea array index from a tab ID
function tabToIndex(tabId)
   for i=0 to 32
      if edit(i).tabId=tabId and edit(i).used then exitfunction i
   next i
endfunction c

function instrRev(search as string, find as string)
   strlen=len(search)
	`Search backwards through the string to find a certain character
   for i=strlen to 1 step -1
      if mid$(search,i)=find then exitfunction i
   next i
endfunction c

function eventClose()
   for i=0 to 32
      if edit(i).handle=currentEdit then index=i
   next i

   removeTab tabs,edit(index).tabId
   setGadgetText currentEdit,""

   count=tabCount(tabs)

	`Adjust the tabId field in each TEditArea so they match up correctly with the document
   for i=0 to 32
      if edit(i).tabId > edit(index).tabId
         edit(i).tabId=edit(i).tabId-1
      endif
   next i

   edit(index).used=0

   `Switch back to the first gadget
   if tabCount(tabs)=0 then eventNew()
   switch(tabToIndex(0))

endfunction

win = createWindow(200,200,600,600,"Example", 0,0,1,0)


imglist = CreateImageList(32,32)
addImageListItem imglist, "1.png"
addImageListItem imglist, "2.png"
addImageListItem imglist, "3.png"

listview = createListView(5,5,580,580, win)
    setListViewStyle listview, 1
    setListViewFullRow listview, 1
    setListViewGrid listview, 1
    setListViewSubImages listview, 1
    setListViewImageList listview, imglist,1
    
   for i = 0 to 40
         addListViewColumn listview, "Column "+str$(i), 150
   next i
   
   for i = 0 to 40
        addListViewItem listview, "Row "+str$(i), rnd(2)
        setListViewItemText listview, i, 1, "row "+str$(i) + " Column 1", rnd(2)
        setListViewItemText listview, i, 2, "row "+str$(i) + " Column 2", rnd(2)
        setListViewItemText listview, i, 3, "row "+str$(i) + " Column 3", rnd(2)
   next i
   

DO
    

LOOP