Sorry your browser is not supported!

set display mode 1024,768,32
bodylength=5
autocam off


`set Frame Rate
sync rate 20

`hide the mouse
hide mouse

`make ground (So I can see how fast I'm going)
color backdrop 0
`make the head
make object sphere 2,4,30,30
color object 2,rgb(0,255,50)
position object 2,20,0,20

make object cube 100,5
scale object 100,4000,100,80
position object 100,100,0,0
make object cube 101,5
scale object 101,80,100,4000
position object 101,200,0,100
make object cube 102,5
scale object 102,80,100,4000
position object 102,0,0,100
make object cube 103,5
scale object 103,4000,100,80
position object 103,100,0,200
make object cube 104,5
scale object 104,4000,1,4000
position object 104,100,0,100
color object 104,rgb(0,255,0)
for x=100 to 103
color object x,rgb(0,0,255)

ghost object on x
next x

`Prepare to make body parts
t=3
partcolor=1

`The body part making loop
for t=3 to bodylength
   `Make a body part
   make object sphere t,3,30,30
   ` color it
   if partcolor=1
      partcolor=2
      color object t,rgb(0,100,0)
   else
      partcolor=1
      color object t,rgb(0,255,50)
   endif
next t

position camera object position x(2),object position y(2)+100,10
point camera object position x(2),object position y(2)+100,0
xrotate camera 90
` game loop
crntspd=10.0
do
   if crntpiece=0
      make object sphere bodylength+1,4,30,30
      color object bodylength+1,rgb(255,0,0)
      set object specular bodylength+1,rgb(255,0,0)
      position object bodylength+1,rnd(180)+5,0,rnd(180)+5
      crntpiece=1
   endif
   if object collision(2,bodylength+1)
      delete object bodylength+1
      make object sphere bodylength+1,3,30,30
      if partcolor=1
         partcolor=2
         color object bodylength+1,rgb(0,100,0)
      else
         partcolor=1
         color object bodylength+1,rgb(0,255,50)
      endif
      bodylength=bodylength+1
      crntpiece=0
      crntspd=crntspd+1.0
   endif

   `set camera to follow snake
   position camera object position x(2),object position y(2)+140,object position z(2)
   `Control the way the head faces by moving the mouse
   if leftkey()=1 then turn object left 2,12
   if rightkey()=1 then turn object right 2,12

   for a=100 to 103
   if object collision(2,a)
   repeat
   ink rgb(255,255,255),0
   set text size 48
   center text screen width()/2,screen height()/2,"YOU LOSE"
   until entry$()
   end
   endif
   next a

   ` position the bits
   t=bodylength
   for a=4 to bodylength
      position object t,object position x(t-1),object position y(t-1),object position z(t-1)
      t=t-1
   next a


   `this want's to be outside the loop because the last body part has to be attatched to the head.
   position object 3, object position x(2),object position y(2),object position z(2)

   `move the head in the direction it's facing
   move object 2,crntspd/10.0
   `put the camera in the right place.

loop

`strategy challenge version 0.000000000000001 by Ric
sync on
sync rate 100
color backdrop 0
autocam off
position camera 0,0,-50
hide light 0
set ambient light 10
make light 1
position light 1,-30,80,-50




ink rgb(0,0,80),0
box 0,0,100,100
ink 0,0
box 2,2,98,98
get image 1000,0,0,100,100

make object sphere 1000,-1000,20,20
texture object 1000,1000
scale object texture 1000,15,15
xrotate object 1000,90
set object light 1000,0

ink rgb(120,120,255),0
set text font "sf automaton_mod"
set text size 20

for sphere=1 to 20
make object sphere sphere,5,30,30
red=rnd(1)*255
green=rnd(1)*255
blue=rnd(1)*255
color object sphere,rgb(red,green,blue)
set object specular power sphere,20
set object specular sphere,rgb(200,200,200)
next sphere


start:

for sphere=1 to 20
show object sphere
next sphere

number=20

sync
text 0,0,"Aim of the game:  Each player removes 1, 2 or 3 balls in turn."
text 0,20,"The winner is the one who removes the last ball."
text 0,60,"Press Space to start."
sync
wait key

playergo=rnd(1)
if playergo=0
  computergo=1
  text 0,0,"I'll go first"
else
  text 0,0,"You go first"
endif
sync
wait 1000



do

if playergo=1 then gosub playergo
if computergo=1 then gosub computergo

