[AGK] Purple Token library (online hi-scores)

Author

Message

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 15th Nov 2023 05:08 Edited at: 11th Dec 2023 18:22

Link

I've added a new feature to the REST api for purpletoken, retrieving the submission dates of scores. Just add "dates=yes" to your POST variables when retrieving scores. I've also written a simple to use library that should hopefully take some confusion out of using the hi-score online service. If you don't yet have a game key, you can register for an account here: https://purpletoken.com/register.php

Updated with Psy's corrections and also added a new error code to capture when a score submission fails due to being too low (if all 20 slots are full).

The library:

/*
*
* Author:       Phaelax
* Date:         Dec 11, 2023
*
* Description:  The Purple Token library was created to make it
*			    easier for users to incorporate the functionality
*               of the Purple Token high-score service from within
*			    AGK Tier 1.
*
* Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
*
*/

// Internally used variables. You should never need to access
// _PT directly in your application
Type _PurpleToken
	key				as string
	submitConn   	as integer
	retrieveConn 	as integer
	scoresRetrieved as integer
	scoreSubmitted  as integer
	scores 			as string
Endtype

Global _PT as _PurpleToken

// This array is safe to access from your application
// and contains the return codes possible for score submission
// The exception is an error code of -1, which is an unknown error
Global _PT_Codes as string[4]

// Must be called before using any other PT commands
function PT_initialize(gameKey as string)
	_PT.key = gameKey
	
	_PT_Codes[1] = "Success"
	_PT_Codes[2] = "Name length exceeds 32 characters"
	_PT_Codes[3] = "Gamekey not recognized"
	_PT_Codes[4] = "Score too low"

endfunction

// Submit a score
function PT_submitScore(player as string, score as integer)
	local vars$ as string
	_PT.scoreSubmitted = 0
    _PT.submitConn = createHTTPConnection()
    setHTTPHost(_PT.submitConn, "purpletoken.com", 1, "", "")
 
    vars$ = "player="+player+"&score="+str(score)+"&gamekey="+_PT.key
 
    sendHTTPRequestASync(_PT.submitConn, "update/index.php", vars$)
endfunction
 
 
 
 
 
// Handles the http responses for submitting and requesting scores
// It is safe to call this every iteration of your game loop
function PT_listener()
	local ptResponse as integer
	local res as integer
	// Score retrieval
	if _PT.retrieveConn > 0
		if _PT.scoresRetrieved = 0
		
			ptResponse = getHTTPResponseReady(_PT.retrieveConn)
			
			if ptResponse = -1
				// Error
			elseif ptResponse = 1
				_PT.scores = GetHTTPResponse(_PT.retrieveConn)
				_PT.scoresRetrieved = 1
			endif
			
			if ptResponse <> 0  // If either success or failed request, end connection
				closeHTTPConnection(_PT.retrieveConn)
				deleteHTTPConnection(_PT.retrieveConn)
				_PT.retrieveConn = 0
			endif
		endif
	endif
	
	// Score submission
	if _PT.submitConn > 0
		res = getHTTPResponseReady(_PT.submitConn)
		if res = -1
			// Error
			_PT.scoreSubmitted = -1
		elseif res = 1
			_PT.scoreSubmitted = val(GetHTTPResponse(_PT.submitConn))
		endif
		if _PT.scoreSubmitted <> 0
			`_PT.scoreSubmitted = 1
			closeHTTPConnection(_PT.submitConn)
			deleteHTTPConnection(_PT.submitConn)
			_PT.submitConn = 0
		endif
		
	endif
endfunction

// If a score is submitted this will return '1' upon completion of the http request, otherwise 0
// Codes can be looked up using the PT_Codes[] array
function PT_submitCompleted()
	if _PT.scoreSubmitted <> 0 then exitfunction 1
endfunction 0

// After a score submission has finished a code is generated (for success or possible errors)
// Once this function is called the code is cleared until a new submission is made
function PT_getSubmitCode()
	local code as integer
	code = _PT.scoreSubmitted
	_PT.scoreSubmitted = 0
endfunction code

// Check if new score data is available after a request is made through PT_requestScores()
// Returns 1 for true, 0 otherwise. If scores are available, command will continue to return 1
// until the data has been retrieved at least once.
function PT_scoresAvailable()
	
endfunction _PT.scoresRetrieved

// Returns the raw score data (comma delimited single-line string)
// Once this function is called, PT_scoresAvailable() will return 0 until a new request is made. 
// However, the last retrieved score data can continue to be accessed through this function
function PT_getScores()
	_PT.scoresRetrieved = 0
endfunction _PT.scores
 
 
 
 
// Initiate the connection to get list of scores
// Once the request has completed, PT_scoresAvailable() will return 1
function PT_requestScores()
	local vars$ as string
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = createHTTPConnection()
    setHTTPHost(_PT.retrieveConn, "purpletoken.com", 1, "", "")
 
    vars$ = "gamekey="+_PT.key
    sendHTTPRequestASync(_PT.retrieveConn, "update/index.php", vars$)
 
endfunction

// Same as above but also retrieves the submission date/time of the scores
// The returned format will then look like: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function PT_requestScoresWithDates()
	local vars$ as string
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = createHTTPConnection()
    setHTTPHost(_PT.retrieveConn, "purpletoken.com", 1, "", "")
 
    vars$ = "dates=yes&gamekey="+_PT.key
    sendHTTPRequestASync(_PT.retrieveConn, "update/index.php", vars$)
 
endfunction

// Returns 1 if there's an active connection for score retrieval, otherwise 0
function PT_RetrieveConnectionActive()
    if _PT.retrieveConn <> 0 then exitfunction 1
endfunction 0

// Returns 1 if there's an active connection for score submission, otherwise 0
function PT_SubmitConnectionActive()
    if _PT.submitConn <> 0 then exitfunction 1
endfunction 0

+ Code Snippet

/*
*
* Author:       Phaelax
* Date:         Dec 11, 2023
*
* Description:  The Purple Token library was created to make it
*			    easier for users to incorporate the functionality
*               of the Purple Token high-score service from within
*			    AGK Tier 1.
*
* Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
*
*/


// Internally used variables. You should never need to access
// _PT directly in your application
Type _PurpleToken
	key				as string
	submitConn   	as integer
	retrieveConn 	as integer
	scoresRetrieved as integer
	scoreSubmitted  as integer
	scores 			as string
Endtype


Global _PT as _PurpleToken

// This array is safe to access from your application
// and contains the return codes possible for score submission
// The exception is an error code of -1, which is an unknown error
Global _PT_Codes as string[4]





// Must be called before using any other PT commands
function PT_initialize(gameKey as string)
	_PT.key = gameKey
	
	_PT_Codes[1] = "Success"
	_PT_Codes[2] = "Name length exceeds 32 characters"
	_PT_Codes[3] = "Gamekey not recognized"
	_PT_Codes[4] = "Score too low"

endfunction



// Submit a score
function PT_submitScore(player as string, score as integer)
	local vars$ as string
	_PT.scoreSubmitted = 0
    _PT.submitConn = createHTTPConnection()
    setHTTPHost(_PT.submitConn, "purpletoken.com", 1, "", "")
 
    vars$ = "player="+player+"&score="+str(score)+"&gamekey="+_PT.key
 
    sendHTTPRequestASync(_PT.submitConn, "update/index.php", vars$)
endfunction
 
 
 
 
 
// Handles the http responses for submitting and requesting scores
// It is safe to call this every iteration of your game loop
function PT_listener()
	local ptResponse as integer
	local res as integer
	// Score retrieval
	if _PT.retrieveConn > 0
		if _PT.scoresRetrieved = 0
		
			ptResponse = getHTTPResponseReady(_PT.retrieveConn)
			
			if ptResponse = -1
				// Error
			elseif ptResponse = 1
				_PT.scores = GetHTTPResponse(_PT.retrieveConn)
				_PT.scoresRetrieved = 1
			endif
			
			if ptResponse <> 0  // If either success or failed request, end connection
				closeHTTPConnection(_PT.retrieveConn)
				deleteHTTPConnection(_PT.retrieveConn)
				_PT.retrieveConn = 0
			endif
		endif
	endif
	
	// Score submission
	if _PT.submitConn > 0
		res = getHTTPResponseReady(_PT.submitConn)
		if res = -1
			// Error
			_PT.scoreSubmitted = -1
		elseif res = 1
			_PT.scoreSubmitted = val(GetHTTPResponse(_PT.submitConn))
		endif
		if _PT.scoreSubmitted <> 0
			`_PT.scoreSubmitted = 1
			closeHTTPConnection(_PT.submitConn)
			deleteHTTPConnection(_PT.submitConn)
			_PT.submitConn = 0
		endif
		
	endif
