WHY does this give a different result on android than it does on pc

Author

Message

micky4fun

10

Years of Service

User Offline

Joined: 15th Sep 2013

Location: uk essex

Posted: 6th May 2014 05:24 Edited at: 6th May 2014 05:25

Link

Hi all

just wondering if someone can explain why this code give a stable result on a pc but a varied results on android using android player or converting to an apk , the ball ends up at random places on android , but same place on pc , press space to fire cannon

+ Code Snippet

rem
rem AGK Application
rem

rem Landscape App
SetDisplayAspect( 4.0/3.0 )

`use w and s to angle canon and press space to shoot the canon ball

setVirtualResolution(800,480)

`create a canon
canon_spr = createSprite(0)
setSpriteSize(canon_spr,30,10)
setSpriteOffset(canon_spr,0,5)
setSpritePositionByOffset(canon_spr,10,300)

`create a canon ball
ball_spr = createSprite(0)
setSpriteSize(ball_spr,8,8)
setSpriteOffset(ball_spr,4,4)
setSpritePhysicsOn(ball_spr,2)
setSpritePhysicsMass(ball_spr,10)

`starting variables
canon_angle# = 315.0
ball_initial_speed# = 200

`set up physics
setPhysicsGravity(0,100)

do

    setSpriteAngle(canon_spr,canon_angle#)

    `press space to fire the canon ball
    if getButtonPressed(1) = 1
        setSpritePositionByOffset(ball_spr, 10,300)

        x_velocity# = ball_initial_speed#*cos(canon_angle#)
        y_velocity# = ball_initial_speed#*sin(canon_angle#)

        setSpritePhysicsVelocity(ball_spr,x_velocity#,y_velocity#)
    endif

    Sync()
loop

thanks
mick

Back to top

Profile PM

Naphier

13

Years of Service

User Offline

Joined: 2nd Oct 2010

Location: St Petersburg, Florida

Posted: 6th May 2014 05:31

Link

It's all to do with sync rate / dropped frames.
Paul's elegant method to help this is like so:

+ Code Snippet

count = 0
	    while ( count < 4 AND timer()-time# >= physicsstep# )
	        StepPhysics( physicsstep# )
	        time# = time# + physicsstep#
	        count = count + 1
	    endwhile

Just put that in your loop and it should be all good unless there are errors elsewhere. I use this and the sprite falls in the same location every time on multiple different devices.

Napland Games - Shape Time - Wordspionage - dFenz Facebook

Back to top

Profile PM Email Website

micky4fun

10

Years of Service

User Offline

Joined: 15th Sep 2013

Location: uk essex

Posted: 6th May 2014 05:55

Link

Hi All

Thanks Naphier for your quick reply , but I have just tried the code snippet in my main loop but still gets the same results , can you show the code snippet inserted into my code so I can see how you have done it

thanks
mick:

Back to top

Profile PM

Ancient Lady

Valued Member

20

Years of Service

User Offline

Joined: 17th Mar 2004

Location: Anchorage, Alaska, USA

Posted: 6th May 2014 06:06

Link

Also, you don't use SetDisplayAspect and SetVirtualResolution together. The first command is meant for use in the Percentage display mode.

That might be causing some issues.

Cheers,
Ancient Lady

Back to top

Profile PM

Naphier

13

Years of Service

User Offline

Joined: 2nd Oct 2010

Location: St Petersburg, Florida

Posted: 6th May 2014 06:27 Edited at: 6th May 2014 06:33

Link

rem
rem AGK Application
rem

rem Landscape App
SetDisplayAspect( 4.0/3.0 )

`use w and s to angle canon and press space to shoot the canon ball

setVirtualResolution(800,480)

`create a canon
canon_spr = createSprite(0)
setSpriteSize(canon_spr,30,10)
setSpriteOffset(canon_spr,0,5)
setSpritePositionByOffset(canon_spr,10,300)

`create a canon ball
ball_spr = createSprite(0)
setSpriteSize(ball_spr,8,8)
setSpriteOffset(ball_spr,4,4)
setSpritePhysicsOn(ball_spr,2)
setSpritePhysicsMass(ball_spr,10)

`starting variables
canon_angle# = 315.0
ball_initial_speed# = 200

`set up physics
setPhysicsGravity(0,100)

//forgot this
physicsstep#=0.017
time# = timer()

do
   //insert here
   count = 0
	    while ( count < 4 AND timer()-time# >= physicsstep# )
	        StepPhysics( physicsstep# )
	        time# = time# + physicsstep#
	        count = count + 1
	    endwhile

// prevent the app dying if it is too slow - forgot this too!
	    if ( count >= 4 ) then time# = timer()

setSpriteAngle(canon_spr,canon_angle#)

`press space to fire the canon ball
    if getButtonPressed(1) = 1
        setSpritePositionByOffset(ball_spr, 10,300)

x_velocity# = ball_initial_speed#*cos(canon_angle#)
        y_velocity# = ball_initial_speed#*sin(canon_angle#)

setSpritePhysicsVelocity(ball_spr,x_velocity#,y_velocity#)
    endif

Sync()
loop

+ Code Snippet

rem
rem AGK Application
rem

rem Landscape App
SetDisplayAspect( 4.0/3.0 )

`use w and s to angle canon and press space to shoot the canon ball

setVirtualResolution(800,480)

`create a canon
canon_spr = createSprite(0)
setSpriteSize(canon_spr,30,10)
setSpriteOffset(canon_spr,0,5)
setSpritePositionByOffset(canon_spr,10,300)

`create a canon ball
ball_spr = createSprite(0)
setSpriteSize(ball_spr,8,8)
setSpriteOffset(ball_spr,4,4)
setSpritePhysicsOn(ball_spr,2)
setSpritePhysicsMass(ball_spr,10)

`starting variables
canon_angle# = 315.0
ball_initial_speed# = 200

`set up physics
setPhysicsGravity(0,100)

//forgot this
physicsstep#=0.017
time# = timer()

do
   //insert here
   count = 0
	    while ( count < 4 AND timer()-time# >= physicsstep# )
	        StepPhysics( physicsstep# )
	        time# = time# + physicsstep#
	        count = count + 1
	    endwhile

    // prevent the app dying if it is too slow - forgot this too!
	    if ( count >= 4 ) then time# = timer()

    setSpriteAngle(canon_spr,canon_angle#)

    `press space to fire the canon ball
    if getButtonPressed(1) = 1
        setSpritePositionByOffset(ball_spr, 10,300)

        x_velocity# = ball_initial_speed#*cos(canon_angle#)
        y_velocity# = ball_initial_speed#*sin(canon_angle#)

        setSpritePhysicsVelocity(ball_spr,x_velocity#,y_velocity#)
    endif

    Sync()
loop

EDIT I think I forgot something...
Forgot to add what you want the physicsstep# to be... sorry about that!
Ugh I also forgot if (count >=4 ) then time# = timer() and the initilization of timer# outside of the loop... Sorry for the mess

Napland Games - Shape Time - Wordspionage - dFenz Facebook

Back to top

Profile PM Email Website

micky4fun

10

Years of Service

User Offline

Joined: 15th Sep 2013

Location: uk essex

Posted: 6th May 2014 15:46

Link

hi all

Thanks Naphier for the speedy update , thought it was me , usually is , works a treat now also thanks for the heads up Ancient lady , will make sure only to use setvirtualresolution from now on

thanks again for both your speedy responses and time

mick

Back to top

Profile PM

Sorry your browser is not supported!

AppGameKit Classic Chat / WHY does this give a different result on android than it does on pc