State-Based Programming (SBP) - GameCreators Forum

Author

Message

zenassem

23

Years of Service

User Offline

Joined: 10th Mar 2003

Location: Long Island, NY

Posted: 25th Nov 2011 14:56 Edited at: 25th Nov 2011 23:29

Link

I am trying to create a State-Based Manager based off a C++ version. (I plan on adapting code for a Process Manager as well); but before I move onto that, I need to make sure that I am intepreting the functionality of the C++ State-Manager correctly.

The idea is to be able to process changing states on a "Per Frame" basis. With the ability to wedge-in states like, displaying a message to the user, even during another "In-Game" routine.

The source requires IanM's Matrix1Utils plug-in

Rem Project: State_Based_Processing (SBP) Manager

`Basic Screen Setup
sync on
sync rate 60

`Globals & State-Stack (sStack) setup
GLOBAL gState$              `variable to hold game state/function name 
GLOBAL fPtr as dword        `variable to hold a return pointer from a function

DIM sStack() as dword       `The StateStack

`..................... BEGIN TEST SNIPPET
Print_SStack()              `Display the empty Stack
gState$ = "State1"          `Change Game_State to State1
sPUSH( gState$ )            `PUSH state onto Stack

gState$ = "State2"          `Change Game_State to State2 
sPUSH( gState$ )            `PUSH state onto Stack

gState$ = "State3"          `Change Game_State to State3
sPUSH( gState$ )            `PUSH state onto Stack
Print_sStack()              `Display Stack

sPROC()                     `Process Latest State
Print_sStack()              `Display Stack

while array count ( sStack() ) > - 1        `Process Remaining States
    sPROC()                 
endwhile

gState$ = "Null_Function"   `Change Game_State to a nonexistent function name
sPUSH( gState$ )            `Attempt to PUSH the state onto the Stack 
Print_sStack()              `Show the Stack is EMPTY

sync
wait key
END
`....................... END TEST SNIPPET

`sStack FUNCTIONS
FUNCTION sPUSH( func$  )
//Add a function pointer to the stack
Ptr = Get Ptr to function ( func$ )
if Ptr > 0
    add to stack sStack()
    sStack() = Ptr
endif
ENDFUNCTION

FUNCTION sPOP()
//Remove a function pointer from the stack
if array count( sStack() ) > -1
    remove from stack sStack()
endif
ENDFUNCTION

FUNCTION sPOPr()
//remove a function pointer from the stack and return the pointer
Ptr as dword
Ptr = -1
    if array count( sStack() ) > -1
        Ptr = sStack()
        remove from stack sStack()
    endif
ENDFUNCTION Ptr

FUNCTION sPROC()
//Process the next pointer on the stack
if array count( sStack() ) > -1
    call function ptr ( sStack() )
endif
ENDFUNCTION

`TEST SNIPPET FUNCTIONS
FUNCTION Print_sStack()
//Display the contents of sStack
print : print "Print_sStack PTR Addr's:"
    if array count( sStack() ) > -1
        for index = 0 to array count( sStack() )
            print "   "; sStack( index )
        next index
    else
       Print "... 0 states to be processed ..."
    endif
print
ENDFUNCTION

FUNCTION State1()
//example function 1
print "Processing.... State1"
sPOP()
ENDFUNCTION

FUNCTION State2()
//example function 2
print "Processing.... State2"
sPOP()
ENDFUNCTION

FUNCTION State3()
//example function 3
print "Processing.... State3"
sPOP()
ENDFUNCTION

+ Code Snippet

Rem Project: State_Based_Processing (SBP) Manager

`Basic Screen Setup
sync on
sync rate 60


`Globals & State-Stack (sStack) setup
GLOBAL gState$              `variable to hold game state/function name 
GLOBAL fPtr as dword        `variable to hold a return pointer from a function

DIM sStack() as dword       `The StateStack 

`..................... BEGIN TEST SNIPPET
Print_SStack()              `Display the empty Stack
gState$ = "State1"          `Change Game_State to State1
sPUSH( gState$ )            `PUSH state onto Stack

gState$ = "State2"          `Change Game_State to State2 
sPUSH( gState$ )            `PUSH state onto Stack

gState$ = "State3"          `Change Game_State to State3
sPUSH( gState$ )            `PUSH state onto Stack
Print_sStack()              `Display Stack 

sPROC()                     `Process Latest State
Print_sStack()              `Display Stack

while array count ( sStack() ) > - 1        `Process Remaining States
    sPROC()                 
endwhile