endfunction



// If a score is submitted this will return '1' upon completion of the http request, otherwise 0
// Codes can be looked up using the PT_Codes[] array
function PT_submitCompleted()
	if _PT.scoreSubmitted <> 0 then exitfunction 1
endfunction 0



// After a score submission has finished a code is generated (for success or possible errors)
// Once this function is called the code is cleared until a new submission is made
function PT_getSubmitCode()
	local code as integer
	code = _PT.scoreSubmitted
	_PT.scoreSubmitted = 0
endfunction code



// Check if new score data is available after a request is made through PT_requestScores()
// Returns 1 for true, 0 otherwise. If scores are available, command will continue to return 1
// until the data has been retrieved at least once.
function PT_scoresAvailable()
	
endfunction _PT.scoresRetrieved




// Returns the raw score data (comma delimited single-line string)
// Once this function is called, PT_scoresAvailable() will return 0 until a new request is made. 
// However, the last retrieved score data can continue to be accessed through this function
function PT_getScores()
	_PT.scoresRetrieved = 0
endfunction _PT.scores
 
 
 
 
// Initiate the connection to get list of scores
// Once the request has completed, PT_scoresAvailable() will return 1
function PT_requestScores()
	local vars$ as string
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = createHTTPConnection()
    setHTTPHost(_PT.retrieveConn, "purpletoken.com", 1, "", "")
 
    vars$ = "gamekey="+_PT.key
    sendHTTPRequestASync(_PT.retrieveConn, "update/index.php", vars$)
 
endfunction



// Same as above but also retrieves the submission date/time of the scores
// The returned format will then look like: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function PT_requestScoresWithDates()
	local vars$ as string
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = createHTTPConnection()
    setHTTPHost(_PT.retrieveConn, "purpletoken.com", 1, "", "")
 
    vars$ = "dates=yes&gamekey="+_PT.key
    sendHTTPRequestASync(_PT.retrieveConn, "update/index.php", vars$)
 
endfunction


 
// Returns 1 if there's an active connection for score retrieval, otherwise 0
function PT_RetrieveConnectionActive()
    if _PT.retrieveConn <> 0 then exitfunction 1
endfunction 0



// Returns 1 if there's an active connection for score submission, otherwise 0
function PT_SubmitConnectionActive()
    if _PT.submitConn <> 0 then exitfunction 1
endfunction 0

Example:

SetWindowTitle( "purpletoken_example" )
SetWindowSize( 1024, 768, 0 )
//UseNewDefaultFonts(1)

// Used for this example only
Type ScoreUDT
    name  as string
    score as integer
    timestamp as string
EndType

// Include the Purple Token library
#include 'purpletoken.agc'

// Initialize purple token with your game key
PT_initialize("your game key here")

do

// Press ENTER key to request retrieval of game scores
    if getRawKeyPressed(13) then PT_requestScoresWithDates()

// Press SPACE key to submit a score
    if getRawKeyPressed(32)
		s$ = "Submitting...."
		PT_submitScore("Beavis", random(999, 9999))
    endif

// If score data is available, this will return 1
	if PT_scoresAvailable()
		// Once you call PT_getScores(), PT_scoresAvailable() will return 0 until a new request is made
		scores$ = PT_getScores()
		// Parse scores how you see fit
		//parseScores(scores$)
		parseScoresWithDates(scores$)
	endif