rotation#=wrapvalue(rotation#)+0.5
for sphere=1 to 20
position object sphere,20*sin((360/20)*sphere+rotation#),20*cos((360/20)*sphere+rotation#),0
next sphere
scroll object texture 1000,0.02,0.02
text 0,400,"score - Me:"+str$(compscore)+"  You:"+str$(playerscore)
sync
loop


playergo:

  text 0,40,"Your go: How many do you want to remove? (1, 2 or 3): "


if scancode()>0 and scancode()<5 and scancode()<=number+1
  remove=scancode()-1
  number=number-remove
  for sphere=number+1 to 20
    hide object sphere
  next sphere
  if number=0 then text 0,100,"You win!":sync:wait 2000:inc playerscore:goto start
  playergo=0:computergo=1
endif

return

computergo:

if waitabit=0

    repeat
    if number/4.0 = int(number/4)
      remove=(rnd(2)+1)
    else
      calculatebestnumber=number
      repeat
        dec calculatebestnumber
      until calculatebestnumber/4.0 = int(calculatebestnumber/4)
      remove=number-calculatebestnumber
    endif
  until remove<=number
endif

text 0,40, "My go: I will remove "+str$(remove)+" balls"

inc waitabit

if waitabit>300
  number=number-remove
  for sphere=number+1 to 20
  hide object sphere
  next sphere
  if number=0 then text 0,100,"I win!":sync:wait 2000:inc compscore:goto start
  playergo=1
  computergo=0
  waitabit=0
endif

return

`Slideways
`Coding Challenge Entry
`By Patrick Lewis
`3/13/2005
`Update 3/15/2005
Sync On:Sync Rate 60:Autocam Off:Hide Mouse
Type Coordinates
   x as Float:y as Float:z as Float
Endtype
Global Object as Coordinates

Type Players
   Score as Integer:Color as String
Endtype
Dim O_Color(36) as String:Dim Blast(36):Dim ObjectSeq(6,6):Dim Player(2) as Players:Global Phase as Byte
Create Bitmap 1,512,512:Set Current bitmap 1:Box 0,0,511,511,RGB(192,192,192),RGB(221,221,221),RGB(192,192,192),RGB(255,255,255):Get Image 2,0,0,511,511:Set Current Bitmap 0:Delete Bitmap 1
b=1:For i =1 to 6:For j = 1 to 6:Make_Crystal(b):Position Object b,j*11-39,i*11-33,100:b=b+1:Next j:Next i
Make Object Cone 40,7.5:Make Object Cylinder 41,3:Make Mesh From Object 41,41:Add Limb 40,1,41:Delete Object 41:Delete Mesh 41:Offset Limb 40,0,0,4.5,0:Disable Object ZDepth 40
Make Camera 1:Color Backdrop 1,RGB(182,183,206):Set Camera to Image 1,1,512,512:Position Camera 1,0,0,200:Point Camera 1,0,0,0
Make Object Plain 42,200,150:Position Object 42,0,0,150:Texture Object 42,1:Set Object Cull 42,1:Turn Object Left 42,180:Set Object Emissive 42,RGB(110,110,110)
`Set Bump Mapping On 42,2

Do
`Select mode: Player vs Player or Player vs AI
 Mode = 1 ` 1=Player vs Player. 2=Player vs AI


 Phase = 1 ` 1=Player 1 choose color. 2=Player 2 choose color. 3=Player 1 turn. 4=Player 2 turn

 csx=Screen Width()/2:csy=Screen Height()/2
 Do
    `Controls
    Offx=Mousex()-csx
    Offy=Mousey()-csy
    Select Phase
       Case 1
          Set Cursor 0,0:Print "Player 1 Select Color"
          ypos=Int(Offy/11)*-11
          xpos=Int(Offx/11)*11-7
          ypos=Min_Max(ypos,-22,33)
          xpos=Min_Max(xpos,-29,26)
          Rotate Object 40,0,0,45
          Position Object 40,xpos+5,ypos-5,100
          If Mouseclick()=1
             O=Pick Object(Object Screen X(40)-10,Object Screen Y(40)-10,1,36)
             Player(1).Color=O_Color(O)
             Phase = 2
          Endif
       Endcase
       Case 2
          Set Cursor 0,0:Print "Player 2 Select Color"
          ypos=Int(Offy/11)*-11
          xpos=Int(Offx/11)*11-7
          ypos=Min_Max(ypos,-22,33)
          xpos=Min_Max(xpos,-29,26)
          Rotate Object 40,0,0,45
          Position Object 40,xpos+5,ypos-5,100
          If Mouseclick()=1
             O=Pick Object(Object Screen X(40)-10,Object Screen Y(40)-10,1,36)
             Player(2).Color=O_Color(O)
             If Player(2).Color<>Player(1).Color
                Phase = 4:Delay=9
             Else
                Player(2).Color=""
             Endif
          Endif
       Endcase
       Case Default
          Set Cursor 0,0:Print "Turn: Player "; Phase-2
          If abs(Offx)>Abs(Offy)
             ypos=Int(Offy/11)*-11
             ypos=Min_Max(ypos,-22,33)
             Position Object 40,40*((Offx>0)-(Offx<0)),ypos,100
             Rotate Object 40,0,0,90*((Offx<0)-(Offx>0))
          Else
             xpos=Int(Offx/11)*11-7
             xpos=Min_Max(xpos,-29,26)
             Position Object 40,xpos,40*((Offy<0)-(Offy>0))+5,100
             Rotate Object 40,0,0,180*(Offy>0)
          Endif
          If mouseclick()=1 And Click=0 And Delay=0
             Row=(Object Position Y(40)+33)/10
             Col=(Object Position X(40)+39)/10
             If Row=0 or Col=0 Then Click=-11 Else Click=11
             Delay=50
          Endif
       Endcase
    Endselect

    `Move crystals
    For i = 1 to 36
       Turn Object Right i,1
       OCol=(Object Position X(i)+39)/10
       ORow=(Object Position Y(i)+33)/10
       If Click<>0
          If Row=0 or Row=7
             If OCol=Col
                Rotate Object i,0,0,0
                Move Object Up i,((Click>0)-(Click<0))
             Endif
          Else
             If ORow=Row
                Rotate Object i,0,0,0
                Move Object Right i,((Click>0)-(Click<0))
             Endif
          Endif
       Else
          If Delay=49
             If OCol=0 Then Position Object i,6*11-39,Object Position Y(i),100:OCol=6
             If OCol=7 Then Position Object i,1*11-39,Object Position Y(i),100:OCol=1
             If ORow=0 Then Position Object i,Object Position X(i),6*11-33,100:ORow=6
             If ORow=7 Then Position Object i,Object Position X(i),1*11-33,100:ORow=1
             ObjectSeq(OCol,ORow)=i
          Endif
       Endif
    Next i
    L=0
    Select Delay
       Case 1
          L=Check_Elim()
       EndCase
       Case 2:If Phase=3 Then Phase=4 Else Phase=3
       Endcase
       Case 40:Check_Diag_Down():EndCase
       Case 42:Check_Diag_Up():EndCase
       Case 44:Check_Vertical():EndCase
       Case 46:Check_Horizontal():EndCase
       Case Default
          If Delay>10 And Delay<40
             BlastEm()
          Endif
       Endcase
    Endselect
    If Click<>0 Then Click=Click-(Click>0)+(Click<0) Else IF Delay>0 Then Delay=Delay-1
    Set Cursor 0,50
    Print "Player 1 Color: "; Player(1).Color;""
    Print "Player 2 Color: "; Player(2).Color;""
    Print ""
    Print "Player 1 Score: "; Player(1).Score
    Print "Player 2 Score: "; Player(2).Score
    Sync
    If L<>0 Then Exit
 Loop
 W=3-L
 Player(W).Score=Player(W).Score+100
 Win=((Player(2).Score>Player(1).Score)+1)*(Player(2).Score<>Player(1).Score)
 If Win
    Center Text Screen Width()/2,0,"Player "+str$(W)+" has Won!"
 Else
    Center Text Screen Width()/2,0,"It's a TIE!"
 EndIf
 Set Cursor 0,50
 Print "Player 1 Color: "; Player(1).Color;""
 Print "Player 2 Color: "; Player(2).Color;""
 Print ""
 Print "Player 1 Score: "; Player(1).Score
 Print "Player 2 Score: "; Player(2).Score
 Center Text Screen Width()/2,24,"Press 'N' to quit, or any key to Play Again!"
 Sync
 Wait key
 If Lower$(Inkey$())="n" Then End
Loop

Function Make_Crystal(ObjectID)
   Make Object Sphere ObjectID,10,3,4
   Color=Rnd(5)
   Restore Colors
   For c = 0 to Color
      Read O_Color(ObjectID),cr,cg,cb,er,eg,eb
   Next c
   Color Object ObjectID,rgb(cr,cg,cb)
   Set Object Emissive ObjectID,rgb(er,eg,eb)
   Set Alpha Mapping On ObjectID,80
   Set Object Cull ObjectID,0
   Blast(ObjectID)=0
Endfunction

Function Check_Horizontal()
Dim clrs(2) as String
For i = 1 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Vertical()
Dim clrs(2) as String
For i = 1 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(j+test,i))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(j+test,i))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Diag_Up()
Dim clrs(2) as String
For i = 1 to 4
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i+test,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i+test,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Diag_Down()
Dim clrs(2) as String
For i = 3 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i-test,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i-test,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function BlastEm()
   For i = 1 to 36
      If Blast(i)=1
         OS#=Object Size(i)-.3
         Scale Object i,OS#/20.0*100.0,OS#/20.0*100.0,OS#/20.0*100.0
         If Object Size(i)<2.0
            If O_Color(i)=Player(Phase-2).Color Then Player(Phase-2).Score=Player(Phase-2).Score+10
            Return_Object(i)
            Delete Object i
            Make_Crystal(i)
            Position Object i,Object.x,Object.y,Object.z
         Endif
      Endif
   Next i
EndFunction

Function Check_Elim()
   c1=0:c2=0
   For i = 1 to 36
      If O_Color(i)=Player(1).Color then c1=c1+1
      If O_Color(i)=Player(2).Color then c2=c2+1
   Next i
Lose=0
If c1<3 Then Lose=1
If c2<3 Then Lose=2
EndFunction Lose

Function Min_Max(Var1,Min,Max)
If Var1<Min then Var1=Min Else If Var1>Max Then Var1=Max
Endfunction Var1

Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Colors:
Data "White",255,255,255,100,100,100,"Red",255,0,0,100,0,0,"Blue",0,0,255,0,0,06,"Green",0,255,0,0,100,0,"Yellow",255,255,0,100,100,0,"Pink",248,86,248,88,0,88

`Slideways
`Coding Challenge Entry
`By Patrick Lewis (aka RiiDii)
`13 March 2005. Updated 14 March 2005
Sync On:Sync Rate 60:Autocam Off
Type Coordinates
   x as Float:y as Float:z as Float
Endtype
Global Object as Coordinates

Type Players
   Score as Integer:Color as String
Endtype

Type Choices
   ColorObject as Integer
   Sequence as Integer
   Mouse as Coordinates
   Count as Integer
EndType

Type AI_Stuff
   Choice as Choices
EndType

Global AI as AI_Stuff
Global ObjectSize as Float

Dim O_Color(36) as String:Dim Blast(36):Dim ObjectSeq(6,6):Dim Player(2) as Players:Global Phase as Byte
Create Bitmap 1,512,512:Set Current bitmap 1:Box 0,0,511,511,RGB(192,192,192),RGB(221,221,221),RGB(192,192,192),RGB(255,255,255):Get Image 2,0,0,511,511:Set Current Bitmap 0:Delete Bitmap 1
Make Object Cone 40,7.5:Make Object Cylinder 41,3:Make Mesh From Object 41,41:Add Limb 40,1,41:Delete Object 41:Delete Mesh 41:Offset Limb 40,0,0,4.5,0:Disable Object ZDepth 40:Set Object Cull 40,0
Make Camera 1:Color Backdrop 1,RGB(182,183,206):Set Camera to Image 1,1,512,512:Position Camera 1,0,0,200:Point Camera 1,0,0,0
Make Object Plain 42,200,150:Position Object 42,0,0,150:Texture Object 42,1:Set Object Cull 42,1:Turn Object Left 42,180:Set Object Emissive 42,RGB(110,110,110)
Set Bump Mapping On 42,2
Create Bitmap 1,200,40:Set Current Bitmap 1:Ink Rgb(0,0,255),0:Box 0,0,199,39:Ink Rgb(255,255,255),0:Center Text 99,14,"Player vs Player":Get Image 3,0,0,199,39
Ink Rgb(0,255,0),0:Box 0,0,199,39:Ink Rgb(255,255,255),0:Center Text 99,14,"Player vs AI":Get Image 4,0,0,199,39:Set Current Bitmap 0:Delete Bitmap 1

Do
 For i = 1 to 36
   If Object Exist(i) Then Delete Object i
 Next i
`Select mode: Player vs Player or Player vs AI
 Make Object Box 1,50,10,10
 Texture Object 1,3
 Make Object Box 2,50,10,10
 Texture Object 2,4
 Set Object Emissive 1,Rgb(25,25,75)
 Set Object Emissive 2,Rgb(25,75,25)
 Position Object 1,0,20,80
 Position Object 2,0,-20,80
 Hide Object 40
 Mode=0
 Show Mouse
 Do
   obj=Pick Object(Mousex(),MouseY(),1,2)
   If MouseClick()=1 Then Mode = obj
   If Mode>0 Then Exit
   If obj
      Pitch Object Up obj,1
   Else
      Rotate Object 1,0,0,0:Rotate Object 2,0,0,0
   Endif
   Sync
 Loop
 Delete Object 1:Delete Object 2
 Hide Mouse
 Show Object 40
 Sleep 1000
 If Mode=2 Then AI.Choice.ColorObject=0

 Player(1).Score=0:Player(2).Score=0

 b=1:For i =1 to 6:For j = 1 to 6:Make_Crystal(b):Position Object b,j*11-39,i*11-33,100:b=b+1:Next j:Next i

 Phase = 1 ` 1=Player 1 choose color. 2=Player 2 choose color. 3=Player 1 turn. 4=Player 2 turn
 ObjectSize=100

 csx=Screen Width()/2:csy=Screen Height()/2
 Do
    `Controls
    Offx=Mousex()-csx
    Offy=Mousey()-csy
    Select Phase
       Case 1
          Set Cursor 0,0:Print "Player 1 Select Color"
          ypos=Int(Offy/11)*-11
          xpos=Int(Offx/11)*11-7
          ypos=Min_Max(ypos,-22,33)
          xpos=Min_Max(xpos,-29,26)
          Rotate Object 40,0,0,45
          Position Object 40,xpos+5,ypos-5,100
          If Mouseclick()=1
             O=Pick Object(Object Screen X(40)-10,Object Screen Y(40)-10,1,36)
             Player(1).Color=O_Color(O)
             Phase = 2
          Endif
       Endcase
       Case 2
          Set Cursor 0,0:Print "Player 2 Select Color"
          If Mode=1
             ypos=Int(Offy/11)*-11
             xpos=Int(Offx/11)*11-7
             ypos=Min_Max(ypos,-22,33)
             xpos=Min_Max(xpos,-29,26)
             Rotate Object 40,0,0,45
             Position Object 40,xpos+5,ypos-5,100
             If Mouseclick()=1
                O=Pick Object(Object Screen X(40)-10,Object Screen Y(40)-10,1,36)
                Player(2).Color=O_Color(O)
                If Player(2).Color<>Player(1).Color
                   Phase = 4:Delay=9
                Else
                   Player(2).Color=""
                Endif
             Endif
          Else
            If AI.Choice.ColorObject=0
               AI.Choice.Sequence=1
               Do
                  AI.Choice.ColorObject=rnd(35)+1
                  If O_Color(AI.Choice.ColorObject)<>Player(1).Color Then Exit
               Loop
            Endif
            If AI.Choice.ColorObject=AI.Choice.Sequence
               Player(2).Color=O_Color(AI.Choice.ColorObject)
               AI.Choice.Count=AI.Choice.Count+1
               If AI.Choice.Count>10 Then Phase=4:Delay=9
            Else
               Return_Object(AI.Choice.Sequence)
               Position Object 40,Object.x+5,Object.y-5,Object.z
               If rnd(20)=1 then AI.Choice.Sequence=AI.Choice.Sequence+1
               AI.Choice.Count=0
            Endif
          Endif
       Endcase

 ` Play
       Case Default
          Set Cursor 0,0:Print "Turn: Player "; Phase-2
          If Phase=4 and Mode=2 And Delay=0
            If AI.Choice.Mouse.x=0 Or rnd(20)=1
               mx=(Rnd(Screen Width()-1)+Rnd(Screen Width()-1))/2
               my=(Rnd(Screen Height()-1)+Rnd(Screen Height()-1))/2
               AI.Choice.Mouse.x=mx
               AI.Choice.Mouse.y=my
            Endif
            Offx=AI.Choice.Mouse.x-csx
            Offy=AI.Choice.Mouse.y-csy
          Endif
          If abs(Offx)>Abs(Offy)
             ypos=Int(Offy/11)*-11
             ypos=Min_Max(ypos,-22,33)
             Position Object 40,40*((Offx>0)-(Offx<0)),ypos,100
             Rotate Object 40,0,0,90*((Offx<0)-(Offx>0))
          Else
             xpos=Int(Offx/11)*11-7
             xpos=Min_Max(xpos,-29,26)
             Position Object 40,xpos,40*((Offy<0)-(Offy>0))+5,100
             Rotate Object 40,0,0,180*(Offy>0)
          Endif
          If Mode=1 Or Phase=3
             If mouseclick()=1 And Click=0 And Delay=0
                Row=(Object Position Y(40)+33)/10
                Col=(Object Position X(40)+39)/10
                If Row=0 or Col=0 Then Click=-11 Else Click=11
                Delay=200
             Endif
          Else
            If rnd(50)=1 And Click=0 And Delay=0
                Row=(Object Position Y(40)+33)/10
                Col=(Object Position X(40)+39)/10
                If Row=0 or Col=0 Then Click=-11 Else Click=11
                Delay=200
            Endif
          Endif
       Endcase
    Endselect

    `Move crystals
    For i = 1 to 36
       Turn Object Right i,1
       OCol=(Object Position X(i)+39)/10
       ORow=(Object Position Y(i)+33)/10
       If Click<>0
          If Row=0 or Row=7
             If OCol=Col
                Rotate Object i,0,0,0
                Move Object Up i,((Click>0)-(Click<0))
             Endif
          Else
             If ORow=Row
                Rotate Object i,0,0,0
                Move Object Right i,((Click>0)-(Click<0))
             Endif
          Endif
       Else
          If Delay=199
             If OCol=0 Then Position Object i,6*11-39,Object Position Y(i),100:OCol=6
             If OCol=7 Then Position Object i,1*11-39,Object Position Y(i),100:OCol=1
             If ORow=0 Then Position Object i,Object Position X(i),6*11-33,100:ORow=6
             If ORow=7 Then Position Object i,Object Position X(i),1*11-33,100:ORow=1
             ObjectSeq(OCol,ORow)=i
          Endif
       Endif
    Next i
    L=0
    Select Delay
       Case 1
          L=Check_Elim()
       EndCase
       Case 2:If Phase=3 Then Phase=4 Else Phase=3
       Endcase
       Case 3:ObjectSize=100:Endcase
       Case 190:Check_Diag_Down():EndCase
       Case 192:Check_Diag_Up():EndCase
       Case 194:Check_Vertical():EndCase
       Case 196:Check_Horizontal():EndCase
       Case Default
          If Delay>10 And Delay<190
             BlastEm()
          Endif
       Endcase
    Endselect
    If Click<>0 Then Click=Click-(Click>0)+(Click<0) Else IF Delay>0 Then Delay=Delay-1
    Set Cursor 0,50
    Print "Player 1 Color: "; Player(1).Color;""
    Print "Player 2 Color: "; Player(2).Color;""
    Print ""
    Print "Player 1 Score: "; Player(1).Score
    Print "Player 2 Score: "; Player(2).Score
    Sync
    If L<>0 Then Exit
 Loop
 W=3-L
 Player(W).Score=Player(W).Score+100
 Win=((Player(2).Score>Player(1).Score)+1)*(Player(2).Score<>Player(1).Score)
 If Win
    Center Text Screen Width()/2,0,"Player "+str$(Win)+" has Won!"
 Else
    Center Text Screen Width()/2,0,"It's a TIE!"
 EndIf
 Set Cursor 0,50
 Print "Player 1 Color: "; Player(1).Color;""
 Print "Player 2 Color: "; Player(2).Color;""
 Print ""
 Print "Player 1 Score: "; Player(1).Score
 Print "Player 2 Score: "; Player(2).Score
 Center Text Screen Width()/2,24,"Press 'N' to quit, or any key to Play Again!"
 Sync
 Wait key
 If Lower$(Inkey$())="n" Then End
Loop

Function Make_Crystal(ObjectID)
   Make Object Sphere ObjectID,10,3,4
   Color=Rnd(5)
   Restore Colors
   For c = 0 to Color
      Read O_Color(ObjectID),cr,cg,cb,er,eg,eb
   Next c
   Color Object ObjectID,rgb(cr,cg,cb)
   Set Object Emissive ObjectID,rgb(er,eg,eb)
   Set Alpha Mapping On ObjectID,80
   Set Object Cull ObjectID,0
   Blast(ObjectID)=0
Endfunction

Function Check_Horizontal()
Dim clrs(2) as String
For i = 1 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Vertical()
Dim clrs(2) as String
For i = 1 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(j+test,i))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(j+test,i))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Diag_Up()
Dim clrs(2) as String
For i = 1 to 4
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i+test,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i+test,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function Check_Diag_Down()
Dim clrs(2) as String
For i = 3 to 6
   For j =1 to 4
      For test = 0 to 2
         clrs(test)=O_Color(ObjectSeq(i-test,j+test))
      Next test
      If clrs(0)=clrs(1) and clrs(1)=clrs(2)
         Plyr=Phase-2
         Oplyr=-Plyr+3
         If clrs(0)<>Player(Oplyr).Color
            For test=0 to 2
               Blast(ObjectSeq(i-test,j+test))=1
            Next test
         Endif
      Endif
   Next j