gState$ = "Null_Function"   `Change Game_State to a nonexistent function name
sPUSH( gState$ )            `Attempt to PUSH the state onto the Stack 
Print_sStack()              `Show the Stack is EMPTY

sync
wait key
END
`....................... END TEST SNIPPET


`sStack FUNCTIONS
FUNCTION sPUSH( func$  )
//Add a function pointer to the stack
Ptr = Get Ptr to function ( func$ )
if Ptr > 0
    add to stack sStack()
    sStack() = Ptr
endif
ENDFUNCTION

FUNCTION sPOP()
//Remove a function pointer from the stack
if array count( sStack() ) > -1
    remove from stack sStack()
endif
ENDFUNCTION 

FUNCTION sPOPr()
//remove a function pointer from the stack and return the pointer
Ptr as dword
Ptr = -1
    if array count( sStack() ) > -1
        Ptr = sStack()
        remove from stack sStack()
    endif
ENDFUNCTION Ptr

FUNCTION sPROC()
//Process the next pointer on the stack
if array count( sStack() ) > -1
    call function ptr ( sStack() )
endif
ENDFUNCTION


`TEST SNIPPET FUNCTIONS
FUNCTION Print_sStack()
//Display the contents of sStack
print : print "Print_sStack PTR Addr's:"
    if array count( sStack() ) > -1
        for index = 0 to array count( sStack() )
            print "   "; sStack( index )
        next index
    else
       Print "... 0 states to be processed ..."
    endif
print
ENDFUNCTION

FUNCTION State1()
//example function 1
print "Processing.... State1"
sPOP()
ENDFUNCTION

FUNCTION State2()
//example function 2
print "Processing.... State2"
sPOP()
ENDFUNCTION

FUNCTION State3()
//example function 3
print "Processing.... State3"
sPOP()
ENDFUNCTION

So instead of having a long SWITCH-CASE statement and numerous flags, an SBP Stack (Last In, First Out) PUSHes functions, Calls them and POPs them as needed, per frame.

I think I have the gist of it, though my test snippet could have been more thought out and could have demonstrated the functionality in a loop.

If anyone has a better method they have worked out, or can see things I may be overlooking (before I move onto the process manager) please share your insights.

~ZENassem

Back to top

Profile PM Email

zenassem

23

Years of Service

User Offline

Joined: 10th Mar 2003

Location: Long Island, NY

Posted: 25th Nov 2011 23:25

Link

*Bump*
I'm sure someone is willing to share their secrets....

~ZENassem

Back to top

Profile PM Email

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 26th Nov 2011 01:47

Link

I can see doing something like what you've done for transient objects in-game (bullets, enemy etc), but not for general game state. If you've made the decision that you want to run the function, why not just run the function now rather than add it to a list that runs the function later. You need to take care not to over-use this functionality, as I can guarantee that it's not as efficient as simply calling the function directly.

Here's a 'for instance' that I've played with on and off for a while now: I have a short routine that adds pre-sync and post-sync handlers to run though a list of functions to call - whenever SYNC is called, they get triggered automatically.

Here's the code that adds those handlers to the list:

+ Code Snippet

   AddSyncEventName(EVENT_STAGE_PRE,   0, "UpdateTiming")
   AddSyncEventName(EVENT_STAGE_PRE,  50, "UpdateBulletsEvent")
   AddSyncEventName(EVENT_STAGE_PRE,  60, "UpdateBackdropEvent")
   
   AddSyncEventName(EVENT_STAGE_POST, 50, "ScanKeyState")
   select Controller
      case USE_MOUSE
         AddSyncEventName(EVENT_STAGE_POST, 50, "UpdateMouseVectors")
      endcase
      case USE_JOYSTICK
         AddSyncEventName(EVENT_STAGE_POST, 50, "UpdateJoystickVectors")
      endcase
   endselect
   AddSyncEventName(EVENT_STAGE_POST, 60, "UpdateShip")

Once those handlers are added, that list isn't changed. Each function gets called at the appropriate place and in the appropriate order every time SYNC is called.

Each of those handlers in turn could issue their own computed function calls - in the program I took the above code from, the UpdateBulletsEvent function does that to give each bullet its own type and behaviour, but only when it decides that it's correct to do so (in this code, that's when there has been a detectable interval of 1ms or greater since the last time it was called):

select FireMode
      case 0
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         inc BulletsFired
      endcase
      case 1
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         inc BulletsFired, 3
      endcase
      case 2
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 20.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 20.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         inc BulletsFired, 5
      endcase
   endselect

