you write your own input routine, eg
sync on:sync rate 0
set text opaque
` numbers to do something while we type
another=100000000
number=-2000
` outer loop
do
`inner loop
do
` change the values of the numbers
inc number
dec another
` and display them
text 50,50,str$(number)
text 80,80,str$(another)
` what key was pressed
key$=inkey$()
` if the key was "enter" then exit the inner loop
if asc(key$)=13 then exit
` if the key was backspace then remove the last character
if asc(key$)=8 and len(typed$)>0 then typed$=left$(typed$,len(typed$)-1):key$=""
` if the key was not null (zero) then add it to the string
if asc(key$)>0 then typed$=typed$+key$
` display what was input so far and add a cursor to the end and three trailing spaces
` to blank out any cursor left behind if we remove a character with backspace
text 100,100,typed$+"| "
` and wait until the user takes their finger off the key befor you continue
repeat
until asc(inkey$())=0
` allow the user to see the changes
sync
` end of the inner loop
loop
` the loop exits when enter is pressed and we see this message
text 200,200,"the final message was > "+typed$
` then we erase the string so that when the program loops we start with nothing in it
typed$=""
` and we let the user see what the full string was they typed
sync
` then wait 2 seconds and then clear the screen so that you can start over
wait 2000
cls
loop
would allow you to enter strings while the values "number" and "another" are being altered by the program, this simple example allows you to backspace over errors, if you want more in the way of editing then you need to find what codes the keys return for "unprintable" characters, cheers.
Mentor.
System spec : Pentium 3.0Ghz, 512MB DDR, 2x160Gb HD (using icewave hd coolers ), DVD RW/CD RW (all modes), multimedia front panel, 6 way surround sound, ATI radeon 9800Pro 128mb.