// If a score is submitted this will return 1 upon completion of the http request, otherwise 0
	if PT_submitCompleted()
		// Once PT_getSubmitCode() is called, the code is wiped clear and
		// PT_submitCompleted() will again return 0 until a new submission is made
		submitCode = PT_getSubmitCode()
		if submitCode = -1 then s$ = "Error"
		s$ = _PT_Codes[submitCode]
	endif

// See status of score submission
	print("Score submitted: "+s$)
	print("")
	
	// Display scores however you want
	//displayScores()
	displayScoresWithDates()

// Listens for the http request responses
	// No sockets are left open or connections in memory if 
	// there have been no requests or submissions
	PT_listener()
	
    Sync()
loop

// Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
function parseScores(scores as string)
	count = countStringTokens(scores, ",")
	size  = val(getStringToken(scores, ",", 1))
	dim scoreboard[size] as ScoreUDT
	j = 1
	for i = 2 to count step 2
		player$ = getStringToken(scores, ",", i)
		score   = val(getStringToken(scores, ",", i+1))
		scoreboard[j].name = player$
		scoreboard[j].score = score
		inc j
	next i
endfunction

// Score format: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function parseScoresWithDates(scores as string)
	count = countStringTokens(scores, ",")
	size  = val(getStringToken(scores, ",", 1))
	dim scoreboard[size] as ScoreUDT
	j = 1
	for i = 2 to count step 3
		player$ = getStringToken(scores, ",", i)
		score   = val(getStringToken(scores, ",", i+1))
		t$ 		= getStringToken(scores, ",", i+2)
		scoreboard[j].name = player$
		scoreboard[j].score = score
		scoreboard[j].timestamp = t$
		inc j
	next i
endfunction

function displayScores()
	size = scoreboard.length
	for i = 1 to size
        print(scoreboard[i].name+" - "+str(scoreboard[i].score))
    next i
endfunction

function displayScoresWithDates()
	s$ = spaces(20)
	size = scoreboard.length
	for i = 1 to size
        print(left(scoreboard[i].name+s$, 20)+" - "+right(spaces(5)+str(scoreboard[i].score),5)+"  :  "+scoreboard[i].timestamp)
    next i
endfunction

+ Code Snippet

SetWindowTitle( "purpletoken_example" )
SetWindowSize( 1024, 768, 0 )
//UseNewDefaultFonts(1)


// Used for this example only
Type ScoreUDT
    name  as string
    score as integer
    timestamp as string
EndType


// Include the Purple Token library
#include 'purpletoken.agc'


// Initialize purple token with your game key
PT_initialize("your game key here")



do


	// Press ENTER key to request retrieval of game scores
    if getRawKeyPressed(13) then PT_requestScoresWithDates()


	// Press SPACE key to submit a score
    if getRawKeyPressed(32)
		s$ = "Submitting...."
		PT_submitScore("Beavis", random(999, 9999))
    endif



	// If score data is available, this will return 1
	if PT_scoresAvailable()
		// Once you call PT_getScores(), PT_scoresAvailable() will return 0 until a new request is made
		scores$ = PT_getScores()
		// Parse scores how you see fit
		//parseScores(scores$)
		parseScoresWithDates(scores$)
	endif

	// If a score is submitted this will return 1 upon completion of the http request, otherwise 0
	if PT_submitCompleted()
		// Once PT_getSubmitCode() is called, the code is wiped clear and
		// PT_submitCompleted() will again return 0 until a new submission is made
		submitCode = PT_getSubmitCode()
		if submitCode = -1 then s$ = "Error"
		s$ = _PT_Codes[submitCode]
	endif



	// See status of score submission
	print("Score submitted: "+s$)
	print("")
	
	// Display scores however you want
	//displayScores()
	displayScoresWithDates()


	// Listens for the http request responses
	// No sockets are left open or connections in memory if 
	// there have been no requests or submissions
	PT_listener()
	
    Sync()
loop





// Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
function parseScores(scores as string)
	count = countStringTokens(scores, ",")
	size  = val(getStringToken(scores, ",", 1))
	dim scoreboard[size] as ScoreUDT
	j = 1
	for i = 2 to count step 2
		player$ = getStringToken(scores, ",", i)
		score   = val(getStringToken(scores, ",", i+1))
		scoreboard[j].name = player$
		scoreboard[j].score = score
		inc j
	next i
endfunction


// Score format: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function parseScoresWithDates(scores as string)
	count = countStringTokens(scores, ",")
	size  = val(getStringToken(scores, ",", 1))
	dim scoreboard[size] as ScoreUDT
	j = 1
	for i = 2 to count step 3
		player$ = getStringToken(scores, ",", i)
		score   = val(getStringToken(scores, ",", i+1))
		t$ 		= getStringToken(scores, ",", i+2)
		scoreboard[j].name = player$
		scoreboard[j].score = score
		scoreboard[j].timestamp = t$
		inc j
	next i
endfunction



function displayScores()
	size = scoreboard.length
	for i = 1 to size
        print(scoreboard[i].name+" - "+str(scoreboard[i].score))
    next i
endfunction



function displayScoresWithDates()
	s$ = spaces(20)
	size = scoreboard.length
	for i = 1 to size
        print(left(scoreboard[i].name+s$, 20)+" - "+right(spaces(5)+str(scoreboard[i].score),5)+"  :  "+scoreboard[i].timestamp)
    next i
endfunction

You can get creative with your high score display!

Tiled TMX Importer V.2
XML Parser V.2
Base64 Encoder/Decoder
Purple Token - Free online hi-score database
Legend of Zelda
Pixel-Perfect Collision

"I like offending people, because I think people who get offended should be offended." - Linus Torvalds

Back to top

Profile PM Email Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 25th Nov 2023 23:47

Link

Awesome

Thank you for your continued work on this great project!

PSY

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

Virtual Nomad

Moderator

18

Years of Service

User Offline

Joined: 14th Dec 2005

Location: SF Bay Area, USA

Posted: 26th Nov 2023 21:17 Edited at: 26th Nov 2023 21:41