Next i
Endfunction

Function BlastEm()
   ObjectSize=ObjectSize-.6
   For i = 1 to 36
      If Blast(i)=1
         Scale Object i,ObjectSize,ObjectSize,ObjectSize
         Return_Object(i)
         If Particles Exist(i)=0
            Make Particles i,0,100,20
            Position Particles i,Object.x,Object.y,Object.z
            Set Particle Floor i,0
            Set Particle Gravity i,2
            Color Particles i,255,50,50
         Endif
         If Object Size(i)<2.0
            If O_Color(i)=Player(Phase-2).Color Then Player(Phase-2).Score=Player(Phase-2).Score+10
            Delete Object i
            Make_Crystal(i)
            Position Object i,Object.x,Object.y,Object.z
            Delete Particles i
         Endif
      Endif
   Next i
EndFunction

Function Check_Elim()
   c1=0:c2=0
   For i = 1 to 36
      If O_Color(i)=Player(1).Color then c1=c1+1
      If O_Color(i)=Player(2).Color then c2=c2+1
   Next i
Lose=0
If c1<3 Then Lose=1
If c2<3 Then Lose=2
EndFunction Lose

Function Min_Max(Var1,Min,Max)
If Var1<Min then Var1=Min Else If Var1>Max Then Var1=Max
Endfunction Var1

Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Colors:
Data "White",255,255,255,100,100,100,"Red",255,0,0,100,0,0,"Blue",0,0,255,0,0,06,"Green",0,255,0,0,100,0,"Yellow",255,255,0,100,100,0,"Pink",248,86,248,88,0,88