`...

function UpdateBulletsEvent()
   if TimeElapsed() <> 0.0 then UpdateBullets( TimeElapsed() )
endfunction

function UpdateBullets( TimePassed as float )
   `...
         call function ptr Bullets(i).FnPtr, i, TimePassed
   `...
endfunction

function AddBullet(x as float, y as float, Angle as float, Speed as float, Lifetime as float, Name as string, Image as integer)
   ` ...
   Bullets().FnPtr = get ptr to function("__BulletMove_" + Name)
   ` ...
endfunction

function __BulletMove_Standard(i as integer, TimePassed as float)
   local This as Bullet_t
   This = Bullets(i)
   
   inc This.X, (-sin(This.Angle) * This.Speed) * TimePassed
   inc This.Y, (cos(This.Angle) * This.Speed) * TimePassed
   
   Bullets(i) = This
endfunction

function __BulletMove_CurveLeft(i as integer, TimePassed as float)
`...
endfunction

function __BulletMove_CurveRight(i as integer, TimePassed as float)
`...
endfunction

+ Code Snippet

   select FireMode
      case 0
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         inc BulletsFired
      endcase
      case 1
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         inc BulletsFired, 3
      endcase
      case 2
         AddBullet(OffsetX, OffsetY, CurrentAngle,        BulletConfig.Speed, BulletConfig.Life, "Standard", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 15.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle - 20.0, BulletConfig.Speed, BulletConfig.Life, "CurveLeft", IMG_BULLET )
         AddBullet(OffsetX, OffsetY, CurrentAngle + 20.0, BulletConfig.Speed, BulletConfig.Life, "CurveRight", IMG_BULLET )
         inc BulletsFired, 5
      endcase
   endselect

`...

function UpdateBulletsEvent()
   if TimeElapsed() <> 0.0 then UpdateBullets( TimeElapsed() )
endfunction

function UpdateBullets( TimePassed as float )
   `...
         call function ptr Bullets(i).FnPtr, i, TimePassed
   `...
endfunction

function AddBullet(x as float, y as float, Angle as float, Speed as float, Lifetime as float, Name as string, Image as integer)
   ` ...
   Bullets().FnPtr = get ptr to function("__BulletMove_" + Name)
   ` ...
endfunction

function __BulletMove_Standard(i as integer, TimePassed as float)
   local This as Bullet_t
   This = Bullets(i)
   
   inc This.X, (-sin(This.Angle) * This.Speed) * TimePassed
   inc This.Y, (cos(This.Angle) * This.Speed) * TimePassed
   
   Bullets(i) = This
endfunction

function __BulletMove_CurveLeft(i as integer, TimePassed as float)
`...
endfunction

function __BulletMove_CurveRight(i as integer, TimePassed as float)
`...
endfunction

However, I haven't shifted everything into the events list - adding bullets is triggered in my main loop.

The choices I would make are:
1. If it doesn't need to be called via CALL FUNCTION, then don't even if you can.
2. If it does need to be called in this way, try to make a static list that will be reused.
3. Only make dynamic calls if there is no other choice.

The further down that list you go, the less efficient your processing will be.

Here's the code for what I've called 'Sync events':

remstart

EventHandler library

Add pre and post sync event handlers.
   Do not add new handlers during sync events as this will result in undefined behaviour

Public functions
      void InitialiseEventHandlers(Lookup as integer)
         Start up the sync event system
         The lookup table is not used - this is for consistancy.

void ShutdownEventHandlers()
         Tear down the sync event system

int  FindSyncEventName(Stage as integer, EventHandlerName as string)
         Search for a sync event function by name.
         Returns -1 if not found, or it's internal index if found.

void AddSyncEventName(Stage as integer, Priority as integer, EventHandlerName as string)
         Add a new sync event, or change the priority of an existing one

void RemoveSyncEventName(Stage as integer, EventHandlerName as string)
         Remove a sync event

void ClearEventHandlers()
         Removes all sync events

Private functions
      void __PreSyncEventHandler()
      void __PostSyncEventHandler()

remend

#constant EVENT_STAGE_PRE           0
#constant EVENT_STAGE_POST          1

type EventHandler_t
   Stage             as integer
   Priority          as integer
   Sequence          as integer
   EventHandler      as dword
   EventHandlerName  as string
endtype

type SyncEventHandlerDetail_t
   Initialised as integer
   IsDirty as integer
   Sequence as integer
endtype

dim SyncEventHandlers() as EventHandler_t
global SyncEventHandlerDetail as SyncEventHandlerDetail_t