Link

Phaelax had this tucked in Code Snippets but it deserves a bigger stage where more people need to utilize it where it's opened up a number of doors for me and can extend the life, audience and general FUN of a game so easily.

make sure to check out the FAQ which does subtly mention a max 32 characters for a player name which can be considered a general unique string that you can use to contain not only a player name or initials but other data as well by using delimeters.

ie, in LoS, i wanted to include the LOCAL date for the player when the score was submitted vs PT's server date as well as a unique Session ID that i can use to purge some scores as a user climbs the ladder without worrying if it was another user with the same initials so the "player" string is crafted and submitted, as follows using the pipe | delimeter:

+ Code Snippet

SubmitObject = submitScore(UserName$+"|"+GetCurrentDate()+"|"+SessionID$, STR(Score), gameKey$)

then to display the data, i can pull the initials and date from the "player" string via GetStringToken() (and add commas to the score for display):

+ Code Snippet

	For i = 2 to TotalScores step 2
		ThisPlayer$ = getStringToken(scores$, ",", i)
		INITS$ = Validate( GetStringToken(ThisPlayer$,"|",1) )
		DATE$ = GetStringToken(ThisPlayer$,"|",2)
		IScore = VAL(getStringToken(scores$, ",", i+1) ) 
		ThisScore$   = AddCommas(IScore)
...

plenty of room to get creative there, too. ie, how about including a player's custom color inside, or something else? for that matter, who says the system can only be used for high scores?

regardless, phaelax is offering lots of potential with this. i'm sure LoS couldn't have reached nearly 400 browser sessions** in 2-3 weeks if there weren't live high scores and a global ladder to climb which extends replayability for it so THANKS for that!

also worth mentioning: since bytecode will leave literal strings inside as human-readable, you should obfuscate your game key(s) using something as simple as THIS (Phaelax-approved method), or some other means.

**btw, yes. the AppGameKit commands necessary to use the server DO function fine in HTML exports.

AGK Resource Directory
Made with AppGameKit on Itch.io
VN @ itch.io | AGK Jam HQ
Some Snippets

Back to top

Profile PM Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 27th Nov 2023 21:51 Edited at: 11th Dec 2023 01:40

Link

@Phaelax
In the library, there should be the following code between line 104 and 105:

+ Code Snippet

_PT.submitConn = 0

Without it, an error will be thrown at line 94 if you use SetErrorMode(2)

PSY

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 11th Dec 2023 15:55 Edited at: 12th Dec 2023 17:01

Link

Hey,

I played around a bit and found an issue in the library in line 102:

+ Code Snippet

_PT.scoreSubmitted = 1

This line must be removed, otherwise the return code after a score submission will always be 1 ( success ), no matter if the character limit of 32 was exceeded or the gameKey was not recognized.

I made some minor changes so the library works with #option_explicit, and also added 2 functions that simply check if there is an active submit or request connection, so that a new submission/request is only made if there are no active connections open.

EDIT: Updated to newest version on 12/12/2023

Here's the updated library:

REM ***********************************************
REM Title: Purple Token Library
REM Author: Phaelax
REM Downloaded from: http://dbcc.zimnox.com/
REM ***********************************************
 
/*
*
* Author:       Phaelax
* Date:         Nov 13, 2023
*
* Description:  The Purple Token library was created to make it
*			    easier for users to incorporate the functionality
*               of the Purple Token high-score service from within
*			    AGK Tier 1.
*
* Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
*
*/
 
 
 
 
 
REM ########################################
REM ###   MODIFIED BY PSY Dec 11, 2023   ###
REM ########################################

// Internally used variables. You should never need to access
// _PT directly in your application
Type _PurpleToken
	key				as string
	submitConn   	as integer
	retrieveConn 	as integer
	scoresRetrieved	as integer
	scoreSubmitted 	as integer
	scores 			as string
Endtype
 
Global _PT as _PurpleToken
 
 
 
// This array is safe to access from your application
// and contains the return codes possible for score submission
// The exception is an error code of -1, which is an unknown error
Global _PT_Codes as string[4]
 
 
 
 
 
// Must be called before using any other PT commands
function PT_Initialize ( gameKey as string )
	
	
	_PT.key = gameKey
 
	_PT_Codes[1] = "Highscore submission successful"
	_PT_Codes[2] = "Name length exceeds 32 characters"
	_PT_Codes[3] = "Gamekey not recognized"
	_PT_Codes[4] = "Score too low"
 
 
endfunction
 
 
 
 
 