Function Make_Robot(ObjectID)
If Object Exist (ObjectID) Then Delete Object ObjectID
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
Color Object ObjectID,Robot.Color
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,100,20
Set Current Bitmap 1
Ink RGB(210,210,210),0
Box 0,0,99,19
Ink Rgb(40,40,40),0
For i = 0 to 90 step 10
   Box i,0,i+1,19
Next i
Get Image 1,0,0,99,19
Delete Bitmap 1
Texture Limb ObjectID,4,1
Texture Limb ObjectID,5,1
Set Object Collision Off ObjectID
Set Object Collision to Boxes ObjectID
EndFunction R

Data 5, 5
Data 2, 1, 7, 4, 1
Data 4, 4, 7, 4, 3
Data 7, 9, 9, 4, 1
Data 1, 1, 1, 1, 1
Data 1, 1, 1, 1, 1
Data 6
Data 5, 2, 2, 2, 4, 2

`  Objects:
`  1  = Grey square
`  2  = Blue square (start)
`  3  = Green square (end)
`  4  = Black square
`  5  = Red square (Rotates RIGHT)
`  6  = Yellow square (WALL)
`  7  = Purple (Rotates to the upper left)
`  8  = Purple (Rotates to the lower right)
`  9  = Purple (rotates lower left)
`  10 = Purple (Rotates upper right)
`  11 = Red Square (Rotates LEFT)