function InitialiseEventHandlers()
   if SyncEventHandlerDetail.Initialised = 0
      SyncEventHandlerDetail.Initialised = 1

` Ensure that the list is completely empty
      undim SyncEventHandlers()
      dim SyncEventHandlers() as EventHandler_t

` Add the sync callbacks
      set presync callback  "__PreSyncEventHandler"
      set postsync callback "__PostSyncEventHandler"

SyncEventHandlerDetail.IsDirty = 0
      SyncEventHandlerSequence = 0
   endif
endfunction

function ShutdownEventHandlers()
   SyncEventHandlerDetail.Initialised = 0

` Disable the sync callbacks
   set presync callback  0
   set postsync callback 0

` Clear the list
   undim SyncEventHandlers()
endfunction

function FindSyncEventName(Stage as integer, EventHandlerName as string)
   for i = 0 to array count( SyncEventHandlers() )
      if SyncEventHandlers(i).Stage = Stage and SyncEventHandlers(i).EventHandlerName = EventHandlerName
         exitfunction i
      endif
   next
endfunction -1

function AddSyncEventName(Stage as integer, Priority as integer, EventHandlerName as string)
   local p as integer

i = FindSyncEventName(Stage, EventHandlerName)
   if i <> -1
      set array index SyncEventHandlers(), i
   else
      p = get ptr to function(EventHandlerName)
      if p = 0 then exitfunction 0

array insert at bottom  SyncEventHandlers()
      SyncEventHandlers().Stage = Stage
      SyncEventHandlers().Sequence = SyncEventHandlerDetail.Sequence
      SyncEventHandlers().EventHandler = get ptr to function(EventHandlerName)
      SyncEventHandlers().EventHandlerName = lower$(EventHandlerName)
      inc SyncEventHandlerSequence
   endif
   
   SyncEventHandlers().Priority = Priority

SyncEventHandlerDetail.IsDirty = 1
endfunction 1

function RemoveSyncEventName(Stage as integer, EventHandlerName as string)
   i = FindSyncEventName(Stage, EventHandlerName)
   if i <> -1 then array delete element SyncEventHandlers(), i
endfunction

function ClearEventHandlers()
   ` Clear the list
   empty array SyncEventHandlers()
endfunction

function __PreSyncEventHandler()
   ` If something has modified the list, sort it
   if SyncEventHandlerDetail.IsDirty
      SyncEventHandlerDetail.IsDirty = 0
      sort array SyncEventHandlers(), 1, 2, 3
   endif

` Start at the top of the list
   array index to top SyncEventHandlers()

` Move through the list, calling each handler, until we either reach the end of the list, or the 'pre' events have been handled
   while array index valid( SyncEventHandlers() )
      if SyncEventHandlers().Stage <> EVENT_STAGE_PRE then exit

call function ptr  SyncEventHandlers().EventHandler
      next array index   SyncEventHandlers()
   endwhile
   ` At this point, the current array item will either be:
   ` Invalid - everything in the array processed
   ` Pointing at the first EVENT_STATE_POST item
endfunction

function __PostSyncEventHandler()
   ` List already initialised from the 'pre' events, so just carry on from the point it left off

