Sorry your browser is not supported!

type touchType
    startX as float
    startY as float
    currX as float
    currY as float
endtype
global touch as touchType[10]

function PinchZoom()
    ptc=touchcount
    touchCount = 0
    i = getRawFirstTouchEvent(0)
    while i>0
        touchCount = touchCount+1
        touch[touchCount].startX = getRawTouchStartX(i)
        touch[touchCount].startY = getRawTouchStartY(i)
        touch[touchCount].currX = getRawTouchCurrentX(i)
        touch[touchCount].currY = getRawTouchCurrentY(i)
        i = getRawNextTouchEvent()
    endwhile
    
    currZoom# = getViewZoom()
    if touchCount = 2
        cx# = getViewOffsetX()
        cy# = getViewOffsetY()
        if ptc<>touchCount
            startZoom#=currZoom#
            startX#=cx#
            startY#=cy#
            touch[1].startX=touch[1].currX
            touch[1].startY=touch[1].currY
            touch[2].startX=touch[2].currX
            touch[2].startY=touch[2].currY
        endif
        
        sx1# = touch[1].startX
        sy1# = touch[1].startY
        sx2# = touch[2].startX
        sy2# = touch[2].startY
        dx# = sx1#-sx2#
        dy# = sy1#-sy2#
        d1# = sqrt(dx#*dx#+dy#*dy#)
        cx1# = touch[1].currX
        cy1# = touch[1].currY
        cx2# = touch[2].currX
        cy2# = touch[2].currY
        dx# = cx1#-cx2#
        dy# = cy1#-cy2#
        d2# = sqrt(dx#*dx#+dy#*dy#)
        zoom# = startZoom#+(d2#-d1#)*currZoom#*0.01
        if zoom#<0.1 then zoom#=0.1
        if zoom#>4.0 then zoom#=4.0
        setViewZoom(zoom#)
        
        msx# = (sx2#+sx1#)*0.5
        msy# = (sy2#+sy1#)*0.5
        mcx# = (cx2#+cx1#)*0.5
        mcy# = (cy2#+cy1#)*0.5
        dx#=(msx#-mcx#)/currZoom#
        dy#=(msy#-mcy#)/currZoom#
        setViewOffset(startX#+dx#,startY#+dy#)
    endif
endfunction

SetErrorMode(2)
SetOrientationAllowed(1, 1, 0, 0)
SetSyncRate(60, 0)
SetScissor(0, 0, 0, 0)
UseNewDefaultFonts(1)

contentStartY# = 0
contentHeight# = 0

// CREATE LIST
noOfRows = 200
for i = 0 to noOfRows
	sprite = CreateSprite(0)
	SetSpriteColor(sprite, random(127, 255), random(127, 255), random(127, 255), 255)
	SetSpritePosition(sprite, 0, i * 10)
	SetSpriteSize(sprite, 100, 10)
	text = CreateText(str(i))
	SetTextAlignment(text, 1)
	SetTextColor(text, 0, 0, 0, 255)
	SetTextPosition(text, 50, (i * 10) + 5)
	if (i = 0) then SetTextString(text, "Start")
	if (i = noOfRows) then SetTextString(text, "End")
	contentHeight# = contentHeight# + 10
next

tweenFlickScroll = CreateTweenCustom(1.2)

do
	print("scrollStartY#:" + str(scrollStartY#))
	print("previousTouchY#:" + str(previousTouchY#))
	print("dY#:" + str(dY#))
	print("scrollStartY#:" + str(scrollStartY#))
	print("contentStartY#:" + str(contentStartY#))
	print("finalY#:" + str(finalY#))
	print("finalDistance#:" + str(finalDistance#))

	if (GetPointerPressed())
		StopTweenCustom(tweenFlickScroll)
		scrollStartY# = GetPointerY()
		viewY# = GetViewOffsetY()
		previousTouchY# = GetPointerY()
		previousTouchTime# = timer()
	else 
		if (GetPointerState())
			//StopTweenCustom(tweenFlickScroll)
			dY# = scrollStartY# - GetPointerY()
			viewDY# = viewY# + dY#
			if (scrollStartY# > contentStartY#)
				if (contentHeight# < 100)
					viewDY# = 0
				elseif (viewDY# > contentHeight# - 100)
					viewDY# = contentHeight# - 100
				endif
				if (viewDY# < 0) then viewDY# = 0
				SetViewOffset(GetViewOffsetX(), viewDY#)
			endif
			// ADJUST THE 0.2 IN LINE BELOW TO SUIT.
			// THIS UPDATES THE LAST Y POSITION EVERY X.X SECONDS.
			// THE LAST Y POSITION AND THE CURRENT Y POSITION IS NEEDED TO CALCULATE THE SWIPE DISTANCE.
			if (timer() - previousTouchTime# > 0.2)
				previousTouchY# = GetPointerY()
				previousTouchTime# = timer()
			endif
		endif
		if (GetPointerReleased())
			scrollDistance# = GetPointerY() - previousTouchY#
			// ADJUST -2 IN LINE BELOW TO SUIT.
			// BASICALLY IT WON'T SCROLL IF THE SWIPE DISTANCE IS SMALL.
			if (scrollDistance# > -4 and scrollDistance# < 4) then scrollDistance# = 0
			// ADJUST 10 IN LINE BELOW TO SUIT.
			// THIS DETERMINES HOW FAR TO SCROLL ONCE SWIPED.
			// THE LARGER THE NUMBER THE FURTHER IT SCROLLS.
			finalDistance# = scrollDistance# * 15
			finalY# = GetViewOffsetY() - finalDistance#
			if (finalY# < 0) then finalY# = 0
			if (finalY# > contentHeight# - 100) then finalY# = contentHeight# - 100
			if (finalDistance# <> 0)
				SetTweenCustomFloat1(tweenFlickScroll, GetViewOffsetY(), finalY#, TweenEaseOut1())
				PlayTweenCustom(tweenFlickScroll, 0)
			endif
		endif
	endif

	if (GetTweenCustomPlaying(tweenFlickScroll))
		SetViewOffset(GetViewOffsetX(), GetTweenCustomFloat1(tweenFlickScroll))
	endif
	
    UpdateAllTweens(GetFrameTime())

    Sync()
loop