`  Moves:
`  1  = "Forward 1"
`  2  = "Forward 2"
`  3  = "Forward 3"
`  4  = "Rotate Left"
`  5  = "Rotate Right"
`  6  = "Rotate 180"
`  7  = "Backward 1"

Data 5, 5            `DIMENSIONS OF LEVEL: Can be any amount. The first is Width and the Second... HEIGHT.

Data 2, 1, 7, 4, 1   `The next 5 (HEIGHT) lines contain the objects of the level
Data 4, 4, 7, 4, 3   `The levels are reversed vertically when it renders. I am lazy therefore.
Data 7, 9, 9, 4, 1
Data 1, 1, 1, 1, 1
Data 1, 1, 1, 1, 1

Data 7               `Number of possible moves
Data 5, 2, 2, 2, 4, 5, 3      `Then the list of moves.

`************** DiNGo DaNGo
`***************** By Jimmy

SYNC ON : SYNC RATE 40 : HIDE MOUSE

DIM Moves(8) as String

Moves(0) = ""
Moves(1) = "Forward 1"
Moves(2) = "Forward 2"
Moves(3) = "Forward 3"
Moves(4) = "Rotate Left"
Moves(5) = "Rotate Right"
Moves(6) = "Rotate 180"
Moves(7) = "Backward 1"


scrW = SCREEN WIDTH()

Make_Robot(100)
SCALE OBJECT 100, 50, 50, 50
INK RGB(255, 255, 255), RGB(0, 0, 0)

MAKE OBJECT CUBE 1, 5
COLOR OBJECT 1, RGB(100, 100, 100)

MAKE OBJECT CUBE 2, 5
COLOR OBJECT 2, RGB(0, 0, 200)

MAKE OBJECT CUBE 3, 5
COLOR OBJECT 3, RGB(0, 200, 0)

MAKE OBJECT CUBE 4, 5
COLOR OBJECT 4, RGB(0, 0, 0)

MAKE OBJECT CUBE 5, 5
COLOR OBJECT 5, RGB(255, 0, 0)

MAKE OBJECT CUBE 6, 3
COLOR OBJECT 6, RGB(255, 255, 0)

MAKE OBJECT CUBE 7, 5
COLOR OBJECT 7, RGB(255, 0, 255)

FOR i=1 TO 7
   HIDE OBJECT i
NEXT i

`MAKE OBJECT SPHERE 100, 4
`COLOR OBJECT 100, RGB(255, 255, 0)
MAKE OBJECT CONE 101, 2
COLOR OBJECT 101, RGB(255, 155, 0)
HIDE OBJECT 101

CurLevel = 0

NEWLEVEL:

GOSUB LoadNextLevel

RESTART:

PPosX# = blueJ*5.4
PPosZ# = blueI*5.4
PAng# = 0
OAng# = 0
CamHeight# = 15.0
curMove = 0
POSITION CAMERA 0, CamHeight#, 0
POINT CAMERA (levW*5.4)/2, 0, (levH*5.4)/2
DO
   `CONTROL CAMERA USING ARROWKEYS 0, 1, 1
   POSITION OBJECT 100, PPosX#, 2, PPosZ#
   POSITION OBJECT 101, PPosX#, 2, PPosZ#
   YROTATE OBJECT 100, PAng#
   ROTATE OBJECT 101, 0, 0, 0
   YROTATE OBJECT 101, PAng#
   MOVE OBJECT 101, 2.5
   XROTATE OBJECT 101, 90

   TEXT 5, 5, "Available Moves"
   FOR i = 1 TO numMoves
      TEXT 5, i*10+10, CHR$(96+i)+": "+Moves(levelMoves(i))
   NEXT i
   TEXT scrW-140, 5, "Queued UP Moves"
   FOR i = 1 TO numQMoves
      IF i = (CurMove-1) THEN INK RGB(255, 255, 0), RGB(0, 0, 0)
      TEXT scrW-140, i*10+10, CHR$(64+i)+": "+Moves(qMoves(i))
      INK RGB(255, 255, 255), RGB(0, 0, 0)
   NEXT i


   OAng# = WRAPVALUE(OAng#+2.0)

   FOR i = 1 TO levH
      FOR j = 1 TO levW
         obj = level(i, j)
         IF obj = 5 THEN YROTATE OBJECT levelObj(i, j), OAng#
         IF obj = 11 THEN YROTATE OBJECT levelObj(i, j), OAng#*-1
         IF obj = 7 THEN XROTATE OBJECT levelObj(i, j), OAng#
         IF obj = 8 THEN XROTATE OBJECT levelObj(i, j), OAng#*-1
         IF obj = 9 THEN ZROTATE OBJECT levelObj(i, j), OAng#
         IF obj = 10 THEN ZROTATE OBJECT levelObj(i, j), OAng#*-1
      NEXT j
   NEXT i


         GOSUB GetCurSquare
         `GOSUB GetNextSquare
         `GOSUB GetPrevSquare

   IF Running = 1
      IF Stopped = 1
         ConvAng# = PAng#
         pI = PPosZ# / 5.4
         pJ = PPosX# / 5.4
         GOSUB GetCurSquare
         GOSUB GetNextSquare
         GOSUB GetPrevSquare

         tSquare = curSquare
         IF Action = 0
            IF OnConvey = 1 THEN Action = 0 : curSquare = 0 : OnConvey = 0
            IF curSquare > 6 AND curSquare < 11 AND OnConvey = 0
               IF curSquare = 7 THEN ConvAng# = 0
               IF curSquare = 8 THEN ConvAng# = 180
               IF curSquare = 9 THEN ConvAng# = 270
               IF curSquare = 10 THEN ConvAng# = 90
               GOSUB GetNextSquare
               GOSUB GetPrevSquare
               Action = 1
               OnConvey = 1
            ENDIF
            IF OnRotator = 1 THEN Action = 0 : curSquare = 0 : OnRotator = 0
            IF curSquare = 5 THEN OnRotator = 1 : Action = 5
            IF curSquare = 11 THEN OnRotator = 1 : Action = 4
         ENDIF
         IF Action = 0 AND curMove > numQMoves
            IF tSquare = 3
               GOSUB UnloadLevel
               GOSUB NEWLEVEL
            ELSE
               GOSUB GameOver
            ENDIF
         ENDIF
         IF Action = 0 THEN Action = qMoves(curMove) : INC curMove
         Stopped = 0
         Movement# = 0
      ELSE
         IF Action > 0 AND Action < 4 OR Action = 7
            Tread# = 0.0
            IF Action <> 7 AND nextSquare <> 6 THEN YROTATE OBJECT 100, ConvAng# : MOVE OBJECT 100, 0.1 : YROTATE OBJECT 100, PAng# : Tread# = -0.01
            IF Action <> 7 AND nextSquare = 6 AND OnConvey = 0 THEN Action = 1 : Movement# = 5.4
            IF Action = 7 AND prevSquare <> 6 THEN YROTATE OBJECT 100, ConvAng# : MOVE OBJECT 100, -0.1 : YROTATE OBJECT 100, PAng# : Tread# = 0.01
            IF Action = 7 AND prevSquare = 6 AND OnConvey = 0 THEN Movement# = 5.4
            INC Movement#, 0.1
            IF OnConvey = 0
               SCROLL LIMB TEXTURE 100, 4, Tread#, 0
               SCROLL LIMB TEXTURE 100, 5, Tread#, 0
            ENDIF
            IF Movement# >= 5.3
               Stopped = 1
               DEC Action
               ConvAng# = 0
               IF Action = 6 THEN Action = 0
               IF curSquare = 0 OR curSquare = 4
                  GOSUB GameOver
               ENDIF
            ENDIF
         ENDIF
         IF Action = 4 OR Action = 5
            IF Action = 4
               PAng# = OBJECT ANGLE Y(100)-2
               IF OnRotator = 0
                  SCROLL LIMB TEXTURE 100, 4, -0.01, 0
                  SCROLL LIMB TEXTURE 100, 5, 0.01, 0
               ENDIF
            ENDIF
            IF Action = 5
               PAng# = OBJECT ANGLE Y(100)+2
               IF OnRotator = 0
                  SCROLL LIMB TEXTURE 100, 4, 0.01, 0
                  SCROLL LIMB TEXTURE 100, 5, -0.01, 0
               ENDIF
            ENDIF
            YROTATE OBJECT 100, PAng#
            INC Movement#, 2.0
            IF Movement# >= 90.0
               Stopped = 1
               Action = 0
            ENDIF
         ENDIF
         IF Action = 6
            PAng# = OBJECT ANGLE Y(100)+2
            YROTATE OBJECT 100, PAng#
            SCROLL LIMB TEXTURE 100, 4, 0.01, 0
            SCROLL LIMB TEXTURE 100, 5, -0.01, 0
            INC Movement#, 2.0
            IF Movement# >= 180.0
               Stopped = 1
               Action = 0
            ENDIF
         ENDIF
         PPosX# = OBJECT POSITION X(100)
         PPosZ# = OBJECT POSITION Z(100)
         pI = PPosZ# / 5.4
         pJ = PPosX# / 5.4
      ENDIF
   ELSE
      POSITION CAMERA 0, CamHeight#, 0
      POINT CAMERA (levW*5.4)/2, 0, (levH*5.4)/2
      IF KEYSTATE(203) = 1 AND leftDown = 0
         PAng# = WRAPVALUE(PAng#-90)
         leftDown = 1
      ENDIF
      IF KEYSTATE(203) = 0 AND leftDown = 1 THEN leftDown = 0

      IF KEYSTATE(205) = 1 AND rightDown = 0
         PAng# = WRAPVALUE(PAng#+90)
         rightDown = 1
      ENDIF
      IF KEYSTATE(205) = 0 AND rightDown = 1 THEN rightDown = 0

      IF KEYSTATE(200) = 1 AND CamHeight# > 5 THEN DEC CamHeight#, 0.5
      IF KEYSTATE(208) = 1 AND CamHeight# < 75 THEN INC CamHeight#, 0.5
      CENTER TEXT scrW/2, 10, "DiNGo DaNGo!!"
      CENTER TEXT scrW/2, 21, "LEVEL: "+STR$(CurLevel)
      CENTER TEXT scrW/2, 40, "HOLD TAB TO VIEW INSTRUCTIONS"

      IF KEYSTATE(15) = 1
         INK RGB(0, 0, 0), RGB(0, 0, 0)
         BOX 97, 103, 545, 320
         INK RGB(255, 255, 255), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 110, "GRAY SQUARES ARE PLATFORMS - OK FOR DINGO"
         INK RGB(255, 0, 0), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 121, "RED SQUARES TURN YOU 90 DEG. IN THE DIR. THEY SPIN"
         INK RGB(255, 0, 255), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 132, "PURPLE SQUARES PUSH YOU 1 SPACE IN THE DIR. THEY SPIN"
         INK RGB(255, 255, 0), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 143, "YELLOW SQUARES SCARE DINGO, HE WILL NOT MOVE ONTO THEM"
         INK RGB(115, 115, 115), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 154, "BLACK SQUARES ARE PITS OF DEATH. GAME OVER."
         INK RGB(255, 255, 255), RGB(0, 0, 0)
         CENTER TEXT scrW/2, 170, "OBJECT: GO FROM BLUE SQUARE TO GREEN SQUARE WITH THE"
         CENTER TEXT scrW/2, 181, "GIVEN MOVES. YOU MAY NEED ALL, YOU MAY NOT"
         CENTER TEXT scrW/2, 210, "USE LEFT-RIGHT ARROW KEYS TO CHOOSE STARTING DIRECTION"
         CENTER TEXT scrW/2, 221, "UP-DOWN ARROW KEYS MOVE THE CAMERA IN AND OUT"
         CENTER TEXT scrW/2, 240, "QUEUE UP YOUR DESIRED MOVES WITH THE CORRESPONDING"
         CENTER TEXT scrW/2, 251, "LETTER ON THE KEYBOARD."
         CENTER TEXT scrW/2, 270, "TO DELETE FROM THE QUEUE, HOLD SHIFT AND USE TEH"
         CENTER TEXT scrW/2, 281, "CAPITALS."
         CENTER TEXT scrW/2, 300, "PRESS SPACE WHEN YOU ARE READY TO DIE."
      ENDIF
      Key = KeyToInt(INKEY$())
      IF Key <> 0 AND KeyDown = 0
         IF Key < 101 AND Key <= numMoves AND levelMoves(Key) <> 0
            INC numQMoves
            qMoves(numQMoves) = levelMoves(Key)
            qMoveKeys(numQMoves) = Key
            levelMoves(Key) = 0
         ENDIF

         IF Key > 100
            Key = Key - 100
            IF Key <= numQMoves AND qMoves(Key) <> 0
               DEC numQMoves
               levelMoves(qMoveKeys(Key)) = qMoves(Key)
               qMoves(Key) = 0
               qMoveKeys(Key) = 0
               FOR i = Key TO numQMoves
                  qMoves(i) = qMoves(i+1)
                  qMoveKeys(i) = qMoveKeys(i+1)
               NEXT i
            ENDIF
         ENDIF
         KeyDown = 1
      ENDIF
      IF Key = 0 AND KeyDown = 1 THEN KeyDown = 0

      IF KEYSTATE(57) = 1 AND SpaceDown = 0
         Running = 1
         curMove = 1
         Stopped = 1
         SpaceDown = 1
      ENDIF
      IF KEYSTATE(57) = 0 AND SpaceDown = 1 THEN SpaceDown = 0
   ENDIF

   `TEXT 5, 200, STR$(nextSquare)+":"+STR$(curSquare)+":"+STR$(prevSquare)
   `TEXT 5, 211, STR$(pNextI)+","+STR$(pNextJ)
   `TEXT 5, 222, STR$(pI)+","+STR$(pJ)
   `TEXT 5, 233, STR$(pPrevI)+","+STR$(pPrevJ)
   SYNC