// Submit a score
function PT_SubmitScore ( _player$ as string, _score as integer )
	
	
	local vars$ as string
		
	
	
	_PT.scoreSubmitted 	= 0
    _PT.submitConn 		= CreateHTTPConnection()
  	SetHTTPHost			( _PT.submitConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "player=" + _player$ + "&score=" + str ( _score ) + "&gamekey=" + _PT.key
 
    SendHTTPRequestASync	( _PT.submitConn, "update/index.php", vars$ )
    
    
endfunction
 
 
 
 
 
// Handles the http responses for submitting and requesting scores
// It is safe to call this every iteration of your game loop
function PT_Listener()
	
	
	local ptResponse 	as integer
	local res 			as integer
 
  
 
	// Score retrieval
	if _PT.retrieveConn > 0
		if _PT.scoresRetrieved = 0
 
			ptResponse = GetHTTPResponseReady ( _PT.retrieveConn )
 
			if ptResponse = -1
				// Error
			elseif ptResponse = 1
				_PT.scores = GetHTTPResponse ( _PT.retrieveConn )
				_PT.scoresRetrieved = 1
			endif
 
			if ptResponse <> 0  // If either success or failed request, end connection
				CloseHTTPConnection	( _PT.retrieveConn )
				DeleteHTTPConnection	( _PT.retrieveConn )
				_PT.retrieveConn = 0
			endif
		endif
	endif
 
 
	// Score submission
	if _PT.submitConn > 0
		
		res = GetHTTPResponseReady ( _PT.submitConn )
		
		if res = -1
			// Error
			_PT.scoreSubmitted = -1
		elseif res = 1
			_PT.scoreSubmitted = val ( GetHTTPResponse ( _PT.submitConn ) )
		endif
		
		if _PT.scoreSubmitted <> 0
			CloseHTTPConnection	( _PT.submitConn )
			DeleteHTTPConnection	( _PT.submitConn )
			_PT.submitConn = 0
		endif
	endif
	
	
endfunction
 
 
 
 
 
// If a score is submitted this will return '1' upon completion of the http request, otherwise 0
// Codes can be looked up using the PT_Codes[] array
function PT_SubmitCompleted()
	if _PT.scoreSubmitted <> 0 then exitfunction 1
endfunction 0
 
 
 
 
 
// After a score submission has finished a code is generated (for success or possible errors)
// Once this function is called the code is cleared until a new submission is made
function PT_GetSubmitCode()
		
	local code as integer
		
	code = _PT.scoreSubmitted
	_PT.scoreSubmitted = 0
	
endfunction code
 
 
 
 
 
// Check if new score data is available after a request is made through PT_RequestScores()
// Returns 1 for true, 0 otherwise. If scores are available, command will continue to return 1
// until the data has been retrieved at least once.
function PT_ScoresAvailable()

endfunction _PT.scoresRetrieved
 
 
 
 
 
// Returns the raw score data (comma delimited single-line string)
// Once this function is called, PT_ScoresAvailable() will return 0 until a new request is made. 
// However, the last retrieved score data can continue to be accessed through this function
function PT_GetScores()
	_PT.scoresRetrieved = 0
endfunction _PT.scores
 
 
 
 
 
// Initiate the connection to get list of scores
// Once the request has completed, PT_scoresAvailable() will return 1
function PT_RequestScores()
	
	
	local vars$ as string
	
	
	
	_PT.scoresRetrieved 	= 0
    _PT.retrieveConn 	= CreateHTTPConnection()
    SetHTTPHost 			( _PT.retrieveConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "gamekey=" + _PT.key
    SendHTTPRequestASync	( _PT.retrieveConn, "update/index.php", vars$ )
 
 
endfunction
 
 
 
 
 
// Same as above but also retrieves the submission date/time of the scores
// The returned format will then look like: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function PT_RequestScoresWithDates()
	
	
	local vars$ as string
	
	
	
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = CreateHTTPConnection()
    SetHTTPHost ( _PT.retrieveConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "dates=yes&gamekey=" + _PT.key
    SendHTTPRequestASync ( _PT.retrieveConn, "update/index.php", vars$ )
 
 
endfunction

// Returns 1 if there's an active connection for score retrieval, otherwise 0
function PT_RetrieveConnectionActive()
	if _PT.retrieveConn <> 0 then exitfunction 1
endfunction 0

// Returns 1 if there's an active connection for score submission, otherwise 0
function PT_SubmitConnectionActive()
	if _PT.submitConn <> 0 then exitfunction 1
endfunction 0

+ Code Snippet

REM ***********************************************
REM Title: Purple Token Library
REM Author: Phaelax
REM Downloaded from: http://dbcc.zimnox.com/
REM ***********************************************
 
/*
*
* Author:       Phaelax
* Date:         Nov 13, 2023
*
* Description:  The Purple Token library was created to make it
*			    easier for users to incorporate the functionality
*               of the Purple Token high-score service from within
*			    AGK Tier 1.
*
* Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
*
*/
 
 
 
 
 
REM ########################################
REM ###   MODIFIED BY PSY Dec 11, 2023   ###
REM ########################################

 
  
    
 
// Internally used variables. You should never need to access
// _PT directly in your application
Type _PurpleToken
	key				as string
	submitConn   	as integer
	retrieveConn 	as integer
	scoresRetrieved	as integer
	scoreSubmitted 	as integer
	scores 			as string
Endtype
 
Global _PT as _PurpleToken
 
 
 
// This array is safe to access from your application
// and contains the return codes possible for score submission
// The exception is an error code of -1, which is an unknown error
Global _PT_Codes as string[4]
 
 
 
 
 
// Must be called before using any other PT commands
function PT_Initialize ( gameKey as string )
	
	
	_PT.key = gameKey
 
	_PT_Codes[1] = "Highscore submission successful"
	_PT_Codes[2] = "Name length exceeds 32 characters"
	_PT_Codes[3] = "Gamekey not recognized"
	_PT_Codes[4] = "Score too low"
 
 
endfunction
 
 
 
 
 
// Submit a score
function PT_SubmitScore ( _player$ as string, _score as integer )
	
	
	local vars$ as string
		
	
	
	_PT.scoreSubmitted 	= 0
    _PT.submitConn 		= CreateHTTPConnection()
  	SetHTTPHost			( _PT.submitConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "player=" + _player$ + "&score=" + str ( _score ) + "&gamekey=" + _PT.key
 
    SendHTTPRequestASync	( _PT.submitConn, "update/index.php", vars$ )
    
    
endfunction
 
 
 
 
 
// Handles the http responses for submitting and requesting scores
// It is safe to call this every iteration of your game loop
function PT_Listener()
	
	
	local ptResponse 	as integer
	local res 			as integer
 
  
 
	// Score retrieval
	if _PT.retrieveConn > 0
		if _PT.scoresRetrieved = 0
 
			ptResponse = GetHTTPResponseReady ( _PT.retrieveConn )
 
			if ptResponse = -1
				// Error
			elseif ptResponse = 1
				_PT.scores = GetHTTPResponse ( _PT.retrieveConn )
				_PT.scoresRetrieved = 1
			endif
 
			if ptResponse <> 0  // If either success or failed request, end connection
				CloseHTTPConnection	( _PT.retrieveConn )
				DeleteHTTPConnection	( _PT.retrieveConn )
				_PT.retrieveConn = 0
			endif
		endif
	endif
 
 
	// Score submission
	if _PT.submitConn > 0
		
		res = GetHTTPResponseReady ( _PT.submitConn )
		
		if res = -1
			// Error
			_PT.scoreSubmitted = -1
		elseif res = 1
			_PT.scoreSubmitted = val ( GetHTTPResponse ( _PT.submitConn ) )
		endif
		
		if _PT.scoreSubmitted <> 0
			CloseHTTPConnection	( _PT.submitConn )
			DeleteHTTPConnection	( _PT.submitConn )
			_PT.submitConn = 0
		endif
	endif
	
	
endfunction
 
 
 
 
 
// If a score is submitted this will return '1' upon completion of the http request, otherwise 0
// Codes can be looked up using the PT_Codes[] array
function PT_SubmitCompleted()
	if _PT.scoreSubmitted <> 0 then exitfunction 1
endfunction 0
 
 
 
 
 
// After a score submission has finished a code is generated (for success or possible errors)
// Once this function is called the code is cleared until a new submission is made
function PT_GetSubmitCode()
		
	local code as integer
		
	code = _PT.scoreSubmitted
	_PT.scoreSubmitted = 0
	
endfunction code
 
 
 
 
 
// Check if new score data is available after a request is made through PT_RequestScores()
// Returns 1 for true, 0 otherwise. If scores are available, command will continue to return 1
// until the data has been retrieved at least once.
function PT_ScoresAvailable()

endfunction _PT.scoresRetrieved
 
 
 
 
 
// Returns the raw score data (comma delimited single-line string)
// Once this function is called, PT_ScoresAvailable() will return 0 until a new request is made. 
// However, the last retrieved score data can continue to be accessed through this function
function PT_GetScores()
	_PT.scoresRetrieved = 0
endfunction _PT.scores
 
 
 
 
 
// Initiate the connection to get list of scores
// Once the request has completed, PT_scoresAvailable() will return 1
function PT_RequestScores()
	
	
	local vars$ as string
	
	
	
	_PT.scoresRetrieved 	= 0
    _PT.retrieveConn 	= CreateHTTPConnection()
    SetHTTPHost 			( _PT.retrieveConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "gamekey=" + _PT.key
    SendHTTPRequestASync	( _PT.retrieveConn, "update/index.php", vars$ )
 
 
endfunction
 
 
 
 
 
// Same as above but also retrieves the submission date/time of the scores
// The returned format will then look like: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function PT_RequestScoresWithDates()
	
	
	local vars$ as string
	
	
	
	_PT.scoresRetrieved = 0
    _PT.retrieveConn = CreateHTTPConnection()
    SetHTTPHost ( _PT.retrieveConn, "purpletoken.com", 1, "", "" )
 
    vars$ = "dates=yes&gamekey=" + _PT.key
    SendHTTPRequestASync ( _PT.retrieveConn, "update/index.php", vars$ )
 
 
endfunction





// Returns 1 if there's an active connection for score retrieval, otherwise 0
function PT_RetrieveConnectionActive()
	if _PT.retrieveConn <> 0 then exitfunction 1
endfunction 0





// Returns 1 if there's an active connection for score submission, otherwise 0
function PT_SubmitConnectionActive()
	if _PT.submitConn <> 0 then exitfunction 1
endfunction 0

Here's an example code where you can submit a legit score, submit a score with an invalid name, and request the score table. You just need to enter your gameKey.

#option_explicit

SetErrorMode ( 2 )

#insert "purpletoken.agc"

type HighscoreTableType

name		as string
	score		as integer
	timestamp	as string

endtype

global scoreboard as HighscoreTableType[]

global scores$ 			as string
global submitCode 		as integer
global submit_result$	as string
global request_result$	as string

SetWindowTitle			( "PurpleToken Highscore Generator" )
SetWindowSize			( 1024, 768, 0 )
SetWindowAllowResize		( 1 )
SetVirtualResolution		( 1024, 768 )
SetOrientationAllowed	( 1, 1, 1, 1 )
SetSyncRate				( 60, 0 )
SetScissor				( 0, 0, 0, 0 )
UseNewDefaultFonts		( 1 )

PT_Initialize ( "GAME KEY" )

repeat
 
 
	// Press ENTER key to request retrieval of game scores
    if GetRawKeyPressed ( 13 ) and NOT PT_RetrieveConnectionActive()
    	request_result$ = "Requesting..."
    	PT_RequestScoresWithDates()
    endif	
 
 
	// Press SPACE key to submit a score
    if GetRawKeyPressed ( 32 ) and NOT PT_SubmitConnectionActive()
		submit_result$ = "Submitting...."
		PT_SubmitScore ( "DAISY", random ( 10000, 99999 ) )
	endif
 
 
 	// Press '2' key to submit a score with a name exceeding the char limit
    if GetRawKeyPressed ( 50 ) and NOT PT_SubmitConnectionActive()
		submit_result$ = "Submitting...."
		PT_SubmitScore ( "THISNAMEISEXCEEDINGTHELIMITOF32CHARS", random ( 10000, 99999 ) )
    endif
    
 
 
	// If score data is available, this will return 1
	if PT_ScoresAvailable()
		// Once you call PT_GetScores(), PT_ScoresAvailable() will return 0 until a new request is made
		scores$ = PT_GetScores()
		// Parse scores how you see fit
		ParseScoresWithDates ( scores$ )
		//ParseScores(scores$)
		request_result$ = "Highscore request completed"
	endif
 
 
 
	// If a score is submitted this will return 1 upon completion of the http request, otherwise 0
	if PT_SubmitCompleted()
		// Once PT_GetSubmitCode() is called, the code is wiped clear and
		// PT_SubmitCompleted() will again return 0 until a new submission is made
		submitCode = PT_GetSubmitCode()
		if submitCode = -1
			submit_result$ = "Unknown error"
		else	
			submit_result$ = _PT_Codes[submitCode]
		endif	
	endif
 
 
 
	// See status
	print ( "Press [ENTER] to retrieve scores" )
	print ( "Press [SPACE] to submit a random score" )
	print ( "Press [2] to submit a random score and a name that has too many characters" )
	print ( "" ) : print ( "" )
	print ( "Last score submission:   " + submit_result$ )
	print ( "Last score request:         " + request_result$ )
	print ( "" ) : print ( "" )
	
 
	// Display scores however you want
	DisplayScoresWithDates()
 	//DisplayScores()
 
 
	// Listens for the http request responses
	// No sockets are left open or connections in memory if 
	// there have been no requests or submissions
	PT_Listener()
 
 
    Sync()
    
    
until GetRawKeyReleased ( 27 )
END

// Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
function ParseScores ( _scores as string )
	
	
	local count 		as integer
	local size 		as integer
	local player$	as string
	local score 		as integer
	local i 		as integer
	local j 		as integer
	
	
	
	count = CountStringTokens ( _scores, "," )
	size  = val ( GetStringToken ( _scores, ",", 1 ) )

scoreboard.length = size
	
	j = 1
	for i = 2 to count step 2
		player$ = GetStringToken ( _scores, ",", i )
		score   = val ( GetStringToken ( _scores, ",", i+1 ) )
		scoreboard[j].name = player$
		scoreboard[j].score = score
		inc j
	next i
	
	
endfunction

// Score format: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function ParseScoresWithDates ( _scores as string )

local count 		as integer
	local size 		as integer
	local i 		as integer
	local j 		as integer
	local player$	as string
	local score 		as integer
	local t$ 		as string	
	
	
	
	count 				= CountStringTokens ( _scores, "," )
	size  				= val ( GetStringToken ( _scores, ",", 1 ) )
	scoreboard.length 	= size
	
	j = 1
	for i = 2 to count step 3
		player$ = GetStringToken ( _scores, ",", i)
		score   = val ( GetStringToken ( _scores, ",", i+1 ) )
		t$ 		= GetStringToken ( _scores, ",", i+2 )
		scoreboard[j].name 		= player$
		scoreboard[j].score 		= score
		scoreboard[j].timestamp	= t$
		inc j
	next i
	
	
endfunction

function DisplayScores()
	
	
	local size	as integer
	local i 	as integer
	
	
	
	size = scoreboard.length
	for i = 1 to size
        print ( scoreboard[i].name + " - " + str ( scoreboard[i].score ) )
    next i
    
    
endfunction

function DisplayScoresWithDates()
	
	
	local blank$		as string
	local size 		as integer
	local i 		as integer
	
	
	
	blank$ = spaces ( 20 )
	size = scoreboard.length
	for i = 1 to size
        print ( left ( scoreboard[i].name + blank$, 20 ) + " - " + right ( spaces ( 5 ) + str ( scoreboard[i].score), 6 ) + "  :  " + scoreboard[i].timestamp )
    next i
    
    
endfunction

+ Code Snippet

#option_explicit

SetErrorMode ( 2 )

#insert "purpletoken.agc"



type HighscoreTableType

	name		as string
	score		as integer
	timestamp	as string

endtype	

global scoreboard as HighscoreTableType[]



global scores$ 			as string
global submitCode 		as integer
global submit_result$	as string
global request_result$	as string



SetWindowTitle			( "PurpleToken Highscore Generator" )
SetWindowSize			( 1024, 768, 0 )
SetWindowAllowResize		( 1 )
SetVirtualResolution		( 1024, 768 )
SetOrientationAllowed	( 1, 1, 1, 1 )
SetSyncRate				( 60, 0 )
SetScissor				( 0, 0, 0, 0 )
UseNewDefaultFonts		( 1 )



PT_Initialize ( "GAME KEY" )



repeat
 
 
	// Press ENTER key to request retrieval of game scores
    if GetRawKeyPressed ( 13 ) and NOT PT_RetrieveConnectionActive()
    	request_result$ = "Requesting..."
    	PT_RequestScoresWithDates()
    endif	
 
 
	// Press SPACE key to submit a score
    if GetRawKeyPressed ( 32 ) and NOT PT_SubmitConnectionActive()
		submit_result$ = "Submitting...."
		PT_SubmitScore ( "DAISY", random ( 10000, 99999 ) )
	endif
 
 
 	// Press '2' key to submit a score with a name exceeding the char limit
    if GetRawKeyPressed ( 50 ) and NOT PT_SubmitConnectionActive()
		submit_result$ = "Submitting...."
		PT_SubmitScore ( "THISNAMEISEXCEEDINGTHELIMITOF32CHARS", random ( 10000, 99999 ) )
    endif
    
 
 
	// If score data is available, this will return 1
	if PT_ScoresAvailable()
		// Once you call PT_GetScores(), PT_ScoresAvailable() will return 0 until a new request is made
		scores$ = PT_GetScores()
		// Parse scores how you see fit
		ParseScoresWithDates ( scores$ )
		//ParseScores(scores$)
		request_result$ = "Highscore request completed"
	endif
 
 
 
	// If a score is submitted this will return 1 upon completion of the http request, otherwise 0
	if PT_SubmitCompleted()
		// Once PT_GetSubmitCode() is called, the code is wiped clear and
		// PT_SubmitCompleted() will again return 0 until a new submission is made
		submitCode = PT_GetSubmitCode()
		if submitCode = -1
			submit_result$ = "Unknown error"
		else	
			submit_result$ = _PT_Codes[submitCode]
		endif	
	endif
 
 
 
	// See status
	print ( "Press [ENTER] to retrieve scores" )
	print ( "Press [SPACE] to submit a random score" )
	print ( "Press [2] to submit a random score and a name that has too many characters" )
	print ( "" ) : print ( "" )
	print ( "Last score submission:   " + submit_result$ )
	print ( "Last score request:         " + request_result$ )
	print ( "" ) : print ( "" )
	
 
	// Display scores however you want
	DisplayScoresWithDates()
 	//DisplayScores()
 
 
	// Listens for the http request responses
	// No sockets are left open or connections in memory if 
	// there have been no requests or submissions
	PT_Listener()
 
 
    Sync()
    
    
until GetRawKeyReleased ( 27 )
END





// Score format: No_Of_Entries,User1,Score1,User2,Score2,User3,Score3
function ParseScores ( _scores as string )
	
	
	local count 		as integer
	local size 		as integer
	local player$	as string
	local score 		as integer
	local i 		as integer
	local j 		as integer
	
	
	
	count = CountStringTokens ( _scores, "," )
	size  = val ( GetStringToken ( _scores, ",", 1 ) )

	scoreboard.length = size
	
	j = 1
	for i = 2 to count step 2
		player$ = GetStringToken ( _scores, ",", i )
		score   = val ( GetStringToken ( _scores, ",", i+1 ) )
		scoreboard[j].name = player$
		scoreboard[j].score = score
		inc j
	next i
	
	
endfunction





// Score format: No_Of_Entries,User1,Score1,Date1,User2,Score2,Date2,User3,Score3,Date3
function ParseScoresWithDates ( _scores as string )
	

	local count 		as integer
	local size 		as integer
	local i 		as integer
	local j 		as integer
	local player$	as string
	local score 		as integer
	local t$ 		as string	
	
	
	
	count 				= CountStringTokens ( _scores, "," )
	size  				= val ( GetStringToken ( _scores, ",", 1 ) )
	scoreboard.length 	= size
	
	j = 1
	for i = 2 to count step 3
		player$ = GetStringToken ( _scores, ",", i)
		score   = val ( GetStringToken ( _scores, ",", i+1 ) )
		t$ 		= GetStringToken ( _scores, ",", i+2 )
		scoreboard[j].name 		= player$
		scoreboard[j].score 		= score
		scoreboard[j].timestamp	= t$
		inc j
	next i
	
	
endfunction





function DisplayScores()
	
	
	local size	as integer
	local i 	as integer
	
	
	
	size = scoreboard.length
	for i = 1 to size
        print ( scoreboard[i].name + " - " + str ( scoreboard[i].score ) )
    next i
    
    
endfunction





function DisplayScoresWithDates()
	
	
	local blank$		as string
	local size 		as integer
	local i 		as integer
	
	
	
	blank$ = spaces ( 20 )
	size = scoreboard.length
	for i = 1 to size
        print ( left ( scoreboard[i].name + blank$, 20 ) + " - " + right ( spaces ( 5 ) + str ( scoreboard[i].score), 6 ) + "  :  " + scoreboard[i].timestamp )
    next i
    
    
endfunction

PSY

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

Virtual Nomad

Moderator

18

Years of Service

User Offline

Joined: 14th Dec 2005

Location: SF Bay Area, USA

Posted: 11th Dec 2023 17:06 Edited at: 11th Dec 2023 17:07

Link

thanks for posting, PSY. i've been trying to sort out an issue with the original code (pre-current library) and only caused more errors. i NEED to get this running without issue and you just saved me a ton of time

AGK Resource Directory
Made with AppGameKit on Itch.io
VN @ itch.io | AGK Jam HQ
Some Snippets

Back to top

Profile PM Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 11th Dec 2023 17:33

Link

You're welcome, glad I could help

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 11th Dec 2023 18:20

Link

Thanks Psy, a few minor oversights. I've also updated the server and added a new error code. Submitting a score that was too low for the top 20 would result in -1 (unknown) error, so I've fixed it to return 4 instead.

Tiled TMX Importer V.2
XML Parser V.2
Base64 Encoder/Decoder
Purple Token - Free online hi-score database
Legend of Zelda
Pixel-Perfect Collision

"I like offending people, because I think people who get offended should be offended." - Linus Torvalds

Back to top

Profile PM Email Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 11th Dec 2023 21:44

Link

Quote: " I've also updated the server and added a new error code. Submitting a score that was too low for the top 20 would result in -1 (unknown) error, so I've fixed it to return 4 instead."

Nice, thanks alot Phaelax !

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 11th Dec 2023 22:02

Link

I forgot to mention another change I made:

The code block In you example line 48-55

+ Code Snippet

    // If a score is submitted this will return 1 upon completion of the http request, otherwise 0
    if PT_submitCompleted()
        // Once PT_getSubmitCode() is called, the code is wiped clear and
        // PT_submitCompleted() will again return 0 until a new submission is made
        submitCode = PT_getSubmitCode()
        if submitCode = -1 then s$ = "Error"
        s$ = _PT_Codes[submitCode]
    endif

should rather be

+ Code Snippet

    // If a score is submitted this will return 1 upon completion of the http request, otherwise 0
    if PT_SubmitCompleted()
        // Once PT_GetSubmitCode() is called, the code is wiped clear and
        // PT_SubmitCompleted() will again return 0 until a new submission is made
        submitCode = PT_GetSubmitCode()
        if submitCode = -1
            submit_result$ = "Unknown error"
        else   
            submit_result$ = _PT_Codes[submitCode]
        endif  
    endif

Otherwise, the code will crash ( array out of bounds ) if submitCode is -1

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 12th Dec 2023 03:49

Link

Yea I made that change as well, I just didn't update the example. Frankly, when i turned on explicit it broke everything. Even after defining variables it still insisted they weren't defined. So I said screw it and left my house lol

Tiled TMX Importer V.2
XML Parser V.2
Base64 Encoder/Decoder
Purple Token - Free online hi-score database
Legend of Zelda
Pixel-Perfect Collision

"I like offending people, because I think people who get offended should be offended." - Linus Torvalds

Back to top

Profile PM Email Website

PSY

Developer

8

Years of Service

User Offline

Joined: 3rd Jul 2016

Location: Laniakea Supercluster

Posted: 12th Dec 2023 16:49

Link

Quote: "Frankly, when i turned on explicit it broke everything. Even after defining variables it still insisted they weren't defined."

Can't be much, probably something got mixed up because I renamed some variables or any other minor oversight.
Or maybe because I worked with .length as Dim doesn't work that way inside functions with #option_explicit.

Quote: "So I said screw it and left my house lol"

I hear you

PSY LABS Games
Coders don't die, they just gosub without return

Back to top

Profile PM Website

Sorry your browser is not supported!

AppGameKit/AppGameKit Studio Showcase / [AGK] Purple Token library (online hi-scores)