` Move through the list, calling each handler, until we either reach the end of the list, or the 'post' events have been handled
   while array index valid( SyncEventHandlers() )
      if SyncEventHandlers().Stage <> EVENT_STAGE_POST then exit

call function ptr  SyncEventHandlers().EventHandler
      next array index   SyncEventHandlers()
   endwhile
endfunction

+ Code Snippet

remstart

   EventHandler library

   Add pre and post sync event handlers.
   Do not add new handlers during sync events as this will result in undefined behaviour

   Public functions
      void InitialiseEventHandlers(Lookup as integer)
         Start up the sync event system
         The lookup table is not used - this is for consistancy.

      void ShutdownEventHandlers()
         Tear down the sync event system

      int  FindSyncEventName(Stage as integer, EventHandlerName as string)
         Search for a sync event function by name.
         Returns -1 if not found, or it's internal index if found.

      void AddSyncEventName(Stage as integer, Priority as integer, EventHandlerName as string)
         Add a new sync event, or change the priority of an existing one

      void RemoveSyncEventName(Stage as integer, EventHandlerName as string)
         Remove a sync event

      void ClearEventHandlers()
         Removes all sync events

   Private functions
      void __PreSyncEventHandler()
      void __PostSyncEventHandler()

remend

#constant EVENT_STAGE_PRE           0
#constant EVENT_STAGE_POST          1




type EventHandler_t
   Stage             as integer
   Priority          as integer
   Sequence          as integer
   EventHandler      as dword
   EventHandlerName  as string
endtype




type SyncEventHandlerDetail_t
   Initialised as integer
   IsDirty as integer
   Sequence as integer
endtype




dim SyncEventHandlers() as EventHandler_t
global SyncEventHandlerDetail as SyncEventHandlerDetail_t




function InitialiseEventHandlers()
   if SyncEventHandlerDetail.Initialised = 0
      SyncEventHandlerDetail.Initialised = 1

      ` Ensure that the list is completely empty
      undim SyncEventHandlers()
      dim SyncEventHandlers() as EventHandler_t

      ` Add the sync callbacks
      set presync callback  "__PreSyncEventHandler"
      set postsync callback "__PostSyncEventHandler"

      SyncEventHandlerDetail.IsDirty = 0
      SyncEventHandlerSequence = 0
   endif
endfunction




function ShutdownEventHandlers()
   SyncEventHandlerDetail.Initialised = 0

   ` Disable the sync callbacks
   set presync callback  0
   set postsync callback 0

   ` Clear the list
   undim SyncEventHandlers()
endfunction




function FindSyncEventName(Stage as integer, EventHandlerName as string)
   for i = 0 to array count( SyncEventHandlers() )
      if SyncEventHandlers(i).Stage = Stage and SyncEventHandlers(i).EventHandlerName = EventHandlerName
         exitfunction i
      endif
   next
endfunction -1




function AddSyncEventName(Stage as integer, Priority as integer, EventHandlerName as string)
   local p as integer

   i = FindSyncEventName(Stage, EventHandlerName)
   if i <> -1
      set array index SyncEventHandlers(), i
   else
      p = get ptr to function(EventHandlerName)
      if p = 0 then exitfunction 0

      array insert at bottom  SyncEventHandlers()
      SyncEventHandlers().Stage = Stage
      SyncEventHandlers().Sequence = SyncEventHandlerDetail.Sequence
      SyncEventHandlers().EventHandler = get ptr to function(EventHandlerName)
      SyncEventHandlers().EventHandlerName = lower$(EventHandlerName)
      inc SyncEventHandlerSequence
   endif
   
   SyncEventHandlers().Priority = Priority

   SyncEventHandlerDetail.IsDirty = 1
endfunction 1




function RemoveSyncEventName(Stage as integer, EventHandlerName as string)
   i = FindSyncEventName(Stage, EventHandlerName)
   if i <> -1 then array delete element SyncEventHandlers(), i
endfunction




function ClearEventHandlers()
   ` Clear the list
   empty array SyncEventHandlers()
endfunction




function __PreSyncEventHandler()
   ` If something has modified the list, sort it
   if SyncEventHandlerDetail.IsDirty
      SyncEventHandlerDetail.IsDirty = 0
      sort array SyncEventHandlers(), 1, 2, 3
   endif

   ` Start at the top of the list
   array index to top SyncEventHandlers()

   ` Move through the list, calling each handler, until we either reach the end of the list, or the 'pre' events have been handled
   while array index valid( SyncEventHandlers() )
      if SyncEventHandlers().Stage <> EVENT_STAGE_PRE then exit

      call function ptr  SyncEventHandlers().EventHandler
      next array index   SyncEventHandlers()
   endwhile
   ` At this point, the current array item will either be:
   ` Invalid - everything in the array processed
   ` Pointing at the first EVENT_STATE_POST item
endfunction




function __PostSyncEventHandler()
   ` List already initialised from the 'pre' events, so just carry on from the point it left off

   ` Move through the list, calling each handler, until we either reach the end of the list, or the 'post' events have been handled
   while array index valid( SyncEventHandlers() )
      if SyncEventHandlers().Stage <> EVENT_STAGE_POST then exit

      call function ptr  SyncEventHandlers().EventHandler
      next array index   SyncEventHandlers()
   endwhile
endfunction

Get the latest Matrix1Utility plug-ins (11-SEPT-2011)

Back to top

Profile PM Email Website

zenassem

23

Years of Service

User Offline

Joined: 10th Mar 2003

Location: Long Island, NY

Posted: 26th Nov 2011 01:57

Link

Understand your points. I'll have to spend a little time going over your code,, but I think you have a better gist of what I was going for without having the material in front of you. From what I have looked at already, you essentially provided the framework of the process-handler that I was going to attempt, except it seems more directed and purposeful.

I had fun in my attempt, but I can see I already went a bit in the wrong direction... I was afraid I was doing that. This will be a big help. Thanks.

~ZENassem

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / State-Based Programming (SBP)