LOOP


UnloadLevel:
   Running = 0
   FOR i = 1 TO levH
      FOR j = 1 to levW
         DELETE OBJECT levelObj(i, j)
      NEXT j
   NEXT i
   UNDIM level(levW, levH)
   UNDIM levelObj(levW, levH)
   UNDIM levelMoves(numMoves)
RETURN

LoadNextLevel:
   READ levW
   READ levH
   DIM level(levW, levH)
   DIM levelObj(levW, levH)
   INC CurLevel
   FOR i = 1 TO levH
      FOR j = 1 to levW
         READ level(i, j)
         IF level(i, j) = 2
            blueI = i
            blueJ = j
         ENDIF
         levelObj(i, j) = FreeObject()
         IF level(i, j) > 6 AND level(i, j) < 11
            CLONE OBJECT levelObj(i, j), 7
         ELSE
            IF level(i, j) = 11
               CLONE OBJECT levelObj(i, j), 5
            ELSE
               CLONE OBJECT levelObj(i, j), level(i, j)
            ENDIF
         ENDIF
         POSITION OBJECT levelObj(i, j), j*5.4, -2.5, i*5.4
      NEXT j
   NEXT i

   READ numMoves
   DIM levelMoves(numMoves)
   DIM qMoves(numMoves)
   DIM qMoveKeys(numMoves)
   numQMoves = 0
   FOR i = 1 to numMoves
      READ levelMoves(i)
   NEXT i
RETURN

GetNextSquare:
   YROTATE OBJECT 100, ConvAng#
   remstart Space# = 5.4
   MOVE OBJECT 100, 5.42
   oZ# = OBJECT POSITION Z(100)
   oX# = OBJECT POSITION X(100)
   pNextI = oZ# / Space#
   TEXT 5, 250, STR$(OBJECT POSITION Z(100))
   TEXT 5, 261, STR$(OBJECT POSITION X(100))
   TEXT 5, 272, STR$(OBJECT ANGLE Y(100))
   pNextJ = oX# / Space#
   MOVE OBJECT 100, -5.42
   remend
   pNextI = pI
   pNextJ = pJ
   IF ConvAng# = 0 THEN pNextI = pI + 1
   IF ConvAng# = 90 THEN pNextJ = pJ + 1
   IF ConvAng# = 180 THEN pNextI = pI - 1
   IF ConvAng# = 270 THEN pNextJ = pJ - 1
   YROTATE OBJECT 100, PAng#
   IF pNextI > levW OR pNextJ > levH OR pNextI < 1 OR pNextJ < 1
      nextSquare = 0
      RETURN
   ENDIF
   nextSquare = level(pNextI, pNextJ)
RETURN

GetCurSquare:
   pI = (OBJECT POSITION Z(100)) / 5.3
   pJ = (OBJECT POSITION X(100)) / 5.3
   `TEXT 5, 250, STR$(OBJECT POSITION Z(100))
   `TEXT 5, 261, STR$(OBJECT POSITION X(100))
   IF pI > levW OR pJ > levH OR pI < 1 OR pJ < 1
      curSquare = 0
      RETURN
   ENDIF
   curSquare = level(pI, pJ)
RETURN

GetPrevSquare:
   YROTATE OBJECT 100, ConvAng#
   REMSTART
   MOVE OBJECT 100, -5.41
   pPrevI = OBJECT POSITION Z(100) / 5.40000
   pPrevJ = OBJECT POSITION X(100) / 5.40000
   MOVE OBJECT 100, 5.41
   REMEND
   pPrevI = pI
   pPrevJ = pJ
   IF ConvAng# = 0 THEN pPrevI = pI - 1
   IF ConvAng# = 90 THEN pPrevJ = pJ - 1
   IF ConvAng# = 180 THEN pPrevI = pI + 1
   IF ConvAng# = 270 THEN pPrevJ = pJ + 1
   YROTATE OBJECT 100, PAng#
   IF pPrevI > levW OR pPrevJ > levH OR pPrevI < 1 OR pPrevJ < 1
      prevSquare = 0
      RETURN
   ENDIF
   prevSquare = level(pPrevI, pPrevJ)
RETURN

GameOver:
   SpaceDown = 1
   Running = 0
   Action = 0
   Stopped = 0
   Movement# = 0.0
   FOR Key = 1 TO numQMoves
      IF Key <= numQMoves AND qMoves(Key) <> 0
         levelMoves(qMoveKeys(Key)) = qMoves(Key)
         qMoves(Key) = 0
         qMoveKeys(Key) = 0
      ENDIF
   NEXT Key
   numQMoves = 0
   DO
      CENTER TEXT scrW/2, 25, "YOU FAILED. PRESS SPACE TO TRY AGAIN OR ESC TO QUIT."
      IF KEYSTATE(57) = 1 AND SpaceDown = 0 THEN SpaceDown = 1 : GOSUB RESTART
      IF KEYSTATE(57) = 0 AND SpaceDown = 1 THEN SpaceDown = 0
      SYNC
   LOOP
RETURN

FUNCTION FreeObject()
   FOR i = 1 TO 65535
      IF OBJECT EXIST(i) = 0 THEN EXITFUNCTION i
   NEXT i
ENDFUNCTION -1

FUNCTION KeyToInt(K as String)
   iKey = ASC(K)
   IF iKey > 96 AND iKey < 123
      EXITFUNCTION iKey - 96
   ENDIF

   IF iKey > 64 AND iKey < 97
      EXITFUNCTION iKey + 36
   ENDIF
ENDFUNCTION 0

Function Make_Robot(ObjectID)
If Object Exist (ObjectID) Then Delete Object ObjectID
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
Color Object ObjectID, RGB(255, 255, 0) `Robot.Color
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,100,20
Set Current Bitmap 1
Ink RGB(210,210,210),0
Box 0,0,99,19
Ink Rgb(40,40,40),0
For i = 0 to 90 step 10
   Box i,0,i+1,19
Next i
Get Image 1,0,0,99,19
Delete Bitmap 1
Texture Limb ObjectID,4,1
Texture Limb ObjectID,5,1
Set Object Collision Off ObjectID
Set Object Collision to Boxes ObjectID
EndFunction R

DATA 5, 5
DATA 2, 1, 5, 1, 1
DATA 1, 6, 1, 6, 1
DATA 1, 6, 3, 6, 1
DATA 1, 1, 6, 1, 1
DATA 1, 1, 1, 1, 1
DATA 6
DATA 1, 1, 4, 5, 6, 2

DATA 5, 5
DATA 1, 1, 1, 1, 1
DATA 1, 6, 1, 6, 5
DATA 1, 6, 2, 6, 11
DATA 1, 6, 6, 6, 5
DATA 1, 1, 1, 1, 3
DATA 9
DATA 6, 2, 6, 2, 1, 2, 4, 1, 4

`  Objects:
`  1  = Grey square
`  2  = Blue square (start)
`  3  = Green square (end)
`  4  = Black square
`  5  = Red square (Rotates RIGHT)
`  6  = Yellow square (WALL)
`  7  = Purple (Rotates to the upper left)
`  8  = Purple (Rotates to the lower right)
`  9  = Purple (rotates lower left)
`  10 = Purple (Rotates upper right)
`  11 = Red Square (Rotates LEFT)

`  Moves:
`  1  = "Forward 1"
`  2  = "Forward 2"
`  3  = "Forward 3"
`  4  = "Rotate Left"
`  5  = "Rotate Right"
`  6  = "Rotate 180"
`  7  = "Backward 1"

Data 5, 5            `DIMENSIONS OF LEVEL: Can be any amount. The first is Width and the Second... HEIGHT.

Data 2, 1, 7, 4, 1   `The next 5 (HEIGHT) lines contain the objects of the level
Data 4, 4, 7, 4, 3   `The levels are reversed vertically when it renders. I am lazy therefore.
Data 7, 9, 9, 4, 1
Data 1, 1, 1, 1, 1
Data 1, 1, 1, 1, 1

Data 7               `Number of possible moves
Data 5, 2, 2, 2, 4, 5, 3      `Then the list of moves.